TextLine  - AS3

行の基準から最も高さのある文字の最上部までのピクセル数を指定します。グラフィックエレメントのみを含む TextLine については、ascent を 0 に設定します。

行内のアトムの数、つまりスペースおよびグラフィックエレメントを含む、分割できないエレメントの数です。

行の基準から最も下に突き出している文字の最下部までのピクセル数を指定します。グラフィックエレメントのみを含む TextLine については、descent を 0 に設定します。

テキスト行がグラフィックエレメントを含んでいるかどうかを示します。

関連する API エレメント

テキスト行がタブを含んでいるかどうかを示します。

行に関連付けられた、TextLineMirrorRegion オブジェクトを含む Vector です。存在しない場合は null になります。

関連する API エレメント

TextBlock 内の次の TextLine または null（現在の線がブロック内の最後の行である場合、または行の有効性が TextLineValidity.STATIC の場合）。

関連する API エレメント

TextBlock 内の前の TextLine。これがブロック内の最初の行である場合、または行の有効性が TextLineValidity.STATIC の場合は null になります。

関連する API エレメント

グラフィックエレメントを表す U+FDEF 文字および行の一部だが表示されない行末の空白を含む、行になったテキストブロック内の生のテキストの長さです。

関連する API エレメント

行を作成したときに、TextBlock.createTextLine() メソッドに対して指定された幅です。この値は、変更によって行の改行処理が再度必要になるのかどうかを判断するときに便利です。

関連する API エレメント

このテキスト行を含む TextBlock。または行の有効性が TextLineValidity.STATIC の場合は null になります。これは、行と TextBlock 間の接続が有効にされていることを意味します。

関連する API エレメント

テキストブロックの生のテキストで、行の最初にあたる文字のインデックスです。

関連する API エレメント

テキスト行の論理的な高さ、つまり ascent + descent に等しくなります。インキが使用される高さを取得するには、継承された height プロパティにアクセスします。

値は、TextBlock.baselineZero が文字であるかどうかにより、行を結合する文字の最上部と最下部、またはアセントとディセントのいずれかの基準間の差に基づいて計算されます。グラフィックエレメントは、これらの基準の計算では考慮されません。

関連する API エレメント

テキスト行の論理的な幅です。テキストエンジンが行をレイアウトするのに使用します。継承された width プロパティにアクセスし、描画されたすべてのピクセルによる境界ボックスの実際の幅を取得します。

関連する API エレメント

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

行のベースラインから最も高さのある文字またはグラフィックの最上部までのピクセル数を指定します。

行のベースラインから最も下に突き出している文字またはグラフィックの最下部までのピクセル数を指定します。

totalAscent + totalDescent に等しい、テキスト行の論理的な高さです。

均等配置をしていない場合の行の幅です。均等配置されていないテキストの場合、この値は textWidth と同じです。均等配置されているテキストの場合、この値は均等配置されていなかった場合の長さであり、textWidth の値が実際の行の幅を表します。例えば、次のストリングが均等配置され、幅に 500 を指定して TextBlock.createTextLine() に送信された場合は、実際の幅が 500 ですが、均等配置されていない幅は 268.9921875 になります。

関連する API エレメント

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

アプリケーションが任意のデータをテキスト行に関連付けるための方法を提供します。

テキスト行の現在の有効性を指定します。このプロパティの値は、TextLineValidity クラスのメンバー内に含まれます。このプロパティの設定規則は、次のようになります。

有効性が TextLineValidity のメンバーではないいずれかのストリングに設定される場合、行は USER_INVALID であると見なされます。USER_INVALID は、このような値を表すためにここで使用される抽象値です。

TextBlock のコンテンツが変更されると、Flash ランタイムは、影響を受けたテキスト行、前の行およびすべての継続行を INVALID としてマークします。以前は最初に影響を受けた行にあったコンテンツ部分が、変更によってその前の行に取り込まれるようになる場合、前の行は無効とマークされる必要があります。

新しく改行された行は、常に VALID です。Flash ランタイムは、継続行を VALID から POSSIBLY_INVALID または INVALID に変更することがあります。このコードは、改行内容が同じである場合は POSSIBLY_INVALID の行を VALID に、同じでない場合は INVALID に変更します。

アプリケーションコードでは、VALID の行を INVALID または USER_INVALID とマークしたり、USER_INVALID の行を VALID とマークしたりできます。アプリケーションコードは、行を POSSIBLY_INVALID とマークすることはできません。

