Stage  - AS3

Flash Player 또는 브라우저에서 스테이지 정렬을 지정하는 StageAlign 클래스 값입니다. 유효한 값은 다음과 같습니다.

align 속성은 Stage 소유자(기본 SWF 파일)와 동일한 보안 샌드박스에 있는 객체에만 사용할 수 있습니다. 스테이지 소유자는 이와 같은 상황을 피하기 위해 Security.allowDomain() 메서드 또는 Security.alowInsecureDomain() 메서드를 호출하여 호출하는 객체의 도메인에 권한을 부여할 수 있습니다. 자세한 내용은 ActionScript 3.0 개발자 안내서의 "보안" 장을 참조하십시오.

관련 API 요소

이 스테이지에서 전체 화면 모드의 사용이 허용되는지 여부를 지정합니다.

이 스테이지에서 텍스트 입력 모드로 전체 화면을 사용할 수 있는지 여부를 지정합니다.

장치 방향이 바뀔 때 스테이지의 방향을 자동으로 변경할지 여부를 지정합니다.

이 속성의 초기값은 응용 프로그램 설명자의 autoOrients 요소에서 파생되며, 기본값은 false입니다. 속성을 false로 변경하면 비헤이비어를 보장할 수 없습니다. 일부 장치에서는 스테이지가 현재 방향으로 유지됩니다. 다른 장치에서는 스테이지 방향이 장치에 정의된 "표준" 방향으로 변경되고 그 후에는 스테이지 방향이 변하지 않습니다.

AIR 프로파일 지원: 이 기능은 휴대 장치에서는 지원되지만 데스크톱 운영 체제 또는 AIR for TV 장치에서는 지원되지 않습니다. Stage.supportsOrientantionChange 속성을 사용하여 런타임에 지원을 테스트할 수 있습니다. 여러 프로파일 간 API 지원에 대한 자세한 내용은 AIR 프로파일 지원을 참조하십시오.

관련 API 요소

브라우저 확대/축소 인수를 지정합니다. 브라우저 확대/축소 인수를 변경할 경우 Stage의 확대/축소 인수에도 영향을 미칩니다.

SWF 배경색입니다.

기본값은 스테이지 배경색이며 SWF 태그 SetBackgroundColor를 통해 설정됩니다.

Flash 런타임의 디스플레이 색상 교정을 제어합니다. 색상 교정은 기본 모니터에 장치의 특정 색상 특성을 지정하는 유효한 ICC 색상 프로파일이 지정되어 있는 경우에만 작동합니다. 기본적으로 Flash 런타임에서는 호스트(일반적으로 브라우저)의 색상 교정과 일치시킵니다.

현재 시스템 및 기본 상태에서 색상 교정을 사용할 수 있는지 확인하려면 Stage.colorCorrectionSupport 속성을 사용합니다. 색상 교정을 사용할 수 있는 경우 스테이지의 모든 색상이 가장 표준적인 색상 공간인 RGB 색상 공간에 있는 것으로 간주됩니다. 입력 장치의 소스 프로파일은 색상 교정 중에는 적용되지 않습니다. 입력 색상 교정은 적용되지 않으며 스테이지 출력만 기본 모니터의 ICC 색상 프로파일에 매핑됩니다.

일반적으로 색상 관리를 활성화하면 예측 가능하고 일관된 색상, 향상된 변환, 정확한 보정, 보다 효율적인 크로스 미디어 출력 등의 이점이 있습니다. 물론 장치 간에 또는 장치와 원본 이미지 간에 색상 영역이 서로 다르기 때문에 색상 관리를 통해 완벽하게 변환 작업을 수행할 수는 없습니다. 또한 색상 관리를 사용하여도 프로파일을 사용자 정의하거나 편집해야 할 수도 있습니다. 색상 프로파일은 브라우저, 운영 체제(OS), OS 확장, 출력 장치, 응용 프로그램 지원 등에 따라 달라집니다.

색상 교정을 적용하면 Flash 런타임 성능이 저하됩니다. 모든 SWF 동영상은 암시적인 표준 RGB 프로파일을 포함하는 문서로 간주되기 때문에 Flash 런타임의 색상 교정은 문서 스타일의 색상 교정입니다. Stage.colorCorrectionSupport 속성을 사용하여 SWF 파일(문서)을 디스플레이 색상 공간으로 표시할 때 Flash 런타임이 색상을 교정하도록 합니다. Flash 런타임은 모니터 간의 차이를 보정할 뿐 입력 장치(카메라, 스캐너 등) 간의 차이는 보정하지 않습니다.

사용할 수 있는 세 가지 값은 flash.display.ColorCorrection 클래스에서 해당하는 상수를 포함하는 다음과 같은 문자열입니다.

• "default": 호스트 시스템과 동일한 색상 교정을 사용합니다.
• "on": 색상 교정을 항상 수행합니다.
• "off": 색상 교정을 수행하지 않습니다.

관련 API 요소

