URLRequest  - AS3

この要求に関する認証要求を処理するかどうかを指定します（true または false）。false の場合、認証チャレンジは HTTP エラーを返します。

以下の認証メソッドがサポートされています。

• Windows — HTTP 認証（基本 / ダイジェスト）、Windows 統合認証（NTLM および Kerberos を含む）、SSL 証明書認証
• Mac — HTTP 認証（基本 / ダイジェスト）、NTLM 認証、SSL 証明書認証

注意：FileReference.upload()、FileReference.download()、および HTMLLoader.load() の各メソッドは、URLRequest.authenticate プロパティをサポートしていません。

デフォルト値： true。

関連する API エレメント

この要求に対する正常な応答データをキャッシュするかどうかを指定します。true に設定すると、AIR アプリケーションはオペレーティングシステムの HTTP キャッシュを使用します。

注意：HTMLLoader.load() メソッドは URLRequest.cacheResponse プロパティをサポートしていません。

デフォルト値： true。

関連する API エレメント

data プロパティのコンテンツの MIME コンテンツタイプです。

デフォルト値は application/x-www-form-urlencoded です。

注意：FileReference.upload()、FileReference.download() および HTMLLoader.load() の各メソッドは、URLRequest.contentType プロパティをサポートしていません。

POST リクエストを送信する場合、contentType プロパティと data プロパティの値が正しく対応している必要があります。contentType プロパティの値は、data プロパティの値を解釈する方法をサーバーに指示します。

• data プロパティの値が URLVariables オブジェクトの場合、contentType の値は application/x-www-form-urlencoded である必要があります。
• data プロパティの値が他の型の場合、contentType の値は送信される POST データ（data プロパティの値に含まれるバイナリまたはストリングのデータ）の型を示す必要があります。
• FileReference.upload() の場合、リクエストの Content-Type は自動的に multipart/form-data に設定され、contentType プロパティの値は無視されます。

Flash Player 10 以降では、"multipart/form-data" などのマルチパート Content-Type にアップロードが含まれていると（アップロードが含まれているかどうかは POST ボディ内の "content-disposition" ヘッダーの "filename" パラメーターで示されます）、そのアップロードに適用されるセキュリティ規則によって POST 処理が拘束されます。

• POST 処理は、マウスのクリックやキーの押下などのユーザーが開始したアクションに応答して実行する必要があります。
• POST 処理がクロスドメインである（POST ターゲットが、POST 要求を送信中の SWF ファイルと同じサーバー上にない）場合は、クロスドメインアクセスを許可する URL ポリシーファイルをターゲットサーバーが提供する必要があります。

また、すべてのマルチパート Content-Type では、RFC2046 標準に準拠した有効なシンタックスを使用する必要があります。シンタックスが有効でない場合は、アップロードに適用されるセキュリティ規則によって POST 処理が拘束されます。

関連する API エレメント

URL リクエストで送信されるデータを含むオブジェクトです。

このプロパティはメソッドプロパティと一緒に使用します。method の値が GET のときは、HTTP クエリ文字列シンタックスを使って、data の値は URLRequest.url の値に追加されます。method の値が POST（または GET 以外の値）のときは、data の値は、HTTP 要求の本文に送信されます。

URLRequest API は、ストリング以外に、バイナリ POST と URL エンコード変数もサポートします。データオブジェクトには、ByteArray、URLVariables、または String オブジェクトを指定できます。

データが使用される方法は、使用されるオブジェクトの型によって異なります。

• オブジェクトが ByteArray オブジェクトの場合、ByteArray オブジェクトのバイナリデータは POST データとして使用されます。GET の場合、ByteArray 型のデータはサポートされません。FileReference.upload() および FileReference.download() の場合も、ByteArray 型のデータはサポートされません。
• オブジェクトが URLVariables オブジェクトで、メソッドが POST の場合、変数は x-www-form-urlencoded 形式を使用してエンコードされ、結果のストリングが POST データとして使用されます。例外は FileReference.upload() の呼び出しです。この場合、変数は、multipart/form-data ポストの個別のフィールドとして送信されます。
• オブジェクトが URLVariables オブジェクトで、メソッドが GET の場合、URLVariables オブジェクトは URLRequest オブジェクトによって送信される変数を定義します。
• それ以外の場合、オブジェクトはストリングに変換され、そのストリングが POST または GET データとして使用されます。

このデータは、navigateToURL() や FileReference.upload() などのメソッドで URLRequest オブジェクトが使用されるまで送信されません。

注意：contentType の値は、data プロパティのデータ型に対応させる必要があります。contentType プロパティの説明の注意を参照してください。

