TextElement

Package	flash.text.engine
Classe	public final class TextElement
Héritage	TextElement ContentElement Object

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

Flash Player 10, AIR 1.5, Flash Lite 4

La classe TextElement représente une chaîne de texte mis en forme. Affectez un objet TextElement à la propriété content d’un objet TextBlock pour créer un bloc de texte. Affectez-le à un objet GroupElement pour le combiner avec d’autres éléments de texte et graphiques en une seule unité. Utilisez la classe ElementFormat pour mettre le texte en forme.

Eléments de l’API associés

ContentElement
ElementFormat
TextBlock

Propriétés publiques

Masquer les propriétés publiques héritées

Afficher les propriétés publiques héritées

	Propriété		Défini par
		constructor : Object Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.	Object
		elementFormat : ElementFormat Objet ElementFormat utilisé pour l’élément.	ContentElement
		eventMirror : EventDispatcher Objet EventDispatcher qui reçoit des copies de chaque événement distribué pour valider les lignes de texte créées en fonction de cet élément de contenu.	ContentElement
		groupElement : GroupElement [lecture seule] Objet GroupElement contenant cet élément, ou null s’il ne fait pas partie d’un groupe.	ContentElement
		rawText : String [lecture seule] Copie du texte dans l’élément, y compris les caractères U+FDEF.	ContentElement
		text : String Reçoit le texte correspondant au contenu de l’élément.	TextElement
		textBlock : flash.text.engine:TextBlock [lecture seule] TextBlock auquel appartient l’élément.	ContentElement
		textBlockBeginIndex : int [lecture seule] Index du premier caractère de cet élément dans le bloc de texte.	ContentElement
		textRotation : String Rotation à appliquer à l’élément en tant qu’unité.	ContentElement
		userData : * Permet à une application d’associer des données arbitraires à l’élément.	ContentElement

Méthodes publiques

Masquer les méthodes publiques héritées

Afficher les méthodes publiques héritées

	Méthode		Défini par
		TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0") Crée une nouvelle occurrence de TextElement.	TextElement
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d’un objet est définie.	Object
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.	Object
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		replaceText(beginIndex:int, endIndex:int, newText:String):void Remplace la plage de caractères que les paramètres beginIndex et endIndex spécifient par le contenu du paramètre newText.	TextElement
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.	Object
		toLocaleString():String Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.	Object
		toString():String Renvoie la représentation sous forme de chaîne de l’objet spécifié.	Object
		valueOf():Object Renvoie la valeur primitive de l’objet spécifié.	Object

Constantes publiques

Masquer les constantes publiques héritées

Afficher les constantes publiques héritées

	Constante		Défini par

Détails de la propriété

text

propriété

text:String

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

Flash Player 10, AIR 1.5, Flash Lite 4

Reçoit le texte correspondant au contenu de l’élément.

La valeur par défaut est null.

Implémentation
public function get text():String
public function set text(value:String):void

Détails du constructeur

()

Constructeur

public function TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

Flash Player 10, AIR 1.5, Flash Lite 4

Crée une nouvelle occurrence de TextElement.

Paramètres

	`text:String` (default = `null`) — Texte de l’élément. La valeur par défaut est `null`.

	`elementFormat:ElementFormat` (default = `null`) — Format de l’élément pour le texte dans l’élément. La valeur par défaut est `null`.

	`eventMirror:EventDispatcher` (default = `null`) — Objet `EventDispatcher` qui reçoit des copies de chaque événement déclenché vers les lignes de texte créées en fonction de cet élément de contenu. La valeur par défaut est `null`.

	`textRotation:String` (default = "`rotate0`") — Rotation appliquée à l’élément en tant qu’unité. Utilisez les constantes `TextRotation` pour cette propriété. La valeur par défaut est `TextRotation.ROTATE_0`.

Exemple ( Comment utiliser cet exemple )

L’exemple suivant crée un objet TextElement à partir d’une chaîne de texte, le met en forme à l’aide d’une taille de police de 12 et la couleur rouge (0xCC0000) et l’affecte à la propriété content d’un TextBlock. Il appelle la fonction createLines() pour couper le bloc de texte en lignes de 150 pixels chacune.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    
    public class TextElementExample extends Sprite {
        
        public function TextElementExample():void {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " +
            "sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut " +
            "enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut " +
            "aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit " +
            "in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur " +
            "sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt " +
            "mollit anim id est laborum.";
            
            var format:ElementFormat = new ElementFormat(null, 12, 0xCC0000);
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock);
        }
        
        private function createLines(textBlock:TextBlock):void {
        
            var yPos = 20;
            var textLine:TextLine = textBlock.createTextLine (null, 150);
 
            while (textLine)
            {
                addChild(textLine);
                textLine.x = 15;
                yPos += textLine.textHeight+2;
                textLine.y = yPos;
                textLine = textBlock.createTextLine(textLine, 150);
            }        
        }
    }
}

Détails de la méthode

replaceText

()

méthode

public function replaceText(beginIndex:int, endIndex:int, newText:String):void

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

Flash Player 10, AIR 1.5, Flash Lite 4

Remplace la plage de caractères que les paramètres beginIndex et endIndex spécifient par le contenu du paramètre newText. Les valeurs beginIndex et endIndex font référence au contenu en cours de text.

Pour supprimer le texte, transmettez null pour newText.

Pour insérer du texte, transmettez la même valeur pour beginIndex et endIndex. Le nouveau texte est inséré avant l’index spécifié.

Pour ajouter du texte, transmettez text.length pour beginIndex et endIndex.

Pour définir tout le texte, transmettez 0 pour beginIndex et text.length pour endIndex.

Paramètres

	`beginIndex:int` — Valeur d’index de base zéro pour la position de début de la plage de remplacement.

	`endIndex:int` — Valeur d’index de base zéro suivant la position de fin de la plage de remplacement.

	`newText:String` — Texte à utiliser pour remplacer la plage de caractères spécifiée.

Valeur émise

RangeError — La valeur beginIndex ou endIndex est hors limite.

Plus d’exemples

Remplacement du texte

Exemple ( Comment utiliser cet exemple )

Cet exemple appelle plusieurs fois replaceText() pour effectuer les opérations suivantes :

Insérer une chaîne au début du texte
Ajouter une chaîne à la fin du texte
Insérer une chaîne au milieu du texte
Remplacer l’ensemble du texte par un nouveau texte

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextLine;
    
    
    public class TextElement_replaceTextExample extends Sprite {
        public function TextElement_replaceTextExample():void {
            
            var str:String = "0123456";
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 14;
            var textElement:TextElement = new TextElement(str, format);
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textElement.replaceText(0, 0, "abc");  
            createLine(textBlock, 20);           //"abc0123456"
            textElement.replaceText(10, 10, "abc");   
            createLine(textBlock, 40);            // "abc0123456abc"
            textElement.replaceText(5, 8, "abc");
            createLine(textBlock, 60);         // "abc01abc56abc"
            textElement.replaceText(0, 13, "abc");
            createLine(textBlock, 80);            // "abc"
            textElement.replaceText(0, 3, "That's all she wrote!");
            createLine(textBlock, 100);        // "That's all she wrote" */
        }
            
        private function createLine(textBlock:TextBlock, y:Number):void {
            var textLine:TextLine = textBlock.createTextLine(null, 150);
            textLine.x = 10;
            textLine.y = y;
            addChild(textLine);
        }
    }
}

Informations juridiques | Politique de confidentialité en ligne

TextElement - AS3

Classes x

text

TextElement

replaceText