function addHandler(add_event:Event) {
    switch(stage.colorCorrection) {
        case ColorCorrection.ON:
            stage.colorCorrection = ColorCorrection.OFF;
            lblCMEnableState.text = "State: " + stage.colorCorrection;
            break;
        case ColorCorrection.OFF:
            stage.colorCorrection = ColorCorrection.DEFAULT;
            lblCMEnableState.text = "State: " + stage.colorCorrection;
            break;
        case ColorCorrection.DEFAULT:
            stage.colorCorrection = ColorCorrection.ON;
            lblCMEnableState.text = "State: " + stage.colorCorrection;
            break;
        default:
            lblCMEnableState.text = "Error.";
            break;
}

Flash 런타임이 색상 교정을 지원하는 운영 체제에서 실행 중인지 여부 및 주(기본) 모니터의 색상 프로파일을 Flash 런타임에서 읽고 인식할 수 있는지 여부를 지정합니다. 이 속성은 또한 대개 브라우저와 같은 호스트 시스템의 색상 교정 기본 상태를 반환합니다. 현재 반환 값은 다음과 같을 수 있습니다.

사용할 수 있는 세 가지 값은 flash.display.ColorCorrectionSupport 클래스에서 해당하는 상수를 포함하는 문자열입니다.

• "unsupported": 색상 교정을 사용할 수 없습니다.
• "defaultOn": 색상 교정을 항상 수행합니다.
• "defaultOff": 색상 교정을 수행하지 않습니다.

관련 API 요소

function addHandler(add_event:Event) {
    if (stage.colorCorrectionSupport == ColorCorrectionSupport.DEFAULT_ON || stage.colorCorrectionSupport == ColorCorrectionSupport.DEFAULT_OFF) {
           lblHasCM.text = "stage.colorCorrectionSupport: " + stage.colorCorrectionSupport;
    } 
    else {
        lblHasCM.text = "stage.colorCorrectionSupport: unsupported";
    }
}

스테이지의 유효 픽셀 배율을 지정합니다. 표준 화면 및 HiDPI(Retina 디스플레이) 화면에서 이 값은 1입니다. 스테이지가 HiDPI 화면에서 렌더링되는 경우에는 픽셀 해상도가 두 배가 되며, 이는 스테이지 크기 조절 모드가 StageScaleMode.NO_SCALE로 설정되어 있는 경우에도 마찬가지입니다. Stage.stageWidth 및 Stage.stageHeight는 계속 클래식 픽셀 단위로 보고됩니다.

장치의 실제 방향입니다.

슬라이드 아웃 키보드가 있는 장치에서는 장치 방향을 결정할 때 가속도계에 의해 감지된 회전보다 키보드의 상태가 더 높은 우선 순위를 갖습니다. 따라서 측면 탑재 키보드가 있는 세로 종횡비 장치에서는 사용자가 장치를 들고 있는 방법에 관계없이 키보드가 열려 있을 때 deviceOrientation 속성은 ROTATED_LEFT를 보고합니다.

이 속성의 값을 설정하거나 비교할 때 StageOrientation 클래스에 정의된 상수를 사용합니다.

AIR 프로파일 지원: 이 기능은 휴대 장치에서는 지원되지만 데스크톱 운영 체제 또는 AIR for TV 장치에서는 지원되지 않습니다. Stage.supportsOrientationChange 속성을 사용하여 런타임에 지원을 테스트할 수 있습니다. 여러 프로파일 간 API 지원에 대한 자세한 내용은 AIR 프로파일 지원을 참조하십시오.

관련 API 요소

사용할 표시 상태를 지정하는 StageDisplayState 클래스의 값입니다. 유효한 값은 다음과 같습니다.

• StageDisplayState.FULL_SCREEN AIR 응용 프로그램 또는 Flash Player의 내용이 스테이지를 사용자의 전체 화면으로 확장하도록 설정합니다. 일부 인쇄되지 않는 키를 제외하고 키보드 입력이 비활성화됩니다.
• StageDisplayState.FULL_SCREEN_INTERACTIVE: 응용 프로그램이 키보드 입력을 허용한 상태에서 사용자의 전체 화면에 걸쳐 스테이지를 확장하도록 설정합니다. (Flash Player 11.3부터는 AIR 및 Flash Player에서 사용할 수 있습니다.)
• StageDisplayState.NORMAL 스테이지를 다시 표준 스테이지 표시 모드로 설정합니다.

전체 화면 모드에서 동영상의 크기 조절 비헤이비어는 scaleMode 설정으로 결정됩니다(HTML 파일에서 Stage.scaleMode 속성 또는 SWF 파일의 embed 태그 설정을 사용하여 설정함). 응용 프로그램이 전체 화면 모드로 전환될 때 scaleMode 속성이 noScale로 설정되어 있으면 Stage의 width 및 height 속성이 업데이트되고 resize 이벤트가 전달됩니다. 그 밖의 크기 조절 모드가 설정되어 있으면 새 화면에 꽉 차게 스테이지 및 해당 내용의 크기가 조절됩니다. 스테이지 객체는 원래의 width 및 height 값을 유지하고 resize 이벤트를 전달하지 않습니다.

다음 제한 사항은 HTML 페이지 내에서 재생되는 SWF 파일(독립 실행형 Flash Player 또는 AIR 런타임을 사용하지 않는)에 적용됩니다.

• 전체 화면 모드를 활성화하려면 다음 예제와 같이 SWF 파일이 포함된 HTML 페이지에서 object 및 embed 태그에 allowFullScreen 매개 변수를 추가하고 allowFullScreen을 "true"로 설정합니다.

  <param name="allowFullScreen" value="true" />
            ...
      <embed src="example.swf" allowFullScreen="true" ... >

  또한 HTML 페이지에서 스크립트를 사용하여 SWF 포함 태그를 생성할 수 있습니다. 적절한 allowFullScreen 설정을 삽입하도록 해당 스크립트를 변경해야 합니다. Flash Professional 및 Flash Builder에서 생성된 HTML 페이지는 AC_FL_RunContent() 함수를 사용하여 SWF 파일에 대한 참조를 포함하므로 다음과 같이 allowFullScreen 매개 변수 설정을 추가해야 합니다.

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• 전체 화면 모드는 마우스 클릭이나 키 누르기에 대한 응답으로 시작되며, 동영상은 사용자 입력 없이 Stage.displayState를 변경할 수 없습니다. Flash 런타임은 전체 화면 모드에서 키보드 입력을 제한합니다. 입력할 수 있는 키에는 전체 화면 모드를 종료하는 키보드 단축키 및 인쇄되지 않는 키(예: 화살표 키, 스페이스바, Shift 키 및 Tab 키) 등이 있습니다. (전체 화면 상호 작용 모드를 사용하여 추가 키의 입력을 지원합니다.) 전체 화면 모드를 종료하는 키보드 단축키에는 Escape 키(Windows, Linux 및 Mac), Ctrl+W(Windows), Command+W(Mac) 및 Alt+F4 등이 있습니다.
• Flash Player 9.0.115.0부터는 전체 화면이 윈도우 없음 모드에서도 윈도우 모드와 같은 방식으로 작동합니다. 윈도우 모드(HTML에서 wmode)를 불투명 윈도우 없음(opaque) 또는 투명 윈도우 없음(transparent)으로 설정하면 전체 화면이 시작될 수 있지만 전체 화면 윈도우는 항상 불투명하게 됩니다.
• 키보드 대화형 기능을 지원하는 전체 화면 상호 작용 모드를 활성화하려면 다음 예제와 같이 allowFullScreenInteractive 매개 변수를 SWF 파일을 포함하는 HTML 페이지의 object 및 embed 태그에 추가하십시오(allowFullScreenInteractive를 "true"로 설정).

  <param name="allowFullScreenInteractive" value="true" />
            ...

SWF 내용을 독립 실행형 Flash Player 또는 AIR에서 실행 중인 경우에는 이러한 제한 사항이 없습니다.

전체 화면 모드를 시작하면 Flash 런타임에서 SWF 내용에 대한 알림 메시지를 짧게 표시하여 사용자에게 전체 화면 모드를 사용 중이며 Escape 키를 눌러 전체 화면 모드를 종료할 수 있음을 알립니다.

전체 화면 상호 작용 모드를 시작하면 Flash Player에서 SWF 내용에 대한 확인 메시지를 표시하여 사용자가 확장된 키보드 입력(인쇄되는 키 포함)에 대한 액세스를 허용할 수 있도록 하고, Escape 키를 눌러 전체 화면 상호 작용 모드를 종료할 수 있음을 알립니다. 확인 메시지의 모양/위치에 대해 가정해서는 안 됩니다. FullScreenEvent.FULL_SCREEN_INTERACTIVE_ACCEPTED 이벤트를 수신 대기하여 사용자가 확장된 키보드 입력에 대한 액세스를 허용했는지 확인할 수 있습니다.

전체 화면 모드로 실행 중인 AIR 내용의 경우 비디오 내용이 재생 중이면 비디오 재생을 중단하거나 전체 화면 모드를 종료할 때까지 시스템 화면 보호기 및 절전 옵션이 비활성화됩니다.

Linux에서 displayState를 StageDisplayState.FULL_SCREEN 또는 StageDisplayState.FULL_SCREEN_INTERACTIVE로 설정하는 것은 비동기 작업입니다.

관련 API 요소

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

키보드 포커스가 있는 대화형 객체입니다. 포커스가 설정되어 있지 않거나 포커스 객체가 호출하는 객체에서 액세스할 수 없는 보안 샌드박스에 속한 경우에는 null입니다.

var myTF:TextField = new TextField();
myTF.border =true;
myTF.type = TextFieldType.INPUT;

addChild(myTF);
stage.focus= myTF;

스테이지의 프레임 속도를 확인하고 설정합니다. 프레임 속도는 초당 프레임으로 정의됩니다. 기본적으로 이 속도는 로드된 첫 번째 SWF 파일의 프레임 속도로 설정됩니다. 유효한 프레임 속도 범위는 초당 0.01 ~ 1000프레임입니다.

참고: 대상 플랫폼이 충분히 빠르지 않거나 플레이어가 표시 장치의 수직 귀선소거 타이밍(보통 LCD 장치에서 60Hz)에 동기화된 경우 응용 프로그램은 높은 속도의 프레임 설정을 따라가지 못할 수 있습니다. 대상 플랫폼에서 높은 CPU 사용량이 예상되는 경우에는 최대 프레임 속도를 낮출 수도 있습니다.

Adobe AIR에서 실행 중인 내용의 경우, 한 Stage 객체의 frameRate 속성을 설정하면 다른 NativeWindow 객체에서 사용되는 모든 Stage 객체의 프레임 속도가 변경됩니다.

전체 화면 크기로 진입할 때 사용할 모니터의 높이를 반환합니다(즉시 해당 상태로 진입하는 경우). 사용자가 여러 모니터를 가진 경우 사용되는 모니터는 해당 시점에서 스테이지의 대부분이 있는 모니터입니다.

참고: 사용자가 값을 검색하는 도중에 한 모니터에서 다른 모니터로 브라우저를 이동하고 전체 화면 크기로 진입하면 값이 잘못될 수 있습니다. Stage.displayState를 StageDisplayState.FULL_SCREEN으로 설정하는 이벤트 핸들러에서 값을 검색하면 정확한 값을 얻을 수 있습니다.

이 값은 모니터의 픽셀 높이이며 Stage.align이 StageAlign.TOP_LEFT로 설정되고 Stage.scaleMode가 StageScaleMode.NO_SCALE로 설정된 경우 스테이지 높이와 동일합니다.

관련 API 요소

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

스테이지의 특정 영역을 전체 화면 모드로 확대하도록 Flash 런타임을 설정합니다. 가능한 경우, Flash 런타임은 하드웨어에서 크기가 조절됩니다. 이 경우 사용자의 컴퓨터에 장착된 그래픽 및 비디오 카드를 사용하며 일반적으로 소프트웨어로 크기를 조절할 때보다 더 빠른 속도로 내용이 표시됩니다.

이 속성이 유효한 사각형으로 설정되고 displayState 속성이 전체 화면 모드로 설정된 경우 Flash 런타임이 지정된 영역의 크기를 조절합니다. ActionScript 내에서 픽셀 단위의 실제 Stage 크기는 변경되지 않습니다. Flash 런타임은 "전체 화면 모드를 종료하려면 Esc 키를 누르십시오."라는 표준 메시지를 표시할 수 있도록 사각형의 크기에 대한 최소 제한을 적용합니다. 이 제한은 대개 약 260 x 30픽셀이지만 플랫폼과 Flash 런타임 버전에 따라 다를 수 있습니다.

이 속성은 Flash 런타임이 전체 화면 모드가 아닌 경우에만 설정할 수 있습니다. 이 속성을 정확히 사용하려면 코드 예제에 나오는 것처럼 먼저 이 속성을 설정한 다음 displayState 속성을 전체 화면 모드로 설정합니다. 참고: Flash Player 15 이상에서 이 속성은 Flash 런타임이 전체 화면 모드인 경우에도 설정할 수 있습니다.

크기 조절을 활성화하려면 fullScreenSourceRect 속성을 rectangle 객체로 설정합니다.

  
     // valid, will enable hardware scaling
     stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
     

크기 조절을 비활성화하려면 ActionScript 3.0에서는 fullScreenSourceRect=null로 설정하고 ActionScript 2.0에서는 undefined로 설정합니다.

     stage.fullScreenSourceRect = null;
     

또한 최종 사용자가 Flash Player 디스플레이 설정 내에서 기본적으로 활성화된 하드웨어적인 크기 조절을 비활성화하도록 선택할 수도 있습니다. 자세한 내용은 www.adobe.com/go/display_settings_kr을 참조하십시오.

관련 API 요소

 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

전체 화면 크기로 진입할 때 사용할 모니터의 폭을 반환합니다(즉시 해당 상태로 진입하는 경우). 사용자가 여러 모니터를 가진 경우 사용되는 모니터는 해당 시점에서 스테이지의 대부분이 있는 모니터입니다.

참고: 사용자가 값을 검색하는 도중에 한 모니터에서 다른 모니터로 브라우저를 이동하고 전체 화면 크기로 진입하면 값이 잘못될 수 있습니다. Stage.displayState를 StageDisplayState.FULL_SCREEN으로 설정하는 이벤트 핸들러에서 값을 검색하면 정확한 값을 얻을 수 있습니다.

이 값은 모니터의 픽셀 폭이며 Stage.align이 StageAlign.TOP_LEFT로 설정되고 Stage.scaleMode가 StageScaleMode.NO_SCALE로 설정된 경우의 스테이지 폭과 동일합니다.

관련 API 요소

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

표시 객체의 높이를 픽셀 단위로 나타냅니다. 높이는 표시 객체 내용의 경계에 따라 계산됩니다. 다음 코드와 같이 height 속성을 설정하면 그에 따라 scaleY 속성이 조절됩니다.

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleY) // 1;
    rect.height = 200;
    trace(rect.scaleY) // 2;

