Camera  - AS3

Quantité de mouvement détecté par la caméra. Les valeurs gérées sont comprises entre 0 (aucun mouvement n’est détecté) et 100 (une grande quantité de mouvement est détectée). La valeur de cette propriété peut vous aider à déterminer s’il est nécessaire de transmettre un paramètre à la méthode setMotionLevel().

Si la caméra est disponible mais qu’elle n’est pas encore utilisée parce que la méthode Video.attachCamera() n’a pas été appelée, cette propriété est définie sur -1.

Si vous diffusez en continu de la vidéo non compressée en local seulement, cette propriété n’est définie que si vous avez affecté une fonction au gestionnaire d’événement. Dans le cas contraire, elle n’est pas définie.

Eléments de l’API associés

Quantité maximale de bande passante pouvant être utilisée par la source vidéo sortante actuelle, en octets. Une valeur de 0 signifie que la source peut utiliser autant de bande passante que nécessaire pour conserver la qualité d’image voulue.

Pour définir cette propriété, utilisez la méthode setQuality().

Eléments de l’API associés

Cadence à laquelle la caméra capture des données, en images par seconde. Cette propriété ne peut pas être définie ; toutefois, vous pouvez utiliser la méthode setMode() pour définir une propriété connexe, fps, qui spécifie la cadence maximale à laquelle vous souhaitez que la caméra capture les données.

Eléments de l’API associés

Fréquence maximale à laquelle la caméra peut capturer des données, en images par seconde. La fréquence maximale possible dépend des capacités de la caméra ; cette fréquence peut ne pas être atteinte.

• Pour définir une valeur souhaitée pour cette propriété, utilisez la méthode setMode().
• Pour déterminer la cadence à laquelle la caméra capture actuellement les données, utilisez la propriété currentFPS.

Eléments de l’API associés

Hauteur de capture actuelle, en pixels. Pour définir une valeur à cette propriété, utilisez la méthode setMode().

Eléments de l’API associés

Index de base zéro qui spécifie la position de la caméra dans le tableau Camera.names, qui répertorie toutes les caméras disponibles.

Eléments de l’API associés

La propriété isSupported est définie sur true si la classe Camera est disponible sur la plate-forme actuelle ; dans le cas contraire, elle est définie sur false.

Nombre d’images vidéos (appelées images-clés) transmises intégralement sans être interpolées par l’algorithme de compression vidéo. La valeur par défaut, 15, indique que chaque quinzième image est une image-clé. Une valeur de 1 signifie que chaque image est une image-clé. Les valeurs autorisées vont de 1 à 300.

Eléments de l’API associés

Indique si les données capturées par la caméra et visionnées localement sont compressées et décompressées (true), comme elles le seraient pour une transmission en directe par le biais de Flash Media Server, ou non compressées (false). La valeur par défaut est false.

Le flux compressé est utile pour les tests, par exemple pour obtenir un aperçu des paramètres de qualité vidéo, mais son coût de traitement est important. L’affichage local est compressé, modifié pour être transmis comme il le serait sur une connexion directe, puis décompressé pour l’affichage local.

Pour définir cette valeur, utilisez Camera.setLoopback(). Pour définir le taux de compression utilisé lorsque vous réglez cette propriété sur true, utilisez Camera.setQuality().

Eléments de l’API associés

Quantité de mouvement requis pour invoquer l’événement activity. Les valeurs gérées sont comprises entre 0 et 100. La valeur par défaut est 50.

La vidéo peut être affichée quelle que soit la valeur de la propriété motionLevel. Pour plus d’informations, voir l’entrée setMotionLevel().

Eléments de l’API associés

Nombre de millisecondes qui s’écoule entre le moment où la caméra arrête la détection du mouvement et le moment où l’événement activity est appelé. La valeur par défaut est 2 000 (2 secondes).

Pour définir cette valeur, utilisez setMotionLevel().

Eléments de l’API associés

Valeur booléenne qui indique si l’utilisateur a refusé (true) ou autorisé (false) l’accès à la caméra dans la boîte de dialogue de confidentialité de Flash Player. Lorsque cette valeur change, l’événement status est distribué.

Eléments de l’API associés

