ScrollPane  - AS3 Flash

import fl.containers.ScrollPane;
import fl.controls.ProgressBar;

var path:String = "test.jpg";

var sp:ScrollPane = new ScrollPane();
sp.move(10,10);
sp.setSize(530,300);
sp.addEventListener(ProgressEvent.PROGRESS,reportProgress);
sp.load(new URLRequest(path));
addChild(sp);

var progressBar:ProgressBar = new ProgressBar();
progressBar.move(10,320);
progressBar.setSize(530,50);
progressBar.source = sp;
addChild(progressBar);

function reportProgress(e:ProgressEvent):void {
    trace(e.bytesLoaded + " loaded out of " + e.bytesTotal);
}

import fl.containers.ScrollPane;

var url:String = "http://www.helpexamples.com/flash/images/image1.jpg";

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.setSize(320, 240);
myScrollPane.move(10, 10);
myScrollPane.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
myScrollPane.load(new URLRequest(url));
addChild(myScrollPane);

function progressHandler(event:ProgressEvent):void {
    var bLoaded:int = event.bytesLoaded;
    var bTotal:int = event.bytesTotal;
    var pctLoaded:int = int(event.currentTarget.percentLoaded);
    trace("progress: " + bLoaded + " of " + bTotal + " bytes loaded (" + pctLoaded + "%)");
}

function completeHandler(event:Event):void {
    trace("complete:");
}

import fl.containers.ScrollPane;
import fl.controls.NumericStepper;

var ns:NumericStepper = new NumericStepper();
ns.minimum = 10;
ns.maximum = 100;
ns.stepSize = 10;
ns.value = ns.maximum;
ns.addEventListener(Event.CHANGE, updateScrollPaneContentAlpha);
addChild(ns);

var sp:ScrollPane = new ScrollPane();
sp.move(0,30);
sp.setSize(180, 160);
sp.source = "http://www.helpexamples.com/flash/images/image2.jpg";
addChild(sp);

function updateScrollPaneContentAlpha(e:Event):void {
    sp.content.alpha = e.target.value / 100;
}

import fl.containers.ScrollPane;
import fl.controls.Button;
import fl.events.ComponentEvent;

var MAX_SCROLLPANE_WIDTH:uint = 400;
var MAX_SCROLLPANE_HEIGHT:uint = 267;

var url:String = "http://www.helpexamples.com/flash/images/image1.jpg";

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.scrollDrag = true;
myScrollPane.cacheAsBitmap = true;
myScrollPane.setSize(MAX_SCROLLPANE_WIDTH, MAX_SCROLLPANE_HEIGHT);
myScrollPane.move(10, 10);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
myScrollPane.load(new URLRequest(url));
addChild(myScrollPane);

var zoomInButton:Button = new Button();
zoomInButton.autoRepeat = true;
zoomInButton.enabled = false;
zoomInButton.label = "Zoom in (+)";
zoomInButton.move(420, 10);
zoomInButton.addEventListener(ComponentEvent.BUTTON_DOWN, zoomInHandler);
addChild(zoomInButton);

var zoomOutButton:Button = new Button();
zoomOutButton.autoRepeat = true;
zoomOutButton.enabled = false;
zoomOutButton.label = "Zoom out (-)";
zoomOutButton.move(420, 40);
zoomOutButton.addEventListener(ComponentEvent.BUTTON_DOWN, zoomOutHandler);
addChild(zoomOutButton);

var cacheButton:Button = new Button();
cacheButton.enabled = false;
cacheButton.emphasized = myScrollPane.cacheAsBitmap;
cacheButton.label = "cacheAsBitmap";
cacheButton.toggle = true;
cacheButton.selected = myScrollPane.cacheAsBitmap;
cacheButton.move(420, 70);
cacheButton.addEventListener(Event.CHANGE, changeHandler);
addChild(cacheButton);

function completeHandler(event:Event):void {
    zoomInButton.enabled = true;
    zoomOutButton.enabled = true;
    cacheButton.enabled = true;
    myScrollPane.removeEventListener(Event.COMPLETE, completeHandler);
}

function changeHandler(event:Event):void {
    myScrollPane.cacheAsBitmap = !myScrollPane.cacheAsBitmap;
    cacheButton.emphasized = myScrollPane.cacheAsBitmap;
}

