Loader  - AS3

load() メソッドまたは loadBytes() メソッドを使用して読み込まれた SWF ファイルまたはイメージ（JPG、PNG、または GIF）ファイルのルート表示オブジェクトが含まれます。

関連する API エレメント

読み込まれているオブジェクトに対応する LoaderInfo オブジェクトを返します。LoaderInfo オブジェクトは、Loader オブジェクトと読み込まれたコンテンツオブジェクト間で共有されます。LoaderInfo オブジェクトは、読み込みの進行状況に関する情報と、読み込まれたファイルに関する統計を提供します。

読み込みに関連するイベントは、Loader オブジェクトの contentLoaderInfo プロパティで参照される LoaderInfo オブジェクトによって送出されます。contentLoaderInfo プロパティは、コンテンツの読み込みの前も、有効な valid LoaderInfo オブジェクトに設定されているので、読み込みの前にイベントリスナーをオブジェクトに追加できます。

読み込まれた SWF で発生する不明なエラーを検出するには、Loader.contentLoaderInfo.uncaughtErrorEvents プロパティではなく、Loader.uncaughtErrorEvents プロパティを使用します。

関連する API エレメント

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

この Loader オブジェクトが読み込んだ SWF で不明なエラーが発生したときに、uncaughtError イベントを送出するオブジェクトです。不明なエラーが発生するのは、いずれかの try..catch ブロックの外側でエラーがスローされたり、登録されたリスナーを持たない ErrorEvent オブジェクトが送出される場合です。

Loader オブジェクトの uncaughtErrorEvents プロパティから送出されるイベントは、プロパティから直接送出されるものではなく、プロパティでバブルされたイベントです。ターゲット段階で uncaughtErrorEvent を送出することはありません。キャプチャおよびバブリング段階以外では、イベントは送出されません。現在の SWF（Loader オブジェクトが定義されている SWF）内の不明なエラーを検出するには、代わりに LoaderInfo.uncaughtErrorEvents プロパティを使用します。

Loader オブジェクトによって読み込まれたコンテンツが AVM1（ActionScript 2）SWF ファイルである場合、AVM1 SWF ファイル内のキャッチされなかったエラーで uncaughtError イベントが発生することはありません。

関連する API エレメント

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

SWF、JPEG、GIF、または PNG などのファイルの読み込みに使用できる Loader オブジェクトを作成します。アセットを Loader インスタンスの子として読み込むには、load() メソッドを呼び出します。その後、Loader オブジェクトを表示リストに追加できます。例えば、DisplayObjectContainer インスタンスの addChild() メソッドを使用して追加します。アセットは読み込まれるとステージに表示されます。

Loader インスタンスを "リスト外" で、つまり、表示リスト上の表示オブジェクトコンテナに追加しなくても使用できます。このモードの場合、Loader インスタンスを使用して、アプリケーションの追加モジュールを含む SWF ファイルを読み込むことができます。

SWF ファイルの読み込みが完了したことを検出するには、Loader オブジェクトの contentLoaderInfo プロパティに関連付けられた LoaderInfo オブジェクトのイベントを使用できます。その時点で、モジュール SWF ファイル内のコードを実行し、モジュールを初期化して、開始できます。リスト外モードでは、Loader インスタンスを使用して、コンポーネントまたはメディアアセットを含む SWF ファイルをロードすることもできます。この場合も、LoaderInfo オブジェクトのイベント通知を使用して、コンポーネントのロードが完了したことを検出できます。 その時点で、アプリケーションは SWF ファイルのライブラリ内のコンポーネントとメディアアセットの使用を開始できます。これは、それらのコンポーネントとアセットを表す ActionScript 3.0 クラスをインスタンス化することによって行います。

Loader オブジェクトの状態を判別するには、Loader オブジェクトの contentLoaderInfo プロパティに関連付けられた LoaderInfo オブジェクトの次のイベントを監視します。

