NumericStepper  - AS3 Flash

Ottiene o imposta un valore che indica se il componente può accettare l'interazione dell'utente. Il valore true indica che il componente può accettare l'interazione dell'utente, mentre il valore false indica che non può.

Se impostate la proprietà enabled su false, il contenitore è visualizzato in grigio e l'input dell'utente viene bloccato (ad eccezione dei componenti Label e ProgressBar).

Il valore predefinito è true.

Ottiene o imposta la modalità IME (Input Method Editor). La modalità IME consente agli utenti di utilizzare una tastiera di tipo QWERTY per immettere dei caratteri appartenenti ai set di caratteri cinese, giapponese e coreano.

Flash imposta la modalità IME specificata quando il componente diventa attivo e reimposta il valore originale quando il componente non è più attivo.

La classe flash.system.IMEConversionMode definisce le costanti per i valori validi per questa proprietà. Impostate questa proprietà su null per impedire l'utilizzo della modalità IME con il componente.

Ottiene o imposta il valore massimo nella sequenza di valori numerici.

Il valore predefinito è 10.

Ottiene o imposta il numero minimo nella sequenza di valori numerici.

Il valore predefinito è 0.

Ottiene o imposta il valore successivo nella sequenza di valori.

Ottiene o imposta il valore precedente nella sequenza di valori.

Ottiene o imposta un numero diverso da zero che descrive l'unità per il cambiamento dei valori. La proprietà value è un multiplo di questo numero meno il minimo. Il componente NumericStepper arrotonda il valore risultante al valore stepSize più vicino.

Il valore predefinito è 1.

Ottiene un riferimento al componente TextInput contenuto nel componente NumericStepper. Utilizzate questa proprietà per accedere al componente TextInput sottostante e per manipolarlo. Ad esempio, potete utilizzarla per cambiare la selezione corrente nella casella di testo o per limitare i caratteri che è possibile immettervi.

Ottiene o imposta il valore corrente del componente NumericStepper.

Il valore predefinito è 1.

Crea una nuova istanza del componente NumericStepper.

Mostra o nasconde l'indicatore di attivazione sul componente.

La classe UIComponent implementa questo metodo mediante la creazione e il posizionamento di un'istanza della classe specificata dallo stile focusSkin.

Parametri

Recupera la mappa di stile predefinita del componente corrente. La mappa di stile contiene il tipo appropriato per il componente, in base allo stile utilizzato dal componente. Ad esempio, lo stile disabledTextFormat contiene un valore null o un oggetto TextFormat. È possibile utilizzare questi stili e chiamare setStyle() sul componente corrente. Il codice seguente consente di ignorare lo stile disabledTextFormat predefinito sul componente specificato:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Elementi API correlati

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Imposta l'istanza del componente come elemento attivo.

Inviato quando l'utente modifica il valore del componente NumericStepper.

Nota: questo evento non viene inviato se si utilizza il codice ActionScript per modificare il valore.

Questo evento ha le seguenti proprietà:

1. Aggiungete il componente NumericStepper alla libreria.
2. Salvate questo codice come NumericStepperExample.as nella stessa directory del FLA.
3. Impostate DocumentClass nel FLA su NumericStepperExample.

package 
{
    import flash.display.Sprite
    import flash.text.TextField;
    import flash.events.Event;
    import fl.controls.NumericStepper;
    
    public class NumericStepperExample extends Sprite
    {
        private var ns1:NumericStepper;
        private var ns2:NumericStepper;
        private var tf1:TextField;
        private var tf2:TextField;
        private var rowHeight1:Number = 10;
        private var rowHeight2:Number = 50;
        
        public function NumericStepperExample() {        
            setupSteppers();
            setupTextFields();
        }
        private function setupTextFields():void {
            tf1 = new TextField();
            tf1.text = "This stepper increments by 1 between 0 and 5. Disables if it reaches 0.";
            tf1.autoSize = "left";
            tf1.x = 100;
            tf1.y = rowHeight1;
            addChild(tf1);
            
            tf2 = new TextField();
            tf2.text = "This stepper increments by 0.01 between 0 and 20. Disables if it reaches 0.";
            tf2.autoSize = "left";
            tf2.x = 100;
            tf2.y = rowHeight2;
            addChild(tf2);
        }
        private function setupSteppers():void {    
            ns1 = new NumericStepper();
            ns1.stepSize = 1;
            ns1.maximum = 5;
            ns1.minimum = 0;
            ns1.addEventListener(Event.CHANGE,changeOccurred);
            ns1.move(10,rowHeight1);
            addChild(ns1);

            ns2 = new NumericStepper();
            ns2.stepSize = 0.01;
            ns2.maximum = 20;
            ns2.minimum = 0;
            ns2.value = 10;
            ns2.addEventListener(Event.CHANGE,changeOccurred);
            ns2.move(10,rowHeight2);
            addChild(ns2);
        }
        private function changeOccurred(e:Event):void {
            var nsTarget:NumericStepper = e.target as NumericStepper;
            if(nsTarget.value == 0) nsTarget.enabled = false;
        }
    }
}