Nom de la caméra en cours, tel que renvoyé par le matériel de la caméra.

Eléments de l’API associés

Tableau de chaînes contenant les noms de toutes les caméras disponibles. L’accès à ce tableau n’affiche pas la boîte de dialogue de confidentialité de Flash Player. Ce tableau indique l’index de base zéro de chaque caméra et le nombre de caméras présentes sur le système (via names.length).

L’appel de la propriété names implique un examen minutieux du matériel. Dans la plupart des cas, vous pouvez utiliser la caméra par défaut.

Eléments de l’API associés

Déterminez si l’application a été autorisée à utiliser la caméra.

Eléments de l’API associés

Spécifie le côté d’un périphérique sur lequel la caméra se trouve.

Utilisez la propriété position pour déterminer si la caméra sur un périphérique mobile se trouve à l’avant ou à l’arrière du périphérique. La fonction suivante vérifie chaque caméra disponible jusqu’à ce qu’il détecte une caméra avec la position souhaitée. Si aucune caméra ne possède la position souhaitée, la caméra par défaut est renvoyée.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

Sur les périphériques mobiles, la position de la caméra est soit CameraPosition.FRONT soit CameraPosition.BACK. S’il s’avère impossible de déterminer la position de la caméra, la position est signalée comme suit : CameraPosition.UNKNOWN. Sur les plates-formes de bureau, la position est toujours CameraPosition.UNKNOWN.

Les constantes pour les valeurs valides de cette propriété sont définies dans la classe CameraPosition.

Eléments de l’API associés

Niveau de qualité d’image requis, tel que déterminé par le taux de compression appliqué à chaque image vidéo. Les valeurs de qualité acceptables sont comprises entre 1 (qualité la plus médiocre, compression maximale) et 100 (qualité optimale, pas de compression). La valeur par défaut est 0, ce qui signifie que la qualité de l’image peut varier si nécessaire pour éviter de dépasser la bande passante disponible.

Pour définir cette propriété, utilisez la méthode setQuality().

Eléments de l’API associés

Largeur de capture actuelle, en pixels. Pour définir une valeur souhaitée pour cette propriété, utilisez la méthode setMode().

Eléments de l’API associés

Remplit un tableau d’octets à partir d’une zone rectangulaire de données de pixels

Écrit un entier non signé (valeur de pixel non multipliée 32 bits) pour chaque pixel dans le tableau d’octets. Le tableau est redimensionné selon le nombre d’octets nécessaire pour contenir tous les pixels.

Paramètres

Eléments de l’API associés

Remplit un vecteur à partir d’une zone rectangulaire de données de pixels.

Ecrit un entier non signé (valeur de pixel non multipliée de 32 bits) pour chaque pixel dans le vecteur. Le vecteur est redimensionné selon le nombre d’entrées nécessaire pour contenir tous les pixels.

Paramètres

Eléments de l’API associés

Copie la dernière image sur une image bitmap.

Cette méthode copie le contenu de la dernière image sur une occurrence de BitmapData.

Paramètres

Eléments de l’API associés

Renvoie une référence à un objet Camera pour capturer de la vidéo. Pour commencer la capture de la vidéo, vous devez relier l’objet Camera à un objet vidéo (voir Video.attachCamera() ). Pour transmettre la vidéo à Flash Media Server, appelez NetStream.attachCamera() pour relier l’objet Camera à un objet NetStream.

Plusieurs appels de la méthode getCamera() référencent le même pilote de caméra. Ainsi, si votre script contient du code comme firstCam:Camera = getCamera() et secondCam:Camera = getCamera(), alors firstCam et secondCam font référence à une même caméra, qui est la caméra par défaut de l’utilisateur.

Sur les périphériques mobiles munis d’une caméra arrière et frontale, il est uniquement possible de capturer des vidéos à partir d’une seule caméra à la fois.

En général, évitez de transmettre la valeur du paramètre name ; contentez-vous d’utiliser getCamera() pour renvoyer une référence à la caméra par défaut. L’utilisateur peut spécifier la caméra par défaut devant être utilisée via le panneau Paramètres de la caméra (comme indiqué plus bas dans cette section).