• open イベントは、読み込みが開始したときに送出されます。
• ioError または securityError イベントは、ファイルを読み込めない場合、あるいは読み込み中にエラーが発生した場合に送出されます。
• progress イベントは、ファイルが読み込まれている間、継続的に発生します。
• complete イベントは、ファイルのダウンロードが完了したときに送出されます。ただし、この時点では、読み込まれたムービークリップのメソッドとプロパティはまだ使用できません。
• init イベントは、読み込まれた SWF ファイルのプロパティおよびメソッドにアクセスできるようになると、送出されます。そのため、読み込まれた SWF ファイルに対して各種の操作を開始できます。このイベントは、complete ハンドラーの前に送出されます。ストリーミング SWF ファイルの場合、init イベントは complete イベントよりもかなり前に発生することがあります。ほとんどの場合、init ハンドラーを使用します。

注意（iOS のみ）：iOS での AIR アプリケーションでは、アプリケーションパッケージからロードする場合のみ、ActionScript を含む SWF ファイルをロードできます。この制約では、ActionScript 向けに書き出されたクラス名を含むアセットなどの、あらゆる ActionScript が対象となります。あらゆる SWF ファイルをロードするためには、親 SWF と同じアプリケーションドメインを使用して SWF をロードする必要があります。

AIR 3.6 より前のバージョンでは、アプリケーションパッケージからロードする場合でも、ネットワーク経由でロードする場合でも、ロードできるのは ActionScript バイトコードを含まない SWF ファイルのみです。ActionScript を含む外部 SWF ファイルを使用する代わりに、SWC ライブラリを作成し、そのライブラリをメイン SWF にリンクしてください。

これらの制約は、アプリケーションを iOS シミュレーター（ipa-test-interpreter-simulator もしくは ipa-debug-interpreter-simulator）またはインタープリターモード（ipa-test-interpreter もしくは ipa-debug-interpreter）で実行する場合には適用されません。

関連する API エレメント

Loader インスタンスに対して現在進行中の load() メソッドの処理をキャンセルします。

関連する API エレメント

SWF、JPEG、プログレッシブ JPEG、非アニメーション GIF、または PNG ファイルを、この Loader オブジェクトの子であるオブジェクトにロードします。アニメーション GIF ファイルを読み込むと、先頭のフレームのみ表示されます。Loader オブジェクトには子を 1 つだけしか含めることができないため、後続の load() 要求を発行すると直前の要求（保留中であれば）を終了し、新たに読み込みを開始します。

注意：AIR 1.5 および Flash Player 10 では、読み込まれるイメージの最大サイズは幅または高さが 8,191 ピクセルです。ただし、総ピクセル数が 16,777,215 ピクセルを超えることはできません（したがって、読み込まれるイメージの幅が 8,191 ピクセルであった場合、高さは 2,048 ピクセルまでしか指定できません）。Flash Player 9 以前および AIR 1.1 以前では、高さの限界は 2,880 ピクセルで幅の限界は 2,880 ピクセルです。

Loader オブジェクトに読み込んだ SWF ファイルまたはイメージは、その Loader オブジェクトの親の表示オブジェクトの位置、回転、および拡大 / 縮小の各プロパティを継承します。

このメソッドを使用して読み込まれたムービーまたはイメージを削除したり、進行中の読み込み処理をキャンセルするには、unload() メソッドを使用します。

SWF ファイルがこのメソッドを使用しないようにするには、SWF コンテンツを含んでいる HTML ページに allowNetworking パラメーター（object タグおよび embed タグのパラメーター）を設定します。

iOS の場合の注意点

iOS での AIR アプリケーションでは、アプリケーションパッケージからロードする場合のみ、ActionScript を含む SWF ファイルをロードできます。この制約では、ActionScript 向けに書き出されたクラス名を含むアセットなどの、あらゆる ActionScript が対象となります。あらゆる SWF ファイルをロードするためには、以下の例のように、親 SWF と同じアプリケーションドメインを使用して SWF をロードする必要があります。

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

また、iOS では、ActionScript バイトコード（ABC）を含む SWF ファイルをロードしてからアンロードし、再度ロードすることはできません。これを行おうとすると、ランタイムでエラー 3764 が発生します。

AIR 3.6 より前のバージョンでは、アプリケーションパッケージからロードする場合でも、ネットワーク経由でロードする場合でも、ロードできるのは ActionScript バイトコードを含まない SWF ファイルのみです。ActionScript を含む外部 SWF ファイルを使用する代わりに、SWC ライブラリを作成し、そのライブラリをメイン SWF にリンクしてください。