TextField 및 Video 객체를 제외하고 빈 스프라이트처럼 내용이 없는 표시 객체는 height를 다른 값으로 설정하려고 해도 높이가 0입니다.

해당 객체의 자식에서 마우스 또는 사용자 입력 장치가 사용하도록 설정되어 있는지 여부를 결정합니다. 객체가 사용하도록 설정되어 있는 경우 사용자는 마우스 또는 사용자 입력 장치를 사용하여 객체와 상호 작용할 수 있습니다. 기본값은 true입니다.

이 속성은 SimpleButton 클래스 대신 Sprite 클래스의 인스턴스를 사용하여 버튼을 만들 때 유용합니다. Sprite 인스턴스를 사용하여 버튼을 만들 때는 addChild() 메서드를 사용하여 별도의 Sprite 인스턴스를 추가함으로써 버튼을 꾸밀 수 있습니다. 이 프로세스는 마우스 이벤트의 예기치 못한 비헤이비어를 초래할 수 있습니다. 부모 인스턴스가 마우스 이벤트의 대상 객체가 될 것으로 생각하고 Sprite 인스턴스를 자식으로 추가했는데 Sprite 인스턴스가 대상 객체가 될 수 있기 때문입니다. 부모 인스턴스가 마우스 이벤트의 대상 객체가 되도록 하려면 부모 인스턴스의 mouseChildren 속성을 false로 설정합니다.

이 속성을 설정할 때 전달되는 이벤트는 없습니다. 대화형 기능을 만들려면 addEventListener() 메서드를 사용해야 합니다.

마우스 잠금을 활성화하려면 true로 설정합니다. 마우스 잠금을 활성화하면 커서가 사라지고 마우스를 제한 없이 움직일 수 있습니다. 마우스 잠금은 데스크톱 응용 프로그램의 전체 화면 모드에서만 활성화할 수 있습니다. 전체 화면 모드가 아닌 응용 프로그램이나 휴대 장치의 응용 프로그램에서 설정하면 예외가 발생합니다.