function zoomInHandler(event:ComponentEvent):void {
    var zoomLvl:Number = myScrollPane.content.scaleX * 1.1;
    updateSP(zoomLvl);
}

function zoomOutHandler(event:ComponentEvent):void {
    var zoomLvl:Number = myScrollPane.content.scaleX / 1.1;
    updateSP(zoomLvl);
}

function updateSP(newScale:Number):void {
    var img:DisplayObject = myScrollPane.content as DisplayObject;
    img.scaleY = newScale;
    img.scaleX = newScale;
    myScrollPane.width = Math.min(img.width, MAX_SCROLLPANE_WIDTH);
    myScrollPane.height = Math.min(img.height, MAX_SCROLLPANE_HEIGHT);
    myScrollPane.update();
}

import fl.containers.ScrollPane;

var url:String = "http://www.helpexamples.com/flash/images/image1.jpg";

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.setSize(320, 240);
myScrollPane.move(10, 10);
myScrollPane.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
myScrollPane.load(new URLRequest(url));
addChild(myScrollPane);

function progressHandler(event:ProgressEvent):void {
    var bLoaded:int = event.bytesLoaded;
    var bTotal:int = event.bytesTotal;
    var pctLoaded:int = int(event.currentTarget.percentLoaded);
    trace("progress: " + bLoaded + " of " + bTotal + " bytes loaded (" + pctLoaded + "%)");
}

function completeHandler(event:Event):void {
    trace("complete:");
}

import fl.containers.ScrollPane;
import fl.events.ScrollEvent;

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.scrollDrag = true;
myScrollPane.source = "http://www.helpexamples.com/flash/images/image2.jpg";
myScrollPane.addEventListener(ScrollEvent.SCROLL, scrollHandler);
myScrollPane.move(10, 10);
addChild(myScrollPane);

function scrollHandler(event:ScrollEvent):void {
    var mySP:ScrollPane = event.currentTarget as ScrollPane;
    trace("scrolling");
    trace("\t" + "direction:", event.direction);
    trace("\t" + "position:", event.position);
    trace("\t" + "horizontalScrollPosition:", mySP.horizontalScrollPosition, "of", mySP.maxHorizontalScrollPosition);
    trace("\t" + "verticalScrollPosition:", mySP.verticalScrollPosition, "of", mySP.maxVerticalScrollPosition);
}

import fl.containers.ScrollPane;

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.source = "http://www.helpexamples.com/flash/images/image1.jpg";
myScrollPane.setSize(320, 240);
myScrollPane.move(10, 10);
addChild(myScrollPane);

import fl.containers.ScrollPane;

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.source = Box;
myScrollPane.setSize(320, 240);
myScrollPane.move(10, 10);
addChild(myScrollPane);

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

import fl.containers.ScrollPane;

var request:URLRequest = new URLRequest("http://www.helpexamples.com/flash/images/image1.jpg");
var sp:ScrollPane = new ScrollPane();
sp.setSize(180, 160);
sp.load(request);
addChild(sp);

import fl.containers.ScrollPane;
import fl.controls.Button;
import fl.controls.TextArea;

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.setSize(320, 240);
myScrollPane.move(10, 10);
myScrollPane.load(new URLRequest(url));
myScrollPane.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
addChild(myScrollPane);

var refreshButton:Button = new Button();
refreshButton.emphasized = true;
refreshButton.label = "refreshPane()";
refreshButton.move(myScrollPane.x + myScrollPane.width + 10, myScrollPane.y);
refreshButton.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(refreshButton);

var myTextArea:TextArea = new TextArea();
myTextArea.editable = false;
myTextArea.setSize(320, 120);
myTextArea.move(myScrollPane.x, myScrollPane.y + myScrollPane.height + 10);
addChild(myTextArea);

function progressHandler(event:ProgressEvent):void {
    var bLoaded:int = event.bytesLoaded;
    var bTotal:int = event.bytesTotal;
    var pctLoaded:int = int(event.currentTarget.percentLoaded);
    addText("progress (" + bLoaded + " of " + bTotal + " bytes loaded -- " + pctLoaded + "%)");
}

function completeHandler(event:Event):void {
    addText("complete");
    addText("----------");
}

function clickHandler(event:MouseEvent):void {
    myScrollPane.refreshPane();
}

