DisplayObjectContainer  - AS3

Determina si los elementos secundarios del objeto están activados para acciones de ratón o de dispositivo de entrada de usuario. Si un objeto está activado, el usuario puede interactuar con él por medio de un ratón o de un dispositivo de entrada de usuario. El valor predeterminado es true.

Esta propiedad es útil cuando se crea un botón con una instancia de la clase Sprite (en lugar de utilizar la clase SimpleButton). Cuando utilice una instancia de Sprite para crear un botón, podrá optar por decorar el botón empleando el método addChild() para añadir instancias adicionales de Sprite. Este proceso puede provocar un comportamiento inesperado con los eventos de ratón, ya que las instancias de Sprite que añada como elementos secundarios pueden convertirse en el objeto de destino de un evento de ratón cuando se espera que la instancia principal sea el objeto de destino. Para asegurarse de que la instancia principal actúa como objeto de destino de los eventos de ratón, puede establecer la propiedad mouseChildren de la instancia principal con el valor false.

No se distribuye ningún evento al establecer esta propiedad. Debe utilizar el método addEventListener() para crear funcionalidad interactiva.

Elementos de API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Devuelve el número de elementos secundarios de este objeto.

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Determina si los elementos secundarios del objeto están habilitados para tabulación. Activa o desactiva la tabulación para los elementos secundarios del objeto. El valor predeterminado es true.

Nota: no se debe utilizar la propiedad tabChildren con Flex. En su lugar, utilice la propiedad mx.core.UIComponent.hasFocusableChildren.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Devuelve un objeto TextSnapshot para esta instancia de DisplayObjectContainer.

Elementos de API relacionados

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

La llamada al constructor new DisplayObjectContainer() emite una excepción ArgumentError. No obstante, puede llamar a los constructores para las siguientes subclases de DisplayObjectContainer:

• new Loader()
• new Sprite()
• new MovieClip()

Añade una instancia secundaria de DisplayObject a esta instancia de DisplayObjectContainer. El elemento secundario se añade delante (encima) de todos los demás elementos secundarios de esta instancia de DisplayObjectContainer. (Para añadir un elemento secundario en una posición de índice concreta, utilice el método addChildAt().)

Si añade un objeto secundario que ya tiene un contenedor de objeto de visualización diferente como elemento principal, el objeto se elimina de la lista de elementos secundarios del otro contenedor de objeto de visualización.

Nota: el comando stage.addChild() puede causar problemas en un archivo SWF publicado, incluidos problemas de seguridad y conflictos con otros archivos SWF cargados. Sólo hay un escenario dentro de una instancia del motor de ejecución de Flash, no importa la cantidad archivos SWF cargados en el motor de ejecución. Por lo tanto, normalmente los objetos no se deben añadir al escenario directamente, bajo ningún concepto. El único objeto que debe contener el escenario es el objeto raíz. Cree un objeto DisplayObjectContainer para contener todos los elementos de la lista de visualización. Seguidamente, si es necesario, añada la instancia de DisplayObjectContainer al escenario.

Parámetros

Elementos de API relacionados

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Añade una instancia secundaria de DisplayObject a esta instancia de DisplayObjectContainer. El elemento secundario situado en la posición de índice especificada. El índice 0 representa el final (la parte inferior) de la lista de visualización de este objeto DisplayObjectContainer.

Por ejemplo, el siguiente ejemplo muestra tres objetos de visualización, etiquetados como a, b y c, en las posiciones de índice 0, 2 y 1 respectivamente:

Si añade un objeto secundario que ya tiene un contenedor de objeto de visualización diferente como elemento principal, el objeto se elimina de la lista de elementos secundarios del otro contenedor de objeto de visualización.

Parámetros

Elementos de API relacionados

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Indica si las restricciones de seguridad provocarían la omisión de objetos de visualización de la lista devuelta al llamar al método DisplayObjectContainer.getObjectsUnderPoint() con el punto point especificado. De manera predeterminada, el contenido de un dominio no puede obtener acceso a objetos de otro dominio a no ser que se les permita hacerlo mediante una llamada al método Security.allowDomain(). Para obtener más información sobre la seguridad, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

El parámetro point está en el espacio de coordenadas del escenario, que puede ser distinto del espacio de coordenadas del contenedor del objeto de visualización (a no ser que el contenedor del objeto de visualización esté en el escenario). Puede utilizar los métodos globalToLocal() y localToGlobal() para convertir puntos entre estos espacios de coordenadas.

Parámetros

Elementos de API relacionados

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Determina si el objeto de visualización especificado es un elemento secundario de la instancia de DisplayObjectContainer o la propia instancia. La búsqueda incluye la lista de visualización completa, incluida esta instancia de DisplayObjectContainer. Los elementos terciarios, cuaternarios, etc., devuelven true.

Parámetros

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Devuelve la instancia del objeto de visualización secundario que sale del índice especificado.

Parámetros

Elementos de API relacionados

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Devuelve el objeto de visualización secundario que sale con el nombre especificado. Si varios objetos de visualización secundarios tienen el nombre especificado, el método devolverá el primer objeto de la lista secundaria.

El método getChildAt() es más rápido que getChildByName(). El método getChildAt() obtiene acceso a un elemento secundario de un conjunto en caché, mientras que el método getChildByName() tiene que atravesar una lista vinculada para obtener acceso a un elemento secundario.

Parámetros

