AccessibilityImplementation  - AS3

Indica un código de error. Los valores se indican fuera de banda, no como valores devueltos. Para indicar un error, defina la propiedad errno como uno de los códigos de error documentados en el apéndice de constantes de AccessibilityImplementation. Esto hace que se omita el valor devuelto. El la propiedad errno de AccessibilityImplementation siempre se borra (se establece en cero) por el reproductor antes de llamar a cualquier método AccessibilityImplementation.

Elementos de API relacionados

Se utilizan para crear un stub de accesibilidad de componentes. Si un componente se libera sin implementación de accesibilidad de ActionScript, Adobe le recomienda añadir un stub de accesibilidad de componentes. Este stub hace que Flash Player en lo que a accesibilidad respecta, trate el componente como un simple gráfico y no tiene que exponer la estructura interna de botones, campos de texto, etc., dentro del componente.

Para crear stub de accesibilidad de componentes, se debe crear una subclase de la clase Acclmpl pertinente, que anule el stub de la propiedad con un valor true.

Elementos de API relacionados

Constructor estático. No cree instancias de AccessibilityImplementation directamente llamando a su constructor. En su lugar, cree nuevas implementaciones de accesibilidad ampliando la clase mx.accessibility.AccImpl para cada nuevo componente.

Elementos de API relacionados

Un método IAccessible que realiza la acción predeterminada asociada al componente que este objeto AccessibilityImplementation representa o de uno de sus elementos secundarios.

Implemente este método sólo si AccessibilityImplementation representa un elemento de IU que tiene una acción predeterminada en el modelo MSAA.

Si está implementando accDoDefaultAction(), sólo para el propio objeto AccessibilityImplementation (o sólo para sus elementos secundarios), necesitará en algunos casos indicar que no hay ninguna acción predeterminada para el elemento childID determinado transferido. Haga esto definiendo la propiedad errno como E_MEMBERNOTFOUND.

Parámetros

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

Método MSAA para devolver un objeto DisplayObject o Rectangle que especifica el recuadro de delimitación de un elemento secundario en AccessibilityImplementation.

Nunca se llama a este método con childID cero. Si su AccessibilityImplementation nunca va a contener elementos secundarios, no debe implementar este método. Si su AccessibilityImplementation puede contener elementos secundarios, este método es obligatorio.

Normalmente puede cumplir los requisitos de este método devolviendo un objeto que represente el propio elemento secundario. Esto funciona siempre que el elemento secundario sea DisplayObject. En estos casos, simplemente devuelva el objeto DisplayObject que corresponde al nombre de instancia asociado con el objeto visual relevante de la lista de visualización.

Si un elemento secundario no aprovechar la técnica explicada arriba, puede ser calcular el recuadro de delimitación usted mismo y devolver un objeto Rectangle con las propiedades: x, y, width y height. Los miembros x e y especifican la esquina superior izquierda del recuadro de delimitación, y los miembros width y height especifican su tamaño. Los cuatro miembros deben estar en unidades de píxeles de escenario y ser relativos al origen del componente que representa AccessibilityImplementation. Las propiedades x e y puede tener valores negativos, ya que el origen de objeto DisplayObject no estña necesariamente en su esquina superior izquierda.

Si el elemento secundario especificado por childID no está visible (es decir, get_accState para ese elemento secundario podría devolver un valor incluyendo STATE_SYSTEM_INVISIBLE), puede devolver null desde accLocation. También puede devolver un objeto Rectangle que represente las coordenadas de la ubicación en la que el elemento secundario aparecería si estuviera visible.

Parámetros

Más información

Elementos de API relacionados

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

Método IAccessible para modificar la selección en el componente que este AccessibilityImplementation representa.

El parámetro childID siempre será distinto de cero. Este método siempre se aplica a un elemento secundario y no tal componente general; Flash Player administra la selección del propio componente.

El parámetro selFlag es un bitfield formado por una o más constantes de indicador de selección que permite a un cliente MSAA indicar cómo el elemento al que se hace referencia con childID debe seleccionarse o tomar la selección. Lo que sigue son descripciones de constantes de indicador de selección y lo que comunican a la implementación de accesibilidad. En la práctica, la mayoría de las implementaciones de este método de implementaciones de accesibilidad que heredan desde la clase mx.accessibility.ListBaseAccImpl de Flex omiten la constante selFlag y dependen del comportamiento del teclado del componente para gestionar la multiselección.

El parámetro selFlag puede o no contener el indicador SELFLAG_TAKEFOCUS. Si lo tiene, se debe definir la selección secundaria al elemento childID especificado y, a menos que SELFLAG_EXTENDSELECTION también esté presente, convertir dicho elemento secundario en ancla de selección. En caso contrario, el ancla de selección y de selección secundaria permanece sin cambios, a pesar de que varios de los indicadores adicionales descritos a continuación puedan modificar la selección.

El argumento selFlag siempre contendrá uno de los siguientes cuatro indicadores, que indican el tipo de modificación de selección que se desea:

• SELFLAG_TAKESELECTION: borra cualquier selección existente y establece la selección en el elemento childID especificado.