다음의 경우 마우스 잠금이 자동으로 비활성화되고 마우스 커서가 다시 표시됩니다.

• 사용자가 Esc 키(모든 플랫폼), Control-W(Windows), Command-W(Mac) 또는 Alt-F4(Windows)를 사용하여 전체 화면 모드를 종료합니다.
• 응용 프로그램 윈도우가 포커스를 잃습니다.
• 모든 개인 정보 대화 상자를 비롯한 모든 설정 UI가 표시됩니다.
• 파일 업로드 대화 상자와 같은 기본 대화 상자가 표시됩니다.

전체 화면 모드를 종료할 경우 이 속성은 자동으로 false로 설정됩니다.

마우스 이동과 연결된 이벤트(예: mouseMove 이벤트)는 MouseEvent 클래스를 사용하여 이벤트 객체를 나타냅니다. 마우스 잠금이 비활성화된 경우 MouseEvent.localX 및 MouseEvent.localY 속성을 사용하여 마우스 위치를 확인합니다. 마우스 잠금이 활성화된 경우 MouseEvent.movementX 및 MouseEvent.movementY 속성을 사용하여 마우스 위치를 확인합니다. movementX 및 movementY 속성에는 마우스 위치의 절대 좌표 대신 마지막 이벤트 이후 마우스 위치의 변경 사항이 포함됩니다.

참고: 응용 프로그램이 전체 화면 모드인 경우 Stage가 아닌 표시 객체에 연결된 마우스 이벤트 리스너는 전달되지 않습니다. 따라서 mouseLock이 true인 경우 마우스 델타 및 다른 모든 마우스 이벤트를 수신하려면 마우스 이벤트 리스너를 Stage 객체에 연결합니다.

관련 API 요소

이 Stage를 포함하는 NativeWindow 객체에 대한 참조입니다.

윈도우는 기본 운영 체제를 나타내고, Stage는 윈도우에 들어 있는 내용을 나타냅니다. 이 속성은 NativeWindow 클래스를 지원하는 플랫폼의 AIR에서 실행되는 내용에 대해서만 유효합니다. 다른 플랫폼에서 이 속성은 null이 됩니다. Flash Player(브라우저에서 실행 중인 내용)에서도 이 속성은 null입니다.

이 객체의 자식 수를 반환합니다.

스테이지의 현재 방향입니다. 이 속성은 StageOrientation 클래스에서 상수로 정의한 다음 네 개의 값 중 하나로 설정됩니다.

스테이지 방향을 설정하려면 setOrientation() 메서드를 사용합니다.

중요: 방향 속성은 2.6 네임스페이스 이상의 Android 장치에서 지원됩니다.

관련 API 요소

사용되는 렌더링 품질을 지정하는 StageQuality 클래스의 값입니다. 유효한 값은 다음과 같습니다.

• StageQuality.LOW - 낮은 렌더링 품질입니다. 그래픽이 앤티앨리어싱되지 않고 비트맵도 매끄럽게 다듬어지지 않지만 런타임은 계속 밉매핑을 사용합니다.
• StageQuality.MEDIUM - 중간 렌더링 품질입니다. 그래픽이 2 x 2 픽셀 격자를 사용하여 앤티앨리어싱되고 비트맵 매끄러움은 Bitmap.smoothing 설정에 따라 달라집니다. 런타임에서 밉매핑을 사용합니다. 이 설정은 텍스트가 포함되지 않은 동영상에 적합합니다.
• StageQuality.HIGH - 높은 렌더링 품질입니다. 그래픽이 4 x 4 픽셀 격자를 사용하여 앤티앨리어싱되고 비트맵 매끄러움은 Bitmap.smoothing 설정에 따라 달라집니다. 런타임에서 밉매핑을 사용합니다. Flash Player에서 사용하는 기본 렌더링 품질 설정입니다.
• StageQuality.BEST - 가장 높은 렌더링 품질입니다. 그래픽이 4 x 4 픽셀 격자를 사용하여 앤티앨리어싱됩니다. Bitmap.smoothing이 true일 경우 런타임은 아티팩트가 보다 적게 생성되는 높은 품질의 다운스케일 알고리즘을 사용합니다. 그러나 Bitmap.smoothing을 true로 설정한 상태로 StageQuality.BEST를 사용하면 성능이 크게 저하되므로 이 설정은 사용하지 않는 것이 좋습니다.

고품질로 설정하면 보다 나은 크기가 조절된 비트맵의 렌더링이 제공됩니다. 그러나 고품질 설정은 계산 비용이 더 높습니다. 특히 크기가 조절된 비디오를 렌더링할 경우 고품질 설정을 사용하면 프레임 속도를 줄일 수 있습니다.

BitmapData.draw() 메서드는 Stage.quality 속성의 값을 사용합니다. 아니면 Stage.quality의 현재 값을 무시하고 BitmapData.drawWithQuality() 메서드를 사용할 수도 있습니다. 이 메서드를 사용하면 quality 매개 변수를 해당 메서드에 지정할 수 있습니다.

Adobe AIR의 데스크톱 프로파일에서는 quality를 StageQuality.BEST 또는 StageQuality.HIGH(기본값은 StageQuality.HIGH)로 설정할 수 있습니다. 다른 값으로 설정할 경우 아무런 영향이 없으며 속성이 그대로 유지됩니다. AIR의 모바일 프로파일에서는 네 가지 quality 설정을 모두 사용할 수 있습니다. 휴대 장치의 기본값은 StageQuality.MEDIUM입니다.

Adobe AIR에서 실행 중인 내용의 경우, 한 Stage 객체의 quality 속성을 설정하면 다른 NativeWindow 객체에서 사용되는 모든 Stage 객체의 렌더링 품질이 변경됩니다.

관련 API 요소

사용할 크기 조절 모드를 지정하는 StageScaleMode 클래스 값입니다. 유효한 값은 다음과 같습니다.

• StageScaleMode.EXACT_FIT - 원래 종횡비를 유지하지 않고 전체 응용 프로그램을 지정된 영역에 표시합니다. 왜곡 현상이 발생할 수 있으며 응용 프로그램이 확장 또는 압축되어 보일 수 있습니다.
• StageScaleMode.SHOW_ALL - 응용 프로그램의 원래 종횡비를 유지하면서 왜곡 없이 전체 응용 프로그램을 지정된 영역에 표시합니다. 응용 프로그램의 두 면에 테두리가 표시될 수 있습니다.
• StageScaleMode.NO_BORDER - 응용 프로그램의 원래 종횡비를 유지하면서 왜곡 없이(일부는 잘릴 수 있음) 전체 응용 프로그램이 지정된 영역을 채웁니다.
• StageScaleMode.NO_SCALE - 플레이어 윈도우의 크기가 변경되는 경우에도 전체 응용 프로그램이 변경되지 않고 유지되도록 고정됩니다. 플레이어 윈도우가 내용보다 작으면 내용이 잘릴 수 있습니다.

관련 API 요소

Flash 런타임 컨텍스트 메뉴에서 기본 항목을 표시할지 또는 숨길지 여부를 지정합니다.