function addText(str:String):void {
    myTextArea.appendText(str + "\n");
    myTextArea.verticalScrollPosition = myTextArea.maxVerticalScrollPosition;
}

import fl.containers.ScrollPane;
import fl.controls.Button;

var baseURL:String = "http://www.helpexamples.com/flash/images/";

var img1Button:Button = new Button();
img1Button.label = "Image 1";
img1Button.move(10, 10);
img1Button.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(img1Button);

var img2Button:Button = new Button();
img2Button.label = "Image 2";
img2Button.move(10, 40);
img2Button.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(img2Button);

var img3Button:Button = new Button();
img3Button.label = "Image 3";
img3Button.move(10, 70);
img3Button.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(img3Button);

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.setSize(320, 240);
myScrollPane.move(120, 10);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
addChild(myScrollPane);

function clickHandler(event:MouseEvent):void {
    switch (event.currentTarget) {
        case img1Button:
            myScrollPane.source = baseURL + "image1.jpg";
            break;
        case img2Button:
            myScrollPane.source = baseURL + "image2.jpg";
            break;
        case img3Button:
            myScrollPane.source = baseURL + "image3.jpg";
            break;
    }
}

function completeHandler(event:Event):void {
    myScrollPane.update();
}

import fl.containers.ScrollPane;
import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/images/image1.jpg";

var conversion:Number = 1024;

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 10);
addChild(myLabel);

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
myScrollPane.load(new URLRequest(url));

function progressHandler(event:ProgressEvent):void {
    var bLoaded:int = int(event.bytesLoaded / conversion);
    var bTotal:int = int(event.bytesTotal / conversion);
    var pctLoaded:int = event.target.percentLoaded as int;
    myLabel.text = bLoaded + " of " + bTotal + " (" + pctLoaded + "%)";
}

function completeHandler(event:Event):void {
    var img:DisplayObject = myScrollPane.content;
    
    myScrollPane.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myScrollPane.removeEventListener(Event.COMPLETE, completeHandler);
    removeChild(myLabel);

    myScrollPane.setSize(img.width, img.height);
    var newX:uint = (stage.stageWidth - myScrollPane.width) / 2;
    var newY:uint = (stage.stageHeight - myScrollPane.height) / 2;
    myScrollPane.move(newX, newY);
    addChild(myScrollPane);
}

import fl.containers.UILoader;

var url:String = "http://www.helpexamples.com/flash/images/image404.jpg"

var myUILoader:UILoader = new UILoader();
myUILoader.load(new URLRequest(url));
myUILoader.move(10, 10);
myUILoader.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
addChild(myUILoader);

function ioErrorHandler(event:IOErrorEvent):void {
    trace("<<", event.text, ">>");
    myUILoader.removeEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
    removeChild(myUILoader);
}

import fl.containers.ScrollPane;

var url:String = "http://www.helpexamples.com/flash/images/image1.jpg";

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.setSize(320, 240);
myScrollPane.move(10, 10);
myScrollPane.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myScrollPane.addEventListener(Event.COMPLETE, completeHandler);
myScrollPane.load(new URLRequest(url));
addChild(myScrollPane);

function progressHandler(event:ProgressEvent):void {
    var bLoaded:int = event.bytesLoaded;
    var bTotal:int = event.bytesTotal;
    var pctLoaded:int = int(event.currentTarget.percentLoaded);
    trace("progress: " + bLoaded + " of " + bTotal + " bytes loaded (" + pctLoaded + "%)");
}

function completeHandler(event:Event):void {
    trace("complete:");
}

import fl.containers.ScrollPane;
import fl.events.ScrollEvent;
import fl.controls.ScrollBarDirection;

var myScrollPane:ScrollPane = new ScrollPane();
myScrollPane.scrollDrag = true;
myScrollPane.source = "http://www.helpexamples.com/flash/images/image1.jpg";
myScrollPane.addEventListener(ScrollEvent.SCROLL, scrollHandler);
addChild(myScrollPane);

function scrollHandler(event:ScrollEvent):void {
    switch (event.direction) {
        case ScrollBarDirection.HORIZONTAL:
            trace("horizontal scroll", event.position, "of", event.currentTarget.maxHorizontalScrollPosition);
            break;
        case ScrollBarDirection.VERTICAL:
            trace("vertical scroll", event.position, "of", event.currentTarget.maxVerticalScrollPosition);
            break;
    }
}