• SELFLAG_EXTENDSELECTION: calcula el rango de elementos secundarios entre (e inclusive) el ancla de selección y elemento childID especificado. Si SELFLAG_ADDSELECTION está presente, añade todos estos elementos secundarios a la selección. Si SELFLAG_REMOVESELECTION está presente, quita todos estos elementos secundarios de la selección. Si no están presentes ni SELFLAG_ADDSELECTION ni SELFLAG_REMOVESELECTION, todos estos elementos secundarios deben adoptar el estado de selección del ancla de selección: si el ancla de selección está seleccionada, añada estos elementos secundarios a la selección; en caso contrario, elimínelos de la selección.

• SELFLAG_ADDSELECTION (sin SELFLAG_EXTENDSELECTION): añade el childID especificado a la selección.

• SELFLAG_REMOVESELECTION (sin SELFLAG_EXTENDSELECTION): elimina los elementos childID especificados de la selección.

Tenga en cuenta que si el componente no tiene multiselección, los únicos valores válidos del parámetro selFlag son SELFLAG_TAKEFOCUS y SELFLAG_TAKESELECTION. En teoría, puede elegir la compatibilidad con SELFLAG_REMOVESELECTION para componentes sin multiselección que permitan al usuario forzar una selección null, pero la práctica mayoría de los componentes sin multiselección no funcionan así, y los clientes MSAA tal vez no intenten este tipo de operación.

Si detecta indicadores que parecen no válidos, defina errno como E_INVALIDARG.

Por último, tenga en cuenta que si se llama a accSelect, Flash Player garantiza la selección host (selección de la ventana en su aplicación contenedora) y que el componente está seleccionado dentro de Flash Player.

Parámetros

Más información

Elementos de API relacionados

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

Método MSAA para devolver la acción predeterminada del componente que este AccessibilityImplementation representa o de uno de sus elementos secundarios.

Implemente este método sólo si AccessibilityImplementation representa un elemento de IU que tiene una acción predeterminada en el modelo MSAA; es importante devolver la cadena exacta especificada por el modelo MSAA. Por ejemplo, la cadena de acción predeterminada de un componente Button es "Press".

Si está implementando get_accDefaultAction, sólo para el propio objeto AccessibilityImplementation (o sólo para sus elementos secundarios), necesitará en algunos casos indicar que no hay ninguna acción predeterminada para el elemento childID determinado transferido. Hágalo simplemente devolviendo null.

Parámetros

Más información

Elementos de API relacionados

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

Método MSAA para devolver el ID de entero sin signo del elemento secundario, si lo hay, que tiene selección de elementos secundarios en el componente. Si no hay ningún elemento secundario seleccionado, el método devuelve cero.

Más información

Elementos de API relacionados

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

Método MSAA para devolver el nombre del componente que este AccessibilityImplementation representa o de uno de sus elementos secundarios.

En el caso del método AccessibilityImplementation mismo (childID == 0), si este método no se implementa, o si no devuelve un valor, Flash Player utiliza el valor de la propiedad AccessibilityProperties.name, si está presente.

Para AccessibilityImplementation que puedan tener elementos secundarios, este método debe implementarse y no debe devolver un valor de cadena si childID es distinto de cero.

En función del tipo de elemento de la interfaz de usuario, los nombres en MSAA pueden significar dos cosas diferentes: un nombre asignado al autor, o bien el contenido real del texto del elemento. Normalmente, el propio AccessibilityImplementation entra en la categoría anterior. Su propiedad name es nombre asignado al autor. Los elementos secundarios siempre entran en la segunda categoría. Sus nombres indican su contenido de texto.

Cuando la propiedad name de una interfaz AccessibilityImplementation tiene el significado de nombre asignado al autor, hay dos formas de poder adquirir nombres de los autores. La primera incluye los nombres presentes en el componente mismo; por ejemplo, un componente Checkbox podría contener una etiqueta de texto que actúe como su nombre. La segunda, por si la primera falla, incluye nombres especificados en la interfaz de usuario y que terminen en AccessibilityProperties.name. Esta opción de repuesto permite a los usuarios especificar nombres del mismo modo que lo harían en cualquier otro Sprite o MovieClip.

Esto deja tres posibilidades para AccessibilityImplementation (childID == cero):

• Nombre asignado por el autor en el componente. El método get_accName se debe implementar y debe devolver un valor de cadena que contenga el nombre de AccessibilityImplementation cuando childID es cero. Si childID es cero pero AccessibilityImplementation no tiene nombre, get_accName debe devolver una cadena vacía para evitar que el reproductor vuelva a la propiedad AccessibilityProperties.name.

• Nombre asignado por el autor de la interfaz de usuario. Si AccessibilityImplementation puede tener elementos secundarios, el método get_accName se debe implementar pero no debe devolver un valor cuando childID es cero. Si AccessibilityImplementation no tendrá nunca elementos secundarios, get_accName no debe implementarse.