showDefaultContextMenu 속성이 true(기본값)로 설정된 경우 모든 컨텍스트 메뉴 항목이 나타납니다. showDefaultContextMenu 속성이 false로 설정된 경우 설정 메뉴 항목 및 정보 메뉴 항목만 표시됩니다.

현재 소프트 키보드에 의해 가려져 있는 스테이지의 영역을 지정하는 직사각형입니다. 소프트 키보드가 표시되지 않을 때 사각형의 구성 요소는 (0,0,0,0)입니다.

관련 API 요소

3차원 컨텐트를 표시하는 데 사용할 수 있는 Stage3D 객체의 목록입니다.

한 번에 사용할 수 있는 Stage3D 객체 수에 제한이 있습니다. 사용 가능한 Stage3D 객체 수는 플랫폼 및 사용 가능한 하드웨어에 따라 다릅니다.

Stage3D 객체는 StageVideo 객체 앞과 Flash 표시 목록 뒤에 그려집니다.

관련 API 요소

포커스를 받은 객체의 경계선을 광선으로 표시할지 여부를 지정합니다.

Stage의 현재 높이를 픽셀 단위로 지정합니다.

Stage.scaleMode 속성의 값이 StageScaleMode.NO_SCALE로 설정된 경우 사용자가 윈도우 크기를 조절하면 stageHeight 속성은 SWF 파일이 차지하는 스크린 영역의 새로운 높이 크기를 반영하도록 변경되는 반면 Stage 내용은 원래 크기를 유지합니다. 다른 크기 조절 모드에서 stageHeight 속성에는 항상 SWF 파일의 원래 높이가 반영됩니다. resize 이벤트에 대해 이벤트 리스너를 추가한 다음 Stage 클래스의 stageHeight 속성을 사용하여 크기 조절된 Flash 런타임 윈도우의 실제 픽셀 크기를 결정할 수 있습니다. 이벤트 리스너를 사용하면 사용자가 윈도우 크기를 조절할 때 화면 내용 조정 방식을 제어할 수 있습니다.

stageHeight 속성을 설정하면 Air for TV 장치가 데스크톱 장치와 약간 다르게 작동합니다. Stage.scaleMode 속성이 StageScaleMode.NO_SCALE로 설정되어 있을 때 stageHeight 속성을 설정하면 스테이지 높이가 SWF의 다음 프레임까지 변경되지 않습니다.

참고: SWF 파일을 호스팅하는 HTML 페이지에서 object 및 embed 태그의 height 특성은 픽셀이 아니라 백분율(예: 100%)로 설정되어야 합니다. 설정이 JavaScript 코드에서 생성되는 경우 AC_FL_RunContent() 메서드의 height 매개 변수도 백분율로 설정되어야 합니다. 이 백분율은 stageHeight 값에 적용됩니다.

관련 API 요소

외부 비디오를 재생하는 데 사용할 수 있는 StageVideo 객체의 목록입니다.

한 번에 사용할 수 있는 StageVideo 객체 수에 제한이 있습니다. SWF의 실행이 시작될 때 사용 가능한 StageVideo 객체 수가 플랫폼 및 사용 가능한 하드웨어에 따라 결정됩니다.

StageVideo 객체를 사용하려면 stageVideos Vector 객체의 멤버를 StageVideo 변수에 할당하십시오.

모든 StageVideo 객체는 스테이지에서 표시 객체 뒤에 표시됩니다. StageVideo 객체는 stageVideos Vector 객체에 나타나는 순서대로 스테이지에 표시됩니다. 예를 들어 stageVideos Vector 객체에 세 개의 항목이 있다고 가정해 보십시오.

1. stageVideos Vector 객체의 0 인덱스에 있는 StageVideo 객체는 모든 StageVideo 객체 뒤에 표시됩니다.
2. 인덱스 1의 StageVideo 객체는 인덱스 0의 StageVideo 객체 앞에 표시됩니다.
3. 인덱스 2의 StageVideo 객체는 인덱스 1의 StageVideo 객체 앞에 표시됩니다.

StageVideo.depth 속성을 사용하여 이 순서를 변경합니다.

참고: AIR for TV 장치는 StageVideo 객체를 하나만 지원합니다.

관련 API 요소

 
var stageVideo:StageVideo;

if ( stage.stageVideos.length >= 1 ) {
    stageVideo = stage.stageVideos[0];
}

Stage의 현재 폭을 픽셀 단위로 지정합니다.

Stage.scaleMode 속성의 값이 StageScaleMode.NO_SCALE로 설정된 경우 사용자가 윈도우의 크기를 조절하면 stageWidth 속성은 SWF 파일이 차지하는 스크린 영역의 새로운 폭 크기를 반영하도록 변경되는 반면 Stage 내용은 원래 정의된 크기를 유지합니다. 다른 크기 조절 모드에서 stageWidth 속성에는 항상 SWF 파일의 원래 폭이 반영됩니다. resize 이벤트에 대해 이벤트 리스너를 추가한 다음 Stage 클래스의 stageWidth 속성을 사용하여 크기 조절된 Flash 런타임 윈도우의 실제 픽셀 크기를 결정할 수 있습니다. 이벤트 리스너를 사용하면 사용자가 윈도우 크기를 조절할 때 화면 내용 조정 방식을 제어할 수 있습니다.

stageWidth 속성을 설정하면 Air for TV 장치가 데스크톱 장치와 약간 다르게 작동합니다. Stage.scaleMode 속성이 StageScaleMode.NO_SCALE로 설정되어 있을 때 stageWidth 속성을 설정하면 스테이지 폭이 SWF의 다음 프레임까지 변경되지 않습니다.

참고: SWF 파일을 호스팅하는 HTML 페이지에서 object 및 embed 태그의 width 특성은 픽셀이 아니라 백분율(예: 100%)로 설정되어야 합니다. 설정이 JavaScript 코드에서 생성되는 경우 AC_FL_RunContent() 메서드의 width 매개 변수도 백분율로 설정되어야 합니다. 이 백분율은 stageWidth 값에 적용됩니다.

관련 API 요소

현재 장치에서 지원하는 방향입니다.

이 목록에 포함된 방향 문자열을 setOrientation() 메서드의 매개 변수로 사용할 수 있습니다. 지원되지 않는 방향을 설정하는 것은 오류 없이 무효화됩니다.

설정할 수 있는 방향은 다음과 같습니다.

관련 API 요소

응용 프로그램이 스테이지 방향 및 장치 회전의 변경을 지원하는지 여부를 나타냅니다. 현재 이 속성은 휴대 장치에서 실행되는 AIR 응용 프로그램에서만 true입니다.

관련 API 요소

객체의 자식에서 탭 기능을 사용할 수 있는지 여부를 결정합니다. 객체의 자식에 대한 탭 기능을 활성화하거나 비활성화합니다. 기본값은 true입니다.

참고: Flex에서 tabChildren 속성을 사용하지 마십시오. 대신 mx.core.UIComponent.hasFocusableChildren 속성을 사용하는 것이 좋습니다.

이 DisplayObjectContainer 인스턴스에 대한 TextSnapshot 객체를 반환합니다.

이는 기본 그래픽 솔루션의 현재 vsync 상태를 나타냅니다. vsync를 활성화/비활성화할 수 있으므로 다음 VSYNC 상태를 기다리지 않고 즉시 렌더링하게 됩니다. 속성을 읽는 것은 언제라도 가능합니다. 그러나 속성을 설정하는 것은 VsyncStateChangeAvailabilityEvent가 발생한 후에만 가능합니다.

