| Pakket | fl.controls |
| Klasse | public class List |
| Overerving | List  SelectableList BaseScrollPane UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object |
| Implementatie | IFocusManagerComponent |
| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
De component List bestaat uit items, rijen en een gegevensaanbieder, die als volgt worden beschreven:
- Item: Een ActionScript-object dat gewoonlijk een beschrijvende eigenschap
labelbevat en een eigenschapdatawaarin de gegevens zijn opgeslagen die aan het item zijn gekoppeld. - Rij: Een component die wordt gebruikt om het item weer te geven.
- Gegevensaanbieder: Een component die de items modelleert die in de component List worden weergegeven.
Standaard gebruikt de component List de klasse CellRenderer om de rijen te leveren waarin de lijstitems worden weergegeven. U kunt deze rijen met programmacode maken. Dit gebeurt gewoonlijk door de klasse CellRenderer met subklassen uit te breiden. De klasse CellRenderer implementeert de interface ICellRenderer, die de reeks eigenschappen en methoden levert waarmee de component List de rijen manipuleert en gegevens en statusinformatie voor weergave naar elke rij verzendt. Deze bevat informatie over de grootte en selectie van gegevens.
De component List bevat methoden die op de gegevensaanbieder ervan werken (zoals addItem() en removeItem()). Met deze en andere methoden kunt u de gegevens manipuleren van een willekeurige array die in hetzelfde frame bestaat als een component List, en de wijzigingen vervolgens uitzenden naar meerdere weergaven. Wanneer een component List niet is voorzien van een externe gegevensaanbieder, maken deze methoden automatisch een instantie van een gegevensaanbieder en stellen deze beschikbaar via de eigenschap List.dataProvider. De component List geeft elke rij weer door middel van een Sprite die de interface ICellRenderer implementeert. Gebruik de eigenschap List.cellRenderer om deze renderer op te geven. U kunt ook zelf een instantie Array maken of van een server downloaden en als gegevensmodel gebruiken voor meerdere lijsten, keuzelijsten, gegevensrasters, enzovoort.
Openbare eigenschappen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergeven| Eigenschap | Gedefinieerd door | ||
|---|---|---|---|
 | accessibilityImplementation : AccessibilityImplementation
