TextLine  - AS3

Especifica el número de píxeles desde la línea base hasta la parte superior de los caracteres más altos de la línea. En un objeto TextLine que contenga un solo elemento gráfico, ascent se establece en 0.

El número de átomos de la línea, esto es, el número de elementos indivisibles, incluidos los espacios y los elementos gráficos.

Especifica el número de píxeles desde la línea base hasta la parte inferior de los caracteres que menos descienden en la línea. En un objeto TextLine que contenga un solo elemento gráfico, descent se establece en 0.

Indica si la línea de texto contiene elementos gráficos.

Elementos de API relacionados

Indica si la línea de texto contiene tabulaciones.

Un vector que contiene los objetos TextLineMirrorRegion asociados a la línea, o null si no hay ninguno.

Elementos de API relacionados

El elemento TextLine siguiente en el objeto TextBlock o null si se trata de la última línea del bloque o su validez es TextLineValidity.STATIC.

Elementos de API relacionados

El elemento TextLine anterior en el objeto TextBlock, o null si se trata de la primera línea del bloque o si su validez es TextLineValidity.STATIC.

Elementos de API relacionados

La longitud del texto sin procesar en el bloque de texto que se convierte en línea, incluidos los caracteres U+FDEF que representen elementos gráficos y cualquier espacio final que pertenezca a la línea, pero que no sea visible.

Elementos de API relacionados

La anchura especificada para el método TextBlock.createTextLine() cuando se creó la línea. Este valor resulta útil para saber si una línea necesita nuevos saltos de línea.

Elementos de API relacionados

El objeto TextBlock que contiene la línea de texto, o null si la validez de la línea es TextLineValidity.STATIC, lo que significa que la conexión entre la línea y el objeto TextBlock se ha interrumpido.

Elementos de API relacionados

El índice del primer carácter de la línea del texto sin procesar en el bloque de texto.

Elementos de API relacionados

La altura lógica de la línea de texto, que equivale a ascent + descent. Para obtener la altura vinculada, acceda a la propiedad height heredada.

El valor se calcula a partir de la diferencia entre las líneas base que limitan la línea, bien en la ideografía inferior, superior, ascendente o descendente, según el valor de TextBlock.baselineZero. Los elementos gráficos no se tienen en cuenta al calcular estas líneas base.

Elementos de API relacionados

La anchura lógic de la línea de texto, que es la anchura que utiliza el motor de texto para trazar la línea. Acceda a la propiedad width heredada para obtener la anchura real del cuadro de delimitación de todos los píxeles dibujados.

Elementos de API relacionados

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Especifica el número de píxeles desde la línea base hasta la parte superior de los caracteres o el gráfico más alto de la línea.

Especifica el número de píxeles desde la línea base hasta la parte inferior de los caracteres o el gráfico que menos desciende en la línea.

La altura lógica total de la línea de texto, que equivale a totalAscent + totalDescent.

El ancho de la línea si no se justificó. Para el texto sin justificar, este valor es el mismo que textWidth. Para el texto justificado, este valor es la longitud que debería haber sido sin la justificación y textWidth representa el ancho de la línea real. Por ejemplo, cuando se justifica la siguiente cadena y se envía a TextBlock.createTextLine() con una anchura de 500, tiene una anchura real de 500 pero una anchura sin justificar de 268.9921875.

Elementos de API relacionados

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Permite a la aplicación asociar datos arbitrarios a la línea de texto.

Especifica la validez actual de la línea de texto. Los valores de esta propiedad se encuentran en los miembros de la clase TextLineValidity. Las reglas para establecer la propiedad son las siguientes:

Una línea tiene el estado USER_INVALID si su validez se establece en cualquier cadena no miembro de TextLineValidity. USER_INVALID es una abstracción empleada en nuestro caso para representar estos valores.

Si se modifica el contenido de TextBlock, el motor de ejecución de Flash marca las líneas afectadas, la línea anterior y las siguientes con el estado INVALID. La línea anterior debe marcarse como INVALID cuando un cambio permite que la línea anterior absorba parte del contenido que se encontraba previamente en la primera línea.

Las líneas con saltos de línea nuevos siempre tienen el estado VALID. El el motor de ejecución de Flash puede hacer que las líneas siguientes pasen de VALID a POSSIBLY_INVALID o INVALID. También puede hacer que las líneas pasen de POSSIBLY_INVALID a VALID si los saltos coinciden, o a INVALID si no lo hacen.

El código de la aplicación puede marcar las líneas VALID como INVALID o USER_INVALID, y las líneas USER_INVALID como VALID. El código de usuario no puede marcar las líneas como POSSIBLY_INVALID.