표시 객체의 폭을 픽셀 단위로 나타냅니다. 폭은 표시 객체 내용의 경계에 따라 계산됩니다. 다음 코드와 같이 width 속성을 설정하면 그에 따라 scaleX 속성이 조절됩니다.

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleX) // 1;
    rect.width = 200;
    trace(rect.scaleX) // 2;

TextField 및 Video 객체를 제외하고 빈 스프라이트처럼 내용이 없는 표시 객체는 width를 다른 값으로 설정하려고 해도 폭이 0입니다.

GPU 합성을 사용할 수 있고 사용 중인지 여부를 나타냅니다. 다음 세 가지 조건이 모두 존재하는 경우에만 wmodeGPU 값이 true입니다.

• GPU 합성이 요청되었습니다.
• GPU 합성을 사용할 수 있습니다.
• GPU 합성이 사용 중입니다.

구체적으로 설명하면, wmodeGPU 속성은 다음 중 하나를 나타냅니다.

1. GPU 합성이 요청되지 않았거나 사용할 수 없습니다. 이 경우 wmodeGPU 속성 값은 false입니다.
2. GPU 합성이 요청되었지만(해당되고 사용 가능한 경우) 내용 제한으로 인해 환경이 최적 렌더링이 아닌 "대체 모드"로 작동하고 있습니다. 이 경우 wmodeGPU 속성 값은 true입니다.
3. GPU 합성이 요청되었고(해당되고 사용 가능한 경우) 환경이 최적 모드로 작동하고 있습니다. 이 경우에도 wmodeGPU 속성 값이 true입니다.

즉, wmodeGPU 속성은 렌더링 환경의 기능과 상태를 식별합니다. GPU 합성을 지원하지 않는 AIR 1.5.2와 같은 런타임의 경우, 값이 항상 false입니다. 앞에서 언급한 대로 GPU 합성이 요청되었고 사용 가능하며 사용 중인 경우에만 값이 true이기 때문입니다.

wmodeGPU 속성은 GPU 합성이 사용 중인지 여부를 런타임에 확인하는 데 유용합니다. wmodeGPU 값은 하드웨어에 의해 내용의 크기가 조절되는지 여부를 나타내므로 그래픽을 올바른 크기로 제공할 수 있습니다. 또한 빠른 경로로 렌더링하고 있는지 여부도 확인할 수 있으므로 내용의 복잡성을 적절하게 조정할 수 있습니다.

브라우저에서 Flash Player를 사용하는 경우 SWF 파일을 호스팅하는 페이지에서 wmode HTML 매개 변수에 대한 gpu 값으로 GPU 합성을 요청할 수 있습니다. 다른 구성의 경우 SWF 파일의 헤더에서 GPU 합성을 요청할 수 있습니다(SWF 제작 도구를 사용하여 설정).

그러나 wmodeGPU 속성으로 현재 렌더링 성능을 식별하지는 못합니다. GPU 합성이 "사용 중"이더라도 렌더링 프로세스가 최적 모드로 작동하고 있지 않을 수 있습니다. 최적 렌더링을 위해 내용을 조정하려면 Flash 런타임 디버거 버전을 사용하여 mm.cfg 파일에서 DisplayGPUBlendsetting을 설정합니다.

참고: 런타임이 첫 번째 렌더링 전달을 수행하기 전에 실행되는 ActionScript에서 참조되는 경우 이 속성은 항상 false입니다. 예를 들어 Adobe Flash Professional의 프레임 1에 있는 스크립트에서 wmodeGPU를 확인하고 SWF 파일이 런타임의 새 인스턴스에서 로드된 첫 번째 SWF 파일인 경우 wmodeGPU 값은 false입니다. 정확한 값을 얻으려면 적어도 하나의 렌더링 전달이 발생할 때까지 기다리십시오. DisplayObject의 exitFrame 이벤트에 대한 이벤트 리스너를 작성할 경우 wmodeGPU 값은 올바른 값입니다.

관련 API 요소

mySprite.addEventListener(EXIT_FRAME, exithandler):

function exithandler(exiteventobject:Event):void {
                trace(stage.wmodeGPU);
}

이 DisplayObjectContainer 인스턴스에 자식 DisplayObject 인스턴스를 추가합니다. 해당 자식은 이 DisplayObjectContainer 인스턴스에 속한 다른 모든 자식의 맨 앞(위)에 추가됩니다. 특정한 인덱스 위치에 자식을 추가하려면 addChildAt() 메서드를 사용합니다.

이미 다른 표시 객체 컨테이너를 부모로 삼고 있는 자식 객체를 추가하는 경우, 그 객체는 다른 표시 객체 컨테이너의 자식 목록에서 제거됩니다.

참고: stage.addChild() 명령은 게시된 SWF 파일에 보안 문제나 로드된 다른 SWF 파일과의 충돌 등의 문제를 발생시킬 수 있습니다. Flash 런타임 인스턴스 내에는 오로지 하나의 스테이지만 있습니다. 런타임에 로드하는 SWF 파일의 수는 중요하지 않습니다. 따라서 일반적으로 스테이지에 객체를 직접 추가해서는 절대 안 됩니다. 스테이지에 포함할 수 있는 객체는 루트 객체뿐입니다. 표시 목록의 모든 항목을 포함하려면 DisplayObjectContainer를 만드십시오. 그런 다음 필요한 경우 스테이지에 DisplayObjectContainer 인스턴스를 추가합니다.

매개 변수

이 DisplayObjectContainer 인스턴스에 자식 DisplayObject 인스턴스를 추가합니다. 자식은 지정된 인덱스 위치에 추가됩니다. 인덱스 0은 이 DisplayObjectContainer 객체에 대한 표시 목록의 맨 뒤(아래)를 나타냅니다.

예를 들어 다음 예제에서는 인덱스 위치가 각각 0, 1, 2인 세 개의 표시 객체 a, b, c를 보여 줍니다.

이미 다른 표시 객체 컨테이너를 부모로 삼고 있는 자식 객체를 추가하는 경우, 그 객체는 다른 표시 객체 컨테이너의 자식 목록에서 제거됩니다.

매개 변수

리스너에서 이벤트 알림을 받을 수 있도록 EventDispatcher 객체에 이벤트 리스너 객체를 등록합니다. 표시 목록의 모든 노드에서 특정 유형의 이벤트, 단계, 우선 순위에 대한 이벤트 리스너를 등록할 수 있습니다.

이벤트 리스너의 등록을 마친 뒤에는 addEventListener()를 추가로 호출하여 그 우선 순위를 변경할 수 없습니다. 리스너의 우선 순위를 변경하려면 먼저 removeListener()를 호출해야 합니다. 그런 다음 해당 리스너를 새로운 우선 순위 레벨로 다시 등록할 수 있습니다.

일단 리스너가 등록된 뒤에 type 또는 useCapture 값을 달리하여 addEventListener()를 이어서 호출하면 별도의 리스너 등록이 생성된다는 것에 유의합니다. 예를 들어 useCapture가 true로 설정된 리스너를 등록하면 이 리스너는 캡처 단계 동안에만 수신합니다. 그러나 useCapture를 false로 설정하고 동일한 리스너 객체를 사용하여 addEventListener()를 다시 호출하면 별도로 두 개의 리스너가 등록되어, 한 리스너는 캡처 단계 동안 수신하고 다른 하나는 대상 및 버블링 단계 동안 수신합니다.

