| Pakiet | fl.managers |
| Klasa | public class StyleManager |
| Dziedziczenie | StyleManager  Object |
| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Właściwości publiczne
Ukryj dziedziczone właściwości publiczne
Pokaż dziedziczone właściwości publiczneMetody publiczne
| Metoda | Zdefiniowane przez | ||
|---|---|---|---|
Tworzy nowy obiekt StyleManager. | StyleManager | ||
[statyczny]
Usuwa styl z określonego składnika. | StyleManager | ||
[statyczny]
Usuwa globalny styl ze wszystkich składników interfejsu użytkownika w dokumencie. | StyleManager | ||
[statyczny]
Pobiera styl związany z konkretnym składnikiem. | StyleManager | ||
[statyczny]
Pobiera styl globalny na podstawie nazwy. | StyleManager | ||
 |
Wskazuje, czy dla obiektu zdefiniowano określoną właściwość. | Object | |
|
Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr. | Object | |
|
Wskazuje, czy określona właściwość istnieje i jest przeliczalna. | Object | |
[statyczny]
Rejestruje instancję składnika w menedżerze stylów. | StyleManager | ||
[statyczny]
Ustawia styl wszystkich wystąpień typu składnika, na przykład wszystkich wystąpień składnika Button lub ComboBox. | StyleManager | ||
|
Ustawia dostępność właściwości dynamicznej używanej w pętlach. | Object | |
[statyczny]
Ustawia globalny styl wszystkich składników interfejsu użytkownika w dokumencie. | StyleManager | ||
|
Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych. | Object | |
|
Zwraca ciąg reprezentujący określony obiekt. | Object | |
|
Zwraca pierwotną wartość dla określonego obiektu. | Object | |
Konstruktor Szczegół
StyleManager | () | Konstruktor |
public function StyleManager()| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Tworzy nowy obiekt StyleManager.
Szczegół metody
clearComponentStyle | () | metoda |
public static function clearComponentStyle(component:Object, name:String):void| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Usuwa styl z określonego składnika.
Parametry
component:Object — Nazwa składnika, z którego ma być usunięty styl.
| |
name:String — Nazwa stylu do usunięcia.
|
Powiązane elementy interfejsu API
clearStyle | () | metoda |
public static function clearStyle(name:String):void| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Usuwa globalny styl ze wszystkich składników interfejsu użytkownika w dokumencie.
Parametry
name:String — Nazwa stylu globalnego do usunięcia.
|
Powiązane elementy interfejsu API
getComponentStyle | () | metoda |
public static function getComponentStyle(component:Object, name:String):Object| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Pobiera styl związany z konkretnym składnikiem.
Parametry
component:Object — Nazwa instancji składnika, w której należy znaleźć żądany styl.
| |
name:String — Nazwa pobieranego stylu.
|
Object — Żądany styl z określonego składnika. Ta funkcja zwraca wartość null, jeśli określony styl nie zostanie znaleziony.
|
Powiązane elementy interfejsu API
getStyle | () | metoda |
public static function getStyle(name:String):Object| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Pobiera styl globalny na podstawie nazwy.
Parametry
name:String — Nazwa pobieranego stylu.
|
Object — Pobrana wartość stylu globalnego.
|
Powiązane elementy interfejsu API
registerInstance | () | metoda |
public static function registerInstance(instance:UIComponent):void| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Rejestruje instancję składnika w menedżerze stylów. Po utworzeniu instancji składnika może ona zarejestrować się w menedżerze stylów, aby otrzymywać powiadomienia o zmianach stylu. Instancje składników mogą rejestrować się w celu otrzymywania powiadomień o zmianach stylu dotyczących konkretnego składnika lub obowiązujących globalnie.
Parametry
instance:UIComponent — Instancja składnika, która ma być zarejestrowana na potrzeby zarządzania stylami.
|
setComponentStyle | () | metoda |
public static function setComponentStyle(component:Object, name:String, style:Object):void| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Ustawia styl wszystkich instancji składnika, np. wszystkich instancji składnika Button (przycisk) lub wszystkich instancji składnika ComboBox (lista kombinowana).
Parametry
component:Object — Typ składnika, na przykład Button lub ComboBox. Jako ten parametr można także przekazać instancję składnika lub klasy, która identyfikuje wszystkie instancje typu składnika.
| |
name:String — Nazwa ustawianego stylu.
| |
style:Object — Obiekt stylu opisujący styl, który ma być ustawiony.
|
Powiązane elementy interfejsu API
setStyle | () | metoda |
public static function setStyle(name:String, style:Object):void| Wersja języka: | ActionScript 3.0 |
| Wersja produktu: | Flash CS3 |
| Wersje środowiska wykonawczego: | Flash Player 9.0.28.0, AIR 1.0 |
Ustawia globalny styl wszystkich składników interfejsu użytkownika w dokumencie.
Parametry
name:String — Wartość typu String określająca nazwę ustawianego stylu.
| |
style:Object — Obiekt stylu do ustawienia. Wartość tej właściwości zależy od stylu ustawionego przez użytkownika. Na przykład jeśli styl jest ustawiony na "textFormat", właściwości style należy przypisać obiekt TextFormat. Niezgodność między nazwą stylu a wartością właściwości style może spowodować nieprawidłowe zachowanie składnika.
|
Powiązane elementy interfejsu API
Przykłady Sposób korzystania z tego przykładu
StyleManagerExample.as
Niniejszy przykład ilustruje sposób dynamicznego tworzenia składnika DataGrid i wykrywania jego zdarzeń.
W celu uruchomienia przykładu należy wykonać poniższe czynności:
- Dodaj składniki DataGrid, Button, Label i TextArea do biblioteki.
- Zapisz ten kod pod nazwą StyleManagerExample.as w tym samym katalogu, co plik FLA.
- W pliku FLA ustaw klasę dokumentu na StyleManagerExample.
package
{
import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.Label;
import fl.controls.TextArea;
import fl.core.UIComponent;
import fl.managers.FocusManager;
import fl.managers.StyleManager;
import flash.display.InteractiveObject;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
public class StyleManagerExample extends Sprite
{
private var btn:Button;
private var ta1:TextArea;
private var ta2:TextArea;
private var ta3:TextArea;
private var ta4:TextArea;
private var description:Label;
private var dg:DataGrid;
private var formatForInstance:TextFormat;
private var formatForGlobal:TextFormat;
private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
public function StyleManagerExample() {
setupComponents();
setupUI();
setupStyles();
}
private function setupUI():void {
var setInstanceStyleBtn:Button = new Button();
var clearInstanceStyleBtn:Button = new Button();
var setClassStyleBtn:Button = new Button();
var clearClassStyleBtn:Button = new Button();
var setGlobalStyleBtn:Button = new Button();
var clearGlobalStyleBtn:Button = new Button();
setInstanceStyleBtn.label = "Set Instance Style";
clearInstanceStyleBtn.label = "Clear Instance Style";
setClassStyleBtn.label = "Set Class Style";
clearClassStyleBtn.label = "Clear Class Style";
setGlobalStyleBtn.label = "Set Global Style";
clearGlobalStyleBtn.label = "Clear Global Style";
setInstanceStyleBtn.focusEnabled = false;
clearInstanceStyleBtn.focusEnabled = false;
setClassStyleBtn.focusEnabled = false;
clearClassStyleBtn.focusEnabled = false;
setGlobalStyleBtn.focusEnabled = false;
clearGlobalStyleBtn.focusEnabled = false;
setInstanceStyleBtn.move(10,310);
clearInstanceStyleBtn.move(10,340);
setClassStyleBtn.move(140,310);
clearClassStyleBtn.move(140,340);
setGlobalStyleBtn.move(270,310);
clearGlobalStyleBtn.move(270,340);
setInstanceStyleBtn.setSize(120,24);
clearInstanceStyleBtn.setSize(120,24);
setClassStyleBtn.setSize(120,24);
clearClassStyleBtn.setSize(120,24);
setGlobalStyleBtn.setSize(120,24);
clearGlobalStyleBtn.setSize(120,24);
setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);
description = new Label();
description.move(10, 370);
description.autoSize = TextFieldAutoSize.LEFT;
description.text = "";
addChild(setInstanceStyleBtn);
addChild(clearInstanceStyleBtn);
addChild(setClassStyleBtn);
addChild(clearClassStyleBtn);
addChild(setGlobalStyleBtn);
addChild(clearGlobalStyleBtn);
addChild(description);
}
private function setupComponents():void {
dg = new DataGrid();
dg.addItem( { Name:"John Alpha", Number:"555-123-0101" } );
dg.addItem( { Name:"Mary Bravo", Number:"555-372-3322" } );
dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
dg.addItem( { Name:"Susan Delta", Number:"555-987-3434" } );
dg.move(10,10);
dg.setSize(200,290);
dg.columns = ["Name","Number"];
addChild(dg);
ta1 = new TextArea();
ta1.move(220,10);
ta1.setSize(150,140);
ta1.text = testString;
ta1.tabEnabled = true;
addChild(ta1);
ta2 = new TextArea();
ta2.move(380,10);
ta2.setSize(150,140);
ta2.text = testString;
ta2.tabEnabled = true;
addChild(ta2);
ta3 = new TextArea();
ta3.move(220,160);
ta3.setSize(150,140);
ta3.text = testString;
ta3.tabEnabled = true;
addChild(ta3);
ta4 = new TextArea();
ta4.move(380,160);
ta4.setSize(150,140);
ta4.text = testString;
ta4.tabEnabled = true;
addChild(ta4);
}
private function setupStyles():void {
formatForGlobal = new TextFormat();
formatForGlobal.font = "Georgia";
formatForGlobal.size = 10;
formatForInstance = new TextFormat();
formatForInstance.underline = true;
}
private function setInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.setStyle("textFormat",formatForInstance);
description.text = "The TextArea object with focus is now underlined.";
}
}
private function clearInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.clearStyle("textFormat");
description.text = "The TextArea object with focus is no longer underlined.";
}
}
private function setClassStyle(e:MouseEvent):void {
var c:Class = TextArea;
var styleName:String = "textPadding";
var value:Number = 10;
StyleManager.setComponentStyle(c,styleName,value);
description.text = "Padding for all TextArea instances is now 10.";
}
private function clearClassStyle(e:MouseEvent):void {
var styleName:String = "textPadding";
var c:Class = TextArea;
StyleManager.clearComponentStyle(c,styleName);
description.text = "TextArea padding has been reset to the default.";
}
private function setGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
var value:Object = formatForGlobal;
StyleManager.setStyle(styleName,value);
description.text = "All components now use font Georgia size 10.";
}
private function clearGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
StyleManager.clearStyle(styleName);
description.text = "Font style for all components has been cleared.";
}
}
}
Tue Jun 12 2018, 12:06 PM Z