Matrix  - AS3

El valor que afecta a la posición de los píxeles a lo largo del eje x cuando se modifica la escala de una imagen o cuando se gira.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

El valor que afecta a la posición de los píxeles a lo largo del eje y cuando se gira una imagen o cuando se sesga.

import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

El valor que afecta a la posición de los píxeles a lo largo del eje z cuando se gira una imagen o cuando se sesga.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

El valor que afecta a la posición de los píxeles a lo largo del eje y cuando se modifica la escala de una imagen o cuando se gira.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

La distancia que se trasladará cada punto a lo largo del eje x.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

La distancia que se trasladará cada punto a lo largo del eje y.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50

Crea un nuevo objeto Matrix con los parámetros especificados. En la notación de matrices, las propiedades se organizarán de este modo:

Si no proporciona ningún parámetro para el nuevo constructor new Matrix(), se crea una matriz de identidad con los valores siguientes:

a = 1

b = 0

c = 0

d = 1

tx = 0

ty = 0

En la notación de matrices, la matriz de identidad tendrá este aspecto:

import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)

Devuelve un nuevo objeto Matrix que es una copia de esta matriz, con una copia exacta del objeto contenido.

Concatena una matriz con la matriz actual y combina eficazmente los efectos geométricos de ambas matrices. En términos matemáticos, la concatenación de matrices equivale a combinarlas utilizando la multiplicación de matrices.

Por ejemplo, si la matriz m1 aplica a un objeto una escala de factor cuatro y la matriz m2 gira un objeto 1,5707963267949 radianes (Math.PI/2), m1.concat(m2) transforma m1 en una matriz que aplica a un objeto una escala cuatro y gira el objeto Math.PI/2 radianes.

Este método sustituye la matriz original con la concatenada. Si desea concatenar dos matrices sin alterar ninguna de las originales, puede copiar primero la matriz de origen con el método clone(), tal como se muestra en la sección de ejemplos de clases.

Parámetros

Copia un objeto Vector3D en columna específica del objeto Matrix3D de llamada.

Parámetros

Copia columnas específicas del objeto Matrix de llamada en el objeto Vector3D. El elemento w del objeto Vector3D no se cambiará.

Parámetros

Copia todos los datos de la matriz desde el objeto Point de origen en el objeto Matrix de llamada.

Parámetros

Copia un objeto Vector3D en fila concreta del objeto Matrix de llamada.

Parámetros

Copia filas concretas del objeto Matrix de llamada en el objeto Vector3D. El elemento w del objeto Vector3D no se cambiará.

Parámetros

Incluye parámetros para escala, rotación y traslación. Cuando se aplica a una matriz define sus valores en función de dichos parámetros.

El método createBox() permite obtener la misma matriz que si aplicara los métodos identity(), rotate(), scale() y translate() de forma consecutiva. Por ejemplo, mat2,2.createBox(, 2, Math.PI/4, 100, 100) tiene el mismo efecto que lo siguiente:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Parámetros

Elementos de API relacionados

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Crea el estilo específico de la matriz que los métodos beginGradientFill() y lineGradientStyle() esperan de la clase Graphics. La anchura y altura se cambian a un valor de par scaleX/scaleY y los valores tx/ty se desplazan con la mitad de la anchura y altura.

Por ejemplo, considere un degradado con las siguientes características:

• GradientType.LINEAR
• Dos colores, verde y azul, con el conjunto de proporciones definida en [0, 255].
• SpreadMethod.PAD
• InterpolationMethod.LINEAR_RGB

Las ilustraciones siguientes muestran degradados en los que se definió la matriz con el método createGradientBox() y con distinta configuración de parámetros:

Configuración de createGradientBox()	Degradado resultante
width = 25; height = 25; rotation = 0; tx = 0; ty = 0;
width = 25; height = 25; rotation = 0; tx = 25; ty = 0;
width = 50; height = 50; rotation = 0; tx = 0; ty = 0;
width = 50; height = 50; rotation = Math.PI / 4; // 45 degrees tx = 0; ty = 0;

Parámetros

Elementos de API relacionados

package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

Tras especificar un punto en el espacio de coordenadas previas a la transformación, devuelve las coordenadas de dicho punto después de la transformación. A diferencia de la transformación estándar aplicada con el método transformPoint(), la transformación del método deltaTransformPoint() no tiene en cuenta los parámetros de traslación tx e ty.

Parámetros

Establece todas las propiedades de la matriz en un valor que genere una transformación nula. Un objeto transformado mediante la aplicación de una matriz de identidad será idéntico al original.

Después de llamar al método identity(), la matriz resultante tiene las propiedades siguientes: a=1, b=0, c=0, d=1, tx=0, ty=0.

En la notación de matrices, la matriz de identidad tendrá este aspecto:

Realiza la transformación inversa de la matriz original. Puede aplicar la matriz inversa a un objeto para deshacer la transformación realizada al aplicar la matriz original.

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Aplica una transformación de giro al objeto Matrix.

El método rotate() modifica las propiedades a, b, c y d del objeto Matrix. En notación de matrices, esto equivale a concatenar la matriz actual con la matriz siguiente:

Parámetros

Aplica una transformación de escala a la matriz. El eje x se multiplica por sx y el eje y se multiplica por sy.

El método scale() modifica las propiedades a y d del objeto Matrix. En notación de matrices, esto equivale a concatenar la matriz actual con la siguiente matriz:

Parámetros

Define los miembros de Matrix en los valores especificados

Parámetros

Devuelve un valor de texto con las propiedades del objeto Matrix.

Devuelve el resultado de aplicar la transformación geométrica representada por el objeto Matrix en el punto especificado.

Parámetros

Traslada la matriz a lo largo de los ejes x e y, tal y como se especifica en los parámetros dx y dy.

Parámetros

1. La aplicación crea un nuevo objeto Matrix myMatrix y utiliza el método trace() para obtener los valores de la propiedad predeterminada del objeto myMatrix.
2. La aplicación llama a createGradientBox() con los parámetros width y height definidos en 200 píxeles, sin rotación y con la distancia de traslación en los ejes x e y definida en 50 píxeles.
3. La aplicación vuelve a imprimir el objeto myMatrix para mostrar los cambios tras llamar a createGradientBox().
4. La aplicación define tres variables para controlar el relleno del cuadro con degradado:
   • colors: define los colores del degradado para que estén entre rojo sólido y azul sólido.
   • alphas: define la opacidad sólida.
   • ratios: define la distribución de los colores para que sea igual para el rojo y el azul.
5. La aplicación llama al método gráfico beginGradientFill(), que se ejecuta en el objeto myMatrix y llama al método lineTo(), lo que da como resultado el cuadro con relleno degradado.

package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}