대상 단계 또는 버블링 단계 전용의 이벤트 리스너를 등록할 수는 없습니다. 버블링은 대상 노드의 조상에만 적용되기 때문에 이들 단계는 등록 과정에서 하나로 통합됩니다.

사용하지 않는 이벤트 리스너는 removeEventListener()를 호출하여 제거하도록 합니다. 이렇게 하지 않으면 메모리 문제가 발생할 수 있습니다. useWeakReference 매개 변수가 true로 설정되지 않은 경우 전달하는 객체가 있는 한, 가비지 수집기는 이벤트 리스너를 제거하지 않으므로 리스너는 메모리에서 자동으로 제거되지 않습니다.

EventDispatcher 인스턴스를 복사해도 연결된 이벤트 리스너는 복사되지 않습니다. 새로 만든 노드에 이벤트 리스너가 필요한 경우, 노드를 만든 후 리스너를 연결해야 합니다. 그러나 EventDispatcher 인스턴스를 이동할 때에는 연결된 이벤트 리스너도 함께 이동됩니다.

이벤트를 처리 중인 노드에서 이벤트 리스너를 등록하는 경우, 그 이벤트 리스너는 현재 단계 동안에는 트리거되지 않지만 이벤트 흐름에서 이후 단계(예: 버블링 단계) 동안에는 트리거될 수 있습니다.

이벤트를 처리 중인 노드에서 이벤트 리스너를 제거하는 경우, 그 리스너는 현재 액션에 의해 트리거됩니다. 일단 제거된 이벤트 리스너는 이후의 처리를 위해 재등록하지 않는 한 다시는 호출되지 않습니다.

매개 변수

function(evt:Event):void

direction 매개 변수에 의해 지정된 포커스 방향을 사용하여 objectToFocus에 의해 지정된 대화형 객체에 키보드 포커스를 설정합니다.

포커스 방향의 개념은 응용 프로그램 또는 응용 프로그램 프레임워크에 의해 정의되어야 합니다. 다른 사용 가능한 속성을 사용하여 정렬 규칙을 설정할 수 있더라도 대화형 객체를 정렬하는 기본 포커스가 없습니다. 예를 들어 대화형 객체를 Stage 또는 표시 목록에 나온 위치에 따라 정렬할 수 있습니다. 포커스가 설정되는 방향을 나타내기 위해 추가 기능을 사용하여 assignFocus()를 호출하는 것은 Stage.focus 속성을 설정하는 것과 같습니다.

objectToFocus는 포커스를 받으면 focusIn 이벤트를 전달합니다. FocusEvent 객체의 direction 속성은 direction 매개 변수의 설정을 보고합니다.

HTMLLoader 객체를 objectToFocus 매개 변수에 지정하면 이 HTMLLoader 객체는 direction 매개 변수 값에 따라 HTML DOM에서 포커스를 받을 수 있는 적당한 객체를 선택합니다. 값이 FocusDirection.BOTTOM인 경우, HTML DOM에서 포커스를 받을 수 있는 객체 중 읽기 순서의 마지막에 있는 객체가 포커스를 받게 됩니다. 값이 FocusDirection.TOP인 경우, HTML DOM에서 포커스를 받을 수 있는 객체 중 읽기 순서의 맨 처음에 있는 객체가 포커스를 받게 됩니다. 값이 NONE인 경우에는 포커스를 받는 현재 요소를 변경하지 않고 HTMLLoader 객체가 포커스를 받게 됩니다.

매개 변수

관련 API 요소

이벤트를 이벤트 흐름으로 전달합니다. 이벤트 대상은 dispatchEvent() 메서드가 호출된 EventDispatcher 객체입니다.

매개 변수

EventDispatcher 객체에 특정 유형의 이벤트에 대한 리스너가 등록되어 있는지 여부를 확인합니다. 이를 통해 이벤트 흐름 계층 구조의 어떤 지점에서 EventDispatcher 객체가 이벤트 유형 처리를 변경했는지 확인할 수 있습니다. 특정 이벤트 유형이 실제로 이벤트 리스너를 트리거하는지를 확인하려면 willTrigger()를 사용합니다.

hasEventListener()와 willTrigger() 간의 차이점은 hasEventListener()가 자신이 속한 객체만 검사하는 반면 willTrigger()는 type 매개 변수에 의해 지정된 이벤트의 전체 흐름을 검사한다는 점입니다.

LoaderInfo 객체로부터 hasEventListener()가 호출된 경우에는 해당 호출자가 액세스할 수 있는 리스너만 고려의 대상이 됩니다.

매개 변수

invalidate() 메서드를 호출하면 Flash 런타임에 신호를 보내 다음에 표시 목록을 렌더링해야 할 때(예: 재생 헤드가 새 프레임으로 진행할 때) 표시 객체에 알립니다. invalidate() 메서드를 호출한 후 다음에 표시 목록이 렌더링될 때 Flash 런타임은 render 이벤트를 수신하도록 등록된 각 표시 객체에 render 이벤트를 전송합니다. Flash 런타임에서 render 이벤트를 전송하도록 하려는 경우마다 invalidate() 메서드를 호출해야 합니다.

render 이벤트를 사용하면 표시 목록이 실제로 렌더링되기 직전에 표시 목록을 변경할 수 있습니다. 즉, 최신 변경을 적용할 때까지 표시 목록 업데이트를 연기할 수 있습니다. 이를 통해 불필요한 화면 업데이트를 제거하므로 성능이 향상될 수 있습니다.

render 이벤트는 stage.invalidate() 메서드를 호출하는 코드와 동일한 보안 도메인에 있는 표시 객체 또는 Security.allowDomain() 메서드를 통해 권한을 부여받은 보안 도메인의 표시 객체에만 전달됩니다.

관련 API 요소

Stage.focus 속성이 보안상의 이유로 null을 반환하는지 여부를 결정합니다. 즉, 포커스가 있는 객체가 SWF 파일이 액세스할 수 없는 보안 샌드박스에 속한 경우 isFocusInaccessible은 true를 반환합니다.

DisplayObjectContainer 자식 목록에서 지정된 index 위치에 있는 자식 DisplayObject를 제거합니다. 제거된 자식의 parent 속성은 null로 설정되며, 해당 자식에 대한 다른 참조가 없을 경우 객체는 가비지 수집됩니다. DisplayObjectContainer에서 해당 자식의 위쪽에 있는 모든 표시 객체의 인덱스 위치는 1씩 줄어듭니다.

가비지 수집기는 미사용 메모리 공간을 재할당합니다. 현재 변수 또는 객체가 더 이상 다른 곳에 저장되거나 참조되지 않을 때 그에 대한 다른 참조가 없으면 가비지 수집기는 해당 변수 또는 객체가 차지하는 메모리 공간을 분석하고 정리합니다.

매개 변수

지정된 종횡비를 사용하여 스테이지를 한 방향으로 설정합니다.

메서드 호출로 인해 스테이지 방향이 바뀌는 경우 Stage 객체가 orientationChange 이벤트를 전달합니다.