関連する API エレメント

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Flash Player キャッシュに保存される（または Flash Player キャッシュから取得される）署名付き Adobe プラットフォームコンポーネントを一意に識別するストリングです。 Adobe プラットフォームコンポーネントは、ユーザーのコンピューターに永続的にキャッシュされる SWF コンテンツを含む署名付きファイル（SWZ ファイル）です。すべての SWZ ファイルはアドビ システムズ社によって署名されます。ダイジェストは単一のキャッシュされているファイルに対応します。ファイルを何らかの方法で変更すると、ダイジェストは予期しない方法で変更されます。ダイジェストを使用することにより、複数のドメインにまたがってキャッシュされているファイルを確認できます。同じダイジェストを持つ 2 つのファイルは同じファイルで、異なるダイジェストを持つ 2 つのファイルは同じファイルではありません。 ダイジェストに「なりすます」ファイル、ダイジェストを装うファイルを作成することは（実質的に）できません。

ダイジェストは、SHA-256 メッセージダイジェストアルゴリズム（16 進数形式で 64 文字長）に基づきます。

例えば、Flex SDK は Flex フレームワークの SWZ を含みます（また、その SWZ ファイルのダイジェストストリングを提供します）。この SWZ を Web サーバーにポストし、それを URLLoader オブジェクトの load() メソッドを使用して SWF ファイルにロードすることができます。エンドユーザーのコンピューターに一致する SWZ ファイルが既にキャッシュされている場合は、そのキャッシュされている SWZ ファイルが使用されます。SWZ ファイルの digest と提供したダイジェストが一致すると、SWZ ファイルは一致します。それ以外の場合は、指定した URL から SWZ ファイルがアプリケーションによってダウンロードされます。

URLRequest オブジェクトの digest パラメーターは、URLLoader.load() メソッドを呼び出して SWZ ファイルをロードする場合にのみ設定します。URLRequest オブジェクトの digest パロパティが、他のメソッドで設定済みである場合は、IOError 例外がスローされます。

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

リダイレクトを続行するか（true）、続行しないか（false）を指定します。

注意：FileReference.upload()、FileReference.download()、および HTMLLoader.load() の各メソッドは、URLRequest.followRedirects プロパティをサポートしていません。

デフォルト値： true。

関連する API エレメント

この要求のアイドルタイムアウト値をミリ秒単位で指定します。

アイドルタイムアウトとは、接続が確立された後、要求が廃棄されるまでの間、クライアントがサーバーからの応答を待機する時間です。

注意：HTMLLoader.load() メソッドは URLRequest.idleTimeout プロパティをサポートしていません。HTMLLoader クラスは、このクラス自体の idleTimeout プロパティを定義します。

デフォルト値： initialized from the URLRequestDefaults.idleTimeout property。

関連する API エレメント

HTTP プロトコルスタックでこの要求のクッキーを管理するかどうかを指定します。true の場合、cookie が要求に追加され、応答 cookie が記憶されます。false の場合、cookie は要求に追加されず 応答 cookie は記憶されませんが、ユーザーは直接ヘッダーを操作することで cookie 自体を管理できます。注意：Windows では、manageCookies が true に設定されている場合、URL 要求に手動で cookie を追加することはできません。他のオペレーティングシステムでは、manageCookies が true、false のどちらに設定されているかに関わらず、要求に cookie を追加することができます。cookie の追加が許可されている場合、cookie のデータを格納している URLRequestHeader オブジェクトを requestHeaders 配列に手動で追加することで、要求に cookie を追加できます。

Mac OS では、cookie は Safari と共有されます。Mac OS でクッキーを消去するには：

1. Safari を開きます。
2. Safari／Preferences を選択し、Security パネルをクリックします。
3. 「Show Cookies」ボタンをクリックします。
4. 「Remove All」ボタンをクリックします。

Windows でクッキーを消去するには：

1. インターネットのプロパティコントロールパネルを開き、「全般」タブをクリックします。
2. 「Cookie の削除」ボタンをクリックします。

デフォルト値： true。

関連する API エレメント

HTTP フォーム送信メソッドを制御します。

（ブラウザーの）Flash Player で実行される SWF コンテンツの場合、このプロパティは GET 操作または POST 操作に制限されます。有効な値は URLRequestMethod.GET または URLRequestMethod.POST です。

Adobe AIR で実行されるコンテンツの場合、そのコンテンツがアプリケーションセキュリティボックス内にあれば、どのストリング値も使用可能です。それ以外の場合、コンテンツが Flash Player で実行されるときと同様に、GET 操作または POST 操作の使用に制限されます。

Adobe AIR で実行中のコンテンツの場合、navigateToURL() 関数を使用すると、ランタイムでは、POST メソッドを使用する URLRequest（method プロパティが URLRequestMethod.POST に設定されているもの）は、GET メソッドとして処理されます。

注意：Flash Player で実行されているときに、参照されるフォームに本文がない場合、Flash Player では自動的に GET 操作が使用されます。これは、メソッドが URLRequestMethod.POST に設定されている場合でも同じです。このため、正しいメソッドが使用されるように、ダミーの body を必ず含めることをお勧めします。

デフォルト値： URLRequestMethod.GET。

関連する API エレメント

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

