ComponentEvent

Paket	fl.events
Sınıf	public class ComponentEvent
Miras Alma	ComponentEvent Event Object

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

ComponentEvent sınıfı, UIComponent sınıfıyla ilişkilendirilen olayları tanımlar. Bunlara şu olaylar dahildir:

ComponentEvent.BUTTON_DOWN: bir düğmeye basıldıktan sonra gönderilir.
ComponentEvent.ENTER: Enter tuşuna basıldıktan sonra gönderilir.
ComponentEvent.HIDE: bir bileşenin visible özelliği false olarak ayarlandıktan sonra gönderilir.
ComponentEvent.LABEL_CHANGE: Enter tuşuna basıldıktan sonra gönderilir.
ComponentEvent.MOVE: bileşen konumunu tanımlayan x veya y özelliklerinde bir değişiklik olduktan sonra gönderilir.
ComponentEvent.RESIZE: bir bileşen yeniden boyutlandırıldıktan sonra gönderilir.
ComponentEvent.SHOW: bir bileşenin visible özelliği true değerine ayarlandıktan sonra gönderilir.

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		bubbles : Boolean [salt okunur] Bir olayın köpüren bir olay olup olmadığını belirtir.	Event
		cancelable : Boolean [salt okunur] Olayla ilişkilendirilmiş davranışın önlenebilir olup olmadığını gösterir.	Event
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		currentTarget : Object [salt okunur] Bu Event nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.	Event
		eventPhase : uint [salt okunur] Olay akışındaki geçerli aşama.	Event
		target : Object [salt okunur] Olay hedefi.	Event
		type : String [salt okunur] Olay türü.	Event

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		ComponentEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false) Bir bileşen olayı hakkında bilgi içeren yeni bir ComponentEvent nesnesi oluşturur.	ComponentEvent
		clone():Event [geçersiz kıl] ComponentEvent nesnesinin bir kopyasını oluşturur ve her parametrenin değerini, orijinal ile aynı olacak şekilde ayarlar.	ComponentEvent
		formatToString(className:String, ... arguments):String Özel ActionScript 3.0 Event sınıfınızdaki toString() yöntemini uygulamak için bir yardımcı işlev.	Event
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isDefaultPrevented():Boolean Olayda preventDefault() öğesinin çağrılmış olup olmadığını kontrol eder.	Event
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		preventDefault():void Bir olayın varsayılan davranışını, bu yapılabiliyorsa iptal eder.	Event
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		stopImmediatePropagation():void Olay akışında geçerli düğümdeki ve ondan sonra gelen düğümlerdeki olay dinleyicilerin işlenmesini engeller.	Event
		stopPropagation():void Olay akışında geçerli düğümden sonra gelen düğümlerdeki olay dinleyicilerin işlenmesini engeller.	Event
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String [geçersiz kıl] ComponentEvent nesnesinin tüm özelliklerini içeren bir dize döndürür.	ComponentEvent
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object

Genel Sabitler

Miras Alınan Genel Sabitleri Gizle

Miras Alınan Genel Sabitleri Göster

	Sabit		Tanımlayan:
		BUTTON_DOWN : String = "buttonDown" [statik] Bir buttonDown olay nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent
		ENTER : String = "enter" [statik] Bir enter olay nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent
		HIDE : String = "hide" [statik] Bir hide olayı nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent
		LABEL_CHANGE : String = "labelChange" [statik] Bir labelChange olay nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent
		MOVE : String = "move" [statik] Bir move olay nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent
		RESIZE : String = "resize" [statik] Bir resize olay nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent
		SHOW : String = "show" [statik] Bir show olayı nesnesinin type özelliğinin değerini tanımlar.	ComponentEvent

Yapıcı Ayrıntı

()

Yapıcı

public function ComponentEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir bileşen olayı hakkında bilgi içeren yeni bir ComponentEvent nesnesi oluşturur. ComponentEvent nesnesi olay dinleyiciye bir parametre olarak iletilir.

Parametreler

	`type:String` — Olayın türü. Olay dinleyicileri bu bilgiye olay nesnesinin `type` özelliğini kullanarak erişebilir. Bir bileşen şu olay türlerine sahip olabilir: `ComponentEvent.BUTTON_DOWN`, `ComponentEvent.ENTER`, `ComponentEvent.HIDE`, `ComponentEvent.LABEL_CHANGE`, `ComponentEvent.MOVE`, `ComponentEvent.RESIZE`, `ComponentEvent.SHOW`.

	`bubbles:Boolean` (default = `false`) — ComponentEvent nesnesinin olay akışının köpürme aşamasında yer alıp almayacağını belirler. Olay dinleyicileri bu bilgiye olay nesnesinin `bubbles` özelliğini kullanarak erişebilir.

	`cancelable:Boolean` (default = `false`) — ComponentEvent nesnesinin iptal edilip edilemeyeceğini belirler. Olay dinleyicileri bu bilgiye olay nesnesinin `cancelable` özelliğini kullanarak erişebilir.

Yöntem Ayrıntısı

clone

()

yöntem

override public function clone():Event

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

ComponentEvent nesnesinin bir kopyasını oluşturur ve her parametrenin değerini, orijinal ile aynı olacak şekilde ayarlar.

Döndürür

Event — Orijinaliyle eşleşen özellik değerlerine sahip yeni bir ComponentEvent nesnesi.

toString

()

yöntem

override public function toString():String

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

ComponentEvent nesnesinin tüm özelliklerini içeren bir dize döndürür. Dize şu biçimdedir:

[ComponentEvent type=value bubbles=value cancelable=value]

Döndürür

String — ComponentEvent nesnesinin dize ile temsil edilen hali.

Sabit Ayrıntısı

BUTTON_DOWN

Sabit

public static const BUTTON_DOWN:String = "buttonDown"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir buttonDown olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

ENTER

Sabit

public static const ENTER:String = "enter"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir enter olayı nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

HIDE

Sabit

public static const HIDE:String = "hide"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir hide olayı nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

İlgili API Öğeleri

SHOW

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek bir List bileşeninin görünürlüğünü açıp kapatan bir Button bileşeni oluşturur:


import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

LABEL_CHANGE

Sabit

public static const LABEL_CHANGE:String = "labelChange"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir labelChange olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

MOVE

Sabit

public static const MOVE:String = "move"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir move olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

Örnek ( Bu örnek nasıl kullanılır? )

Şu değer, Slider bileşeni değerini temel alarak UILoader bileşen örneğini yeniden konumlandırır.


import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

RESIZE

Sabit

public static const RESIZE:String = "resize"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir resize olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek harici görüntüyü UILoader bileşen örneğine yükler ve resize olayı ve move() yöntemini kullanarak Sahne Alanı'nda ortalar:


import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

SHOW

Sabit

public static const SHOW:String = "show"

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir show olayı nesnesinintype özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Olay nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Olayı gönderen nesne. Hedef her zaman olayı dinleyen nesne değildir. Olayı dinleyen nesneye erişmek için `currentTarget` özelliğini kullanın.

İlgili API Öğeleri

HIDE

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek bir List bileşeninin görünürlüğünü açıp kapatan bir Button bileşeni oluşturur:


import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

ComponentEvent - AS3 Flash

Sınıflar x

ComponentEvent

clone

toString

BUTTON_DOWN

ENTER

HIDE

LABEL_CHANGE

MOVE

RESIZE

SHOW