Transform  - AS3

表示オブジェクトのカラーを全体的に調整する値を格納している ColorTransform オブジェクトです。

関連する API エレメント

この表示オブジェクトおよびルートレベルまでのすべての親オブジェクトに適用される、結合されたカラー変換を表す ColorTransform オブジェクトです。異なるレベルで異なるカラー変換を適用した場合、すべての変換が連結されて、このプロパティ用の 1 つの ColorTransform オブジェクトになります。

関連する API エレメント

この表示オブジェクトおよびルートレベルまでのそのすべての親オブジェクトの結合された変換マトリックスを表す Matrix オブジェクトです。異なるレベルで異なる変換マトリックスを適用した場合、すべてのマトリックスが連結されて、このプロパティ用の 1 つのマトリックスになります。 また、ブラウザーで実行されるサイズ変更可能な SWF コンテンツの場合、このプロパティでは、ウィンドウのサイズ変更に伴って生じるステージ座標とウィンドウ座標との差異が考慮されます。このため、このプロパティは、ローカル座標をウィンドウ座標に変換しますが、そのウィンドウ座標はステージの座標空間とは異なる場合があります。

表示オブジェクトの拡大 / 縮小、回転、および移動を変更する値を格納している Matrix オブジェクトです。

matrix プロパティが null 以外の値に設定されていると、matrix3D プロパティは null になります。また、matrix3D プロパティが null 以外の値に設定されていると、matrix プロパティは null になります。

関連する API エレメント

3 次元表示オブジェクトの Matrix3D オブジェクトへのアクセスを提供します。Matrix3D オブジェクトは、表示オブジェクトの位置と方向を決定する変換マトリックスを表します。Matrix3D オブジェクトは、遠近法に基づく投影を実行することもできます。

matrix プロパティが null 以外の値に設定されていると、matrix3D プロパティは null になります。また、matrix3D プロパティが null 以外の値に設定されていると、matrix プロパティは null になります。

関連する API エレメント

3 次元表示オブジェクトの PerspectiveProjection オブジェクトへのアクセスを提供します。PerspectiveProjection オブジェクトを使用して、ステージの遠近法に基づく変形を変更したり、遠近法に基づく変形を表示オブジェクトの 3 次元の子すべてに割り当てることができます。

視点とステージの縦横比（サイズ）に基づいて、デフォルトの PerspectiveProjection オブジェクトがルートオブジェクトに割り当てられます。

関連する API エレメント

ステージ上の表示オブジェクトの境界を示す矩形を定義する Rectangle オブジェクトです。

Matrix3D オブジェクトを返します。Matrix3D オブジェクトは、現在の表示オブジェクトの空間を基準にして、指定された表示オブジェクトの空間を変換します。getRelativeMatrix3D() メソッドを使用すると、ある 3 次元表示オブジェクトを基準にして別の 3 次元表示オブジェクトを移動できます。

パラメーター

関連する API エレメント

1. TransformExample() コンストラクターが新しい Sprite オブジェクト target を作成します。
2. TransformExample() コンストラクターは draw() メソッドを呼び出します。このメソッドは、グラデーションの四角形をスプライトに描画します。
3. TransformExample() コンストラクターはスプライトに click イベントリスナーを追加します。これは clickHandler() メソッドによって処理されます。
4. clickHandler() メソッドは、新しい Matrix オブジェクト skewMatrix を作成し、傾斜効果を適用します。もう 1 つの行列 tempMatrix は、スプライトの現在の変換行列に割り当てられ、skewMatrix と concat() メソッドによって結合されます。この行列は正方形のスプライトの transform.matrix プロパティに割り当てられます。ユーザーが正方形をクリックするたびに clickHandler() を呼び出して、正方形のシェイプを傾斜させて変更します。
5. また、clickHandler() メソッドは、新しい ColorTransform オブジェクトを作成します。 新しい ColorTransform オブジェクトの redOffset プロパティは redOffset の現在の値に設定され、25 ずつ増加します。同様に、blueOffset プロパティは 25 ずつ減少します。クリックするたびに、スプライトのカラーが変化します。

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}