• Nombre con contenido. El método get_accName deben implementarse y debe devolver un valor de cadena adecuado cuando childID es cero. Si childId es cero pero AccessibilityImplementation no tiene contenido, get_accName debe devolver una cadena vacía para evitar que el reproductor vuelva a la propiedad AccessibilityProperties.name.

Tenga en cuenta que en los elementos secundarios (si AccessibilityImplementation puede tenerlos), el tercer caso aplica siempre. El método get_accName debe implementarse y debe devolver un valor de cadena adecuado cuando childID es distinto de cero.

Parámetros

Más información

Elementos de API relacionados

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

Método MSAA para devolver la función del sistema del componente que este AccessibilityImplementation representa o de uno de sus elementos secundarios. Las funciones del sistema están predefinidas para todos los componentes de MSAA.

Parámetros

Más información

Elementos de API relacionados

Método MSAA para devolver un conjunto que contiene el ID de todos los elementos secundarios que se hayan seleccionado. El conjunto devuelto puede contener cero, uno o varios ID, todos los enteros sin signo.

Más información

Elementos de API relacionados

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

Método IAccessible para devolver el estado actual del motor de ejecución del componente que este AccessibilityImplementation representa o de uno de sus elementos secundarios.

Este método debe devolver una combinación de cero, uno o más de las constantes de estado de objetos predefinidas para los componentes en MSAA. Cuando se aplica más de un estado, las constantes de estado deben combinarse en un bitfield utilizando |, el operador OR en modo bit.

Para indicar que no se aplica ninguna de las constantes de estado actuales, este método debe devolver cero.

No es necesario para realizar el seguimiento o informar sobre los estados STATE_SYSTEM_FOCUSABLE o STATE_SYSTEM_FOCUSED. Flash Player gestiona automáticamente estos estados.

Parámetros

Más información

Elementos de API relacionados

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

Método MSAA para devolver el valor del motor de ejecución del componente que este AccessibilityImplementation representa o de uno de sus elementos secundarios.

Implemente este método sólo si AccessibilityImplementation representa un elemento de IU que tiene valor en el modelo MSAA. Tenga en cuenta que algunos elementos de la interfaz que tienen un "valor" aparente exponen este valor de diversos modos, como get_accName (texto, por ejemplo), get_accState (casillas de verificación, por ejemplo), o get_accSelection (cuadros de lista, por ejemplo).

Si está implementando get_accValue, sólo para el propio objeto AccessibilityImplementation (o sólo para sus elementos secundarios), necesitará en algunos casos indicar que no hay ningún concepto de valor para el elemento childID determinado transferido. Hágalo simplemente devolviendo null.

Parámetros

Más información

Elementos de API relacionados

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Devuelve un conjunto que contiene ID de enteros sin signo de todos los elementos secundarios de AccessibilityImplementation.

La longitud del conjunto puede ser cero. Los ID del conjunto deben aparecer en el mismo orden lógico que los elementos secundarios que representan. Si AccessibilityImplementation puede contener elementos secundarios, este método es obligatorio; de lo contrario, no lo aplique.

Al asignar ID secundario a sus elementos secundarios, utilice cualquier esquema que conserve su singularidad dentro de cada instancia de AccessibilityImplementation. No es necesario que los ID secundarios sean contiguos y su orden no tiene por qué coincidir con el orden lógico de los elementos secundarios. Debe lograr no tener que volver a utilizar ID secundarios; si se elimina un elemento secundario, su ID nunca deben volver a utilizarse durante toda la vida de instancia en AccessibilityImplementation. Tenga en cuenta que, debido a opciones de implementación del código de Flash Player, podrían producirse comportamientos no deseables si utiliza ID secundarios digitales que superen un millón.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Devuelve true o false para indicar si el objeto de texto que tiene un recuadro de delimitación especificado por x, y, widthy height debe considerarse como una etiqueta para el componente que AccessibilityImplementation representa.

Las coordenadas x e y son relativas a la esquina superior izquierda del componente al que se aplica AccessibilityImplementation y pueden ser negativas. Todas las coordenadas están en unidades de píxeles de escenario.

Este método permite que los componentes accesibles se adapten a la búsqueda de relaciones de etiquetado automático en Flash Player, que permiten que el texto externo a un objeto proporcione el nombre del objeto. Este método se suministra porque se espera que los criterios de reconocimiento de etiquetas no son los mismos en todos los componentes. Si implementa este método, debe utilizar criterios geométricos similares a los que se utilizan dentro del código del reproductor para los botones y campos de texto. Los criterios son los siguientes:

• En los botones, cualquier texto dentro del botón por completo se considera una etiqueta.
• En los campos de texto, cualquier texto por encima y cercano alineado a la izquierda, o cercano a la izquierda, se considera una etiqueta.

Si el componente que representa AccessibilityImplementation nunca debe participar en las relaciones de etiquetado automático, no implemente isLabeledBy. Esto equivale a devolver siempre false. Un caso en el que isLabeledBy no deben implementarse se produce si AccessibilityImplementation entra dentro del caso “nombre asignado por el autor en el componente” descrito en get_accName.

Tenga en cuenta que este método no se basa en cualquier método IAccessible; es específico de Flash.

Parámetros