TextBlock  - AS3

Indique que vous souhaitez améliorer l’aspect de l’écran au détriment de la fidélité d’impression WYSIWYG. Dans le cas des plates-formes et des polices qui ne prennent pas en charge le positionnement de glyphes de sous-pixels lors du rendu des polices de périphérique, mais qui prennent en charge la mise à l’échelle non linéaire, le fait de définir cette propriété sur true permet d’utiliser ces mesures, au détriment de la fidélité d’impression WYSIWYG, en particulier pour les petites tailles de point. La mise à l’échelle non linéaire des polices consiste à mettre à l’échelle la largeur de glyphes individuelles en vue de dissimuler les écarts disgracieux provoqués par l’accrochage aux pixels.

Sur les plates-formes qui prennent en charge le positionnement de glyphes de sous-pixels, cet indicateur est ignoré.

Cet indicateur n’a aucun effet sur le rendu des polices incorporées.

La valeur par défaut est true.

Police utilisée pour déterminer les lignes de base de toutes les lignes créées à partir du bloc, quel que soit leur contenu. Les lignes de base dépendent de la police et de sa taille.

La valeur par défaut est null. Lorsque la police de la ligne de base est null, la taille de police de la ligne de base est ignorée et la ligne de base de toutes les lignes est basée sur la police et la taille du texte le plus large de la ligne. Lorsque vous spécifiez à la fois baselineFontDescription et baselineFontSize, ces paramètres déterminent les lignes de base de toutes les lignes du bloc de texte, indépendamment de leur contenu. Cette combinaison est plus généralement utilisée dans la typographie asiatique.

Eléments de l’API associés

Taille de police utilisée pour calculer les lignes de base des lignes créées à partir du bloc. Les lignes de base dépendent de la police et de sa taille.

La valeur par défaut est 12. Lorsque la police de la ligne de base est null, la taille de police de la ligne de base est ignorée et la ligne de base de toutes les lignes est basée sur la police et la taille du texte le plus large de la ligne.

Eléments de l’API associés

Spécifie quelle ligne de base est au niveau y=0 pour les lignes créées à partir de ce bloc. Les valeurs valides de cette propriété sont les membres de la classe TextBaseline.

La valeur par défaut est TextBaseline.ROMAN.

Pour définir les valeurs pour cette propriété, utilisez les valeurs de chaîne suivantes :

Eléments de l’API associés

Spécifie le niveau d’intégration du paragraphe bidirectionnel du bloc de texte. En règle générale, utilisez 0 pour les paragraphes LTR (anglais, japonais, etc.) et 1 pour les paragraphes RTL (arabe, hébreu, etc.). L’utilisation de valeurs autres que 0 ou 1 est réservée aux cas spéciaux ; voir UAX#9, « Unicode Bidirectional Algorithm » (http://www.unicode.org/reports/tr9/) pour plus de détails.

La valeur par défaut est 0.

Le fait de modifier bidiLevel définit la validité de toutes les lignes précédemment coupées en deux sur TextLineValidity.INVALID. Après la modification de bidiLevel, la propriété firstInvalidLine est égale à la propriété firstLine et vous devez créer à nouveau les sauts de toutes les lignes du TextBlock.

Eléments de l’API associés

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Détient le contenu du bloc de texte. ContentElement étant une classe de base, affectez content à une occurrence d’une sous-classe ContentElement : TextElement, GraphicElement ou GroupElement. Un objet TextElement contient une chaîne, un objet GraphicElement contient un objet DisplayObject et un objet GroupElement contient un objet Vector contenant un ou plusieurs objets TextElement ou GraphicElement ou d’autres objets GroupElement. Utilisez un TextElement pour un paragraphe de texte homogène, un GraphicElement pour un élément graphique et un GroupElement pour une combinaison de texte et d’éléments graphiques ou pour plusieurs occurrences de ces éléments, ainsi que d’autres objets GroupElement.

La valeur par défaut est null.

La modification de la propriété content change la validité de toute ligne créée précédemment en TextLineValidity.INVALID. Après la modification de content, la propriété firstInvalidLine est égale à la propriété firstLine et vous devez recréer les sauts de toutes les lignes du TextBlock.

Eléments de l’API associés

Identifie la première ligne du bloc de texte dans laquelle TextLine.validity n’est pas égal à TextLineValidity.VALID.

La valeur par défaut est null.

Eléments de l’API associés

Premier TextLine du TextBlock, le cas échéant.

La valeur par défaut est null.

Eléments de l’API associés

Dernier TextLine du TextBlock, le cas échéant.

La valeur par défaut est null.

Eléments de l’API associés

Fait pivoter les lignes de texte du bloc de texte en une seule unité. Appelez la méthode createTextLine() après avoir défini lineRotation pour qu’elle prenne effet. La valeur par défaut est TextRotation.ROTATE_0.

La rotation finale d’un glyphe dépend des valeurs de , de ElementFormat.textRotation, de ContentElement.textRotation et de TextBlock.lineRotation.