De huidige toegankelijkheidsimplementatie (AccessibilityImplementation) voor deze InteractiveObject-instantie. | InteractiveObject | |
| accessibilityProperties : AccessibilityProperties
De huidige toegankelijkheidsopties voor dit weergaveobject. | DisplayObject | |
| allowMultipleSelection : Boolean
Hiermee wordt een Booleaanse waarde opgehaald die aangeeft of meerdere items in de lijst tegelijk kunnen worden geselecteerd. | SelectableList | |
| alpha : Number
Geeft de alpha-transparantiewaarde van het opgegeven object aan. | DisplayObject | |
| blendMode : String
Een waarde uit de klasse BlendMode die opgeeft welke overvloeimodus moet worden gebruikt. | DisplayObject | |
| blendShader : Shader [alleen-schrijven]
Stelt de arcering in die moet worden gebruikt om voor- en achtergrond in elkaar te laten overvloeien. | DisplayObject | |
| buttonMode : Boolean
Geeft de knopmodus van deze sprite op. | Sprite | |
| cacheAsBitmap : Boolean
Indien ingesteld op true, plaatsen Flash-runtimes een interne bitmaprepresentatie van het weergaveobject in cache. | DisplayObject | |
| cacheAsBitmapMatrix : Matrix
Als dit Matrix-object niet null is, definieert het hoe een weergaveobject wordt gerenderd als cacheAsBitmap wordt ingesteld op true. | DisplayObject | |
| constructor : Object
Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. | Object | |
| contextMenu : NativeMenu
Geeft het contextmenu op dat is gekoppeld aan dit object. | InteractiveObject | |
| dataProvider : DataProvider
Hiermee wordt het gegevensmodel opgehaald of ingesteld van de lijst met items die moet worden weergegeven. | SelectableList | |
| doubleClickEnabled : Boolean
Geeft op of dit object gebeurtenissen doubleClick ontvangt. | InteractiveObject | |
| dropTarget : DisplayObject [alleen-lezen]
Geeft het weergaveobject op waarover de sprite wordt gesleept of waarop de sprite is neergezet. | Sprite | |
| enabled : Boolean
Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de component gebruikersinteractie kan accepteren. | UIComponent | |
| filters : Array
Een geïndexeerde array die elk filterobject bevat dat momenteel is gekoppeld aan het weergaveobject. | DisplayObject | |
| focusEnabled : Boolean
Hiermee wordt een Booleaanse waarde opgehaald of ingesteld die aangeeft of de component focus kan krijgen nadat de gebruiker erop heeft geklikt. | UIComponent | |
| focusManager : IFocusManager
Hiermee wordt de FocusManager opgehaald of ingesteld die de focus voor deze component en de andere items op hetzelfde niveau bepaalt. | UIComponent | |
| focusRect : Object
Geeft op of dit object een focusrechthoek weergeeft. | InteractiveObject | |
| graphics : Graphics [alleen-lezen]
Geeft het object Graphics op dat bij deze sprite hoort, waarbij vectortekenopdrachten kunnen optreden. | Sprite | |
| height : Number [overschrijven]
Hiermee wordt de hoogte van de component, in pixels, opgehaald of ingesteld. | UIComponent | |
| hitArea : Sprite
Wijst een andere sprite aan als raakgebied voor een sprite. | Sprite | |
| horizontalLineScrollSize : Number
Hiermee wordt een waarde opgehaald of ingesteld die de hoeveelheid inhoud beschrijft die horizontaal moet worden geschoven wanneer er op een schuifpijl wordt geklikt. | BaseScrollPane | |
| horizontalPageScrollSize : Number
Hiermee wordt de hoeveelheid pixels opgehaald of ingesteld waarmee het schuifblokje op de horizontale schuifbalk moet worden verplaatst wanneer in het schuifbalkvak wordt geklikt. | BaseScrollPane | |
| horizontalScrollBar : ScrollBar [alleen-lezen]
Hiermee wordt een verwijzing naar de horizontale schuifbalk opgehaald. | BaseScrollPane | |
| horizontalScrollPolicy : String
Hiermee wordt een waarde opgehaald of ingesteld die de toestand van de horizontale schuifbalk aangeeft. | BaseScrollPane | |
| horizontalScrollPosition : Number
Hiermee wordt een waarde ingesteld of opgehaald die de horizontale positie in pixels van de horizontale schuifbalk in het schuifvenster beschrijft. | BaseScrollPane | |
| iconField : String
Hiermee wordt het itemveld met het pictogram voor het item opgehaald of ingesteld. | List | ||
| iconFunction : Function
Hiermee wordt de functie opgehaald of ingesteld die moet worden gebruikt om het pictogram voor het item te verkrijgen. | List | ||
| labelField : String
Hiermee wordt de naam opgehaald of ingesteld van het veld in het object dataProvider dat moet worden weergegeven als label in het veld TextInput en in de vervolgkeuzelijst. | List | ||
| labelFunction : Function
Hiermee wordt de functie opgehaald of ingesteld die moet worden gebruikt om het label voor het item te verkrijgen. | List | ||
| length : uint [alleen-lezen]
Hiermee wordt het aantal items in de gegevensaanbieder opgehaald. | SelectableList | |
| loaderInfo : LoaderInfo [alleen-lezen]
Retourneert een object LoaderInfo dat informatie bevat over het laden van het bestand waartoe dit weergaveobject behoort. | DisplayObject | |
| mask : DisplayObject
Het aanroepende weergaveobject wordt gemaskeerd door het opgegeven object mask. | DisplayObject | |
| maxHorizontalScrollPosition : Number [overschrijven]
Hiermee wordt het aantal pixels opgehaald of ingesteld waarmee de lijst naar rechts schuift wanneer de eigenschap horizontalScrollPolicy op ScrollPolicy.ON is ingesteld. | SelectableList | |
| maxVerticalScrollPosition : Number [alleen-lezen]
Hiermee wordt de maximale verticale schuifpositie voor de huidige inhoud, in pixels, opgehaald. | BaseScrollPane | |
| metaData : Object
Krijgt het metagegevensobject van de DisplayObject-instantie als de metagegevens zijn opgeslagen naast de instantie van dit DisplayObject in het SWF-bestand door een PlaceObject4-markering. | DisplayObject | |
| mouseChildren : Boolean
Bepaalt of de onderliggende elementen van het object door de muis of door een gebruikersinvoerapparaat worden ingeschakeld. | DisplayObjectContainer | |
| mouseEnabled : Boolean
Geeft aan of dit object berichten van de muis of gebruikersinvoer ontvangt. | InteractiveObject | |
| mouseFocusEnabled : Boolean
Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de component focus kan krijgen nadat de gebruiker erop heeft geklikt. | UIComponent | |
| mouseX : Number [alleen-lezen]
Geeft de x-coördinaat van de apparaatpositie van de muis of de gebruikersinvoer aan in pixels. | DisplayObject | |
| mouseY : Number [alleen-lezen]
Geeft de y-coördinaat van de apparaatpositie van de muis of de gebruikersinvoer aan in pixels. | DisplayObject | |
| name : String
Geeft de instantienaam van het DisplayObject aan. | DisplayObject | |
| needsSoftKeyboard : Boolean
Geeft aan of een virtueel toetsenbord (een softwaretoetsenbord op het scherm) moet worden weergegeven wanneer deze InteractiveObject-instantie focus krijgt. | InteractiveObject | |
| numChildren : int [alleen-lezen]
Retourneert het aantal onderliggende objecten van dit object. | DisplayObjectContainer | |
| opaqueBackground : Object
Geeft op of het weergaveobject dekkend is met een bepaalde achtergrondkleur. | DisplayObject | |
| parent : DisplayObjectContainer [alleen-lezen]
Geeft het object DisplayObjectContainer aan dat dit weergaveobject bevat. | DisplayObject | |
| root : DisplayObject [alleen-lezen]
Voor een weergaveobject in een geladen SWF-bestand is de eigenschap root het bovenste weergaveobject in het gedeelte van de boomstructuur van het weergaveoverzicht dat wordt vertegenwoordigd door dat SWF-bestand. | DisplayObject | |
| rotation : Number
Geeft de rotatie van de instantie DisplayObject vanaf de oorspronkelijke oriëntatie (in graden) aan. | DisplayObject | |
| rotationX : Number
Geeft in graden de X-asrotatie van de DisplayObject-instantie aan ten opzichte van de 3D parent-container. | DisplayObject | |
| rotationY : Number
Geeft in graden de y-asrotatie van de DisplayObject-instantie aan ten opzichte van de 3D parent-container. | DisplayObject | |
| rotationZ : Number
Geeft in graden de z-asrotatie van de DisplayObject-instantie aan ten opzichte van de 3D parent-container. | DisplayObject | |
| rowCount : uint [overschrijven]
Hiermee wordt het aantal rijen opgehaald of ingesteld dat ten minste gedeeltelijk in de lijst zichtbaar is. | List | ||
| rowHeight : Number
Hiermee wordt de hoogte van elke rij in de lijst, in pixels, opgehaald of ingesteld. | List | ||
| scale9Grid : Rectangle
Het huidige schaalraster dat wordt gebruikt. | DisplayObject | |
| scaleX : Number [overschrijven]
Hiermee wordt de huidige breedte van de component met een schaalfactor vermenigvuldigd. | UIComponent | |
| scaleY : Number [overschrijven]
Hiermee wordt de huidige hoogte van de component met een schaalfactor vermenigvuldigd. | UIComponent | |
| scaleZ : Number
Bepaalt de diepteschaal (percentage) van een object zoals deze wordt toegepast vanuit het registratiepunt van het object. | DisplayObject | |
| scrollRect : Rectangle
De verschuivende rechthoekgrenzen van het weergaveobject. | DisplayObject | |
| selectable : Boolean
Hiermee wordt een Booleaanse waarde opgehaald of ingesteld die aangeeft of de items in de lijst kunnen worden geselecteerd. | SelectableList | |
| selectedIndex : int
Hiermee wordt de index van het geselecteerde item in een enkelvoudige-selectielijst opgehaald of ingesteld. | SelectableList | |
| selectedIndices : Array
Hiermee wordt een array opgehaald of ingesteld die de items bevat die in een meervoudige-selectielijst zijn geselecteerd. | SelectableList | |
| selectedItem : Object
Hiermee wordt het item opgehaald of ingesteld dat in een enkelvoudige-selectielijst is geselecteerd. | SelectableList | |
| selectedItems : Array
Hiermee wordt een array opgehaald of ingesteld die de objecten voor de items bevat die in een meervoudige-selectielijst zijn geselecteerd. | SelectableList | |
| softKeyboard : String
Bepaalt het uiterlijk van het schermtoetsenbord. | InteractiveObject | |
| softKeyboardInputAreaOfInterest : Rectangle
Definieert het gebied dat als scherm moet blijven fungeren wanneer een softwaretoetsenbord wordt weergegeven (niet beschikbaar op iOS). | InteractiveObject | |
| soundTransform : flash.media:SoundTransform
Beheert geluid binnen deze sprite. | Sprite | |
| stage : Stage [alleen-lezen]
Het werkgebied van het weergaveobject. | DisplayObject | |
| tabChildren : Boolean
Bepaalt of de onderliggende objecten van het object tabnavigatie hebben. | DisplayObjectContainer | |
| tabEnabled : Boolean
Geeft op of dit object in de tabvolgorde is opgenomen. | InteractiveObject | |
| tabIndex : int
Geeft de tabvolgorde van objecten in een SWF-bestand op. | InteractiveObject | |
| textSnapshot : flash.text:TextSnapshot [alleen-lezen]
Retourneert een object TextSnapshot voor deze instantie DisplayObjectContainer. | DisplayObjectContainer | |
| transform : flash.geom:Transform
Een object met eigenschappen die betrekking hebben op de matrix van een weergaveobject, de kleurtransformatie en de pixelbeperkingen. | DisplayObject | |
| useBitmapScrolling : Boolean
Indien ingesteld op true, wordt de eigenschap cacheAsBitmap voor de schuivende inhoud op true ingesteld; indien ingesteld op false, wordt de eigenschap op false ingesteld. | BaseScrollPane | |
| useHandCursor : Boolean
Een Booleaanse waarde die aangeeft of het wijzende handje wordt weergegeven wanneer de cursor wordt bewogen over een sprite waarin de eigenschap buttonMode is ingesteld op true. | Sprite | |
| verticalLineScrollSize : Number
Hiermee wordt een waarde opgehaald of ingesteld die de hoeveelheid pixels beschrijft die verticaal moeten worden geschoven wanneer er op een schuifpijl wordt geklikt. | BaseScrollPane | |
| verticalPageScrollSize : Number
Hiermee wordt de hoeveelheid pixels opgehaald of ingesteld waarmee het schuifblokje op de verticale schuifbalk moet worden verplaatst wanneer in het schuifbalkvak wordt geklikt. | BaseScrollPane | |
| verticalScrollBar : ScrollBar [alleen-lezen]
Hiermee wordt een verwijzing naar de verticale schuifbalk opgehaald. | BaseScrollPane | |
| verticalScrollPolicy : String
Hiermee wordt een waarde opgehaald of ingesteld die de toestand van de verticale schuifbalk aangeeft. | BaseScrollPane | |
| verticalScrollPosition : Number
Hiermee wordt een waarde ingesteld of opgehaald die de verticale positie in pixels van de verticale schuifbalk in het schuifvenster beschrijft. | BaseScrollPane | |
| visible : Boolean [overschrijven]
Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de huidige componentinstantie zichtbaar is. | UIComponent | |
| width : Number [overschrijven]
Hiermee wordt de breedte van de component, in pixels, opgehaald of ingesteld. | UIComponent | |
| x : Number [overschrijven]
Hiermee wordt de x-coördinaat opgehaald of ingesteld die de positie van de component langs de x-as binnen de bovenliggende container vertegenwoordigt. | UIComponent | |
| y : Number [overschrijven]
Hiermee wordt de y-coördinaat opgehaald of ingesteld die de positie van de component langs de y-as binnen de bovenliggende container vertegenwoordigt. | UIComponent | |
| z : Number
Geeft de z-coördinaatpositie langs de z-as van de DisplayObject-instantie aan ten opzichte van de bovenliggende 3D-container. | DisplayObject | |
Openbare methoden
| Methode | Gedefinieerd door | ||
|---|---|---|---|
List()
Hiermee wordt een nieuwe instantie van de component List gemaakt. | List | ||
|
Voegt een onderliggende instantie DisplayObject toe aan deze instantie DisplayObjectContainer. | DisplayObjectContainer | |
|
Voegt een onderliggende instantie DisplayObject toe aan deze instantie DisplayObjectContainer. | DisplayObjectContainer | |
| addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Registreert een gebeurtenislistenerobject bij een object EventDispatcher, zodat de listener een melding van een gebeurtenis ontvangt. | EventDispatcher | |
|
Hiermee wordt een item aan het einde van de lijst met items toegevoegd. | SelectableList | |
|
Hiermee wordt een item bij de opgegeven index aan de lijst met items toegevoegd. | SelectableList | |
|
Geeft aan of vanwege beveiligingsbeperkingen weergaveobjecten worden weggelaten uit de lijst die wordt geretourneerd wanneer de methode DisplayObjectContainer.getObjectsUnderPoint() wordt aangeroepen met het opgegeven punt. | DisplayObjectContainer | |
|
Hiermee wordt een stijl gewist die op de renderers in de lijst is ingesteld. | SelectableList | |
|
Hiermee wordt het momenteel geselecteerde item in de lijst gewist en de eigenschap selectedIndex op -1 ingesteld. | SelectableList | |
|
Hiermee wordt een stijleigenschap van deze componentinstantie verwijderd. | UIComponent | |
|
Bepaalt of het opgegeven weergaveobject een onderliggend object van de instantie DisplayObjectContainer of de instantie zelf is. | DisplayObjectContainer | |
|
Verzendt een gebeurtenis naar de gebeurtenisstroom. | EventDispatcher | |
|
Hiermee wordt de focusindicator van deze component weergegeven of verborgen. | UIComponent | |
|
Hiermee wordt een directe tekenhandeling gestart zonder dat alles ongeldig wordt gemaakt, zoals met invalidateNow. | UIComponent | |
|
Retourneert een rechthoek die het gebied van het weergaveobject aangeeft ten opzichte van het coördinatensysteem van het object targetCoordinateSpace. | DisplayObject | |
|
Retourneert de onderliggende weergaveobjectinstantie bij de opgegeven index. | DisplayObjectContainer | |
|
Retourneert de onderliggende weergaveobjectinstantie met de opgegeven naam. | DisplayObjectContainer | |
|
Retourneert de indexpositie van een onderliggende instantie DisplayObject. | DisplayObjectContainer | |
|
Hiermee wordt het object opgehaald dat momenteel focus heeft. | UIComponent | |
|
Hiermee wordt het item bij de opgegeven index opgehaald. | SelectableList | |
|
Hiermee wordt de index geretourneerd van het volgende item in de dataProvider waarin het eerste teken van het label overeenkomt met een opgegeven teken. | SelectableList | |
|
Retourneert een array met objecten die zich onder het opgegeven punt bevinden en onderliggende objecten van deze instantie DisplayObjectContainer zijn (of onderliggende objecten van onderliggende objecten van die instantie). | DisplayObjectContainer | |
|
Retourneert een rechthoek die de grens van het weergaveobject aangeeft op basis van het coördinatensysteem dat wordt gedefinieerd door de paramater targetCoordinateSpace, minus enige streken op vormen. | DisplayObject | |
|
Hiermee wordt een stijl opgehaald die op de renderers in de lijst is ingesteld. | SelectableList | |
|
Hiermee wordt een stijleigenschap opgehaald die in de stijlopzoekketen van de component is ingesteld. | UIComponent | |
[statisch]
Hiermee wordt de standaardstijlkaart voor de huidige component opgehaald. | List | ||
|
Hiermee worden de (algemene) werkgebiedcoördinaten van het object point omgezet in (lokale) objectcoördinaten. | DisplayObject | |
|
Converteert een tweedimensionaal punt van de (algemene) werkruimtecoördinaten naar (lokale) coördinaten van een driedimensionaal weergaveobject. | DisplayObject | |
|
Controleert of het object EventDispatcher listeners heeft geregistreerd voor een specifiek type gebeurtenis. | EventDispatcher | |
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
|
Evalueert het selectiekader van het weergaveobject om te zien of dit het selectiekader van het weergaveobject obj overlapt of snijdt. | DisplayObject | |
|
Hiermee wordt het weergaveobject geëvalueerd om te zien of deze een punt dat is opgegeven door de parameters x en y, overlapt of doorsnijdt. | DisplayObject | |
|
Hiermee wordt een eigenschap als ongeldig gemarkeerd en wordt de component bij het volgende frame opnieuw getekend, tenzij anders wordt aangegeven. | UIComponent | |
|
Hiermee wordt een specifieke itemrenderer ongeldig. | SelectableList | |
|
Hiermee wordt de renderer voor het item bij de opgegeven index ongeldig. | SelectableList | |
|
Hiermee wordt de gehele lijst ongeldig gemaakt en worden alle items gedwongen opnieuw getekend. | SelectableList | |
|
Hiermee wordt gecontroleerd of het opgegeven item in de lijst is geselecteerd. | SelectableList | |
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
|
Hiermee wordt de ICellRenderer voor een bepaald itemobject opgehaald, indien aanwezig. | SelectableList | |
[overschrijven]
Hiermee wordt de tekenreeks opgehaald die de renderer voor het opgegeven gegevensobject weergeeft op basis van de eigenschappen labelField en labelFunction. | List | ||
|
Converteert een driedimensionaal punt van de (lokale) coördinaten van het driedimensionale weergaveobject naar een tweedimensionaal punt in de (algemene) werkruimtecoördinaten. | DisplayObject | |
|
Hiermee worden de (lokale) weergaveobjectcoördinaten van het object point omgezet in (algemene) werkgebiedcoördinaten. | DisplayObject | |
| [statisch]
Hiermee worden de stijlen van meerdere klassen in één object samengevoegd. | UIComponent | |
|
Hiermee wordt de component naar de opgegeven positie binnen het bovenliggende item verplaatst. | UIComponent | |
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
|
Hiermee worden alle items uit de lijst verwijderd. | SelectableList | |
|
Verwijdert de opgegeven onderliggende instantie DisplayObject uit de lijst met onderliggende objecten van de instantie DisplayObjectContainer. | DisplayObjectContainer | |
|
Verwijdert een onderliggend DisplayObject uit de opgegeven indexpositie in de lijst met onderliggende objecten van de DisplayObjectContainer. | DisplayObjectContainer | |
|
Verwijdert alle onderliggende DisplayObject-instanties uit de lijst met onderliggende objecten van de instantie DisplayObjectContainer. | DisplayObjectContainer | |
|
Verwijdert een listener uit het object EventDispatcher. | EventDispatcher | |
|
Hiermee wordt het opgegeven item uit de lijst verwijderd. | SelectableList | |
|
Hiermee wordt het item bij de opgegeven index verwijderd. | SelectableList | |
|
Hiermee wordt het item bij de opgegeven index vervangen door een ander item. | SelectableList | |
|
Geeft een virtueel toetsenbord weer. | InteractiveObject | |
[overschrijven]
Hiermee wordt de lijst naar het item bij de opgegeven index geschoven. | List | ||
|
Hiermee wordt de lijst naar het item geschoven op de locatie die wordt aangegeven door de huidige waarde van de eigenschap selectedIndex. | SelectableList | |
|
Wijzigt de positie van een bestaand onderliggend object in de weergaveobjectcontainer. | DisplayObjectContainer | |
|
Hiermee wordt de focus ingesteld op deze component. | UIComponent | |
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
|
Hiermee wordt een stijl op de renderers in de lijst ingesteld. | SelectableList | |
|
Hiermee wordt de grootte van de component op de opgegeven breedte en hoogte ingesteld. | UIComponent | |
|
Hiermee wordt een stijleigenschap op deze componentinstantie ingesteld. | UIComponent | |
|
Hiermee worden de elementen van de huidige gegevensaanbieder gesorteerd. | SelectableList | |
|
Hiermee worden de elementen van de huidige gegevensaanbieder op een of meer velden gesorteerd. | SelectableList | |
|
Hiermee kan de gebruiker de opgegeven sprite slepen. | Sprite | |
|
Hiermee kan de gebruiker de opgegeven sprite naar een apparaat met aanraakbediening slepen. | Sprite | |
|
Stopt recursief de tijdlijnuitvoering van alle filmclips die beginnen bij dit object. | DisplayObjectContainer | |
|
Beëindigt de methode startDrag(). | Sprite | |
|
Beëindigt de startTouchDrag()-methode, voor gebruik met apparaten met aanraakbediening. | Sprite | |
|
Wisselt de z-volgorde (van voor naar achter) van de twee opgegeven onderliggende objecten om. | DisplayObjectContainer | |
|
Wisselt de z-volgorde (van voor naar achter) van de onderliggende objecten op de twee opgegeven indexposities in de lijst met onderliggende objecten om. | DisplayObjectContainer | |
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
|
Retourneert een tekenreeksrepresentatie van het opgegeven object. | Object | |
|
Hiermee worden de eigenschappen en de lay-out van dit object gevalideerd en bijgewerkt, waarbij het object zonodig opnieuw wordt getekend. | UIComponent | |
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
|
Controleert of een gebeurtenislistener is geregistreerd bij dit object EventDispatcher of een van de voorouders voor het opgegeven type gebeurtenis. | EventDispatcher | |
Beschermde methoden
Gebeurtenissen
Stijlen
Stijlen zijn of algemeen of ze zijn gekoppeld aan een bepaald thema. Als de stijl algemeen is, kan deze bij elk thema worden gebruikt. Als een stijl is gekoppeld aan een bepaald thema, kan de stijl alleen worden gebruikt als uw toepassing het desbetreffende thema gebruikt.
Algemene stijlen
Openbare constanten
Eigenschapdetails
iconField | eigenschap |
iconField:String| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het itemveld met het pictogram voor het item opgehaald of ingesteld.
Opmerking: de eigenschap iconField wordt niet gebruikt als de eigenschap iconFunction op een callback-functie is ingesteld.
De standaardwaarde is "icon".
Implementatie
public function get iconField():String public function set iconField(value:String):voidVoorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt een lijst gemaakt met een pictogram voor elk item. Het voorbeeld werkt alleen wanneer de bibliotheek een symbool met de naam
RedBox bevat en in de symbooleigenschappen van het pictogram de optie Exporteren voor ActionScript wordt geschakeld:
import fl.data.DataProvider;
import fl.controls.List;
var dp:DataProvider = new DataProvider();
dp.addItem( { iconSource:RedBox, label:"Item 1" } );
dp.addItem( { iconSource:RedBox, label:"Item 2" } );
dp.addItem( { iconSource:RedBox, label:"Item 3" } );
var list:List = new List();
list.iconField = "iconSource";
list.dataProvider = dp;
addChild(list);
iconFunction | eigenschap |
iconFunction:Function| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de functie opgehaald of ingesteld die moet worden gebruikt om het pictogram voor het item te verkrijgen.
Opmerking: de eigenschap iconField wordt niet gebruikt als de eigenschap iconFunction op een callback-functie is ingesteld.
De standaardwaarde is null.
Implementatie
public function get iconFunction():Function public function set iconFunction(value:Function):voidVoorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt de eigenschap
iconFunction gebruikt om voor een beperkt aantal items in een lijst een pictogram weer te geven. Het voorbeeld werkt alleen wanneer de bibliotheek een symbool met de naam RedBox bevat en in de symbooleigenschappen van het pictogram de optie Exporteren voor ActionScript wordt geschakeld:
import fl.data.DataProvider;
import fl.controls.List;
var dp:DataProvider = new DataProvider();
dp.addItem( { label:"Item 1" } );
dp.addItem( { label:"Item 2" } );
dp.addItem( { label:"Item 3" } );
var list:List = new List();
list.iconFunction = determineIcon;
list.dataProvider = dp;
addChild(list);
function determineIcon(item:Object):String {
if(item.label == "Item 2") {
return "RedBox";
}
else {
return null;
}
}
labelField | eigenschap |
labelField:String| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de naam opgehaald of ingesteld van het veld in het object dataProvider dat moet worden weergegeven als label in het veld TextInput en in de vervolgkeuzelijst.
Standaard geeft de component de eigenschap label van elk dataProvider-item weer. Wanneer de dataProvider-items echter geen eigenschaplabel bevatten, kunt u de eigenschaplabelField instellen zodat deze een andere eigenschap gebruikt.
Opmerking: de eigenschap labelField wordt niet gebruikt als de eigenschap labelFunction op een callback-functie is ingesteld.
De standaardwaarde is "label".
Implementatie
public function get labelField():String public function set labelField(value:String):voidVerwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld worden de items in een lijst weergegeven met de eigenschap
abbreviatedLabel in plaats van de standaardeigenschap label:
import fl.data.DataProvider;
import fl.controls.List;
var dp:DataProvider = new DataProvider();
dp.addItem( { abbreviatedLabel:"NY", label:"New York" } );
dp.addItem( { abbreviatedLabel:"CA", label:"California" } );
dp.addItem( { abbreviatedLabel:"WA", label:"Washington" } );
dp.addItem( { abbreviatedLabel:"CT", label:"Connecticut" } );
dp.addItem( { abbreviatedLabel:"VT", label:"Vermont" } );
var list:List = new List();
list.setSize(40,100);
list.labelField = "abbreviatedLabel"
list.dataProvider = dp;
addChild(list);
labelFunction | eigenschap |
labelFunction:Function| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de functie opgehaald of ingesteld die moet worden gebruikt om het label voor het item te verkrijgen.
Standaard geeft de component de eigenschap label van elk dataProvider-item weer. Sommige sets hebben echter geen veld label of hebben geen veld waarvan de waarde als zodanig als label kan worden gebruikt. Een bepaalde gegevensset bevat bijvoorbeeld hele namen, maar deze worden opgeslagen in de velden lastName en firstName. In een dergelijk geval kan deze eigenschap worden gebruikt om een callback-functie in te stellen die de waarden van de velden lastName en firstName samenvoegt tot een volledige naamreeks die wordt weergegeven.
Opmerking: de eigenschap labelField wordt niet gebruikt als de eigenschap labelFunction op een callback-functie is ingesteld.
De standaardwaarde is null.
Implementatie
public function get labelFunction():Function public function set labelFunction(value:Function):voidVoorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld wordt de eigenschap
labelFunction van een lijst ingesteld op een functie die de tekenreeksen opmaakt die in elke cel worden weergegeven:
import fl.data.DataProvider;
import fl.controls.List;
var myDataProvider:DataProvider = new DataProvider();
myDataProvider.addItem({name:"User A", price:0.43});
myDataProvider.addItem({name:"User B", price:0.34});
var users:List = new List();
users.dataProvider = myDataProvider;
users.labelFunction = myLabelFunction;
addChild(users);
function myLabelFunction(item:Object):String {
return item.name + " ($" + item.price.toFixed(2) + ")";
}
rowCount | eigenschap |
rowCount:uint[overschrijven] | Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het aantal rijen opgehaald of ingesteld dat ten minste gedeeltelijk in de lijst zichtbaar is.
Implementatie
override public function get rowCount():uint override public function set rowCount(value:uint):voidVoorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld wordt de grootte van een lijst ingesteld en wordt het aantal mogelijk zichtbare rijen bepaald door de eigenschap
rowCount te traceren:
import fl.data.DataProvider;
import fl.controls.List;
var dp:DataProvider = new DataProvider();
var i:uint;
for(i=0; i<100; i++) {
dp.addItem( { label: "Item " + i } );
}
var list:List = new List();
list.setSize(100,300);
list.dataProvider = dp;
addChild(list);
trace(list.rowCount); // 15
In het volgende voorbeeld wordt de eigenschap
rowCount gebruikt om op basis van de huidige waarde van een schuifregelaar de grootte van een component List in te stellen:
import fl.controls.Slider;
import fl.controls.List;
import fl.data.DataProvider;
import fl.events.SliderEvent;
var dp:DataProvider = new DataProvider();
var i:int;
for (i=0; i<8; i++) {
dp.addItem({label:"Item " + i});
}
var mySlider:Slider = new Slider();
mySlider.move(10, 10);
mySlider.tickInterval = 1;
mySlider.snapInterval = 1;
mySlider.minimum = 2;
mySlider.maximum = 9;
mySlider.liveDragging = true;
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);
var myList:List = new List();
myList.dataProvider = dp;
myList.move(mySlider.x, mySlider.y + 20);
myList.setSize(100, 50);
addChild(myList);
function changeHandler(event:SliderEvent):void {
myList.rowCount = event.value;
}
rowHeight | eigenschap |
rowHeight:Number| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de hoogte van elke rij in de lijst, in pixels, opgehaald of ingesteld.
De standaardwaarde is 20.
Implementatie
public function get rowHeight():Number public function set rowHeight(value:Number):voidConstructordetails
List | () | Constructor |
public function List()| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een nieuwe instantie van de component List gemaakt.
Methodedetails
getStyleDefinition | () | methode |
public static function getStyleDefinition():Object| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de standaardstijlkaart voor de huidige component opgehaald. Op de stijlkaart vindt u het type dat voor de component geschikt is, afhankelijk van de stijl die de component gebruikt. De stijl disabledTextFormat bevat bijvoorbeeld de waarde null of een object TextFormat. U kunt deze stijlen gebruiken en setStyle() aanroepen voor de huidige component. De volgende code overschrijft de standaardstijl disabledTextFormat voor de opgegeven component:
componentInstance.setStyle("disabledTextFormat", new TextFormat());Object — Standaardstijlenobject.
|
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt een stijlbrowser voor verscheidene componentklassen gemaakt:
import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane", data:BaseScrollPane } );
dp.addItem( { label: "Button", data:Button } );
dp.addItem( { label: "CellRenderer", data:CellRenderer } );
dp.addItem( { label: "CheckBox", data:CheckBox } );
dp.addItem( { label: "ColorPicker", data:ColorPicker } );
dp.addItem( { label: "ComboBox", data:ComboBox } );
dp.addItem( { label: "DataGrid", data:DataGrid } );
dp.addItem( { label: "HeaderRenderer", data:HeaderRenderer } );
dp.addItem( { label: "ImageCell", data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label", data:Label } );
dp.addItem( { label: "List", data:List } );
dp.addItem( { label: "NumericStepper", data:NumericStepper } );
dp.addItem( { label: "ProgressBar", data:ProgressBar } );
dp.addItem( { label: "RadioButton", data:RadioButton } );
dp.addItem( { label: "ScrollPane", data:ScrollPane } );
dp.addItem( { label: "Slider", data:Slider } );
dp.addItem( { label: "TextArea", data:TextArea } );
dp.addItem( { label: "TextInput", data:TextInput } );
dp.addItem( { label: "TileList", data:TileList } );
dp.addItem( { label: "UILoader", data:UILoader } );
dp.addItem( { label: "UIComponent", data:UIComponent } );
var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);
var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);
function showStyleDefinition(e:Event):void {
var componentClass:Class = e.target.selectedItem.data as Class;
var styles:Object = componentClass["getStyleDefinition"].call(this);
trace(styles.toString());
var styleData:DataProvider = new DataProvider();
for(var i:* in styles) {
trace(i + " : " + styles[i]);
styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
}
styleData.sortOn("StyleName");
dg.dataProvider = styleData;
}
itemToLabel | () | methode |
override public function itemToLabel(item:Object):String| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de tekenreeks opgehaald die de renderer voor het opgegeven gegevensobject weergeeft op basis van de eigenschappen labelField en labelFunction.
Opmerking: de eigenschap labelField wordt niet gebruikt als de eigenschap labelFunction op een callback-functie is ingesteld.
Parameters
item:Object — Het object dat moet worden gerenderd.
|
String — De tekenreeks die wordt weergegeven op basis van de gegevens.
|
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt getoond hoe u het label van een lijstitem bepaalt wanneer de muis erboven wordt gehouden:
import fl.controls.List;
import fl.data.DataProvider;
import fl.events.ListEvent;
var myDataProvider:DataProvider = new DataProvider();
myDataProvider.addItem({label:"Carrot", price:0.43});
myDataProvider.addItem({label:"Tomato", price:0.34});
myDataProvider.addItem({label:"Blueberry", price:0.72});
myDataProvider.addItem({label:"Turnip", price:0.24});
var myList:List = new List();
myList.setSize(300,80);
myList.dataProvider = myDataProvider;
myList.labelFunction = myLabelFunction;
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, announceLabel);
addChild(myList);
function myLabelFunction(item:Object):String {
return item.label + " - Current price: ($" + item.price.toFixed(2) + ")";
}
function announceLabel(e:ListEvent):void {
var list:List = e.target as List;
var item:Object = e.item;
trace("Label: " + item.label);
trace("Label displayed: " + list.itemToLabel(item));
}
scrollToIndex | () | methode |
override public function scrollToIndex(newCaretIndex:int):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt de lijst naar het item bij de opgegeven index geschoven. Wanneer de index buiten bereik ligt, verandert de schuifpositie niet.
Parameters
newCaretIndex:int — De indexlocatie waar u naartoe bladert.
|
Voorbeelden Hoe dit voorbeeld te gebruiken
ListExample.as
In dit voorbeeld zien u hoe u een lijst maakt en andere instanties List met de selecties ervan vult.
- Voeg de klassen List, Button en Label toe aan de bibliotheek.
- Sla deze code op als ListExample.as in dezelfde map als de FLA.
- Stel de DocumentClass in de FLA in op ListExample.
package
{
import flash.display.Sprite
public class ListExample extends Sprite
{
import flash.events.*;
import fl.data.DataProvider;
import fl.controls.List
import fl.controls.Label
import fl.controls.Button
private var clearButton:Button;
private var availableItems:List;
private var selectedItemList:List;
private var selectedItemsList:List;
public function ListExample() {
createComponents();
setupComponents();
}
private function setupComponents():void {
var dp:Array = new Array();
var i:uint;
var count:uint = availableItems.rowCount * 2;
for (i = 0; i < count; i++) {
dp.push({label:"Item " + i});
}
availableItems.allowMultipleSelection = true;
availableItems.dataProvider = new DataProvider(dp);
availableItems.addEventListener(Event.CHANGE, updateLists);
clearButton.addEventListener(MouseEvent.CLICK, clearHandler);
}
private function clearHandler(event:MouseEvent):void {
availableItems.clearSelection();
// clear data providers
selectedItemList.dataProvider = new DataProvider();
selectedItemsList.dataProvider = new DataProvider();
}
private function updateLists(e:Event):void {
selectedItemList.dataProvider = availableItems.selectedItem ? new DataProvider([availableItems.selectedItem]) : new DataProvider();
selectedItemsList.dataProvider = new DataProvider(availableItems.selectedItems);
}
private function createComponents():void {
clearButton = new Button();
availableItems = new List();
selectedItemList = new List();
selectedItemsList = new List();
var availableItemsLabel:Label = new Label();
var selectedItemListLabel:Label = new Label();
var selectedItemsListLabel:Label = new Label();
clearButton.move(10,142);
availableItems.move(10,32);
selectedItemList.move(120,32);
selectedItemsList.move(230,32);
availableItemsLabel.move(10,10);
selectedItemListLabel.move(120,10);
selectedItemsListLabel.move(230,10);
clearButton.label = "Clear Selection"
availableItemsLabel.text = "Available Items";
selectedItemListLabel.text = "Selected Item";
selectedItemsListLabel.text = "All Selected Items";
addChild(clearButton);
addChild(availableItems);
addChild(selectedItemList);
addChild(selectedItemsList);
addChild(availableItemsLabel);
addChild(selectedItemListLabel);
addChild(selectedItemsListLabel);
}
}
}
Wed Jun 13 2018, 11:42 AM Z