String  - AS3

Un entero que especifica el número de caracteres del objeto String especificado.

Dado que todos los índices de cadenas están basados en cero, el índice del último carácter de cualquier cadena x es x.length - 1.

Crea un nuevo objeto String inicializado con la cadena especificada.

Nota: dado que los literales de cadena utilizan menos espacio que los objetos String y son generalmente más fáciles de usar, deberá utilizar literales de cadena en lugar de la clase String a no ser que exista un motivo específico para utilizar un objeto String en lugar de un literal de cadena.

Devuelve el carácter situado en la posición especificada por el parámetro index. Si index no es un número entre 0 y string.length - 1, se devolverá una cadena vacía.

Este método es igual que String.charCodeAt(), con la diferencia de que el valor devuelto es un carácter, no un código de carácter de entero de 16 bits.

Parámetros

Elementos de API relacionados

Devuelve el código de carácter numérico Unicode del carácter situado en el index especificado. Si index no es un número entre 0 y string.length - 1, se devolverá NaN.

Este método es igual que String.charAt(), con la diferencia de que el valor devuelto es un código de carácter de entero de 16 bits, no el carácter en sí.

Parámetros

Elementos de API relacionados

Añade los argumentos proporcionados al final del objeto String, los convierte en cadenas si es necesario y devuelve la cadena resultante. El valor original del objeto String de origen permanece sin cambios.

Parámetros

Devuelve una cadena formada por los caracteres representados por los códigos de caracteres Unicode de los parámetros.

Parámetros

Busca la cadena y devuelve la posición en la que aparece por primera vez val en la posición de startIndex o después de dicha posición dentro de la cadena que origina la llamada. Este índice está basado en cero, con lo cual se considera que el primer carácter está en el índice 0, no en el índice 1. Si no se encuentra val, el método devuelve -1.

Parámetros

Elementos de API relacionados

Busca la cadena de derecha a izquierda y devuelve el índice de la última posición en que aparece val antes que startIndex. El índice está basado en cero, lo que significa que el primer carácter se encuentra en el índice 0 y el último en string.length - 1. Si no se encuentra val, el método devuelve -1.

Parámetros

Elementos de API relacionados

Compara el orden de clasificación de dos o más cadenas y devuelve el resultado de la comparación como un entero. Aunque este método está pensado para gestionar la comparación de forma específica para una localización, la implementación ActionScript 3.0 no produce un resultado diferente de otras comparaciones de cadenas tales como las de los operadores de igualdad (==) o desigualdad (!=). Si las cadenas son equivalentes, el valor devuelto es 0. Si el valor de cadena original precede al valor de cadena especificado por other, el valor devuelto es un entero negativo cuyo valor absoluto representa el número de caracteres que separan los dos valores de cadena. Si el valor de cadena original va después de other, el valor devuelto es un entero positivo cuyo valor absoluto representa el número de caracteres que separan los dos valores de cadena.

Parámetros

Establece la correspondencia del patrón pattern especificado con la cadena.

Parámetros

Elementos de API relacionados

Establece la correspondencia del patrón pattern especificado con la cadena y devuelve una nueva cadena en la que la primera coincidencia de pattern se sustituye por el contenido especificado por repl. El parámetro pattern puede ser una cadena o una expresión normal. El parámetro repl puede ser una cadena o una función; si es una función, la cadena devuelta por la función se inserta en lugar de la coincidencia. La cadena original no se modifica.

En el siguiente ejemplo, sólo se sustituye la primera instancia de "sh" (con distinción entre mayúsculas y minúsculas):

    var myPattern:RegExp = /sh/;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seashore.

En el siguiente ejemplo, todas las instancias de "sh" (con distinción entre mayúsculas y minúsculas) se sustituyen porque el indicador g (global) está definido en la expresión normal:

    var myPattern:RegExp = /sh/g;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seaschore.

En el siguiente ejemplo, todas las instancias de "sh" se sustituyen porque el indicador g (global) está definido en la expresión normal y las coincidencias no distinguen entre mayúsculas y minúsculas, ya que está definido el indicador i (ignoreCase):

    var myPattern:RegExp = /sh/gi;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // sche sells seaschells by the seaschore.

Parámetros

var str:String = "flip-flop";
    var pattern:RegExp = /(\w+)-(\w+)/g;
    trace(str.replace(pattern, "$2-$1")); // flop-flip

    var str1:String = "abc12 def34";
    var pattern:RegExp = /([a-z]+)([0-9]+)/;
    var str2:String = str1.replace(pattern, replFN);
    trace (str2);   // 12abc 34def
    
    function replFN():String {
      return arguments[2] + arguments[1];
    }

    {"abc12", "abc", "12", 0, "abc12 def34"}

    {"def34", "def", "34", 6, "abc123 def34"}

Elementos de API relacionados

Busca el patrón pattern especificado y devuelve el índice de la primera subcadena coincidente. Si no hay ninguna subcadena coincidente, el método devuelve -1.

Parámetros

Elementos de API relacionados

Devuelve una cadena que incluye el carácter inicial (startIndex) y todos los caracteres que aparecen hasta el carácter endIndex, sin incluir éste último. El objeto String original no se modifica. Si no se especifica el parámetro endIndex, el final de la subcadena será el final de la cadena. Si el carácter indexado por startIndex es el mismo o está situado a la derecha del carácter indexado por endIndex, el método devolverá una cadena vacía.

