MovieClip  - AS3

MovieClip インスタンスのタイムライン内の再生ヘッドが置かれているフレームの番号を示します。ムービークリップに複数のシーンがある場合、この値は現在のシーンのフレーム番号です。

mc1.gotoAndStop(mc1.currentFrame + 5);

MovieClip インスタンスのタイムライン内の現在のフレームにあるラベルです。現在のフレームにラベルがない場合、currentLabel は null です。

MovieClip インスタンスのタイムライン内の再生ヘッドが置かれている現在のラベルです。現在のフレームにラベルがない場合、ラベルを含んだ前のフレームの名前に currentLabel が設定されます。現在のフレームと前のフレームにラベルが含まれない場合、currentLabel は null を返します。

trace(mc1.currentLabel);

現在のシーンの FrameLabel オブジェクトの配列を返します。MovieClip インスタンスがシーンを使用していない場合、配列には MovieClip インスタンス全体のすべてのフレームラベルが含まれます。

関連する API エレメント

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

MovieClip インスタンスのタイムライン内の再生ヘッドが置かれている現在のシーンです。

関連する API エレメント

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

ムービークリップの有効 / 無効を示すブール値です。enabled のデフォルト値は true です。enabled が false に設定されると、ムービークリップの「オーバー」、「ダウン」、「アップ」の各フレームは無効になります。ムービークリップは、イベント（mouseDown、mouseUp、keyDown、keyUp など）を引き続き受け取ります。

enabled プロパティは、ムービークリップのボタンに似たプロパティのみを制御します。enabled プロパティはいつでも変更できます。このプロパティの変更後、ムービークリップはすぐに有効 / 無効になります。enabled プロパティが false に設定されている場合、オブジェクトは自動タブ順序に含まれません。

mc1.enabled = false;

ストリーミング SWF ファイルからロードされたフレーム数です。framesLoaded プロパティを使用して、特定のフレームおよびその前のすべてのフレームの内容がロードされていてブラウザーでローカルに使用できるかどうかを判別できます。 これを使用して、大きい SWF ファイルのダウンロードを監視することもできます。例えば、SWF ファイルの指定されたフレームがロードを完了するまで、その SWF ファイルがロード中であることを示すメッセージをユーザーに表示する場合に使用できます。

ムービークリップに複数のシーンがある場合は、framesLoaded プロパティは、ムービークリップ内のすべてのシーンのロード済みフレームの数を返します。

関連する API エレメント

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

ムービークリップが現在再生されているかどうかを示すブール値です。

MovieClip インスタンス内のシーンの名前、フレーム数、フレームラベルがリストされた Scene オブジェクトの配列です。

関連する API エレメント

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

MovieClip インスタンス内のフレーム総数です。

ムービークリップに複数のフレームがある場合は、totalFrames プロパティは、ムービークリップ内のすべてのシーンのフレーム総数を返します。

 trace(mc1.totalFrames);

SimpleButton または MovieClip オブジェクトである他の表示オブジェクトがマウス解放イベントまたは他のユーザー入力解放イベントを受け取ることができるかどうかを示します。trackAsMenu プロパティを使用してメニューを作成できます。trackAsMenu プロパティは、任意の SimpleButton または MovieClip オブジェクトに対して設定できます。trackAsMenu プロパティのデフォルト値は false です。

trackAsMenu プロパティはいつでも変更できます。このプロパティを変更したムービークリップには、新しい動作が直ちに反映されます。

 mc1.trackAsMenu = true;

新しい MovieClip インスタンスを作成します。MovieClip の作成後、ステージ上の表示オブジェクトコンテナの addChild() メソッドまたは addChildAt() メソッドを呼び出せます。

指定されたフレームで SWF ファイルの再生を開始します。この処理は、フレーム内のすべての残存アクションが実行を完了した後に行われます。フレームだけでなくシーンも指定する場合は、scene パラメーターの値も指定してください。

パラメーター

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

このムービークリップの指定されたフレームに再生ヘッドを送り、そこで停止させます。この処理は、フレーム内のすべての残存アクションが実行を完了した後に行われます。フレームに加えてシーンを指定する場合は、scene パラメーターを指定してください。

パラメーター

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

次のフレームに再生ヘッドを送り、停止します。この処理は、フレーム内のすべての残存アクションが実行を完了した後に行われます。

関連する API エレメント

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

MovieClip インスタンスの次のシーンに再生ヘッドを移動します。この処理は、フレーム内のすべての残存アクションが実行を完了した後に行われます。

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

ムービークリップのタイムライン内で再生ヘッドを移動します。

関連する API エレメント

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

直前のフレームに再生ヘッドを戻し、停止します。この処理は、フレーム内のすべての残存アクションが実行を完了した後に行われます。

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

MovieClip インスタンスの直前のシーンに再生ヘッドを移動します。この処理は、フレーム内のすべての残存アクションが実行を完了した後に行われます。

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

ムービークリップ内の再生ヘッドを停止します。

1. コンストラクター関数で、MovieClipExample オブジェクト（MovieClip を拡張する）のプロパティの値を表示するのに使用するテキストフィールドを定義します。
2. getPropertiesString() メソッドの戻り値が、outputText テキストフィールドのテキストとして使用されます。getPropertiesString() メソッドは、ムービークリップの以下のプロパティの値が取り込まれたストリングを返します。currentFrame、currentLabel、currentScene、framesLoaded、totalFrames、およびtrackAsMenu があります。
3. コンストラクター関数内の 2 行のコードは、width プロパティおよび height プロパティ（outputText テキストフィールドのプロパティ）を調整します。
4. コンストラクター関数の最後の行は、outputText テキストフィールドを表示リストに追加します。

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}