Vous ne pouvez pas utiliser ActionScript pour définir un paramètre d’autorisation ou de refus pour l’accès à la caméra, mais vous pouvez afficher la boîte de dialogue de configuration de la caméra des paramètres d’Adobe Flash Player dans laquelle l’utilisateur peut définir l’autorisation de la caméra. Lorsqu’un fichier SWF utilisant la méthode attachCamera() tente d’associer la caméra renvoyée par la méthode getCamera() à un objet Video ou NetStream, Flash Player affiche une boîte de dialogue qui permet à l’utilisateur d’autoriser ou de refuser l’accès à la caméra (vérifiez la taille de la fenêtre de votre application qui doit être au moins de 215 x 138 pixels, taille minimale requise par Flash Player pour afficher la boîte de dialogue). Lorsque l’utilisateur répond à la boîte de dialogue de configuration de la caméra, Flash Player renvoie un objet information dans l’événement status qui précise la réponse de l’utilisateur : Camera.muted indique que l’utilisateur a refusé l’accès à une caméra ; Camera.unmuted qu’il en a autorisé l’accès. Pour déterminer si l’utilisateur a refusé ou autorisé l’accès à la caméra sans traiter l’événement status, utilisez la propriété muted.

Dans Flash Player, l’utilisateur peut spécifier des paramètres de confidentialité permanents pour un domaine spécifique. Pour ce faire, il lui suffit de cliquer sur le bouton droit de la souris (Windows et Linux) ou de cliquer sur le bouton droit de la souris tout en maintenant la touche Contrôle enfoncée (Macintosh) sur un fichier SWF en cours de lecture, de sélectionner Paramètres, d’ouvrir la boîte de dialogue Confidentialité, puis de sélectionner Mémoriser. Si l’utilisateur sélectionne Mémoriser, Flash Player ne l’invite plus à autoriser ou refuser l’accès à votre caméra des fichiers SWF de ce domaine.

Remarque : la méthode attachCamera() n’invoque pas la boîte de dialogue permettant d’autoriser ou de refuser l’accès à la caméra si l’utilisateur a refusé l’accès en sélectionnant Mémoriser dans la boîte de dialogue Paramètres de Flash Player. Dans ce cas, vous pouvez demander à l’utilisateur de modifier le paramètre d’autorisation ou de refus en affichant le panneau de confidentialité de Flash Player pour l’utilisateur à l’aide de Security.showSettings(SecurityPanel.PRIVACY).

Si getCamera() renvoie la valeur null, cela signifie que la caméra est utilisée par une autre application ou qu’aucune caméra n’est installée sur le système. Pour déterminer si une caméra est installée, utilisez la propriété names.length. Pour afficher le panneau Paramètres de la caméra de Flash Player qui permet à l’utilisateur de choisir la caméra à référencer par getCamera(), utilisez Security.showSettings(SecurityPanel.CAMERA).

L’analyse du matériel à la recherche de caméras exige un certain temps. Lorsque le moteur d’exécution détecte au moins une caméra, le matériel n’est plus analysé pendant la durée de vie de l’occurrence du lecteur. Cependant, si le moteur d’exécution ne détecte pas de caméra, il effectue une analyse à chaque appel de getCamera. Cela est particulièrement pratique si la caméra est désactivée. Si votre fichier SWF contient un bouton Réessayer qui appelle getCamera, Flash Player peut localiser la caméra sans que l’utilisateur ne soit obligé de redémarrer le fichier SWF.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Demande l’autorisation d’accès à la caméra pour l’application.

Spécifie les images qui sont transmises intégralement (keyframes) sans être interpolées par l’algorithme de compression vidéo. Cette méthode ne fonctionne que si vous transmettez la vidéo via Flash Media Server.

L’algorithme de compression vidéo de Flash compresse la vidéo en transmettant uniquement les éléments modifiés à partir de la dernière image de la vidéo. Ces portions sont appelées images interpolées. Les images d’une vidéo peuvent être interpolées en fonction du contenu de l’image précédente. Une image-clé, en revanche, est une image vidéo complète. Elle n’est pas interpolée sur la base des images précédentes.