これらの制約は、アプリケーションを iOS シミュレーター（ipa-test-interpreter-simulator もしくは ipa-debug-interpreter-simulator）またはインタープリターモード（ipa-test-interpreter もしくは ipa-debug-interpreter）で実行する場合には適用されません。

Loader のセキュリティ

このメソッドを使用するときは、Loader クラスの説明にある Flash Player セキュリティモデルを考慮してください。

Flash Player 10 以降では、"multipart/form-data" などのマルチパート Content-Type にアップロードが含まれていると（アップロードが含まれているかどうかは POST ボディ内の "content-disposition" ヘッダーの "filename" パラメーターで示されます）、そのアップロードに適用されるセキュリティ規則によって POST 処理が拘束されます。

• POST 処理は、マウスのクリックやキーの押下などのユーザーが開始したアクションに応答して実行する必要があります。
• POST 処理がクロスドメインである（POST ターゲットが、POST 要求を送信中の SWF ファイルと同じサーバー上にない）場合は、クロスドメインアクセスを許可する URL ポリシーファイルをターゲットサーバーが提供する必要があります。

また、すべてのマルチパート Content-Type では、RFC2046 標準に準拠した有効なシンタックスを使用する必要があります。シンタックスが有効でない場合は、アップロードに適用されるセキュリティ規則によって POST 処理が拘束されます。

セキュリティについて詳しくは、Flash Player デベロッパーセンターのトピック：セキュリティを参照してください。

パラメーター

関連する API エレメント

ByteArray オブジェクトに保管されているバイナリデータからロードします。

loadBytes() メソッドは、非同期のメソッドです。読み込まれたオブジェクトのプロパティにアクセスする前に「init」イベントを待機する必要があります。

このメソッドを使用するときは、Loader クラスの説明にある Flash Player セキュリティモデルを考慮してください。

注意（iOS のみ）：iOS での AIR アプリケーションでは、アプリケーションパッケージからロードする場合のみ、ActionScript を含む SWF ファイルをロードできます。この制約では、ActionScript 向けに書き出されたクラス名を含むアセットなどの、あらゆる ActionScript が対象となります。あらゆる SWF ファイルをロードするためには、親 SWF と同じアプリケーションドメインを使用して SWF をロードする必要があります。

AIR 3.6 より前のバージョンでは、iOS ではこのメソッドの効果はありません。

パラメーター

関連する API エレメント

IFilePromise インスタンスを読み込みます。

loadFilePromise メソッドは IFilePromise オブジェクトを使用し、バイナリデータを読み込みます。ビデオなど、データがプログレッシブストリームの場合、読み込まれたオブジェクトのプロパティにアクセスする前に、"init" または progress イベントを待ちます。それ以外の場合、データが完全に読み込まれたことを確認する complete イベントを待ちます。

このメソッドを使用するときは、Loader クラスの説明にある Flash Player セキュリティモデルを考慮してください。

パラメーター

関連する API エレメント

load() メソッドを使用してロードされた、この Loader オブジェクトの子を削除します。関連した LoaderInfo オブジェクトの property は null にリセットされます。他のオブジェクトが参照している可能性があるので、子は必ずしも破棄されるとは限りません。ただし、Loader オブジェクトの子ではなくなります。

unload() メソッドを呼び出したときに、Loader オブジェクトの contentLoaderInfo プロパティが null に設定されます。SWF と一緒にロードされたすべての視覚的アセットがアンロードされ、メモリから削除されます。ロードされた SWF 内の ActionScript クラス定義はメモリ内に残され、ロードされた SWF と同じアプリケーションドメイン内のコードでこれらのクラスのインスタンスにアクセスして、新しいインスタンスを作成できます。

注意（iOS のみ）：AIR 3.6 より前のバージョンでは、iOS ではこのメソッドの効果はありません。

