| Paquete | flash.text.engine |
| Clase | public final class TextElement |
| Herencia | TextElement  ContentElement Object |
| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10, AIR 1.5, Flash Lite 4 |
content de un objeto TextBlock para crear un bloque de texto. Asígnelo a un objeto GroupElement para combinarlo con otros elementos gráficos y texto como una unidad. Utilice la clase ElementFormat para dar formato al texto.
Elementos de API relacionados
Propiedades públicas
Ocultar propiedades públicas heredadas
Mostrar propiedades públicas heredadas| Propiedad | Definido por | ||
|---|---|---|---|
 | constructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada. | Object | |
| elementFormat : ElementFormat
El objeto ElementFormat utilizado para el elemento. | ContentElement | |
| eventMirror : EventDispatcher
El objeto EventDispatcher que recibe copias de cada evento distribuido en las líneas de texto válidas según este elemento de contenido. | ContentElement | |
| groupElement : GroupElement [solo lectura]
El objeto GroupElement que contiene este elemento o null si no se encuentra en ningún grupo. | ContentElement | |
| rawText : String [solo lectura]
Una copia del texto en el elemento, incluidos los caracteres U+FDEF. | ContentElement | |
| text : String
Recibe el texto que representa el contenido del elemento. | TextElement | ||
| textBlock : flash.text.engine:TextBlock [solo lectura]
Objeto TextBlock al que pertenece el elemento. | ContentElement | |
| textBlockBeginIndex : int [solo lectura]
Índice del bloque de texto del primer carácter de este elemento. | ContentElement | |
| textRotation : String
La rotación aplicada al elemento como una unidad. | ContentElement | |
| userData : *
Permite a la aplicación asociar datos arbitrarios al elemento. | ContentElement | |
Métodos públicos
| Método | Definido por | ||
|---|---|---|---|
TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")
Crea una nueva instancia de TextElement. | TextElement | ||
|
Indica si un objeto tiene definida una propiedad especificada. | Object | |
|
Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro. | Object | |
|
Indica si existe la propiedad especificada y si es enumerable. | Object | |
Reemplaza el rango de caracteres especificados por los parámetros beginIndex y endIndex con el contenido del parámetro newText. | TextElement | ||
|
Establece la disponibilidad de una propiedad dinámica para operaciones de bucle. | Object | |
|
Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional. | Object | |
|
Devuelve la representación de cadena del objeto especificado. | Object | |
|
Devuelve el valor simple del objeto especificado. | Object | |
Constantes públicas
Información sobre propiedades
text | propiedad |
text:String| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Recibe el texto que representa el contenido del elemento.
El valor predeterminado es null.
Implementación
public function get text():String public function set text(value:String):voidInformación sobre constructores
TextElement | () | Información sobre |
public function TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Crea una nueva instancia de TextElement.
Parámetrostext:String (default = null)null.
| |
elementFormat:ElementFormat (default = null)null.
| |
eventMirror:EventDispatcher (default = null)EventDispatcher que recibe copias de cada evento distribuido en las líneas de texto en base a este elemento de contenido. El valor predeterminado es null.
| |
textRotation:String (default = "rotate0")TextRotation para esta propiedad. El valor predeterminado es TextRotation.ROTATE_0.
|
Ejemplo ( Cómo utilizar este ejemplo )
El siguiente ejemplo crea un objeto TextElement a partir de una cadena de texto, le da formato con un tamaño de fuente 12 y color rojo (0xCC0000), y lo asigna a la propiedad
content de un objeto TextBlock. Llama a la función createLines() para dividir el bloque de texto en líneas de 150 píxeles cada una.
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.ElementFormat;
public class TextElementExample extends Sprite {
public function TextElementExample():void {
var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " +
"sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut " +
"enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut " +
"aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit " +
"in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur " +
"sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt " +
"mollit anim id est laborum.";
var format:ElementFormat = new ElementFormat(null, 12, 0xCC0000);
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
createLines(textBlock);
}
private function createLines(textBlock:TextBlock):void {
var yPos = 20;
var textLine:TextLine = textBlock.createTextLine (null, 150);
while (textLine)
{
addChild(textLine);
textLine.x = 15;
yPos += textLine.textHeight+2;
textLine.y = yPos;
textLine = textBlock.createTextLine(textLine, 150);
}
}
}
}
Información sobre métodos
replaceText | () | método |
public function replaceText(beginIndex:int, endIndex:int, newText:String):void| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Reemplaza el rango de caracteres especificados por los parámetros beginIndex y endIndex con el contenido del parámetro newText. Los valores de beginIndex y endIndex hacen referencia al contenido actual del texto.
Para eliminar texto, transfiera null a newText.
Para insertar texto, transfiera el mismo valor a beginIndex y a endIndex. El nuevo texto se inserta delante del índice especificado.
Para añadir texto, transfiera text.length a beginIndex y a endIndex.
Para definir todo el texto, transfiera 0 a beginIndex y text.length a endIndex.
Parámetros
beginIndex:int — El valor de índice basado en cero para la posición inicial del rango de sustitución.
| |
endIndex:int — El valor de índice basado en cero que sigue a la posición final del rango de sustitución.
| |
newText:String — El texto que va a reemplazar al rango de caracteres especificado.
|
Emite
RangeError — Los elementos beginIndex o endIndex especificados están fuera de rango.
|
Ejemplo ( Cómo utilizar este ejemplo )
Este ejemplo llama a
replaceText() varias veces para hacer lo siguiente:
- insertar una cadena al principio del texto
- agregar una cadena al final del texto
- insertar una cadena en mitad del texto
- reemplazar todo el texto por texto nuevo
package {
import flash.display.Sprite;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.TextElement;
import flash.text.engine.TextBlock;
import flash.text.engine.TextLine;
public class TextElement_replaceTextExample extends Sprite {
public function TextElement_replaceTextExample():void {
var str:String = "0123456";
var fontDescription:FontDescription = new FontDescription("Arial");
var format:ElementFormat = new ElementFormat(fontDescription);
format.fontSize = 14;
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
textElement.replaceText(0, 0, "abc");
createLine(textBlock, 20); //"abc0123456"
textElement.replaceText(10, 10, "abc");
createLine(textBlock, 40); // "abc0123456abc"
textElement.replaceText(5, 8, "abc");
createLine(textBlock, 60); // "abc01abc56abc"
textElement.replaceText(0, 13, "abc");
createLine(textBlock, 80); // "abc"
textElement.replaceText(0, 3, "That's all she wrote!");
createLine(textBlock, 100); // "That's all she wrote" */
}
private function createLine(textBlock:TextBlock, y:Number):void {
var textLine:TextLine = textBlock.createTextLine(null, 150);
textLine.x = 10;
textLine.y = y;
addChild(textLine);
}
}
}
Tue Jun 12 2018, 02:12 PM Z