Pour déterminer la valeur du paramètre keyFrameInterval, tenez compte de la bande passante et de l’accessibilité de la lecture vidéo. Une valeur keyFrameInterval élevée (envoi moins fréquent des images-clés), par exemple, entraîne une consommation réduite de bande passante. En revanche, le temps nécessaire au positionnement de la tête de lecture à un point donné de la vidéo est susceptible d’augmenter, car il sera peut-être nécessaire d’interpoler un plus grand nombre d’images précédentes avant que la vidéo puisse reprendre.

Inversement, une valeur keyFrameInterval faible (envoi plus fréquent des images-clés) augmente la consommation de bande passante, car des images vidéo intégrales sont transmises plus souvent, mais elle peut réduire le temps nécessaire à la localisation d’une image spécifique dans une vidéo enregistrée.

Paramètres

Eléments de l’API associés

Indique s’il est nécessaire d’utiliser un flux vidéo compressé pour un visionnage local des données reçues par la caméra. Cette méthode n’est applicable que si vous transmettez du contenu vidéo à l’aide de Flash Media Server. Le réglage de compress sur true vous permet de déterminer plus précisément la façon dont la vidéo se présentera lorsque les utilisateurs la visionneront en temps réel.

Bien qu’un flux compressé soit utile à des fins de test, par exemple pour se faire une idée des paramètres de qualité vidéo, les coûts de traitement qu’il entraîne sont élevés car il implique plus qu’une simple compression. Le contenu vidéo est compressé, édité à des fins de transmission comme sur une connexion en direct, puis décompressé pour un visionnage local.

Pour définir le taux de compression utilisé lorsque vous réglez compress sur true, servez-vous de Camera.setQuality().

Paramètres

Eléments de l’API associés

Définit le mode de capture de la caméra sur le mode natif qui remplit le mieux les conditions requises. Si la caméra ne dispose pas d’un mode natif correspondant à tous les paramètres que vous transmettez, le moteur d’exécution sélectionne un mode de capture qui synthétise le mieux le mode demandé. Cette manipulation peut nécessiter le découpage de l’image et l’omission d’images.

Par défaut, le moteur d’exécution omet des images si nécessaire pour conserver la taille de l’image. Pour réduire le nombre d’images omises, même si cela passe par une réduction de la taille de l’image, définissez le paramètre favorArea sur false.

Lorsqu’il choisit un mode natif, le moteur d’exécution tente de conserver le format demandé dans la mesure du possible. Par exemple, si vous publiez la commande myCam.setMode(400, 400, 30) et que les valeurs de largeur et de hauteur maximales disponibles sur la caméra sont 320 et 288, le moteur d’exécution définit la largeur et la hauteur sur 288. Ce faisant, le moteur d’exécution conserve le format 1/1 que vous avez demandé.

Pour déterminer les valeurs affectées à ces propriétés une fois la sélection, par le moteur d’exécution, du mode qui correspond le mieux aux valeurs que vous avez demandées, utilisez les propriétés width, height et fps.

Si vous utilisez Flash Media Server, vous pouvez également capturer des images uniques ou créer une séquence en accéléré. Pour plus d’informations, voir la méthode NetStream.attachCamera().

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Spécifie la quantité de mouvement requise pour distribuer l’événement activity. Peut éventuellement définir le nombre de millisecondes qui doit s’écouler sans activité avant que le moteur d’exécution ne considère que le mouvement a cessé et distribue l’événement.

Remarque : la vidéo peut être affichée quelle que soit la valeur du paramètre motionLevel. Ce paramètre détermine uniquement à quel moment et dans quelles circonstances l’événement est distribué, pas si du contenu vidéo est capturé ou affiché.

Pour empêcher la caméra de détecter le mouvement, attribuez la valeur 100 au paramètre motionLevel. Dans ce cas, l’événement activity n’est jamais distribué (vous utiliserez probablement cette valeur à des fins de tests uniquement, par exemple pour désactiver temporairement des gestionnaires qui seraient normalement déclenchés par la distribution de l’événement).

