Video  - AS3

Indique le type de filtre appliqué aux vidéos décodées dans le cadre du posttraitement. La valeur par défaut, 0, autorise le compresseur vidéo à appliquer le filtre de dégroupage si nécessaire.

La compression de la vidéo peut engendrer des artefacts indésirables. Vous pouvez utiliser la propriété deblocking pour définir des filtres de dégroupage et, pour la vidéo compressée utilisant le codex On2, ringing.

Blocking désigne les défauts visibles entre les limites des blocs qui composent chaque image vidéo. Ringing fait référence aux déformations observées au niveau des bords des éléments dans une image vidéo.

Deux filtres de dégroupage sont disponibles : l’un dans le codec Sorenson, l’autre dans le codec On2 VP6. Un filtre de deringing est également disponible lorsque vous utilisez le codec On2 VP6. Pour définir un filtre, utilisez une des valeurs suivantes :

• 0 — Autorise le compresseur vidéo à appliquer le filtre de dégroupage si nécessaire.
• 1 — N’utilise pas de filtre de dégroupage.
• 2 — Utilise le filtre de dégroupage Sorenson.
• 3 — Pour la vidéo On2 seulement, utilise le filtre de dégroupage On2, mais pas de filtre de deringing.
• 4 — Pour la vidéo On2 seulement, utilise le filtre de dégroupage et le filtre de deringing On2.
• 5 — Pour la vidéo On2 seulement, utilise le filtre de dégroupage On2 et un filtre de deringing On2 optimisé.

Si une valeur supérieure à 2 est sélectionnée pour la vidéo alors que vous utilisez le codec Sorenson, le décodeur Sorenson applique par défaut la valeur 2.

Le filtre de dégroupage a un effet sur les performances globales de lecture et il n’est généralement pas nécessaire pour la vidéo à large bande passante. Si le système d’un utilisateur n’est pas assez puissant, il lui sera peut-être difficile de lire la vidéo avec un tel filtre activé.

Indique si la vidéo doit être lissée (interpolée) lors de son redimensionnement. Pour faciliter le lissage, le moteur d’exécution doit être en mode haute qualité (paramètre par défaut). La valeur par défaut est false (pas de lissage).

Pour une lecture vidéo avec Flash Player 9.0.115.0 et versions ultérieures, définissez cette propriété sur true pour tirer parti de l’optimisation d’image mip-mapping.

Informations complémentaires

Nombre entier spécifiant la hauteur en pixels du flux vidéo. Pour les flux vidéo en direct, cette valeur est identique à la propriété Camera.height de l’objet Camera qui capture le flux vidéo. Pour les fichiers vidéo enregistrés, cette valeur correspond à la hauteur de la vidéo. L’événement NetStream.Video.DimensionChange est distribué dans le cas de vidéos enregistrées lorsque cette valeur change.

Vous pouvez utiliser cette propriété, par exemple, pour garantir que l’utilisateur regarde la vidéo au même format que celui auquel elle a été capturée, quel que soit le format réel de l’objet Video sur la scène.

Eléments de l’API associés

Nombre entier spécifiant la largeur en pixels du flux vidéo. Pour les flux vidéo en direct, cette valeur est identique à la propriété Camera.width de l’objet Camera qui capture le flux vidéo. Pour les fichiers vidéo enregistrés, cette valeur correspond à la largeur de la vidéo. L’événement NetStream.Video.DimensionChange est distribué dans le cas de vidéos enregistrées lorsque cette valeur change.

Vous pouvez utiliser cette propriété, par exemple, pour garantir que l’utilisateur regarde la vidéo au même format que celui auquel elle a été capturée, quel que soit le format réel de l’objet Video sur la scène.

Eléments de l’API associés

Crée une occurrence de Video. Si la valeur des paramètres width et height n’est pas définie, les valeurs par défaut sont utilisées. Vous pouvez aussi définir les propriétés de largeur et de hauteur de l’objet Video après sa construction initiale à l’aide des propriétés Video.width et Video.height. Lors de la création d’un objet Video, il est interdit de définir une largeur et une hauteur nulles. Si vous transmettez la valeur zéro, les valeurs par défaut sont appliquées.

Une fois l’objet Video créé, appelez la méthode DisplayObjectContainer.addChild() ou DisplayObjectContainer.addChildAt() pour l’ajouter à un objet DisplayObjectContainer parent.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Spécifie un flux vidéo provenant d’une caméra à afficher dans le cadre de l’objet Video de l’application.

Utilisez cette méthode pour associer une vidéo en direct capturée par l’utilisateur à l’objet Video. Vous pouvez diffuser la vidéo en direct localement sur l’ordinateur ou le périphérique sur lequel elle a été capturée, ou l’envoyer à Flash Media Server et utiliser ce serveur pour envoyer le flux aux autres utilisateurs.

Remarque : dans une application AIR for iOS, il est impossible d’afficher la caméra vidéo lorsque l’application a recours au mode de rendu sur GPU.

Paramètres

Eléments de l’API associés

Spécifie un flux vidéo à afficher dans le cadre de l’objet Video dans l’application. Le flux vidéo est soit un fichier vidéo lu avec NetStream.play(), soit un objet Camera, soit null. Si vous utilisez un fichier vidéo, vous pouvez le stocker dans le système de fichiers local ou sur le serveur Flash Media Server. Si la valeur de l’argument netStream correspond à null, la vidéo n’est plus lue dans l’objet Video.

Il n’est pas nécessaire d’utiliser cette méthode si un fichier vidéo contient uniquement des données audio ; la partie audio des fichiers vidéo est automatiquement lue lors de l’appel de la méthode NetStream.play(). Pour contrôler les données audio associées à un fichier vidéo, utilisez la propriété soundTransform de l’objet NetStream qui lit le fichier vidéo.

Paramètres

Eléments de l’API associés

Efface l’image actuellement affichée dans l’objet Video (pas le flux vidéo). Cette méthode est très utile pour gérer l’image en cours. Par exemple, vous pouvez effacer la dernière image ou afficher des informations en attente sans masquer l’objet Video.

Eléments de l’API associés

Dans cet exemple, le code qui crée les objets Video et NetStream, et appelle Video.attachNetStream() et NetStream.play(), est placé dans une fonction de gestionnaire. Le gestionnaire est appelé uniquement si la tentative de connexion à l’objet NetConnection a réussi, ce qui est le cas lorsque l’événement netStatus renvoie un objet info doté d’une propriété code signalant la réussite de l’opération. Il est recommandé d’attendre l’établissement d’une connexion avant d’appeler NetStream.play().

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }