TextBlock  - AS3

Especifica que quiere mejorar la apariencia de la pantalla a costa de la fidelidad de impresión WYSIWYG (lo que se ve en la pantalla es lo que se obtiene). En plataformas y fuentes que no admiten posición de glifos de subpíxeles durante el procesamiento de fuentes del dispositivo, pero que sí admitan escalado no lineal, al establecer esta propiedad como true se permite el uso de métricas, aunque sacrificando la fidelidad de impresión WYSIWYG, especialmente en tamaños pequeños de puntos. No funciona ningún escalado de fuente lineal si se escala la anchura de los glifos individuales para ocultar los huecos antiestéticos causados por el ajuste de los píxeles.

En las plataformas que no admiten posición de glifos de subpíxeles, este indicador se omite.

Este indicador no tiene ningún efecto en el procesamiento de fuentes incorporadas

El valor predeterminado es true.

La fuente empleada para determinar las líneas base de todas las líneas con saltos en el bloque, independientemente de su contenido. Las líneas base dependen de la fuente y del tamaño de fuente.

El valor predeterminado es null. Si la fuente de la línea base es null, el tamaño de fuente de la línea base se omite, ya que cualquier línea se basará en la fuente y el tamaño del texto más grande de la línea. Si especifica baselineFontDescription y baselineFontSize, determinan las líneas base de todas las líneas del bloque, independientemente de su contenido. Esta combinación suele ser más útil en la tipografía asiática.

Elementos de API relacionados

El tamaño de fuente empleado para calcular las líneas base de las líneas con saltos en el bloque. Las líneas base dependen de la fuente y del tamaño de fuente.

El valor predeterminado es 12. Si la fuente de la línea base es null, el tamaño de fuente de la línea base se omite, ya que cualquier línea se basará en la fuente y el tamaño del texto más grande de la línea.

Elementos de API relacionados

Especifica qué línea base está en y=0 para las líneas creadas a partir de este bloque. Los valores válidos de esta propiedad se encuentran en los miembros de la clase TextBaseline.

El valor predeterminado es TextBaseline.ROMAN.

Para definir los valores de esta propiedad, utilice los siguientes valores de cadena:

Elementos de API relacionados

Especifica el nivel de incorporación de párrafo bidireccional del bloque de texto. En general, utilice 0 para párrafos de izquierda a derecha (inglés, japonés, etc.) y 1 para párrafos de derecha a izquierda (árabe, hebreo, etc.). El uso de valores distintos de 0 o 1 se reserva para casos especiales; consulte UAX#9, "Algoritmo bidireccional Unicode" (http://www.unicode.org/reports/tr9/) para obtener más información.

El valor predeterminado es 0.

Si se modifica la propiedad bidLevel, cambia la validez de todas las líneas divididas anteriormente a TextLineValidity.INVALID. Una vez cambiada la propiedad bidLevel, firstInvalidLine es igual que la propiedad firstLine y debe volver a dividir todas las líneas de TextBlock.

Elementos de API relacionados

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Alberga el contenido del bloque de texto. Como ContentElement es una clase base, se debe asignar la propiedad content a una instancia de una subclase de ContentElement: TextElement, GraphicElement o GroupElement. Un objeto TextElement contiene una cadena, un objeto GraphicElement contiene un objeto de visualización y un objeto GroupElement contiene un objeto Vector con uno o más objetos TextElement, GraphicElement o GroupElement. Utilice un objeto TextElement para párrafos de texto homogéneo, un objeto GraphicElement para gráficos y un objeto GroupElement para una combinación de texto y gráficos. Puede utilizar varias instancias de estos elementos, así como otros objetos GroupElement.

El valor predeterminado es null.

Si se modifica la propiedad content, cambia la validez de todas las líneas creadas anteriormente a TextLineValidity.INVALID. Una vez cambiada la propiedad content, firstInvalidLine es igual que la propiedad firstLine y debe volver a dividir todas las líneas de TextBlock.

Elementos de API relacionados

Identifica la primera línea del bloque de texto en la que TextLine.validity no es igual a TextLineValidity.VALID.

El valor predeterminado es null.

Elementos de API relacionados

El primer elemento TextLine de TextBlock, si existe.

El valor predeterminado es null.

Elementos de API relacionados

El último elemento TextLine de TextBlock, si existe.

El valor predeterminado es null.

Elementos de API relacionados

Gira las líneas de texto del bloque de texto como una unidad. Llame al método createTextLine() después de haber establecido lineRotation para que surta efecto. El valor predeterminado es TextRotation.ROTATE_0.

La rotación final de cualquier glifo depende de los valores de ElementFormat.textRotation, ContentElement.textRotation y TextBlock.lineRotation.

TextBlock.lineRotation se suele utilizar en texto asiático. Para crear un párrafo de texto japonés vertical, haga lo siguiente:

1. Establezca la propiedad TextBlock.lineRotation en TextRotation.ROTATE_90.
2. Deje la propiedad ElementFormat.textRotation del contenido como predeterminada, TextRotation.AUTO.

Utilice las siguientes constantes, definidas en la clase TextRotation, para establecer el valor de esta propiedad:

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Especifica los tabuladores del texto en el bloque de texto. Lo hace en forma de un vector de objetos TabStop.

El valor predeterminado es null, lo que indica que no se especifica ninguna tabulación. Si no se especifica ninguna tabulación (o el punto de inserción está fuera de la última tabulación especificada), el motor de ejecución crea tabulaciones de media pulgada de forma predeterminada.

Si se establece la propiedad tabStops, el bloque TextBlock hace una copia del vector para uso interno. Modificar el vector original o su contenido no afecta al bloque TextBlock. Si se consulta la propiedad tabStops, se devuelve una copia del vector interno. De nuevo, modificar este vector devuelto o su contenido no afecta al bloque TextBlock.

Elementos de API relacionados

Especifica el valor TextJustifier que se utiliza en la creación de líneas.

El valor predeterminado es un objeto TextJustifier construido predeterminado.

Si se establece la propiedad textJustifier, TextBlock hace una copia del bloque para uso interno. Modificar el objeto original no afecta al bloque TextBlock. Si se consulta la propiedad textJustifier, se devuelve una copia del objeto interno. De nuevo, modificar este objeto devuelto no afecta al bloque TextBlock.

Elementos de API relacionados

Indica el resultado de una operación createTextLine() Si cambia el contenido del bloque, se invalidan los saltos anteriores y se restablece la propiedad en null.

El valor predeterminado es null.

Los valores de esta propiedad se encuentran enTextLineCreationResult

Elementos de API relacionados

Permite a la aplicación asociar datos arbitrarios al bloque de texto. Los datos podrían ser información que se refiere al contenido, como una fecha de revisión o el nombre del autor, o bien se podrían almacenar los datos en la caché que utiliza durante el procesamiento.

Crea un objeto TextBlock

Elementos de API relacionados

Ordena al bloque de texto que cree una línea de texto a partir de su propio contenido. Ésta comienza en el punto especificado por el parámetro previousLine y se rompe en el punto especificado por el parámetro width. La línea de texto es un objeto TextLine que se puede añadir a la lista de visualización.

Si se introducen saltos de línea en un intervalo de bloque de texto en el que ya se hayan introducido saltos puede modificar la validez de las líneas que se vean afectadas por la acción. El estado de las líneas puede pasar de VALID a INVALID o POSSIBLY_INVALID. Si una línea con salto se alinea perfectamente con otra línea anterior con estado POSSIBLY_INVALID, la línea anterior y todas las líneas con estado POSSIBLY_INVALID volverán a tener un estado VALID. La validez de las líneas que se han definido en valores que no son miembros de TextLineValidity no cambian a VALID, pero podrían cambiar a INVALID. Compruebe la propiedad firstInvalidLine después de cualquier cambio realizado en el bloque de texto para saber dónde empieza o continúa la división de las líneas de texto.

Puede crear saltos de palabras artificiales si incluye el carácter de espacio de anchura cero (ZWSP, Zero Width Space) de Unicode en el texto. Esto resulta útil en idiomas como el tailandés, donde es necesario consultar el diccionario para introducir correctamente los saltos de línea. El motor de ejecución de Flash no incluye este diccionario.

Con el fin de reducir la sobrecarga de memoria, cuando se han creado todas las líneas deseadas (a menos que se espere que las líneas sean necesarias para crear saltos de línea repetidos debidos, por ejemplo, al cambio de tamaño del contenedor), el usuario debe llamar al método releaseLineCreationData() para permitir que el bloque de texto elimine los datos temporales asociados a saltos de línea.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Vuelca el contenido subyacente del objeto TextBlock como una cadena XML. Esto puede resultar útil en las pruebas automatizadas e incluye texto, formato e información de diseño.

A continuación se describe la salida:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Para ver una descripción de la salida de cada línea, consulte el método TextLine.dump().

Nota: el contenido y el formato de la salida puede cambiar en el futuro. Adobe no garantiza que este método siga siendo compatible con versiones anteriores.

Elementos de API relacionados

Busca el índice del siguiente límite del objeto Atom en el índice de caracteres especificado, sin incluir el carácter en el índice especificado. Los caracteres entre límites de átomos se combinan para formar un átomo en TextLine, como una 'e' con un acento incorporado.

