Label  - AS3 Flash

Bir etiketin text özelliğini sığdırmak için nasıl boyutlandırıldığını ve hizalandığını anlatan bir dizeyi alır veya ayarlar. Şunlar, geçerli değerlerdir:

• TextFieldAutoSize.NONE: Etiket, metne sığması için yeniden boyutlandırılmaz veya hizalanmaz.
• TextFieldAutoSize.LEFT: Etiketin sağ ve alt tarafları, metne sığması için yeniden boyutlandırılır. Sol ve üst taraflar yeniden boyutlandırılmaz.
• TextFieldAutoSize.CENTER: Etiketin sol ve sağ tarafları, metne sığması için yeniden boyutlandırılır. Etiketin yatay merkezi, orijinal yatay merkez konumunda bağlı kalır.
• TextFieldAutoSize.RIGHT: Etiketin sol ve alt tarafları, metne sığması için yeniden boyutlandırılır. Sağ ve üst taraflar yeniden boyutlandırılmaz.

Varsayılan değer şudur TextFieldAutoSize.NONE.

İlgili API Öğeleri

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Boşluklar veya satır kesmeler gibi ekstra beyaz boşluğun HTML metni içeren bir Label bileşeninden kaldırılıp kaldırılmayacağını gösteren değeri alır veya ayarlar. true değeri, beyaz boşluğun kaldırılacağını, false değeri ise kalacağını gösterir.

condenseWhite özelliği yalnızca htmlText özelliği kullanılarak ayarlanan metni etkiler, text özelliğini etkilemez. Metni text özelliğini kullanarak ayarlarsanız, condenseWhite özelliği yok sayılır.

condenseWhite özelliğini true olarak ayarlarsanız, metin alanındaki satırları kesmek için <br> ve <p> gibi standart HTML komutlarını kullanmanız gerekir.

Varsayılan değer şudur false.

İlgili API Öğeleri

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Bileşenin yüksekliğini piksel cinsinden alır veya ayarlar.

Bu özelliğin ayarlanması, bir resize olayının gönderilmesine neden olur. Ne zaman gönderildiği hakkında ayrıntılı bilgi edinmek için resize olayına bakın.

Bileşenin scaleY özelliği 1.0 değilse, bileşenin dahili koordinatlarından alınan yükseklik değeri üst koordinatların height değeriyle eşleşmez. Örneğin yüksekliği 100 piksel olan ve scaleY değeri 2 olan bir bileşen üst öğesinde 100 piksel değere sahiptir, ancak 50 piksel yüksekliğinde olduğunu gösteren bir değeri dahili olarak saklar.

İlgili API Öğeleri

Label bileşeni tarafından görüntülenecek metni, o metnin stillerini ifade eden HTML işaretlemesi de dahil olmak üzere alır veya ayarlar. Bu özellikteki HTML metnini, TextField nesnesi tarafından desteklenen HTML etiketlerinin alt kümesini kullanarak belirtebilirsiniz.

text özelliğinin varsayılan değeri Özellik denetçisinde değiştirilirse, değiştirilen bu değer, Özellik denetçisindeki htmlText özelliği alanındaki her değere göre öncelik kazanır. Özellik denetçisindeki htmlText özelliğini kullanmak için text özellik alanı, Label değerini tam olarak gösterildiği şekilde içermelidir. ActionScript ile kodlama yaparken, text özelliğinin değerini ayarlamanız gerekmez, varsayılan değer Label olur.

Varsayılan değer şudur "".

İlgili API Öğeleri

Metnin seçilip seçilemeyeceğini gösteren bir değeri alır veya ayarlar. true değeri seçilebileceğini, false değeri ise seçilemeyeceğini gösterir.

Seçilebilecek metin, kullanıcı tarafından Label bileşeninden kopyalanabilir.

Varsayılan değer şudur false.

Label bileşeni tarafından görüntülenecek düz metni alır veya ayarlar.

HTML işaretlemelerini temsil eden karakterlerin dizede özel bir anlamı olmadığını ve girildiği şekilde görüneceğini unutmayın.

HTML etiketleri içeren metni görüntülemek için htmlText özelliğini kullanın. HTML, htmlText özelliğini kullanarak ayarladığınız her metni değiştirir ve text özelliği, HTML metninin düz bir metin sürümünü, kaldırılan HTML etiketleri ile döndürür.

text özelliği, özellik denetçisindeki varsayılan değerden değiştirildiyse, özellik denetçisindeki htmlText özelliğine göre öncelik kazanır.

Varsayılan değer şudur "Label".

İlgili API Öğeleri

Label bileşeninin dahili metin alanına gönderilen başvuru.

Bileşenin genişliğini piksel cinsinden alır veya ayarlar.

Bu özelliğin ayarlanması, bir resize olayının gönderilmesine neden olur. Ne zaman gönderildiği hakkında ayrıntılı bilgi edinmek için resize olayına bakın.

Bileşenin scaleX özelliği 1.0 değilse, bileşenin dahili koordinatlarından alınan genişlik değeri üst koordinatların width değeriyle eşleşmez. Örneğin genişliği 100 piksel olan ve scaleX değeri 2 olan bir bileşen üst öğesinde 100 piksel değere sahiptir, ancak 50 piksel genişliğinde olduğunu gösteren bir değeri dahili olarak saklar.

İlgili API Öğeleri

Metin alanının kelime kaydırma işlemini destekleyip desteklemediğini gösteren değeri alır veya ayarlar. true değeri desteklediğini, false değeri ise desteklemediğini gösterir.

Varsayılan değer şudur false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Yeni bir Label bileşeni örneği oluşturur.

Geçerli bileşen için varsayılan stil eşlemesini alır. Stil eşlemesi, bileşenin kullandığı stile bağlı olarak bileşen için uygun olan türü içerir. Örneğin disabledTextFormat stili, null değeri veya TextFormat nesnesi içerir. Geçerli bileşende bu stilleri kullanılabilir ve setStyle() öğesini çağırabilirsiniz. Şu kod, belirtilen bileşendeki varsayılan disabledTextFormat stilini geçersiz kılar:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

İlgili API Öğeleri

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Bileşenin genişliğinde veya yüksekliğinde değişiklik yapıldıktan sonra gönderilir.

Not: Etiket metnini değiştirmek için ActionScript kodu kullanırsanız bu olay meydana gelmez.

Bu olay şu özelliklere sahiptir:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Label ve Button bileşenlerini kütüphanenize ekleyin.
2. Bu kodu FLA dosyanızla aynı dizine LabelExample.as olarak kaydedin.
3. FLA dosyasındaki DocumentClass öğesini LabelExample olarak ayarlayın.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}