ProgressEvent

パッケージ	flash.events
クラス	public class ProgressEvent
継承	ProgressEvent Event Object
サブクラス	ModuleEvent, ResourceEvent, RSLEvent, StyleEvent, VideoProgressEvent

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

ProgressEvent オブジェクトは、ロード処理が開始されたとき、またはソケットがデータを受信したときに送出されます。これらのイベントは通常、SWF ファイル、イメージまたはデータがアプリケーションにロードされるときに生成されます。次の 2 種類のキーボードイベントがあります。ProgressEvent.PROGRESS および ProgressEvent.SOCKET_DATAまた AIR では、NativeProcess クラスによって子プロセスとの間でデータの送受信が行われるときに、ProgressEvent オブジェクトが送出されます。

例を表示

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		bubbles : Boolean [読み取り専用] イベントがバブリングイベントかどうかを示します。	Event
		bytesLoaded : Number リスナーがイベントを処理しているときに読み込まれたアイテム数またはバイト数です。	ProgressEvent
		bytesTotal : Number 読み込みプロセスが成功した場合に読み込まれるアイテムまたはバイトの総数です。	ProgressEvent
		cancelable : Boolean [読み取り専用] イベントに関連付けられた動作を回避できるかどうかを示します。	Event
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		currentTarget : Object [読み取り専用] イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。	Event
		eventPhase : uint [読み取り専用] イベントフローの現在の段階です。	Event
		target : Object [読み取り専用] イベントターゲットです。	Event
		type : String [読み取り専用] イベントのタイプです。	Event

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		ProgressEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, bytesLoaded:Number = 0, bytesTotal:Number = 0) progress イベントに関する情報を含む Event オブジェクトを作成します。	ProgressEvent
		clone():Event [オーバーライド] ProgressEvent オブジェクトのコピーを作成して、各プロパティの値を元のプロパティの値と一致するように設定します。	ProgressEvent
		formatToString(className:String, ... arguments):String カスタム ActionScript 3.0 Event クラスに toString() メソッドを実装するためのユーティリティ関数です。	Event
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isDefaultPrevented():Boolean イベントで preventDefault() メソッドが呼び出されたかどうかを確認します。	Event
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		preventDefault():void イベントのデフォルト動作をキャンセルできる場合に、その動作をキャンセルします。	Event
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		stopImmediatePropagation():void イベントフローの現在のノードおよび後続するノードで、イベントリスナーが処理されないようにします。	Event
		stopPropagation():void イベントフローの現在のノードに後続するノードで、イベントリスナーが処理されないようにします。	Event
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String [オーバーライド] ProgressEvent オブジェクトのすべてのプロパティを含むストリングを返します。	ProgressEvent
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

パブリック定数

継承されるパブリック定数を隠す

継承されるパブリック定数を表示

	定数		定義元
		PROGRESS : String = "progress" [静的] progress イベントオブジェクトの type プロパティ値を定義します。	ProgressEvent
		SOCKET_DATA : String = "socketData" [静的] socketData イベントオブジェクトの type プロパティ値を定義します。	ProgressEvent
		STANDARD_ERROR_DATA : String = "standardErrorData" [静的] standardErrorData イベントオブジェクトの type プロパティ値を定義します。	ProgressEvent
		STANDARD_INPUT_PROGRESS : String = "standardInputProgress" [静的] standardInputProgress イベントオブジェクトの type プロパティ値を定義します。	ProgressEvent
		STANDARD_OUTPUT_DATA : String = "standardOutputData" [静的] standardOutputData イベントオブジェクトの type プロパティ値を定義します。	ProgressEvent

プロパティの詳細

bytesLoaded

プロパティ

bytesLoaded:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

リスナーがイベントを処理しているときに読み込まれたアイテム数またはバイト数です。

実装
public function get bytesLoaded():Number
public function set bytesLoaded(value:Number):void

bytesTotal

プロパティ

bytesTotal:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

読み込みプロセスが成功した場合に読み込まれるアイテムまたはバイトの総数です。progress イベントが Socket オブジェクトに送出または関連付けられる場合は、コンストラクターの bytesTotal パラメーターに値が指定されない限り、bytesTotal は常に 0 になります。実際に送受信されたバイト数は設定されず、アプリケーション開発者に任されます。

実装
public function get bytesTotal():Number
public function set bytesTotal(value:Number):void

コンストラクターの詳細

()

コンストラクター

public function ProgressEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, bytesLoaded:Number = 0, bytesTotal:Number = 0)

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

progress イベントに関する情報を含む Event オブジェクトを作成します。イベントリスナーには Event オブジェクトがパラメーターとして渡されます。

パラメーター

	`type:String` — イベントのタイプです。有効な値は次のとおりです。`ProgressEvent.PROGRESS`、 `ProgressEvent.SOCKET_DATA`、`ProgressEvent.STANDARD_ERROR_DATA`、`ProgressEvent.STANDARD_INPUT_PROGRESS` および `ProgressEvent.STANDARD_OUTPUT_DATA`。

	`bubbles:Boolean` (default = `false`) — Event オブジェクトがイベントフローのバブリング段階で処理されるかどうかを判断します。

	`cancelable:Boolean` (default = `false`) — Event オブジェクトがキャンセル可能かどうかを判断します。

	`bytesLoaded:Number` (default = `0`) — リスナーがイベントを処理しているときに読み込まれたアイテム数またはバイト数です。

	`bytesTotal:Number` (default = `0`) — 読み込みプロセスが成功した場合に読み込まれるアイテムまたはバイトの総数です。