Parámetros

Elementos de API relacionados

Busca el índice del siguiente límite de palabra en el índice de caracteres especificado, sin incluir el carácter en el índice especificado. Los limites de palabras se determinan en función de las propiedades Unicode de los caracteres.

Parámetros

Busca el índice del límite del átomo anterior en el índice de caracteres especificado, sin incluir el carácter en el índice especificado. Los caracteres entre límites de átomos se combinan para formar un átomo en TextLine, como una 'e' con un acento incorporado.

Parámetros

Elementos de API relacionados

Busca el índice del límite de palabra anterior en el índice de caracteres especificado, sin incluir el carácter en el índice especificado. Los limites de palabras se determinan en función de las propiedades Unicode de los caracteres.

Parámetros

Devuelve el parámetro TextLine que contiene el carácter especificado por el parámetro charIndex.

Parámetros

Ordena al bloque de texto que reutilice una línea de texto existente para crear una línea de texto a partir de su propio contenido. Ésta comienza en el punto especificado por el parámetro previousLine y se rompe en el punto especificado por el parámetro width. La línea de texto es un objeto TextLine que se puede añadir a la lista de visualización. Al reutilizar una línea de texto existente, se mejora el rendimiento gracias a la reducción de creación de objetos.

El parámetro textLine que se vuelve a crear se libera de cualquier bloque de texto en que se encuentre, si está en alguno. Además, todas las propiedades, incluidas las propiedades heredadas de DisplayObjectContainer, InteractiveObject y DisplayObject se restablecen a sus valores predeterminados. Por último, todos los elementos secundarios de la línea se eliminan, incluidos elementos gráficos y otros elementos decorativos, y todos los detectores de eventos en la línea se eliminan. Para mejorar el rendimiento, la única excepción a este restablecimiento completo es que la línea en sí no se eliminará de su elemento principal.

Si se introducen saltos de línea en un intervalo de bloque de texto en el que ya se hayan introducido saltos puede modificar la validez de las líneas que se vean afectadas por la acción. El estado de las líneas puede pasar de VALID a INVALID o POSSIBLY_INVALID. Si una línea con salto se alinea perfectamente con otra línea anterior con estado POSSIBLY_INVALID, la línea anterior y todas las líneas con estado POSSIBLY_INVALID volverán a tener un estado VALID. La validez de las líneas que se han definido en valores que no son miembros de TextLineValidity no cambian a VALID, pero podrían cambiar a INVALID. Compruebe la propiedad firstInvalidLine después de cualquier cambio realizado en el bloque de texto para saber dónde empieza o continúa la división de las líneas de texto.

Puede crear saltos de palabras artificiales si incluye el carácter de espacio de anchura cero (ZWSP, Zero Width Space) de Unicode en el texto. Esto resulta útil en idiomas como el tailandés, donde es necesario consultar el diccionario para introducir correctamente los saltos de línea. El motor de ejecución de Flash no incluye este diccionario.

Con el fin de reducir la sobrecarga de memoria, cuando se han creado todas las líneas deseadas (a menos que se espere que las líneas sean necesarias para crear saltos de línea repetidos debidos, por ejemplo, al cambio de tamaño del contenedor), el usuario debe llamar al método releaseLineCreationData() para permitir que el bloque de texto elimine los datos temporales asociados a saltos de línea.

Parámetros

Elementos de API relacionados

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Ordena al bloque de texto que libere a todos los datos temporales asociados a la creación de líneas de texto. Para minimizar el uso de memoria de la aplicación, se debe llamar al método releaseLineCreationData() cuando se haya terminado de crear líneas de texto a partir de un bloque de texto. Sin embargo, para maximizar el rendimiento la recreación de saltos de línea (por ejemplo, cuando se cambia el tamaño del contenedor) no se debe llamar al método releaseLineCreationData(). Es responsabilidad de la aplicación equilibrar la memoria frente al rendimiento.

El proceso recomendado para el texto que no se espera cambiar es el siguiente: inicializar un bloque de texto, llamar al método createTextLine() con la frecuencia que sea necesario para crear la salida deseada y, a continuación, llamar al método releaseLineCreationData()

Elementos de API relacionados

Elimina un rango de líneas de texto de la lista de líneas mantenida por TextBlock. Esto permite eliminar los datos innecesarios de las líneas si existen más referencias.

Establece los miembros textBlock, nextLine y previousLine de las líneas eliminadas en null. Establece el valor de validity en las líneas eliminadas y en todas las líneas que siguen a las líneas eliminadas en TextBlock con TextLineValidity.INVALID.

Parámetros

Elementos de API relacionados