| Pakket | fl.data |
| Klasse | public class DataProvider |
| Overerving | DataProvider  EventDispatcher Object |
| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Een gegevensaanbieder is een lineaire verzameling van items die dienen als gegevensbron, bijvoorbeeld een array. Elk item in een gegevensaanbieder is een object of XML-object dat een of meer velden met gegevens bevat. U kunt toegang tot de items in de gegevensaanbieder krijgen via de index, door de methode DataProvider.getItemAt() te gebruiken.
Openbare eigenschappen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergeven| Eigenschap | Gedefinieerd door | ||
|---|---|---|---|
 | constructor : Object
Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. | Object | |
| length : uint [alleen-lezen]
Het aantal items in de gegevensaanbieder. | DataProvider | ||
Openbare methoden
| Methode | Gedefinieerd door | ||
|---|---|---|---|
DataProvider(value:Object = null)
Hiermee wordt een nieuw object DataProvider gemaakt met een lijst, een XML-instantie of een array van gegevensobjecten als gegevensbron. | DataProvider | ||
| addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Registreert een gebeurtenislistenerobject bij een object EventDispatcher, zodat de listener een melding van een gebeurtenis ontvangt. | EventDispatcher | |
Hiermee wordt een item aan het einde van de gegevensaanbieder toegevoegd. | DataProvider | ||
Hiermee wordt een nieuw item aan de gegevensaanbieder bij de opgegeven index toegevoegd. | DataProvider | ||
Hiermee worden meerdere items aan het einde van de DataProvider toegevoegd en wordt een gebeurtenis DataChangeType.ADD verzonden. | DataProvider | ||
Hiermee worden diverse items bij de opgegeven index aan de gegevensaanbieder toegevoegd en wordt een gebeurtenis DataChangeType.ADD verzonden. | DataProvider | ||
Hiermee wordt een kopie van het huidige object DataProvider gemaakt. | DataProvider | ||
Hiermee worden de opgegeven items aan het einde van de huidige gegevensaanbieder samengevoegd. | DataProvider | ||
|
Verzendt een gebeurtenis naar de gebeurtenisstroom. | EventDispatcher | |
Retourneert het item bij de opgegeven index. | DataProvider | ||
Retourneert de index van het opgegeven item. | DataProvider | ||
|
Controleert of het object EventDispatcher listeners heeft geregistreerd voor een specifiek type gebeurtenis. | EventDispatcher | |
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
Hiermee worden alle gegevensitems in de DataProvider ongeldig gemaakt en wordt een gebeurtenis DataChangeEvent.INVALIDATE_ALL verzonden. | DataProvider | ||
Hiermee wordt het opgegeven item ongeldig gemaakt. | DataProvider | ||
Hiermee wordt het item bij de opgegeven index ongeldig gemaakt. | DataProvider | ||
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
Hiermee worden de opgegeven gegevens aan de gegevens in de gegevensaanbieder toegevoegd en worden alle dubbele items verwijderd. | DataProvider | ||
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
Hiermee worden alle items uit de gegevensaanbieder verwijderd en wordt een gebeurtenis DataChangeType.REMOVE_ALL verzonden. | DataProvider | ||
|
Verwijdert een listener uit het object EventDispatcher. | EventDispatcher | |
Hiermee wordt het opgegeven item uit de gegevensaanbieder verwijderd en wordt een gebeurtenis DataChangeType.REMOVE verzonden. | DataProvider | ||
Hiermee wordt het item bij de opgegeven index verwijderd en wordt een gebeurtenis DataChangeType.REMOVE verzonden. | DataProvider | ||
Hiermee wordt een bestaand item door een nieuw item vervangen en wordt een gebeurtenis DataChangeType.REPLACE verzonden. | DataProvider | ||
Hiermee wordt het item bij de opgegeven index vervangen en wordt een gebeurtenis DataChangeType.REPLACE verzonden. | DataProvider | ||
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
Hiermee worden de items in de gegevensaanbieder gesorteerd en wordt een gebeurtenis DataChangeType.SORT verzonden. | DataProvider | ||
Hiermee worden de items in de gegevensaanbieder op het opgegeven veld gesorteerd en wordt een gebeurtenis DataChangeType.SORT verzonden. | DataProvider | ||
Hiermee wordt een representatie van de gegevens in de gegevensaanbieder gemaakt in de vorm van een object Array. | DataProvider | ||
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
[overschrijven]
Hiermee wordt een tekenreeksrepresentatie van de gegevens in de gegevensaanbieder gemaakt. | DataProvider | ||
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
|
Controleert of een gebeurtenislistener is geregistreerd bij dit object EventDispatcher of een van de voorouders voor het opgegeven type gebeurtenis. | EventDispatcher | |
Gebeurtenissen
| Gebeurtenis | Overzicht | Gedefinieerd door | ||
|---|---|---|---|---|
| [uitgezonden gebeurtenis] Wordt verzonden wanneer Flash Player of de AIR-toepassing de besturingssysteemfocus krijgt en actief wordt. | EventDispatcher | ||
| Wordt verzonden nadat de gegevens zijn gewijzigd. | DataProvider | |||
| [uitgezonden gebeurtenis] Wordt verzonden wanneer Flash Player of de AIR-toepassing de systeemfocus verliest en inactief wordt. | EventDispatcher | ||
| Wordt verzonden voordat de gegevens worden gewijzigd. | DataProvider | |||
Eigenschapdetails
length | eigenschap |
length:uint [alleen-lezen] | Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Het aantal items in de gegevensaanbieder.
Implementatie
public function get length():uintVoorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt een instantie van de component List gemaakt en wordt de grootte van de lijst ingesteld op basis van het aantal items in de gegevensaanbieder:
import fl.controls.List;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"Item 1"});
dp.addItem({label:"Item 2"});
dp.addItem({label:"Item 3"});
dp.addItem({label:"Item 4"});
var myList:List = new List();
myList.dataProvider = dp;
myList.rowHeight = 35;
myList.rowCount = dp.length;
myList.move(10, 10);
addChild(myList);
Constructordetails
DataProvider | () | Constructor |
public function DataProvider(value:Object = null)| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een nieuw object DataProvider gemaakt met een lijst, een XML-instantie of een array van gegevensobjecten als gegevensbron.
Parametersvalue:Object (default = null) |
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt de methode
addItem() gebruikt om een nieuwe gegevensaanbieder te maken:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"item 1a"});
dp.addItem({label:"item 2a"});
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
In het volgende voorbeeld wordt een gegevensaanbieder gevuld met behulp van een object Array:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var arr:Array = new Array();
arr.push({label:"item 1b"});
arr.push({label:"item 2b"});
var dp:DataProvider = new DataProvider(arr);
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
In het volgende voorbeeld wordt een gegevensaanbieder gevuld met behulp van een XML-object met kenmerken:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var xml:XML = <items>
<item label="item 1c" />
<item label="item 2c" />
</items>;
var dp:DataProvider = new DataProvider(xml);
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
In het volgende voorbeeld wordt een gegevensaanbieder gevuld met behulp van een XML-object met onderliggende knooppunten:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var xml:XML = <items>
<item>
<label>item 1d</label>
</item>
<item>
<label>item 2d</label>
</item>
</items>;
var dp:DataProvider = new DataProvider(xml);
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
Methodedetails
addItem | () | methode |
public function addItem(item:Object):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een item aan het einde van de gegevensaanbieder toegevoegd.
Parameters
item:Object — Het item dat moet worden toegevoegd aan het einde van de huidige gegevensaanbieder.
|
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt de methode
addItem() gebruikt om een nieuwe gegevensaanbieder te maken:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"item 1a"});
dp.addItem({label:"item 2a"});
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
addItemAt | () | methode |
public function addItemAt(item:Object, index:uint):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een nieuw item aan de gegevensaanbieder bij de opgegeven index toegevoegd. Wanneer de opgegeven index de lengte van de gegevensaanbieder overschrijdt, wordt de index genegeerd.
Parameters
item:Object — Een object dat de gegevens bevat voor het item dat moet worden toegevoegd.
| |
index:uint — De index waarbij het item moet worden toegevoegd.
|
Gegenereerde uitzondering
RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.
|
Verwante API-elementen
addItems | () | methode |
public function addItems(items:Object):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden meerdere items aan het einde van de DataProvider toegevoegd en wordt een gebeurtenis DataChangeType.ADD verzonden. De items worden toegevoegd in de volgorde waarin zij worden opgegeven.
Parameters
items:Object — De items die moeten worden toegevoegd aan de gegevensaanbieder.
|
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In het volgende voorbeeld wordt de methode
addItems() gebruikt om verschillende items toe te voegen aan de gegevensaanbieder:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var arr:Array = [{col1:"1.A", col2:"1.B"}, {col1:"2.A", col2:"2.B"}]
var dp:DataProvider = new DataProvider();
dp.addItems(arr);
trace(dp.length); // 2
var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.setSize(200, 160);
myDataGrid.move(10, 10);
addChild(myDataGrid);
addItemsAt | () | methode |
public function addItemsAt(items:Object, index:uint):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden diverse items bij de opgegeven index aan de gegevensaanbieder toegevoegd en wordt een gebeurtenis DataChangeType.ADD verzonden.
Parameters
items:Object — De items die moeten worden toegevoegd aan de gegevensaanbieder.
| |
index:uint — De index waarbij de items moeten worden ingevoegd.
|
Gegenereerde uitzondering
RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.
|
Verwante API-elementen
clone | () | methode |
public function clone():DataProvider| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een kopie van het huidige object DataProvider gemaakt.
Geretourneerde waardeDataProvider — Een nieuwe instantie van dit object DataProvider.
|
concat | () | methode |
public function concat(items:Object):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden de opgegeven items aan het einde van de huidige gegevensaanbieder samengevoegd. Deze methode verzendt een gebeurtenis DataChangeType.ADD.
Parameters
items:Object — De items die moeten worden toegevoegd aan de gegevensaanbieder.
|
Verwante API-elementen
getItemAt | () | methode |
public function getItemAt(index:uint):Object| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Retourneert het item bij de opgegeven index.
Parameters
index:uint — Locatie van het item dat moet worden geretourneerd.
|
Object — Het item bij de opgegeven index.
|
Gegenereerde uitzondering
RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.
|
Verwante API-elementen
getItemIndex | () | methode |
public function getItemIndex(item:Object):int| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Retourneert de index van het opgegeven item.
Parameters
item:Object — Het item dat moet worden gezocht.
|
int — De index van het opgegeven item of -1 wanneer het opgegeven item niet kan worden gevonden.
|
Verwante API-elementen
invalidate | () | methode |
public function invalidate():void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden alle gegevensitems in de DataProvider ongeldig gemaakt en wordt een gebeurtenis DataChangeEvent.INVALIDATE_ALL verzonden. Items worden ongeldig gemaakt nadat zij zijn gewijzigd; de ongeldig gemaakte items worden door de DataProvider automatisch opnieuw getekend.
Verwante API-elementen
invalidateItem | () | methode |
public function invalidateItem(item:Object):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het opgegeven item ongeldig gemaakt. Een item wordt ongeldig gemaakt nadat het is gewijzigd; het ongeldig gemaakte item wordt door de DataProvider automatisch opnieuw getekend.
Parameters
item:Object — Het item dat ongeldig moet worden gemaakt.
|
Verwante API-elementen
invalidateItemAt | () | methode |
public function invalidateItemAt(index:int):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het item bij de opgegeven index ongeldig gemaakt. Een item wordt ongeldig gemaakt nadat het is gewijzigd; het ongeldig gemaakte item wordt door de DataProvider automatisch opnieuw getekend.
Parameters
index:int — Index van het item dat ongeldig moet worden gemaakt.
|
Gegenereerde uitzondering
RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.
|
Verwante API-elementen
merge | () | methode |
public function merge(newData:Object):void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden de opgegeven gegevens aan de gegevens in de gegevensaanbieder toegevoegd en worden alle dubbele items verwijderd. Deze methode verzendt een gebeurtenis DataChangeType.ADD.
Parameters
newData:Object — Gegevens die moeten worden samengevoegd in de gegevensaanbieder.
|
Verwante API-elementen
removeAll | () | methode |
public function removeAll():void| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden alle items uit de gegevensaanbieder verwijderd en wordt een gebeurtenis DataChangeType.REMOVE_ALL verzonden.
Verwante API-elementen
removeItem | () | methode |
public function removeItem(item:Object):Object| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het opgegeven item uit de gegevensaanbieder verwijderd en wordt een gebeurtenis DataChangeType.REMOVE verzonden.
Parameters
item:Object — Het item dat moet worden verwijderd.
|
Object — Het item dat is verwijderd.
|
Verwante API-elementen
removeItemAt | () | methode |
public function removeItemAt(index:uint):Object| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het item bij de opgegeven index verwijderd en wordt een gebeurtenis DataChangeType.REMOVE verzonden.
Parameters
index:uint — Index van het item dat moet worden verwijderd.
|
Object — Het item dat is verwijderd.
|
Gegenereerde uitzondering
RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.
|
Verwante API-elementen
replaceItem | () | methode |
public function replaceItem(newItem:Object, oldItem:Object):Object| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een bestaand item door een nieuw item vervangen en wordt een gebeurtenis DataChangeType.REPLACE verzonden.
Parameters
newItem:Object — Het item dat moet worden vervangen.
| |
oldItem:Object — Het vervangende item.
|
Object — Het item dat is vervangen.
|
Gegenereerde uitzondering
RangeError — Het item is niet gevonden in de gegevensaanbieder.
|
Verwante API-elementen
replaceItemAt | () | methode |
public function replaceItemAt(newItem:Object, index:uint):Object| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt het item bij de opgegeven index vervangen en wordt een gebeurtenis DataChangeType.REPLACE verzonden.
Parameters
newItem:Object — Het vervangende item.
| |
index:uint — De index van het item dat moet worden vervangen.
|
Object — Het item dat is vervangen.
|
Gegenereerde uitzondering
RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.
|
Verwante API-elementen
sort | () | methode |
public function sort(... sortArgs):*| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden de items in de gegevensaanbieder gesorteerd en wordt een gebeurtenis DataChangeType.SORT verzonden.
Parameters
... sortArgs — De argumenten die moeten worden gebruikt voor het sorteren.
|
* — De geretourneerde waarde is afhankelijk van het feit of de methode argumenten ontvangt. Zie de methode Array.sort() voor meer informatie. Deze methode retourneert 0 als de eigenschap sortOption is ingesteld op Array.UNIQUESORT.
|
Verwante API-elementen
sortOn | () | methode |
public function sortOn(fieldName:Object, options:Object = null):*| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee worden de items in de gegevensaanbieder op het opgegeven veld gesorteerd en wordt een gebeurtenis DataChangeType.SORT verzonden. Het opgegeven veld kan een tekenreeks zijn, of een array van tekenreekswaarden die verschillende velden aanduiden om op te sorteren volgens prioriteit.
Parameters
fieldName:Object — Het itemveld waarop moet worden gesorteerd. Deze waarde kan een tekenreeks of een array van tekenreekswaarden zijn.
| |
options:Object (default = null) |
* — De geretourneerde waarde is afhankelijk van het feit of de methode argumenten ontvangt. Zie de methode Array.sortOn() voor meer informatie. Wanneer de eigenschap sortOption is ingesteld op Array.UNIQUESORT, retourneert deze methode 0.
|
Verwante API-elementen
toArray | () | methode |
public function toArray():Array| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een representatie van de gegevens in de gegevensaanbieder gemaakt in de vorm van een object Array.
Geretourneerde waardeArray — Een representatie van de gegevens in de gegevensaanbieder in de vorm van een object Array.
|
toString | () | methode |
override public function toString():String| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Hiermee wordt een tekenreeksrepresentatie van de gegevens in de gegevensaanbieder gemaakt.
Geretourneerde waardeString — Een tekenreeksrepresentatie van de gegevens in de gegevensaanbieder.
|
Gebeurtenisdetails
dataChange | Gebeurtenis |
Type gebeurtenisobject:
eigenschap DataChangeEvent.type =
fl.events.DataChangeEventeigenschap DataChangeEvent.type =
fl.events.DataChangeEvent.DATA_CHANGE| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Wordt verzonden nadat de gegevens zijn gewijzigd.
Hiermee wordt de waarde van de eigenschaptype van een gebeurtenisobject dataChange gedefinieerd.
Deze gebeurtenis heeft de volgende eigenschappen:
| Eigenschap | Waarde |
|---|---|
bubbles | false |
cancelable | false; er is geen standaardgedrag om te annuleren. |
changeType | Hiermee wordt het type wijziging aangegeven dat is toegepast. |
currentTarget | Het object dat het gebeurtenisobject actief verwerkt met een gebeurtenislistener. |
endIndex | Geeft de index aan van het laatste item dat is gewijzigd. |
items | Een array die de gewijzigde items bevat. |
startIndex | Geeft de index aan van het eerste item dat is gewijzigd. |
target | Het object dat de gebeurtenis heeft verzonden. Het doel is niet altijd het object dat luistert naar de gebeurtenis. Gebruik de eigenschap currentTarget om toegang te krijgen tot het object dat luistert naar de gebeurtenis. |
Verwante API-elementen
preDataChange | Gebeurtenis |
Type gebeurtenisobject:
eigenschap DataChangeEvent.type =
fl.events.DataChangeEventeigenschap DataChangeEvent.type =
fl.events.DataChangeEvent.PRE_DATA_CHANGE| Taalversie: | ActionScript 3.0 |
| Productversie: | Flash CS3 |
| Runtimeversies: | Flash Player 9.0.28.0, AIR 1.0 |
Wordt verzonden voordat de gegevens worden gewijzigd.
Hiermee wordt de waarde van de eigenschaptype van een gebeurtenisobject preDataChange gedefinieerd. Dit gebeurtenisobject wordt verzonden voordat de componentgegevens zijn gewijzigd.
Deze gebeurtenis heeft de volgende eigenschappen:
| Eigenschap | Waarde |
|---|---|
bubbles | false |
cancelable | false; er is geen standaardgedrag om te annuleren. |
changeType | Hiermee wordt het type wijziging aangegeven dat moet worden toegepast. |
currentTarget | Het object dat het gebeurtenisobject actief verwerkt met een gebeurtenislistener. |
endIndex | Hiermee wordt de index aangegeven van het laatste item dat moet worden gewijzigd. |
items | Een array die de items bevat die moeten worden gewijzigd. |
startIndex | Hiermee wordt de index aangegeven van het eerste item dat moet worden gewijzigd. |
target | Het object dat de gebeurtenis heeft verzonden. Het doel is niet altijd het object dat luistert naar de gebeurtenis. Gebruik de eigenschap currentTarget om toegang te krijgen tot het object dat luistert naar de gebeurtenis. |
Verwante API-elementen
Voorbeelden Hoe dit voorbeeld te gebruiken
DataProviderExample.as
In dit voorbeeld wordt getoond hoe u gegevensaanbieders kunt gebruiken om de inhoud van diverse gegevensrasters te onderhouden.
U kunt als volgt het voorbeeld uitvoeren:
- Voeg de componenten Label, Button, ComboBox, TextInput en DataGrid toe aan de bibliotheek.
- Sla deze code op als DataProviderExample.as in dezelfde map als het FLA-bestand.
- Stel de klasse Document in het FLA-bestand in op DataProviderExample.
package
{
import fl.controls.Button;
import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.Label;
import fl.controls.TextInput;
import fl.data.DataProvider;
import flash.display.Sprite;
import flash.events.*;
import flash.text.TextFieldAutoSize;
public class DataProviderExample extends Sprite
{
private var southern:DataGrid;
private var northern:DataGrid;
private var world:DataGrid;
private var southernRoster:DataProvider;
private var northernRoster:DataProvider;
private var leagueCB:ComboBox;
private var nameTI:TextInput;
private var goalsTI:TextInput;
private var submitBtn:Button;
public function DataProviderExample() {
southernRoster = new DataProvider();
northernRoster = new DataProvider();
createDataGrids();
createUI();
}
private function createUI():void {
var description:Label = new Label();
description.text = "Enter player's name, goals scored, and hemisphere of origin:";
description.autoSize = TextFieldAutoSize.LEFT;
nameTI = new TextInput();
goalsTI = new TextInput();
var submitBtn:Button = new Button();
submitBtn.label = "Submit Player";
submitBtn.addEventListener(MouseEvent.CLICK, submitPlayer);
leagueCB = new ComboBox();
leagueCB.addItem( { label:"Northern", data: 0 } );
leagueCB.addItem( { label:"Southern", data: 1 } );
description.move(10,10);
nameTI.move(10,40);
nameTI.setSize(150,24);
goalsTI.move(170,40);
goalsTI.setSize(40,24);
leagueCB.move(220,40);
leagueCB.setSize(120,24);
submitBtn.move(350,40);
goalsTI.restrict = "0123456789";
addChild(description);
addChild(leagueCB);
addChild(submitBtn);
addChild(nameTI);
addChild(goalsTI);
}
private function submitPlayer(e:MouseEvent):void {
if(nameTI.text != "" && goalsTI.text != "") {
var targetRoster:DataProvider;
if(leagueCB.selectedItem.label == "Southern") {
targetRoster = southernRoster;
}
else {
targetRoster = northernRoster;
}
targetRoster.addItem( { Name: nameTI.text, Goals: goalsTI.text } );
var worldRoster:DataProvider = southernRoster.clone();
worldRoster.merge(northernRoster);
worldRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
southernRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
northernRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
world.dataProvider = worldRoster;
nameTI.text = "";
goalsTI.text = "";
}
}
private function createDataGrids():void {
southern = new DataGrid();
northern = new DataGrid();
world = new DataGrid();
southern.move(10,100);
northern.move(180,100);
world.move(350,100);
southern.setSize(170, 250);
northern.setSize(170, 250);
world.setSize(170, 250);
southern.columns =
northern.columns =
world.columns = [ "Name", "Goals" ];
southern.dataProvider = southernRoster;
northern.dataProvider = northernRoster;
addChild(southern);
addChild(northern);
addChild(world);
var northernLabel:Label = new Label();
northernLabel.autoSize = TextFieldAutoSize.LEFT;
northernLabel.text = "Southern Hemisphere";
northernLabel.move(10,75);
addChild(northernLabel);
var southernLabel:Label = new Label();
southernLabel.autoSize = TextFieldAutoSize.LEFT;
southernLabel.text = "Northern Hemisphere";
southernLabel.move(180,75);
addChild(southernLabel);
var majorLabel:Label = new Label();
majorLabel.autoSize = TextFieldAutoSize.LEFT;
majorLabel.text = "World";
majorLabel.move(350,75);
addChild(majorLabel);
}
}
}
Wed Jun 13 2018, 11:42 AM Z