TextBlock.lineRotation est généralement utilisé pour le texte asiatique. Pour créer un paragraphe de texte japonais vertical, procédez comme suit :

1. Définissez la propriété TextBlock.lineRotation sur TextRotation.ROTATE_90.
2. Conservez la propriété ElementFormat.textRotation du contenu par défaut, TextRotation.AUTO.

Utilisez les constantes suivantes, définies dans la classe TextRotation, pour définir la valeur de cette propriété :

Plus d’exemples

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Spécifie les arrêts de tabulation du texte du bloc de texte, sous la forme d’un vecteur d’objets TabStop.

La valeur par défaut est null, c’est-à-dire qu’aucun taquet de tabulation n’est spécifié. Si aucun taquet de tabulation n’est spécifié (ou si le point d’insertion se trouve au-delà du dernier taquet de tabulation spécifié), le moteur d’exécution crée des tabulations demi-pouce par défaut.

Lorsque la propriété tabStops est définie, le TextBlock effectue une copie du vecteur pour usage interne. La modification du vecteur original ou de son contenu n’a aucune incidence sur le TextBlock. Lorsque la propriété tabStops est interrogée, une copie du vecteur interne est renvoyée. La modification du vecteur renvoyé ou de son contenu n’a aucune incidence sur le TextBlock.

Eléments de l’API associés

Spécifie le TextJustifier à utiliser lors de la création de ligne.

La valeur par défaut est un objet TextJustifier créé par défaut.

Lorsque la propriété textJustifier est définie, le TextBlock effectue une copie de l’objet pour usage interne. La modification de l’objet original n’a aucune incidence sur le TextBlock. Lorsque la propriété textJustifier est interrogée, une copie de l’objet interne est renvoyée. Nous vous rappelons que la modification de cet objet renvoyé n’a aucune incidence sur le TextBlock.

Plus d’exemples

Eléments de l’API associés

Indique le résultat d’une opération createTextLine(). La modification du contenu du bloc invalide les sauts de ligne précédents et réinitialise cette propriété sur null.

La valeur par défaut est null.

Les valeurs de cette propriété sont les membres de TextLineCreationResult.

Eléments de l’API associés

Permet à l’application d’associer des données arbitraires au bloc de texte. Les données peuvent être des informations faisant référence au contenu, par exemple, une date de révision ou le nom de l’auteur, ou peuvent être des données mises en cache et requises lors du traitement.

Crée un objet TextBlock

Eléments de l’API associés

Indique au bloc de texte de créer une ligne de texte à partir de son contenu, en commençant au point spécifié par le paramètre previousLine et en faisant un saut de ligne au point spécifié par le paramètre width. La ligne de texte est un objet TextLine, que vous pouvez ajouter à la liste d’affichage.

Insérer des sauts de ligne dans une plage de blocs de texte dans laquelle une séparation existe déjà peut modifier la validité des lignes dans et au-delà de la zone où sont situés les sauts de ligne. L’état des lignes peut passer de VALID à INVALID ou à POSSIBLY_INVALID. Si un nouveau saut de ligne s’aligne parfaitement avec un saut de ligne précédent dont l’état est POSSIBLY_INVALID, cette dernière ligne et toutes les lignes POSSIBLY_INVALID reprennent un état VALID. La validité des lignes définies sur des valeurs n’appartenant pas à TextLineValidity ne devient pas VALID, mais peut devenir INVALID. Vérifiez la propriété firstInvalidLine après chaque modification du bloc de texte pour savoir où commencer ou poursuivre les sauts de lignes de texte.

Vous pouvez créer des séparations de mots artificielles en incluant le caractère Unicode ZWSP (Zero Width Space), ou espace sans chasse, dans le texte. Cela peut se révéler utile pour les langues telles que le Thaïlandais, qui requiert un dictionnaire pour les sauts de ligne corrects. Le moteur d’exécution de Flash ne dispose pas d’un tel dictionnaire.

Pour réduire les ressources supplémentaires de mémoire requises, l’utilisateur doit appeler la méthode releaseLineCreationData() afin que le bloc de texte puisse supprimer les données temporaires associées aux sauts de ligne lorsque toutes les lignes souhaitées ont été créées, à moins qu’il soit nécessaire de recréer plusieurs fois les lignes, notamment suite au redimensionnement du conteneur.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Libère le contenu sous-jacent du TextBlock sous forme de chaîne XML. Cela peut se révéler utile lors de tests automatisés, et comprend le texte, le formatage et les informations de mise en forme.

Voici le résultat :

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Pour obtenir une description du résultat pour chaque ligne, voir la méthode TextLine.dump().

Remarque : le contenu et le format du résultat peuvent changer dans le futur. Adobe ne garantie pas la compatibilité ascendante pour cette méthode.

Eléments de l’API associés

Recherche l’index de la prochaine limite d’atome à partir de l’index de caractère spécifié, sans inclure le caractère situé au niveau de l’index spécifié. Les caractères situés entre les limites des atomes se combinent pour former un seul atome dans un TextLine, par exemple un ’e’ et un accent aigu.