Parámetros

Elementos de API relacionados

Divide un objeto String en un conjunto de subcadenas fragmentándolo siempre que aparece el parámetro delimitador delimiter.

Si el parámetro delimiter es una expresión normal, sólo se tendrá en cuenta la primera coincidencia en una posición determinada, aunque el control hacia atrás pudiera encontrar una coincidencia de subcadena no vacía en dicha posición. Por ejemplo:

     var str:String = "ab";
     var results:Array = str.split(/a*?/); // results == ["","b"]
     
     results = str.split(/a*/); // results == ["","b"].)

Si el parámetro delimiter es una expresión normal que contiene paréntesis de agrupaciones, cada vez que se encuentre delimiter, se unirán los resultados (incluidos los resultados no definidos) en el conjunto de salida. Por ejemplo

     var str:String = "Thi5 is a tricky-66 example.";
     var re:RegExp = /(\d+)/;
     var results:Array = str.split(re);
         // results == ["Thi","5"," is a tricky-","66"," example."]

Si se especifica el parámetro limit, el conjunto devuelto sólo tendrá el número especificado de elementos.

Si delimiter es una cadena vacía, una expresión normal vacía o una expresión normal que puede coincidir con una cadena vacía, cada carácter individual de la cadena se incluye en la salida como un elemento del conjunto.

Si el parámetro delimiter tiene el valor undefined, se situará la cadena completa en el primer elemento del conjunto devuelto.

Parámetros

Elementos de API relacionados

Devuelve una subcadena formada por los caracteres que comienzan en el valor de startIndex especificado y que tienen una longitud especificada por len. La cadena original permanece sin cambios.

Parámetros

Devuelve una cadena formada por el carácter especificado por startIndex y por todos los caracteres hasta endIndex - 1. Si no se especifica endIndex, se utilizará String.length. Si el valor de startIndex es igual al valor de endIndex, el método devolverá una cadena vacía. Si el valor de startIndex es mayor que el valor de endIndex, los parámetros se intercambiarán automáticamente antes de que se ejecute la función. La cadena original permanece sin cambios.

Parámetros

Devuelve una copia de esta cadena con todos los caracteres en mayúsculas convertidos en minúsculas. La cadena original permanece sin cambios. Aunque este método está pensado para gestionar la conversión de forma específica para una localización, la implementación ActionScript 3.0 no produce un resultado diferente del método toLowerCase().

Elementos de API relacionados

Devuelve una copia de esta cadena con todos los caracteres en minúsculas convertidos en mayúsculas. La cadena original permanece sin cambios. Aunque este método está pensado para gestionar la conversión de forma específica para una localización, la implementación ActionScript 3.0 no produce un resultado diferente del método toUpperCase().

Elementos de API relacionados

Devuelve una copia de esta cadena con todos los caracteres en mayúsculas convertidos en minúsculas. La cadena original permanece sin cambios.

Este método convierte todos los caracteres (no sólo A-Z) para los que existan equivalentes Unicode en minúsculas:

     var str:String = " JOSÉ BARÇA";
     trace(str.toLowerCase()); // josé barça

Estas asignaciones de caja se definen en la especificación de base de datos de caracteres Unicode.

Elementos de API relacionados

Devuelve una copia de esta cadena con todos los caracteres en minúsculas convertidos en mayúsculas. La cadena original permanece sin cambios.

Este método convierte todos los caracteres (no sólo a-z) para los que existan equivalentes Unicode en mayúsculas:

     var str:String = "José Barça";
     trace(str.toUpperCase()); // JOSÉ BARÇA

Estas asignaciones de caja se definen en la especificación de base de datos de caracteres Unicode.

Elementos de API relacionados

Devuelve el valor simple de una instancia String. Este método está diseñado para convertir un objeto String en un valor de cadena simple. Dado que los motores de ejecución de Flash llaman automáticamente a valueOf() cuando es preciso, sólo tendrá que llamar a este método explícitamente en casos poco frecuentes.

1. El constructor de StringExample declara varias instancias locales de String, que se inicializan con diversas cadenas y un nuevo objeto StringHelper.
2. La clase StringHelper tiene los siguientes métodos:
   • replace(): llama a los métodos split() y join() de String para eliminar una subcadena de la cadena transferida y sustituirla por una nueva.
   • trim(): llama a los métodos trimBack() y trimFront() utilizando las cadenas transferidas y devuelve la cadena actualizada.
   • trimFront(): elimina sucesivamente todos los caracteres que coinciden con el parámetro char, comenzando desde la parte inicial de la cadena hasta llegar al final, hasta que el primer carácter de la cadena no coincida con char; entonces devuelve la cadena actualizada.
   • trimBack(): elimina sucesivamente todos los caracteres que coinciden con el parámetro char, comenzando desde el final de la cadena hasta llegar al principio, hasta que el último carácter de la cadena no coincida con char; entonces, devuelve la cadena actualizada.
   • stringToCharacter(): devuelve el primer carácter de la cadena transferido.
3. A continuación, se generan tres cadenas con las variables de cadena declaradas: con una llamada al método replace() se genera la segunda cadena, y con una llamada a trim() se genera la tercera cadena.

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}