TextLine  - AS3

Spécifie le nombre de pixels séparant la ligne de base du haut des plus grands caractères de la ligne. Dans le cas d’un TextLine contenant uniquement un élément graphique, ascent est défini sur 0.

Nombre d’atomes dans la ligne, correspondant au nombre d’éléments indivisibles, espaces et éléments graphiques compris.

Spécifie le nombre de pixels séparant la ligne de base du bas des caractères descendants les plus bas de la ligne. Dans le cas d’un TextLine contenant uniquement un élément graphique, descent est défini sur 0.

Indique si la ligne de texte contient des éléments graphiques.

Eléments de l’API associés

Indique si la ligne de texte contient des tabulations.

Vecteur contenant les objets TextLineMirrorRegion associés à la ligne, ou null lorsqu’il n’y en a pas.

Eléments de l’API associés

Prochain TextLine du TextBlock, ou null si la ligne en cours est la dernière ligne du bloc ou si sa validité est TextLineValidity.STATIC.

Eléments de l’API associés

TextLine précédent du TextBlock, ou null s’il s’agit de la première ligne du bloc ou si la validité de la ligne est TextLineValidity.STATIC.

Eléments de l’API associés

Longueur du texte brut dans le bloc de texte devenant la ligne, y compris les caractères U+FDEF représentant des éléments graphiques et tous les espaces à droite faisant partie de la ligne mais non affichés.

Eléments de l’API associés

Largeur spécifiée à la méthode TextBlock.createTextLine() lors de la création de la ligne. Cette valeur est très utile lorsque l’on doit décider si une modification nécessite une nouvelle séparation de la ligne.

Eléments de l’API associés

Bloc de texte contenant cette ligne de texte, ou null si la validité de la ligne est TextLineValidity.STATIC, ce qui signifie que la connexion entre la ligne et le bloc de texte a été rompue.

Eléments de l’API associés

Index du premier caractère de la ligne dans le texte brut du bloc de texte.

Eléments de l’API associés

Hauteur logique de la ligne de texte, égale à ascent + descent. Pour obtenir la hauteur encrée, accédez à la propriété height héritée.

La valeur est calculée à partir de la différence entre les lignes de base qui limitent la ligne, ideo top/bottom ou ascent/descent, selon si TextBlock.baselineZero est ideo ou non. Les éléments graphiques ne sont pas pris en compte lors du calcul de ces lignes de base.

Eléments de l’API associés

Largeur logique de la ligne de texte, correspondant à la largeur utilisée par le moteur de saisie pour positionner la ligne. Accédez à la propriété héritée width pour obtenir la largeur réelle du cadre de sélection de tous les pixels dessinés.

Eléments de l’API associés

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Spécifie le nombre de pixels séparant la ligne de base du haut du caractère descendant (ou de l’image) le plus élevé de la ligne.

Spécifie le nombre de pixels séparant la ligne de base du bas du caractère descendant (ou de l’image) le plus bas de la ligne.

Hauteur logique totale de la ligne de texte, égale à totalAscent + totalDescent.

Largeur de la ligne si elle n’était pas justifiée. Dans le cas de texte non justifié, cette valeur est identique à textWidth. Dans le cas de texte justifié, cette valeur correspond à ce qu’aurait été la longueur sans justification et textWidth représente la largeur réelle de la ligne. Par exemple, lorsque la chaîne suivante est justifiée et envoyée à TextBlock.createTextLine() avec une largeur de 500, sa largeur réelle est de 500 mais sa largeur non justifiée de 268.9921875.

Eléments de l’API associés

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Permet à l’application d’associer des données arbitraires à la ligne de texte.

Spécifie la validité actuelle de la ligne de texte. Les valeurs valides pour cette propriété sont les membres de la classe TextLineValidity. Les règles de définition de cette propriété sont les suivantes :

Une ligne est considérée USER_INVALID si la validité est définie sur une chaîne quelconque, non membre de TextLineValidity. USER_INVALID est une abstraction utilisée ici pour représenter une telle valeur.

Lorsque le contenu du TextBlock est modifié, le moteur d’exécution de Flash marque les lignes de texte affectées, la ligne précédente et toutes les lignes suivantes comme INVALID. La ligne précédente doit être désignée comme non valide lorsqu’une modification l’autorise à absorber une partie du contenu auparavant sur la première ligne affectée.

Les lignes nouvellement séparées sont toujours VALID. Le moteur d’exécution de Flash peut faire passer les lignes suivantes de VALID à POSSIBLY_INVALID ou à INVALID. Il peut transformer les lignes POSSIBLY_INVALID en VALID si les sauts de ligne correspondent ou en INVALID dans le cas contraire.

Le code de l’application peut marquer les lignes VALID en INVALID ou en USER_INVALID, et les lignes USER_INVALID en VALID. Le code de l’application ne peut pas marquer des lignes comme POSSIBLY_INVALID.

