ElementFormat  - AS3

Especifica el tipo de línea base en el elemento contenedor con el que se alinean las líneas de base dominantes de los elementos con este formato. Utilice constantes TextBaseline para esta propiedad.

El elemento vertical de mayor tamaño de la línea determina la alineación de las líneas base a menos que TextBlock.baselineFontDescription y TextBlock.baselineFontSize se establezcan para suplantar esa lógica.

El valor predeterminado es TextBaseline.USE_DOMINANT_BASELINE.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Especifica la transparencia de los elementos de línea afectados por este objeto. Los valores válidos oscilan entre 0 (totalmente transparente) y 1 (totalmente opaco). Los objetos de visualización que tienen alpha configurado con el valor 0 están activos, aunque no sean visibles.

El valor predeterminado es 1.

Elementos de API relacionados

Indica el cambio de línea base del elemento, en píxeles.

El elemento se aleja de dominantBaseline según la cantidad especificada. El desplazamiento se añade a la posición y de los miembros del elemento de forma que, en texto no girado, un cambio de línea base positivo mueve el elemento hacia abajo y un cambio de línea base negativo mueve el elemento hacia arriba.

El valor predeterminado es 0.0, lo que indica que no hay ningún cambio.

Oportunidad de salto de línea aplicada al texto. Esta propiedad determina los caracteres que se pueden utilizar para establecer saltos cuando el texto de ajuste se divide en varias líneas. Utilice constantes BreakOpportunity para esta propiedad.

El valor predeterminado es BreakOpportunity.AUTO.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Indica el color del texto. Entero que contiene tres componentes RGB de 8 bits; por ejemplo, 0xff0000 es rojo y 0x00FF00, verde.

El valor predeterminado es 0x000000 (negro).

Caja de dígitos para este texto. La caja de dígitos afecta al estilo y a la colocación de grupos de caracteres numéricos. Utilice constantes DigitCase para esta propiedad.

El valor predeterminado es DigitCase.DEFAULT.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Anchura de dígitos para este texto. Utilice constantes DigitWidth para esta propiedad.

El valor predeterminado es DigitWidth.DEFAULT.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Especifica el tipo de línea de base que se utiliza como línea de base dominante. La línea de base dominante se alinea con la línea de base de alineación para determinar la posición vertical del elemento en la línea. Utilice constantes TextBaseline para esta propiedad.

El contenido del elemento determina las líneas base. En el caso de una propiedad TextElement, el tamaño de fuente y de punto determina las líneas base. En el caso de una propiedad GraphicElement, la altura del elemento determina las líneas base.

El valor predeterminado es TextBaseline.ROMAN.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Un objeto cuyas propiedades describen una fuente.

El valor predeterminado es un objeto FontDescription construido predeterminado.

Cuando se establece la propiedad fontDescription, el objeto FontDescription suministrado se bloquea: su propiedad locked se establece como true. Un elemento FontDescription bloqueado no es modificable.

Elementos de API relacionados

El tamaño del texto, en píxeles.

El valor predeterminado es 12.0.

El ajuste entre caracteres ajusta los píxeles entre determinados pares de caracteres para que puedan leerse mejor. Todas las fuentes con tablas de ajuste entre caracteres admiten ajuste entre caracteres.

El valor predeterminado es Kerning.ON.

Para definir los valores de esta propiedad, utilice las siguientes constantes de la clase Kerning:

Elementos de API relacionados

Nivel de ligadura utilizado en este texto. Se produce una ligadura cuando se unen dos o más formatos de carta en un único glifo. Las ligaduras normalmente sustituyen a los caracteres consecutivos que comparten componentes comunes, como parejas de letras 'fi', 'fl' o 'ae'. Se utilizan con conjuntos de caracteres latinos y no latinos. Utilice constantes LigatureLevel para esta propiedad.