Pour déterminer la quantité de mouvement actuellement détectée par la caméra, utilisez la propriété activityLevel. Les valeurs de sensibilité de mouvement correspondent directement aux valeurs d’activité. La valeur d’activité 0 est associée à l’absence totale de mouvement. La valeur d’activité 100 est associée au mouvement constant. Lorsque vous êtes immobile, votre valeur d’activité est inférieure à votre valeur de sensibilité de mouvement. Inversement, lorsque vous vous déplacez, vos valeurs d’activité sont fréquemment supérieures à votre valeur de sensibilité de mouvement.

L’objectif de cette méthode est similaire à celui de Microphone.setSilenceLevel(). Les deux méthodes sont utilisées pour spécifier à quel moment il convient de distribuer l’événement activity. Toutefois, leur impact sur la publication des flux diffère de manière significative :

• Microphone.setSilenceLevel() est conçu pour optimiser la bande passante. Lorsqu’un flux audio est considéré comme étant silencieux, aucune donnée audio n’est envoyée. En revanche, un message unique indiquant le début du silence est envoyé.
• Camera.setMotionLevel() est conçu pour détecter le mouvement et n’a aucune incidence sur l’utilisation de la bande passante. La vidéo est envoyée peu importe qu’un flux vidéo détecte du mouvement ou non.

Paramètres

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Définit la quantité maximale de bande passante par seconde ou la qualité d’image requise pour les données vidéo sortantes actuelles. Cette méthode ne peut généralement être appliquée que si vous transmettez la vidéo via Flash Media Server.

Utilisez-la pour spécifier l’élément de la vidéo sortante le plus important pour votre application, la bande passante ou la qualité de l’image.

• Pour indiquer que la bande passante est prioritaire, attribuez une valeur à bandwidth et la valeur 0 à quality. Le moteur d’exécution transmet une vidéo de qualité optimale dans la bande passante spécifiée. Si nécessaire, le moteur d’exécution réduit la qualité de l’image afin d’éviter de dépasser la bande passante spécifiée. En général, plus le mouvement augmente, plus la qualité diminue.
• Pour indiquer que la qualité est prioritaire, transmettez la valeur 0 à bandwidth et une valeur numérique à quality. Le moteur d’exécution utilise autant de bande passante que nécessaire pour conserver la qualité spécifiée. Si nécessaire, le moteur d’exécution réduit la fréquence pour conserver la qualité de l’image. En général, plus le mouvement augmente, plus la consommation de bande passante augmente également.
• Pour spécifier que la bande passante et la qualité sont aussi importantes l’une que l’autre, transmettez des valeurs numériques aux deux paramètres. Le moteur d’exécution transmet alors de la vidéo permettant de respecter la qualité requise et ne dépassant pas la bande passante spécifiée. Si nécessaire, le moteur d’exécution réduit la fréquence pour conserver la qualité de l’image sans dépasser la bande passante spécifiée.

Paramètres

Eléments de l’API associés

Distribué lorsqu’une caméra commence ou termine une session. Appelez Camera.setMotionLevel() pour spécifier la quantité de mouvement requise pour déclencher un événement activity avec une valeur activating de true ou le délai devant s’écouler sans activité avant le déclenchement d’un événement activity avec une valeur activating de false.

Les propriétés de cet événement sont les suivantes :

Distribué lorsque l’application demande l’autorisation d’utiliser la caméra sur le périphérique. Vérifiez la valeur de la propriété status pour déterminer si l’autorisation a été accordée ou refusée.

Eléments de l’API associés

Distribué lorsqu’une caméra publie son état. Avant d’accéder à une caméra, le moteur d’exécution affiche une boîte de dialogue de confidentialité pour permettre aux utilisateurs d’autoriser ou de refuser l’accès à leur caméra. Si la propriété code est définie sur "Camera.Muted", l’utilisateur a interdit au fichier SWF d’accéder à sa caméra. Si la propriété code est réglée sur "Camera.unmuted", l’utilisateur a autorisé le fichier SWF à accéder à sa caméra.

Remarque : cet événement n’est pas distribué sur la plate-forme AIR. Il est utilisé uniquement dans Flash Player.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Envoyé après qu’un nouveau cadre de caméra a été traité par le moteur d’exécution et est disponible pour la copie.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Remarque : une caméra doit être reliée à votre ordinateur pour le bon déroulement de cet exemple.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}