Paramètres

Eléments de l’API associés

Recherche l’index de la prochaine limite de mot à partir de l’index de caractère spécifié, sans comprendre le caractère situé au niveau de l’index spécifié. Les limites de mot sont déterminées à partir des propriétés Unicode des caractères.

Paramètres

Recherche l’index de la limite d’atome précédente jusqu’à l’index de caractère spécifié, sans inclure le caractère situé au niveau de l’index spécifié. Les caractères situés entre les limites des atomes se combinent pour former un seul atome dans un TextLine, par exemple un ’e’ et un accent aigu.

Paramètres

Eléments de l’API associés

Recherche l’index de la précédente limite de mot jusqu’à l’index de caractère spécifié, sans comprendre le caractère situé au niveau de l’index spécifié. Les limites de mot sont déterminées à partir des propriétés Unicode des caractères.

Paramètres

Renvoie le TextLine contenant le caractère spécifié par le paramètre charIndex.

Paramètres

Indique au bloc de texte de réutiliser une ligne de texte existante pour créer une ligne de texte à partir de son contenu, en commençant au point spécifié par le paramètre previousLine et en faisant un saut de ligne au point spécifié par le paramètre width. La ligne de texte est un objet TextLine, que vous pouvez ajouter à la liste d’affichage. La réutilisation d’une ligne de texte existante améliore les performances, car moins d’objets sont créés.

L’objet textLine recréé est dégagé du bloc de texte dans lequel il se trouve, le cas échéant. Par ailleurs, toutes les propriétés, notamment les propriétés héritées de DisplayObjectContainer, InteractiveObject et DisplayObject, sont réinitialisées à leurs valeurs par défaut. Enfin, tous les enfants de la ligne sont supprimés, notamment les éléments graphiques et autres décorations ; tous les écouteurs d’événement dans la ligne sont également supprimés. Pour améliorer les performances, la seule exception à cette réinitialisation est que la ligne elle-même n’est pas supprimée de son parent.

Insérer des sauts de ligne dans une plage de blocs de texte dans laquelle une séparation existe déjà peut modifier la validité des lignes dans et au-delà de la zone où sont situés les sauts de ligne. L’état des lignes peut passer de VALID à INVALID ou à POSSIBLY_INVALID. Si un nouveau saut de ligne s’aligne parfaitement avec un saut de ligne précédent dont l’état est POSSIBLY_INVALID, cette dernière ligne et toutes les lignes POSSIBLY_INVALID reprennent un état VALID. La validité des lignes définies sur des valeurs n’appartenant pas à TextLineValidity ne devient pas VALID, mais peut devenir INVALID. Vérifiez la propriété firstInvalidLine après chaque modification du bloc de texte pour savoir où commencer ou poursuivre les sauts de lignes de texte.

Vous pouvez créer des séparations de mots artificielles en incluant le caractère Unicode ZWSP (Zero Width Space), ou espace sans chasse, dans le texte. Cela peut se révéler utile pour les langues telles que le Thaïlandais, qui requiert un dictionnaire pour les sauts de ligne corrects. Le moteur d’exécution de Flash ne dispose pas d’un tel dictionnaire.

Pour réduire les ressources supplémentaires de mémoire requises, l’utilisateur doit appeler la méthode releaseLineCreationData() afin que le bloc de texte puisse supprimer les données temporaires associées aux sauts de ligne lorsque toutes les lignes souhaitées ont été créées, à moins qu’il soit nécessaire de recréer plusieurs fois les lignes, notamment suite au redimensionnement du conteneur.

Paramètres

Eléments de l’API associés

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Indique au bloc de texte de libérer toutes les données temporaires associées à la création de lignes de texte. Pour minimiser l’encombrement mémoire de l’application, nous vous conseillons d’appeler la méthode releaseLineCreationData() lorsque vous avez terminé la création de lignes de texte à partir d’un bloc de texte. Cependant, pour optimiser les performances de nouveaux sauts de lignes (notamment lorsque le conteneur est redimensionné), vous devez éviter d’appeler la méthode releaseLineCreationData(). C’est à l’application de trouver un juste équilibre entre mémoire et performances.

La procédure recommandée pour du texte qui ne subira aucune modification est la suivante : initialisez un bloc de texte, appelez la méthode createTextLine() aussi souvent que nécessaire pour obtenir le résultat souhaité, puis appelez la méthode releaseLineCreationData().

Eléments de l’API associés

Supprime une plage de lignes de texte de la liste des lignes conservées par le TextBlock. Les lignes peuvent ainsi être nettoyées lorsque aucune autre référence n’existe.

Définissez sur null les textBlock, nextLine et previousLine appartenant aux lignes supprimées. Définissez sur TextLineValidity.INVALID la validity des lignes supprimées et de toutes les lignes qui les suivent dans le TextBlock.

Paramètres

Eléments de l’API associés