アプリケーションコードは、いずれの行も STATIC とマークできます。この操作を行うと、block メンバーが null になります。STATIC のテキスト行内のグラフィックエレメントが STATIC のテキスト行の派生元であるテキストブロックから改行された新しいテキスト行の部分である場合、それらはすべて削除され、親が再設定されます。

関連する API エレメント

TextLine の基になるコンテンツを XML ストリングとしてダンプします。これにはテキスト、書式およびレイアウト情報が含まれており、自動化されたテストで役立ちます。

次に出力について説明します。

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

注意：このメソッドからのコンテンツおよび出力のフォーマットは、今後変更される可能性があります。アドビ システムズ社は、このメソッドの後方互換性は保証していません。

関連する API エレメント

このメソッドは使用されなくなり、効果はありません。アトムデータは圧縮されており、メモリ使用率の管理における要因とはなりません。

関連する API エレメント

指定されたインデックス位置にあるアトムの双方向レベルを取得します。TextBlock.bidiLevel と行を構成する文字の Unicode の双方向プロパティの組み合わせで決まります。

例えば、テキストブロックがヘブライ語のテキストで始まる場合、TextBlock.bidiLevel に 1 を設定して、右から左方向をデフォルトに設定します。テキストの中に英語の引用（左から右方向）がある場合は、そのテキストの AtomBidiLevel には 2 が設定されています。その英語の中にアラビア語（右から左方向）が入っている場合には、AtomBidiLevel は 3 になります。アラビア語の中で数字（左から右方向）が出てくる場合は、その数字の AtomBidiLevel の設定値は 4 です。アトムがどの行で終わるかは関係ありません。ヘブライ語のアトムは AtomBidiLevel が 1、英語のアトムは AtomBidiLevel が 2、アラビア語のアトムは AtomBidiLevel が 3、数字のアトムは AtomBidiLevel が 4 です。

パラメーター

関連する API エレメント

テキスト行を基準として、指定されたインデックス位置にあるアトムの境界を取得します。指定されたアトムの境界は、行の水平座標（x）、行の垂直座標（y）、幅（w）および高さ（h）で構成されます。すべての値はピクセル単位です。

パラメーター

指定されたインデックス位置にあるベースラインに従って測定したアトムの中心を取得します。

パラメーター

指定されたインデックス位置にあるアトムのグラフィックを取得します（アトムが文字の場合は null）。

パラメーター

charIndex パラメーターで指定された文字を含むアトムのインデックスを返します。行内の各アトムにその文字が指定されていない場合は -1 を返します。charIndex は、行を含むテキストブロックのコンテンツ全体に対する相対的な値です。

パラメーター

x パラメーターおよび y パラメーターで指定されたポイントにあるアトムのインデックスを返します。そのポイントにアトムがない場合は -1 を返します。

このメソッドが取り出す座標値はグローバル座標なので、MouseEvent.stageX および MouseEvent.stageY プロパティと一緒に使うことが簡単にできます。

パラメーター

指定されたインデックス位置にあるアトムのテキストブロック開始インデックスを取得します。

パラメーター

指定されたインデックス位置にあるアトムのテキストブロック終了インデックスを取得します。

パラメーター

指定されたインデックス位置にあるアトムの回転を取得します。このプロパティには、TextRotation 定数が使用されます。アトムの回転は、エレメントおよび行の累積された回転です。主に、TextLine を操作するときにキャレット（カーソル）の方向を設定するために使用されます。

パラメーター

関連する API エレメント

指定されたインデックス位置にあるアトムの左側に単語境界があるかどうかを示します。単語境界は、行に指定される文字の Unicode プロパティに基づいて決定されます。

パラメーター

TextBlock.baselineZero を基準にして、指定されたベースラインの位置を取得します。

パラメーター

関連する API エレメント

mirror パラメーターの指定と mirror プロパティが一致する行の最初の TextLineMirrorRegion を返します。一致しない場合は null を返します。

単一の TextElement でも、双方向および改行の状態によっては 1 行または複数行に対する複数の TextLineMirrorRegion オブジェクトを作成できます。nextRegion および previousRegion プロパティは、1 つのテキストエレメントから生成されたすべてのミラー領域をリンクします。

パラメーター

関連する API エレメント

テキスト行の最大要求幅（ピクセル単位）です。 TextBlock.createTextLine() メソッドはこの定数を width パラメーターの値を指定しない場合のデフォルト値として使用します。

関連する API エレメント

1. NumericStepper コンポーネントをライブラリに追加します。
2. このコードを FLA と同じディレクトリに TextLineExample.as という名前で保存します。
3. FLA のプロパティウィンドウでクラスを TextLineExample に設定します。

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}