HTTP リクエストヘッダーの配列が HTTP リクエストに追加されます。配列は URLRequestHeader オブジェクトから構成されます。配列の各オブジェクトは、次のように名前ストリングと値ストリングを含む URLRequestHeader オブジェクトである必要があります。

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Flash Player および AIR ランタイムには、リクエストヘッダーに一定の制限があります。詳しくは、URLRequestHeader クラスの説明を参照してください。

URLRequest パラメーターを受け取るメッソドすべてが requestHeaders プロパティをサポートしているわけではありません。呼び出すメソッドのマニュアルを参照してください。例えば、FileReference.upload() メソッドおよび FileReference.download() メソッドは、URLRequest.requestHeaders プロパティをサポートしていません。

ブラウザーの制限により、カスタム HTTP リクエストヘッダーは POST リクエストだけをサポートし、GET リクエストはサポートしません。

関連する API エレメント

リクエストされる URL です。

Uniform Resource Locator 仕様で危険と説明されている文字（http://www.faqs.org/rfcs/rfc1738.html を参照）や、URLRequest オブジェクトの URL スキームで予約されている文字（予約されている目的以外に使用する場合）は、必ずエンコードしてください。例えば、パーセント（%）記号の場合は "%25" を、番号記号の場合は "%23" を使用し、"http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25" などと示します。

デフォルトで、URL は呼び出し元のファイルと同じドメインにある必要があります。ただし、コンテンツが Adobe AIR アプリケーションセキュリティボックスで実行中の場合を除きます。異なるドメインからデータをロードする必要があるときは、データをホストするサーバーに URL ポリシーファイルを配置します。詳細については、URLRequest クラスの説明を参照してください。

Adobe AIR で実行されるコンテンツの場合、アプリケーションセキュリティサンドボックス内のファイル（AIR アプリケーションと共にインストールされるファイル）は、次の URL スキームのいずれかを使用して URL にアクセスできます。

• http および https
• file
• app-storage
• app

注意：IPv6（Internet Protocol version 6）は AIR および Flash Player 9.0.115.0 以降のバージョンでサポートされています。IPv6 は、128 bit のアドレスをサポートするインターネットプロトコルのバージョンです（32 bit のアドレスをサポートする、以前の IPv4 プロトコルの機能を向上したものです）。ネットワークインターフェイスでの IPv6 のアクティブ化が必要になる場合があります。詳細については、データをホストするオペレーティングシステムのヘルプを参照してください。ホストしているシステムで IPv6 がサポートされる場合、次に示すように、角括弧（[]）内に URL の IPv6 数値リテラルアドレスを指定できます。

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

この URLRequest がデータを取得する前に、ローカルキャッシュを参照するかどうかを指定します。

注意：HTMLLoader.load() メソッドは URLRequest.useCache プロパティをサポートしていません。

デフォルト値： true。

関連する API エレメント

HTTP 要求で使用されるユーザーエージェントストリングを指定します。

デフォルト値は、Flash Player で使用されるユーザーエージェントストリングと同じです。これは、Macintosh、Linux、Windows で異なります。

注意：HTMLLoader オブジェクトの load() メソッドで URLRequest オブジェクトが使用される場合、このプロパティはユーザーエージェントストリングに影響しません。HTMLLoader オブジェクトに対しユーザーエージェントストリングを設定するには、HTMLLoader オブジェクトの userAgent プロパティを設定するか、静的な URLRequestDefaults.userAgent プロパティを設定します。

関連する API エレメント

URLRequest オブジェクトを作成します。System.useCodePage が true の場合、リクエストは Unicode ではなく、システムのコードページを使ってエンコードされます。System.useCodePage が false の場合、リクエストはシステムのコードページではなく、Unicode を使ってエンコードされます。

関連する API エレメント

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

新しい URLRequest 内の URL の一部を、ソースの URLRequest からリダイレクトされた URL に置換することを許可します。最初の要求がリダイレクトされた後、その後の要求を、リダイレクトされたサーバーの場所に直接送信することができます。

最初の URLRequest が完了し、HTTPStatusEvent.redirected が true の場合、最初の要求を sourceRequest として使用し、このメソッドを呼び出すことができます。デフォルトでは、リダイレクトされた URL のドメインを使用して、この URLRequest の URL のドメインが置換されます。このメソッドを呼び出す前に、URLRequest.url を設定する必要があります。このメソッドは、この URLRequest が読み込まれる前に呼び出す必要があります。オプションとして、wholeURL パラメーターが true の場合、ソースの URLRequest のファイル名を除く URL 全体を使用して、この URLRequest の最終的なファイル名を除く URL 全体が置換されます。また、オプションとして pattern パラメーターに文字列や正規表現を指定して呼び出すこともできます。このパターンが検索され、replace パラメーターの文字列に置換されます。この検索と置換は、URL の置換後に行われます。

パラメーター

関連する API エレメント

この例を実行するには、XMLFile.xml というファイルを SWF ファイルと同じディレクトリに配置します。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}