Elementos de API relacionados

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Devuelve la posición de índice de una instancia child de DisplayObject.

Parámetros

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Devuelve un conjunto de objetos que quedan bajo el punto especificado y son elementos secundarios (o terciarios, etc.) de esta instancia de DisplayObjectContainer. Los objetos secundarios que son inaccesibles por motivos de seguridad se omiten en el conjunto devuelto. Para determinar si esta restricción de seguridad afecta al conjunto devuelto, llame al método areInaccessibleObjectsUnderPoint().

El parámetro point está en el espacio de coordenadas del escenario, que puede ser distinto del espacio de coordenadas del contenedor del objeto de visualización (a no ser que el contenedor del objeto de visualización esté en el escenario). Puede utilizar los métodos globalToLocal() y localToGlobal() para convertir puntos entre estos espacios de coordenadas.

Parámetros

Elementos de API relacionados

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Elimina la instancia child de DisplayObject especificada de la lista de elementos secundarios de la instancia de DisplayObjectContainer. La propiedad parent del elemento secundario eliminado se establece como null y el objeto se recoge como dato innecesario si no hay ninguna otra referencia al elemento secundario. La posición de índice de los objetos de visualización situados por encima del elemento secundario en DisplayObjectContainer se reduce en 1.

La eliminación de datos innecesarios rescata espacio de memoria no utilizado. Cuando deja de haber una referencia activa o un almacenamiento de una variable o un objeto en algún lugar, la recogida de datos innecesarios limpia el espacio de memoria que ocupaba si no hay ninguna otra referencia a estos.

Parámetros

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Elimina una instancia de DisplayObject secundaria de la posición de index especificada en la lista de elementos secundarios de DisplayObjectContainer. La propiedad parent del elemento secundario eliminado se establece como null y el objeto se recoge como dato innecesario si no hay ninguna otra referencia al elemento secundario. La posición de índice de los objetos de visualización situados por encima del elemento secundario en DisplayObjectContainer se reduce en 1.

La eliminación de datos innecesarios rescata espacio de memoria no utilizado. Cuando deja de haber una referencia activa o un almacenamiento de una variable o un objeto en algún lugar, la recogida de datos innecesarios limpia el espacio de memoria que ocupaba si no hay ninguna otra referencia a estos.

Parámetros

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Elimina todas las instancias child de DisplayObject especificadas de la lista de elementos secundarios de la instancia de DisplayObjectContainer. La propiedad parent del elemento secundario eliminado se establece como null y los objetos se recogen como datos innecesarios si no hay ninguna otra referencia al elemento secundario.

La eliminación de datos innecesarios rescata espacio de memoria no utilizado. Cuando deja de haber una referencia activa o un almacenamiento de una variable o un objeto en algún lugar, la recogida de datos innecesarios limpia el espacio de memoria que ocupaba si no hay ninguna otra referencia a estos.

Parámetros

Cambia la posición de un elemento secundario existente en el contendor de objeto de visualización. Esto afecta a la disposición en capas de los objetos secundarios. Por ejemplo, el siguiente ejemplo muestra tres objetos de visualización, etiquetados como a, b y c, en las posiciones de índice 0, 1 y 2 respectivamente:

Cuando se utiliza el método setChildIndex() y se especifica una posición de índice ya ocupada, sólo se pueden cambiar las posiciones situadas entre la posición nueva y antigua de los objetos de visualización. El resto permanecen invariables. Si se mueve un elemento secundario a un índice INFERIOR que su índice actual, todos los elementos secundarios AUMENTARÁN en 1 su referencia de índice. Si se mueve un elemento secundario a un índice SUPERIOR que su índice actual, todos los elementos secundarios DISMINUIRÁN en 1 su referencia de índice. Por ejemplo, si el contenedor de objeto secundario del ejemplo anterior se denomina container, podrá intercambiar la posición de los objetos de visualización etiquetados como a y b llamando al siguiente código:

container.setChildIndex(container.getChildAt(1), 0);

Este código da como resultado la siguiente disposición de objetos:

Parámetros

Elementos de API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Se detiene gradualmente la ejecución de línea de tiempo de todos los objetos MovieClip con raíz en este objeto.

No se tienen en cuenta los objetos de visualización secundarios que pertenecen a un entorno limitado de seguridad al que no tiene acceso el código en ejecución.

Nota: no se detendrá la transmisión de reproducción de medios controlada a través de un objeto NetStream.

Intercambia el orden z (de delante a atrás) de los dos objetos secundarios especificados. Todos los demás objetos secundarios del contenedor de objeto de visualización permanecerán en la misma posición de índice.

Parámetros

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Intercambia el orden z (de delante a atrás) de los objetos secundarios situados en las posiciones de índice especificadas en la lista de elementos secundarios. Todos los demás objetos secundarios del contenedor de objeto de visualización permanecerán en la misma posición de índice.

Parámetros

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. El constructor llama al método configureAssets().
2. El método configureAssets() crea los objetos Sprite child y lastChild.
3. Un bucle for crea los cinco cuadrados de color naranja y los coloca uno detrás de otro.
4. Cuando se crea un objeto CustomSprite, su constructor llama al método draw() del objeto CustomSprite que crea un cuadrado de 50 x 50 píxeles mediante la llamada a los métodos beginFill(), drawRect() y endFill() de la clase Graphics. El método addChild() añade cada cuadrado a la lista de visualización.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}