メソッドの詳細

clone

()

メソッド

override public function clone():Event

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

ProgressEvent オブジェクトのコピーを作成して、各プロパティの値を元のプロパティの値と一致するように設定します。

戻り値

Event — 元のオブジェクトと同じプロパティ値を含む新しい ProgressEvent オブジェクトです。

toString

()

メソッド

override public function toString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

ProgressEvent オブジェクトのすべてのプロパティを含むストリングを返します。ストリングは次の形式です。

[ProgressEvent type=value bubbles=value cancelable=value bytesLoaded=value bytesTotal=value]

戻り値

String — ProgressEvent オブジェクトのすべてのプロパティを含むストリングです。

定数の詳細

PROGRESS

定数

public static const PROGRESS:String = "progress"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

type プロパティ（progress イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`bytesLoaded`	リスナーがイベントを処理しているときに読み込まれたアイテム数またはバイト数です。
`bytesTotal`	読み込みプロセスが成功した場合に最終的に読み込まれるアイテムまたはバイトの総数です。
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	進行状況をレポートするオブジェクトです。

SOCKET_DATA

定数

public static const SOCKET_DATA:String = "socketData"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

type プロパティ（socketData イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	Event をアクティブに処理しているオブジェクトです。
`bytesLoaded`	リスナーがイベントを処理しているときに読み込まれたアイテム数またはバイト数です。
`bytesTotal`	0。このプロパティは、`socketData` イベントオブジェクトによって使用されません。
`target`	進行状況をレポートするソケットです。

関連する API エレメント

flash.net.Socket.socketData

STANDARD_ERROR_DATA

定数

public static const STANDARD_ERROR_DATA:String = "standardErrorData"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2, Flash Lite 4

type プロパティ（standardErrorData イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	Event をアクティブに処理しているオブジェクトです。
`bytesLoaded`	このイベントにともない、NativeProcessObject.error によってバッファーされたエラーデータのバイト数です。
`bytesTotal`	0。このプロパティは、`standardErrorData` イベントオブジェクトによって使用されません。
`target`	エラーデータを報告する NativeProcess オブジェクトです。

STANDARD_INPUT_PROGRESS

定数

public static const STANDARD_INPUT_PROGRESS:String = "standardInputProgress"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2, Flash Lite 4

type プロパティ（standardInputProgress イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	Event をアクティブに処理しているオブジェクトです。
`bytesLoaded`	このイベントにともない、NativeProcessObject.error によってバッファーされたエラーデータのバイト数です。
`bytesTotal`	0。このプロパティは、`standardInputProgress` イベントオブジェクトによって使用されません。
`target`	エラーデータを報告する NativeProcess オブジェクトです。

STANDARD_OUTPUT_DATA

定数

public static const STANDARD_OUTPUT_DATA:String = "standardOutputData"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2, Flash Lite 4

type プロパティ（standardOutputData イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	Event をアクティブに処理しているオブジェクトです。
`bytesLoaded`	このイベントにともない、NativeProcessObject.output によってバッファーされた出力データのバイト数です。
`bytesTotal`	0。このプロパティは、`standardOutputData` イベントオブジェクトによって使用されません。
`target`	出力データを報告する NativeProcess オブジェクトです。

例この例の使用方法

ProgressEventExample.as

次の例では、ProgressEventExample クラスを使用して、ファイルのダウンロード中に様々なイベントリスナーを使用する方法を示します。この例では、次の処理を実行します。

downloadURL と fileName という 2 つのプロパティが作成されます。このプロパティは、ダウンロードされたファイルの場所と名前を示します。
ProgressEventExample コンストラクターでは、file という名前の新しい FileReference オブジェクトが作成され、configureListeners() メソッドに渡されます。
次に、downloadURL プロパティと fileName プロパティが file.download() に渡されます。これによって、ファイルをダウンロードする場所の指定が求められます。
configureListeners() メソッドは、7 つのイベントリスナーとそれに関連するサブスクライバメソッドを追加します。
1. cancel/cancelHandler() は、ファイルのダウンロードがキャンセルされた場合に送出されます。
2. complete / complereHandler() は、ファイルのダウンロードプロセスが終了したときに送出されます。
3. ioError/ioErrorHandler() は、ダウンロードファイルが使用できない場合、またはアクセスできない場合に送出されます。
4. open/openHandler() は、ダウンロード操作が開始したときに送出されます。
5. progress/progressHandler() は、ダウンロードプロセスが開始したときと終了したときに送出されます。
6. securityError/securityErrorHandler は、ローカル再生のセキュリティ設定がダウンロードファイル（ローカル対ネットワーク）のデータアクセスの種類と一致しない場合に送出されます。この後の「メモ」を参照してください。
7. select/selectHandler() は、ダウンロードオブジェクトが選択されたときに送出されます。

注意：

「ローカルでの再生に関するセキュリティ」を「ネットワークファイルのみにアクセス」に設定して SWF ファイルをコンパイルする必要があります。
この例では SomeFile.pdf という名前のファイルが必要です。
この例では、FileReference オブジェクトで使用可能なすべてのイベントを利用しますが、ほとんどの場合、必要になるのは 1 つのサブセットのみです。


package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}

法律上の注意 | プライバシーポリシー

ProgressEvent - AS3

クラス x

bytesLoaded

bytesTotal

ProgressEvent

clone

toString

PROGRESS

SOCKET_DATA

STANDARD_ERROR_DATA

STANDARD_INPUT_PROGRESS

STANDARD_OUTPUT_DATA