El código de la aplicación puede marcar cualquier línea como STATIC. Si lo hace, el miembro de block pasa a ser null. Todos los elementos gráficos de una línea de texto STATIC se eliminan y se reasocian si forman parte de un nuevo salto de línea en el bloque de texto desde el que se derivó la línea de texto STATIC originalmente.

Elementos de API relacionados

Vuelca el contenido subyacente del objeto TextLine como una cadena XML. Esto puede resultar útil en las pruebas automatizadas e incluye texto, formato e información de diseño.

A continuación se describe la salida:

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Nota: el contenido y el formato de la salida de este método puede cambiar en el futuro. Adobe no garantiza que este método siga siendo compatible con versiones anteriores.

Elementos de API relacionados

Este método está desfasado y no tiene ningún efecto. Los datos del átomo se comprimen y no afectan a la gestión de la eficiencia de la memoria.

Elementos de API relacionados

Obtiene el nivel bidireccional del átomo en el índice especificado. Se determina mediante una combinación de TextBlock.bidiLevel y las propiedades bidireccionales Unicode de los caracteres que forman la línea.

Por ejemplo, si comienza un bloque de texto con texto en hebreo, establecerá TextBlock.bidiLevel como 1, definiendo un valor predeterminado de derecha a izquierda. Si dentro del texto se muestra una cita en inglés (izquierda a derecha), ese texto tendrá un valor AtomBidiLevel de 2. Si dentro del inglés también aparece árabe (derecha a izquierda), AtomBidiLevel para esa ejecución se definirá en 3. Si dentro del texto en árabe se incluye un número (izquierda a derecha), el valor AtomBidiLevel para el número será 4. No importa la línea en que terminen los átomos. Los átomos de hebreo son AtomBidiLevel 1, los de inglés AtomBidiLevel 2, los de árabe AtomBidiLevel 3 y los numéricos AtomBidiLevel 4.

Parámetros

Elementos de API relacionados

Obtiene los límites del átomo en el índice especificado con relación a la línea de texto. Los límites del átomo especificado son la posición horizontal (x) en la línea, la posición vertical (y) la anchura (w) y la altura (h). Todos los valores se expresan en píxeles.

Parámetros

Obtiene el centro del átomo medido con respecto a la línea base en el índice especificado.

Parámetros

Obtiene el gráfico del átomo en el índice especificado, o bien es null si el átomo es un carácter.

Parámetros

Devuelve el índice del átomo que contiene el carácter especificado por el parámetro charIndex, o -1 si el carácter no se encuentra en ningún átomo de la línea. charIndex se calcula en relación con todo el contenido del bloque de texto que contiene la línea.

Parámetros

Devuelve el índice del átomo en el punto especificado por los parámetros x e y, o -1 si no hay ningún átomo en dicho punto.

Este método realiza coordenadas globales, por lo que podrá utilizarlo fácilmente con las propiedades MouseEvent.stageX y MouseEvent.stageY.

Parámetros

Obtiene el índice inicial del bloque de texto del átomo en el índice especificado.

Parámetros

Obtiene el índice final del bloque de texto del átomo en el índice especificado.

Parámetros

Obtiene la rotación del átomo en el índice especificado. Se utilizan constantes de TextRotation para esta propiedad. La rotación del átomo es la suma de rotaciones del elemento y de la línea. Se usa principalmente para definir la orientación del carácter de intercalación (cursor) cuando interactúa con TextLine.

Parámetros

Elementos de API relacionados

Indica si existe un límite de palabras a la izquierda del átomo en el índice especificado. Los límites de palabras se calculan en función de las propiedades Unicode de los caracteres que forman la línea.

Parámetros

Obtiene la posición de la línea base especificada con relación a TextBlock.baselineZero.

Parámetros

Elementos de API relacionados

Devuelve el primer objeto TextLineMirrorRegion de la línea cuya propiedad mirror coincide con la especificada por el parámetro mirror, o null si no hay ninguna coincidencia.

Incluso un solo elemento TextElement puede producir varios objetos TextLineMirrorRegion en una o más líneas, en función de la orientación bidireccional y los saltos de línea. Las propiedades nextRegion y previousRegion vinculan todas las regiones reflejadas generadas a partir de un elemento de texto.

Parámetros

Elementos de API relacionados

Anchura máxima requerida de una línea de texto, en píxeles. El método TextBlock.createTextLine() utiliza esta constante como valor predeterminado para el parámetro width, si no especifica un valor.

Elementos de API relacionados

1. Añada el componente NumericStepper a la biblioteca.
2. Guarde este código como TextLineExample.as en el mismo directorio que el archivo FLA.
3. Defina la clase en la ventana Propiedades de FLA en TextLineExample.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}