Le code de l’application peut marquer n’importe quelle ligne comme STATIC. Dans ce cas, le membre du bloc devient null. Tous les éléments graphiques d’une ligne de texte STATIC sont supprimés et à nouveau apparentés s’ils font partie d’une nouvelle séparation de ligne de texte du bloc de texte d’où dérive à l’origine la ligne de texte STATIC.

Eléments de l’API associés

Libère le contenu sous-jacent du TextLine sous forme de chaîne XML. Cela peut se révéler utile lors de tests automatisés, et comprend le texte, le formatage et les informations de mise en forme.

Voici le résultat :

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Remarque : il est possible que le contenu et le format du résultat de cette méthode changent dans le futur. Adobe ne garantit pas la compatibilité ascendante de cette méthode.

Eléments de l’API associés

Cette méthode est déconseillée et n’a aucun effet. Les données de l’atome sont compressées et ne permettent pas une gestion efficace de la mémoire.

Eléments de l’API associés

Récupère le niveau bidirectionnel de l’atome au niveau de l’index spécifié. Déterminée par une combinaison de TextBlock.bidiLevel et des propriétés bidirectionnelles Unicode des caractères qui composent la ligne.

Par exemple, si vous commencez un bloc de texte par un texte hébreu, vous définissez TextBlock.bidiLevel sur 1, en définissant droite à gauche par défaut. Si le texte contient une citation en anglais (de gauche à droite), ce texte a un paramètre AtomBidiLevel de 2. Si le texte anglais contient une section en arabe (de droite à gauche), le paramètre AtomBidiLevel de ce texte passe à 3. Si le texte arabe contient un nombre (de gauche à droite), le paramètre AtomBidiLevel du nombre est 4. La ligne dans laquelle les atomes se terminent importe peu ; les atomes hébreux sont AtomBidiLevel 1, les atomes anglais sont AtomBidiLevel 2, les atomes arabes sont AtomBidiLevel 3 et les atomes de nombre sont AtomBidiLevel 4.

Paramètres

Eléments de l’API associés

Récupère les limites de l’atome au niveau de l’index spécifié par rapport à la ligne de texte. Les limites de l’atome spécifié sont constituées de sa position horizontale (x) dans la ligne, de sa position verticale (y) dans la ligne, de sa largeur (w) et de sa hauteur (h). Toutes les valeurs sont en pixels.

Paramètres

Récupère le centre de l’atome tel que mesuré le long de la ligne de base au niveau de l’index spécifié.

Paramètres

Récupère le graphique de l’atome au niveau de l’index spécifié, ou null si l’atome est un caractère.

Paramètres

Renvoie l’index de l’atome contenant le caractère spécifié par le paramètre charIndex ou -1 si le caractère ne contribue à aucun atome dans la ligne. Le paramètre charIndex est relatif à l’ensemble du contenu du bloc de texte contenant la ligne.

Paramètres

Renvoie l’index de l’atome situé au niveau du point spécifié par les paramètres x et y ou -1 s’il n’y a pas d’atome au niveau de ce point.

Cette méthode prend les coordonnées globales de sorte qu’elles puissent être aisément utilisées avec les propriétés MouseEvent.stageX et MouseEvent.stageY.

Paramètres

Récupère l’index de début du bloc de texte de l’atome au niveau de l’index spécifié.

Paramètres

Récupère l’index de fin du bloc de texte de l’atome au niveau de l’index spécifié.

Paramètres

Récupère la rotation de l’atome au niveau de l’index spécifié. Des constantes TextRotation sont utilisées pour cette propriété. La rotation de l’atome correspond aux rotations cumulées de l’élément et de la ligne. Il est principalement utilisé pour définir l’orientation du caret (curseur) lors de l’interaction avec le TextLine.

Paramètres

Eléments de l’API associés

Indique s’il existe ou non une limite de mot à gauche de l’atome au niveau de l’index spécifié. Les limites de mot sont déterminées à partir des propriétés Unicode des caractères qui constituent la ligne.

Paramètres

Récupère la position de la ligne de base spécifiée par rapport au TextBlock.baselineZero.

Paramètres

Eléments de l’API associés

Renvoie le premier TextLineMirrorRegion de la ligne dont la propriété mirror correspond à celle spécifiée par le paramètre mirror, ou null s’il n’y a pas de correspondance.

Même un seul TextElement peut produire plusieurs objets TextLineMirrorRegion sur une ou plusieurs lignes, selon les paramètres bidirectionnel et de saut de ligne. Les propriétés nextRegion et previousRegion relient toutes les zones miroir générées par un élément de texte.

Paramètres

Eléments de l’API associés

Largeur maximale requise d’une ligne de texte, en pixels. La méthode TextBlock.createTextLine() utilise cette constante comme valeur par défaut du paramètre width, si vous ne spécifiez pas de valeur.

Eléments de l’API associés

1. Ajoutez le composant NumericStepper dans la bibliothèque.
2. Enregistrez ce code sous le nom TextLineExample.as dans le même répertoire que votre fichier FLA.
3. Dans la fenêtre Propriétés du fichier FLA, définissez Class sur TextLineExample.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}