장치 방향이 지원되는지 알아보려면 Stage.supportsOrientantionChange 속성의 값을 확인하십시오.

AIR 프로파일 지원: 이 기능은 휴대 장치에서는 지원되지만 데스크톱 운영 체제 또는 AIR for TV 장치에서는 지원되지 않습니다. Stage.supportsOrientantionChange 속성을 사용하여 런타임에 지원을 테스트할 수 있습니다. 여러 프로파일 간 API 지원에 대한 자세한 내용은 AIR 프로파일 지원을 참조하십시오.

매개 변수

관련 API 요소

표시 객체 컨테이너에서 기존 자식의 위치를 변경합니다. 이것은 자식 객체의 계층 구성에 영향을 줍니다. 예를 들어 다음 예제에서는 인덱스 위치가 각각 0, 1, 2인 세 개의 표시 객체 a, b, c를 보여 줍니다.

setChildIndex() 메서드를 사용하여 이미 사용 중인 인덱스 위치를 지정할 때 변경되는 위치는 표시 객체의 이전 위치와 새 위치뿐입니다. 다른 모든 것들은 그대로 있습니다. 자식이 현재 인덱스보다 낮은 인덱스로 이동되면 그 사이에 있는 모든 자식의 인덱스 참조가 하나씩 늘어납니다. 자식이 현재 인덱스보다 높은 인덱스로 이동되면 그 사이에 있는 모든 자식의 인덱스 참조가 하나씩 줄어듭니다. 예를 들어 이전 예제에서 다룬 표시 객체 컨테이너의 이름이 container라면 다음 코드를 호출하여 a 표시 객체와 b 표시 객체의 위치를 맞바꿀 수 있습니다.

container.setChildIndex(container.getChildAt(1), 0);

이 코드는 객체를 다음과 같이 배열합니다.

매개 변수

스테이지를 지정된 방향으로 설정합니다.

StageOrientation 클래스에서 상수로 정의한 다음 네 개의 값 중 하나로 newOrientation 매개 변수를 설정합니다.

매개 변수를 StageOrientation.UNKNOWN으로 설정하거나 테이블에 나열된 문자열 값 이외의 값으로 설정하지 마십시오.

장치 방향 변경이 지원되는지 알아보려면 Stage.supportsOrientantionChange 속성의 값을 확인하십시오. supportedOrientations 속성이 제공하는 목록에서 현재 장치가 지원하는 방향을 확인하십시오.

방향 설정은 비동기 작업입니다. 따라서 setOrientation() 메서드를 호출한 후 바로 완료되지 않을 수도 있습니다. orientationChange 이벤트에 대한 이벤트 리스너를 추가하여 방향 변경 작업 완료 시점을 확인합니다.

중요: AIR 2.6 이전의 Android 장치에서는 setOrientation() 메서드가 지원되지 않습니다.

매개 변수

관련 API 요소

자식 목록에서 지정된 두 곳의 인덱스 위치에 있는 자식 객체의 z 순서(전후 순서)를 맞바꿉니다. 표시 객체 컨테이너에 있는 다른 모든 자식 객체의 인덱스 위치는 그대로 유지됩니다.

매개 변수

이 EventDispatcher 객체 또는 조상 객체에 지정한 이벤트 유형에 대한 이벤트 리스너가 등록되어 있는지 여부를 확인합니다. 지정된 유형의 이벤트가 이 EventDispatcher 객체나 그 자손으로 전달되었을 때 이벤트 흐름의 특정 단계에서 이벤트 리스너가 트리거되는 경우 이 메서드는 true를 반환합니다.

hasEventListener() 메서드와 willTrigger() 메서드 간의 차이점은 hasEventListener()가 자신이 속한 객체만 검사하는 반면 willTrigger() 메서드는 type 매개 변수에 의해 지정된 이벤트의 전체 이벤트 흐름을 검사한다는 점입니다.

LoaderInfo 객체로부터 willTrigger()가 호출된 경우에는 해당 호출자가 액세스할 수 있는 리스너만 고려의 대상이 됩니다.

매개 변수

Stage 객체의 browserZoomFactor 속성이 변경되었을 때 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

Stage 객체가 전체 화면 모드를 시작하거나 전체 화면 모드에서 벗어날 때 전달됩니다. 전체 화면 모드 변경은 ActionScript나 키보드 단축키를 호출하는 사용자에 의해, 또는 현재 포커스가 전체 화면 윈도우 밖으로 벗어나는 경우에 시작됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

포인터가 스테이지 영역을 벗어날 때 Stage 객체에서 전달됩니다. 마우스 버튼을 누르면 이벤트가 전달되지 않습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

스테이지 방향이 변경될 때 Stage 객체에 의해 전달됩니다.

사용자가 장치를 회전하거나 슬라이드 아웃 키보드를 열 때 또는 setAspectRatio()가 호출될 때 방향이 변경될 수 있습니다.

참고: autoOrients 속성이 false이면 장치가 회전될 때 스테이지 방향이 변경되지 않습니다. 따라서 autoOrients가 true인 경우에는 장치 회전에 대해 StageOrientationEvents만 전달됩니다.

스테이지 방향 변경이 시작될 때 Stage 객체에 의해 전달됩니다.

중요: orientationChanging 이벤트는 Android 장치에 전달되지 않습니다.

참고:

• autoOrients 속성이 false이면 장치가 회전될 때 스테이지 방향이 변경되지 않습니다. 따라서 autoOrients가 true인 경우에는 장치 회전에 대해 StageOrientationEvents만 전달됩니다.
• setOrientation() 메서드를 사용하여 프로그래밍 방식으로 방향을 설정하는 경우 orientationChanging 이벤트가 전달되지 않습니다.

Stage 객체의 scaleMode 속성이 StageScaleMode.NO_SCALE로 설정된 상태에서 SWF 파일의 크기가 조절될 때 전달됩니다. Flash Player 15 이상의 경우, 전체 화면 모드에서 화면 방향을 변경할 때도 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

stageVideos 속성의 상태가 변경될 때 Stage 객체에 의해 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}

vsync 속성의 상태가 변경될 때 Stage 객체에 의해 전달됩니다.

VsyncStateChangeAvailabilityEvent 이벤트 객체의 type 속성 값을 정의합니다.

package {
    import flash.display.Sprite;
    import flash.events.VsyncStateChangeAvailabilityEvent
    public class VsyncExample extends Sprite {
        public function VsyncExample()
        { stage.addEventListener(VsyncStateChangeAvailabilityEvent.VSYNC_STATE_CHANGE_AVAILABILITY, onVsyncStateChangeAvailability); }
        public function onVsyncStateChangeAvailability(event:VsyncStateChangeAvailabilityEvent):void
        {
            if (event.available)
            {
                // vsyncEnabled is now changeable and can be turned off.
                stage.vsyncEnabled = false; // Now, AS can change VSYNC state because event.available is true
                trace("vsyncEnabled of Stage object is changeable");
            }
            else
            {
                // vsyncEnabled is not changeable now. This could be due to fallback to software rendering, for example.
                stage.vsyncEnabled = false; // This will be ignored because event.available is now false
                trace("vsyncEnabled of Stage object is read-only");
                trace("Current value of vsyncEnabled of Stage object is "+ stage.vsyncEnabled);
            }
        }
    }
}