El valor predeterminado es LigatureLevel.COMMON.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Configuración regional del texto. Controla las transformaciones de la caja y su forma. Se utilizan identificadores estándar de configuración regional. Por ejemplo"en", "en_US" y "en-US" se refieren a inglés y "ja" a japonés. Consulte la lista de códigos iso639-2 para obtener una lista de códigos de configuración regional.

El valor predeterminado es "en".

Indica si ElementFormat está bloqueado. Si es true, ElementFormat no es modificable. Llame al método ElementFormat.clone() para obtener una copia sin bloquear del objeto ElementFormat.

Establece la rotación aplicada a glifos individuales. Utilice las constantes definidas en la clase TextRotation para esta propiedad.

El valor predeterminado es TextRotation.AUTO.

La rotación final de cualquier glifo es la suma de ElementFormat.textRotation, ContentElement.textRotation y TextBlock.lineRotation.

Se suele utilizar esta propiedad para texto asiático en el que se deben girar los caracteres para mostrarlos adecuadamente en posición vertical. Utilice TextRotation.AUTO en combinación con TextBlock.lineRotation = TextRotation.ROTATE_90 para lograr esto.

Si se establece esta propiedad en fuentes que no contengan información de disposición vertical, puede arrojar resultados no deseados. Las fuentes que contienen una tabla vmtx o VORG, como la fuente japonesa "MS Mincho", funcionan correctamente porque dichas tablas suministran los datos que necesita el motor de visualización para mostrar un diseño correcto. Las fuentes como Verdana, que no contienen la información necesaria, no pueden realizar esta función.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

El espaciado o el ajuste entre caracteres manual que se aplica a la derecha de cada glifo en píxeles. Si Ajuste entre caracteres está activado, el valor de trackingLeft se añade a los valores de la tabla de ajuste entre caracteres de la fuente. Si Ajuste entre caracteres está desactivado, el valor trackingLeft se utiliza como valor manual de ajuste entre caracteres. Admite tanto valores positivos como negativos.

Normalmente, el valor de espaciado deseado se divide entre trackingRight y trackingLeft. De lo contrario, en texto de direccionalidad combinado, se hace dos veces el espaciado en un límite bidi y ninguno en el otro.

El valor predeterminado es 0.0.

Ejemplo:

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingLeft = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingLeft = -1.0;
     

El espaciado o el ajuste entre caracteres manual que se aplica a la derecha de cada glifo en píxeles. Si Ajuste entre caracteres está activado, el valor trackingRight se añade a los valores de la tabla de ajuste entre caracteres de la fuente. Si Ajuste entre caracteres está desactivado, el valor trackingRight se utiliza como valor manual de ajuste entre caracteres. Admite tanto valores positivos como negativos.

Normalmente, el valor de espaciado deseado se divide entre trackingRight y trackingLeft. De lo contrario, en texto de direccionalidad combinado, se hace dos veces el espaciado en un límite bidi y ninguno en el otro.

El valor predeterminado es 0.0.

Ejemplo:

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingRight = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingRight = -1.0;
     

Caja tipográfica para este texto. Utilice las constantes definidas en la clase TypographicCase para esta propiedad.

El valor predeterminado es TypographicCase.DEFAULT.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Crea un objeto ElementFormat.

Construye una copia clonada y sin bloquear de ElementFormat.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

Devuelve un objeto FontMetrics con propiedades que describen la caja emBox, la posición y el grosor del tachado, y la posición y el grosor del subrayado para la fuente especificada por fontDescription y fontSize.

Elementos de API relacionados

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 24;            
            var fm1:FontMetrics = ef1.getFontMetrics();

            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

Este ejemplo crea dos objetos ElementFormat y establece algunas de sus propiedades. Seguidamente, asigna los nuevos formatos ElementFormat a un objeto TextElement que se ha asignado como contenido de un bloque TextBlock. Tenga en cuenta que cambiar el formato ElementFormat de un elemento TextElement no afecta a las líneas de texto creadas previamente por el bloque TextBlock principal.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}