子 SWF ファイルを解放する前に、LocalConnection、NetConnection、NetStream、Sound オブジェクトなど、子 SWF ファイルのオブジェクト内のストリームをすべて明示的に閉じておくことをお勧めします。そうしなかった場合は、子 SWF ファイルが解放された後も、子 SWF ファイルのオーディオの再生が続く場合があります。子 SWF ファイルのストリームを閉じるには、unload イベントを受け取る子にイベントリスナーを追加します。親が Loader.unload() を呼び出すと、unload イベントが子に対して送出されます。次のコードは、このような処理を行う例を示します。

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

関連する API エレメント

子 SWF ファイルの内容のアンロードを試み、ロードされた SWF ファイルのコマンドの実行を中止します。このメソッドは、Loader.load() または Loader.loadBytes() を使用してロードされた SWF ファイルのアンロードを試みます。このために、子 SWF ファイルの EventDispatcher、NetConnection、Timer、Sound、または Video オブジェクトへの参照を削除します。この結果、子 SWF ファイルおよび子 SWF ファイルの表示リストで以下が行われます。

• サウンドが停止されます。
• Stage イベントリスナーが削除されます。
• enterFrame、frameConstructed、exitFrame、activate、および deactivate のイベントリスナーが削除されます。
• タイマーが停止されます。
• Camera インスタンスおよび Microphone インスタンスがデタッチされます。
• ムービークリップが停止されます。

unloadAndStop() メソッドを呼び出したときに、Loader オブジェクトの contentLoaderInfo プロパティが null に設定されます。SWF と一緒にロードされたすべての視覚的アセットがアンロードされ、メモリから削除されます。ロードされた SWF 内の ActionScript クラス定義はメモリ内に残され、ロードされた SWF と同じアプリケーションドメイン内のコードでこれらのクラスのインスタンスにアクセスして、新しいインスタンスを作成できます。

注意（iOS のみ）：AIR 3.6 より前のバージョンでは、iOS ではこのメソッドの効果はありません。

パラメーター

関連する API エレメント

1. url プロパティを作成します。これはイメージファイルの場所と名前です。
2. LoaderExample コンストラクターでは、loader という名前の新しい Loader オブジェクトが作成され、手順 3 出説明する configureListeners() メソッドに渡されます。
3. コンストラクターは、request という URLRequest オブジェクトの新しいインスタンスを作成しますが、その前に、ファイル名と場所が分かるように url を渡します。
4. request オブジェクトが loader オブジェクトの load() メソッドに渡されます。これにより、イメージが表示リストにロードされます。
5. clickHandler イベントリスナーがローダーの click イベントに対して登録されます。マウスをクリックすると、ロードされたイメージはアンロードされます。
6. configureListeners() メソッドは、次のメソッドを使用して、7 つのイベントリスナーを追加します。
   • completeHandler() メソッドは、イメージのロードが完了したときに実行されます。
   • httpStatusHandler() メソッドは、イメージがローカルにロードされない場合で、ネットワーク要求を行うことができ、Flash Player がそれを検出できる場合にのみ実行されます。
   • initHandler() メソッドが実行されるのは、completeHandler() メソッドの前、progressHandler() メソッドの後です。一般的には、SWF ファイルをロードするとき、init イベントの方が便利です。
   • ioErrorHandler() メソッドは、イメージファイルを使用できないか、イメージファイルにアクセスできない場合に実行されます。
   • openHandler() メソッドは、イメージファイルが最初に開かれたときに実行されます。
   • progressHandler() メソッドは、イメージファイルのロードが開始したときに実行され、イメージのロードが完了したときに再び実行されます。
   • unLoadHandler() メソッドは、ユーザーがイメージをクリックしたときに unload() メソッドを使用してイメージがアンロードされた場合に実行されます。

次の要件に注意してください。

• この例では、Image.gif という名前のファイルがコンパイル済み SWF ファイルと同じディレクトリに配置されている必要があります。メイン SWF ファイルのサイズ内に収まる領域を持つイメージを使用します。
• この例では、LoaderInfo オブジェクトで使用可能なすべてのイベントを利用しますが、ほとんどの場合、必要になるのは 1 つのサブセットのみです。特に、イメージファイルをロードするだけの場合は、ローカルイメージをロードするときの complete イベント（および必要に応じて ioError イベント）で十分です。

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}