AccessibilityImplementation  - AS3

오류 코드를 나타냅니다. 오류가 반환 값으로 표시되는 게 아니라 범위를 벗어난 것으로 표시됩니다. 오류를 나타내려면 errno 속성을 AccessibilityImplementation 상수 부록에 나열된 오류 코드 중 하나로 설정합니다. 그러면 반환 값은 무시됩니다. AccessibilityImplementation의 errno 속성은 항상 AccessibilityImplementation 메서드가 호출되기 전에 플레이어에 의해 지워집니다(즉, 0으로 설정됨).

관련 API 요소

구성 요소 액세스 가능성 스텁을 만드는 데 사용됩니다. 구성 요소가 ActionScript 액세스 가능성 구현 없이 릴리스된 경우 구성 요소 액세스 가능성 스텁을 추가하는 것이 좋습니다. 이 스텁은 액세스 가능성을 위해 구성 요소 내의 버튼, 텍스트 필드 등의 내부 구조를 그대로 노출시키기보다는 구성 요소 자체를 하나의 단순한 그래픽으로 처리합니다.

구성 요소 액세스 가능성 스텁을 만들려면 관련 AccImpl 클래스를 하위 클래스로 만들어 true 값으로 속성 스텁을 재정의합니다.

관련 API 요소

정적 생성자입니다. 생성자를 호출하는 방식으로 직접 AccessibilityImplementation을 인스턴스화하지 말고, 새 구성 요소를 추가할 때마다 mx.accessibility.AccImpl 클래스를 확장하여 새로운 액세스 가능성 구현을 만듭니다.

관련 API 요소

AccessibilityImplementation이 나타내는 구성 요소 또는 그 자식 요소 중 하나와 연결된 기본 액션을 수행하는 IAccessible 메서드입니다.

AccessibilityImplementation이 MSAA 모델에서 기본 액션이 있는 UI 요소를 나타내는 경우에만 이 메서드를 구현하십시오.

AccessibilityImplementation 자체를 위해서만 또는 그 자식 요소를 위해서만 accDoDefaultAction()을 구현하는 경우, 상황에 따라, 이전에 전달된 특정 childID에 대한 기본 액션이 없음을 나타내야 합니다. 이를 위해서는 errno 속성을 E_MEMBERNOTFOUND로 설정합니다.

매개 변수

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

AccessibilityImplementation에서 자식 요소의 테두리 상자를 지정하는 DisplayObject 또는 Rectangle을 반환하는 MSAA 메서드입니다.

childID가 0인 경우 이 메서드가 호출되지 않습니다. AccessibilityImplementation에 자식 요소를 포함하지 않을 계획이라면 이 메서드를 구현하지 않아야 합니다. AccessibilityImplementation이 자식 요소를 포함할 수 있다면 이 메서드를 반드시 구현해야 합니다.

자식 요소 자체를 나타내는 객체를 반환하면 이 메서드의 요구 사항을 대체로 충족할 수 있습니다. 이 메서드는 자식 요소가 DisplayObject인 경우에만 유효합니다. 이러한 경우, 표시 목록에서 관련 있는 시각적 객체와 연결된 인스턴스 이름에 해당하는 DisplayObject만 반환하면 됩니다.

자식 요소가 위에서 설명한 방법에 적합하지 않다면 테두리 상자 계산을 직접 수행하여 x, y, width, height 속성이 있는 Rectangle을 반환해도 됩니다. x 및 y 멤버는 테두리 상자의 왼쪽 상단을 지정하고, width 및 height 멤버는 크기를 지정합니다. 네 개의 멤버는 모두 스테이지 픽셀 단위여야 하고 AccessibilityImplementation이 나타내는 구성 요소 원점을 기준으로 합니다. DisplayObject의 원점이 반드시 왼쪽 상단에 있을 필요가 없으므로 x 및 y 속성은 음수 값을 가질 수 있습니다.

childID로 지정한 자식 요소가 표시되지 않는 경우, 즉 해당 자식의 get_accState가 STATE_SYSTEM_INVISIBLE을 포함한 값을 반환하는 경우, accLocation에서 null을 반환할 수 있습니다. 자식 요소가 표시되는 경우 해당 좌표를 나타내는 Rectangle을 반환할 수도 있습니다.

매개 변수

추가 정보

관련 API 요소

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

AccessibilityImplementation이 나타내는 구성 요소에서 선택을 변경하는 IAccessible 메서드입니다.

childID 매개 변수는 항상 0이 아닙니다. 이 메서드는 항상 전체 구성 요소가 아닌 자식 요소에 적용됩니다. 전체 구성 요소 자체의 선택은 Flash Player가 관리합니다.

selFlag 매개 변수는 MSAA 클라이언트에서 childID가 참조하는 항목을 선택하거나 항목이 포커스를 받는 방법을 나타내는 데 사용되는 하나 이상의 선택 플래그 상수로 구성된 비트 필드입니다. 다음에서는 선택 플래그 상수와 이 상수가 액세스 가능성 구현으로 전달하는 항목을 설명합니다. 실제로 Flex mx.accessibility.ListBaseAccImpl 클래스에서 상속되는 액세스 가능성 구현에서 이 메서드를 구현할 때는 대부분 selFlag 상수를 무시하고 대신 구성 요소의 키보드 선택 동작에 의존하여 다중 선택을 처리합니다.

selFlag 매개 변수는 SELFLAG_TAKEFOCUS 플래그를 포함할 수도, 포함하지 않을 수도 있습니다. 포함하는 경우 자식 포커스를 지정된 childID로 설정하고, SELFLAG_EXTENDSELECTION도 함께 있는 경우가 아니라면 자식 요소를 선택의 기준점으로 삼습니다. 그렇지 않을 경우, 아래 설명된 추가 플래그로 인해 선택이 수정되더라도 자식 포커스와 선택 기준점은 수정되지 않아야 합니다.

selFlag 인수는 항상 다음 네 개의 플래그 중 하나를 포함하는데, 각각의 플래그는 권장되는 선택 수정 유형을 나타냅니다.

• SELFLAG_TAKESELECTION: 기존 선택을 모두 지우고 현재 선택을 지정된 childID로 설정합니다.

• SELFLAG_EXTENDSELECTION: 선택 기준점과 지정된 childID를 포함하여 그 사이에 존재하는 자식 요소의 범위를 계산합니다. SELFLAG_ADDSELECTION이 있는 경우 이러한 자식 요소를 모두 선택에 추가합니다. SELFLAG_REMOVESELECTION이 있는 경우 이러한 자식 요소를 모두 선택에서 제거합니다. SELFLAG_ADDSELECTION과 SELFLAG_REMOVESELECTION이 모두 없는 경우 이러한 자식 요소의 상태는 선택 기준점의 선택 상태와 같아야 합니다. 즉, 선택 기준점이 선택되면 이러한 자식 요소를 선택에 추가하고 그렇지 않으면 선택에서 제거해야 합니다.

• SELFLAG_ADDSELECTION(SELFLAG_EXTENDSELECTION 없음): 지정된 childID를 선택에 추가합니다.

• SELFLAG_REMOVESELECTION(SELFLAG_EXTENDSELECTION 없음): 지정된 childID를 선택에서 제거합니다.

다중 선택이 불가능한 구성 요소의 경우 selFlag 매개 변수 값으로는 SELFLAG_TAKEFOCUS와 SELFLAG_TAKESELECTION만 유효합니다. 이론적으로는 다중 선택이 불가능한 구성 요소에 SELFLAG_REMOVESELECTION을 지원하여 사용자가 null을 선택할 수 있도록 하는 것도 가능하지만, 실제로 다중 선택이 불가능한 대부분의 구성 요소는 이런 식으로 작동하지 않으며 MSAA 클라이언트도 이런 유형의 작업을 시도하지 않을 수 있습니다.

유효하지 않은 플래그가 있을 경우 errno를 E_INVALIDARG로 설정합니다.

마지막으로 유의할 점은 accSelect를 호출하면 Flash Player에서 호스트 포커스(해당 컨테이너 응용 프로그램의 창 포커스)가 있는지 그리고 구성 요소가 Flash Player 내에 포커스를 가지고 있는지 확인한다는 것입니다.

매개 변수

추가 정보

관련 API 요소

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

AccessibilityImplementation이 나타내는 구성 요소 또는 그 자식 요소 중 하나의 기본 액션을 반환하는 MSAA 메서드입니다.

AccessibilityImplementation이 MSAA 모델에서 기본 액션이 있는 UI 요소를 나타내는 경우에만 이 메서드를 구현하십시오. MSAA 모델이 지정한 정확한 문자열을 반환해야 합니다. 예를 들어 Button 구성 요소의 기본 액션 문자열은 "Press"입니다.

AccessibilityImplementation 자체를 위해서만 또는 그 자식 요소를 위해서만 get_accDefaultAction을 구현하는 경우, 상황에 따라, 이전에 전달된 특정 childID에 대한 기본 액션이 없음을 나타내야 합니다. 이를 위해서는 null을 반환하기만 하면 됩니다.

매개 변수

추가 정보

관련 API 요소

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

자식 포커스가 구성 요소 내에 있는 자식 요소의 부호 없는 정수 ID(있는 경우)를 반환하는 MSAA 메서드입니다. 자식 포커스가 있는 자식이 없을 경우 메서드는 0을 반환합니다.

추가 정보

관련 API 요소

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

AccessibilityImplementation이 나타내는 구성 요소 또는 그 자식 요소 중 하나의 이름을 반환하는 MSAA 메서드입니다.

AccessibilityImplementation 자체의 경우(childID == 0), 이 메서드를 구현하지 않거나 이 메서드가 값을 반환하지 않으면 AccessibilityProperties.name 속성 값(있는 경우)이 사용됩니다.

자식 요소를 가질 수 있는 AccessibilityImplementation의 경우 이 메서드를 반드시 구현해야 하고 childID가 0이 아닐 때 문자열 값을 반환해야 합니다.

사용자 인터페이스 요소의 유형에 따라 MSAA의 이름은 작성자가 지정한 이름 또는 요소의 실제 텍스트 내용 중 하나를 의미합니다. 일반적으로 AccessibilityImplementation 자체는 전자에 해당합니다. 즉, name 속성이 작성자가 지정한 이름입니다. 자식 요소는 항상 후자에 해당합니다. 다시 말해 자식 요소의 이름이 텍스트 내용을 나타냅니다.

AccessibilityImplementation의 name 속성에 작성자가 지정한 이름이라는 의미가 있는 경우 구성 요소는 두 가지 방법으로 작성자의 이름을 얻을 수 있습니다. 첫 번째 방법은 구성 요소 자체에 이름을 포함하는 것입니다. 예를 들어 체크 상자 구성 요소는 이름 역할을 하는 텍스트 레이블을 포함할 수 있습니다. 첫 번째 방법을 대체하는 두 번째 방법은 UI에 이름을 지정하여 AccessibilityProperties.name에 저장하는 것입니다. 이 대체 방법을 사용하면 다른 Sprite나 MovieClip의 경우처럼 이름을 지정할 수 있습니다.

두 번째 방법의 경우 AccessibilityImplementation 자체(childID == zero)에 대해 다음 세 가지가 가능합니다.

• 작성자가 지정한 이름이 구성 요소 내에 포함됩니다. get_accName 메서드는 반드시 구현해야 하고 childID가 0일 때 AccessibilityImplementation의 이름이 포함된 문자열 값을 반환해야 합니다. childID가 0이지만 AccessibilityImplementation에 이름이 없는 경우, get_accName이 빈 문자열을 반환하여 Player가 AccessibilityProperties.name 속성을 대신 사용하지 않도록 합니다.

• 작성자가 지정한 이름을 UI에서 가져옵니다. AccessibilityImplementation이 자식 요소를 가질 수 있는 경우 get_accName 메서드를 구현해야 하지만 childID가 0일 때 값을 반환해서는 안 됩니다. AccessibilityImplementation이 자식 요소를 가질 일이 없다면 get_accName을 구현하지 않아야 합니다.

• 내용을 지정하는 이름입니다. get_accName 메서드를 구현해야 하고 childID가 0일 때 적절한 문자열 값을 반환해야 합니다. childID가 0이지만 AccessibilityImplementation에 내용이 없는 경우, get_accName이 빈 문자열을 반환하여 Player가 AccessibilityProperties.name 속성을 대신 사용하지 않도록 합니다.

자식 요소의 경우(AccessibilityImplementation가 자식 요소를 가질 수 있는 경우) 세 번째 사례가 항상 적용됩니다. get_accName 메서드를 구현해야 하고 childID가 0이 아닐 때 적절한 문자열 값을 반환해야 합니다.

매개 변수

추가 정보

관련 API 요소

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

AccessibilityImplementation이 나타내는 구성 요소 또는 그 자식 요소 중 하나의 시스템 역할을 반환하는 MSAA 메서드입니다. MSAA의 모든 구성 요소의 경우 시스템 역할이 미리 정의됩니다.

매개 변수

추가 정보

관련 API 요소

선택된 모든 자식 요소의 ID가 포함된 배열을 반환하는 MSAA 메서드입니다. 반환된 배열에는 ID가 0개, 1개 또는 여러 개 있을 수 있는데 모두 부호가 없는 정수입니다.

추가 정보

관련 API 요소

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

AccessibilityImplementation이 나타내는 구성 요소 또는 그 자식 요소 중 하나의 현재 런타임 상태를 반환하는 IAccessible 메서드입니다.

이 메서드는 MSAA의 구성 요소에 대해 미리 정의된 객체 상태 상수 0개, 1개 또는 여러 개의 조합을 반환해야 합니다. 여러 상태가 적용되는 경우 bitwise OR 연산자 |를 사용하여 상태 상수를 비트 필드로 결합합니다.

현재 적용되는 상태 상수가 없음을 나타내려면 이 메서드가 0을 반환해야 합니다.

STATE_SYSTEM_FOCUSABLE 또는 STATE_SYSTEM_FOCUSED 상태를 추적하거나 보고할 필요는 없습니다. Flash Player가 이러한 상태를 자동으로 처리합니다.

매개 변수

추가 정보

관련 API 요소

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

AccessibilityImplementation이 나타내는 구성 요소 또는 그 자식 요소 중 하나의 런타임 값을 반환하는 MSAA 메서드입니다.

AccessibilityImplementation이 MSAA 모델에서 값이 있는 UI 요소를 나타내는 경우에만 이 메서드를 구현하십시오. 다만, 명백한 '값'을 가진 일부 UI 요소는 실제로 get_accName(예: 텍스트), get_accState(예: 체크 상자), get_accSelection(예: 목록 상자) 등의 여러 방법을 사용하여 이 값을 노출합니다.

AccessibilityImplementation 자체를 위해서만 또는 그 자식 요소를 위해서만 get_accValue를 구현하는 경우, 상황에 따라, 이전에 전달된 특정 childID에 대한 값 개념이 없음을 나타내야 합니다. 이를 위해서는 null을 반환하기만 하면 됩니다.

매개 변수

추가 정보

관련 API 요소

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

AccessibilityImplementation의 자식 요소 중 부호 없는 정수 ID를 포함하는 배열을 반환합니다.

배열의 길이는 0일 수 있습니다. 배열의 ID는 각 ID가 나타내는 자식 요소와 동일한 논리 순서로 나타나야 합니다. AccessibilityImplementation이 자식 요소를 포함할 수 있다면 이 메서드를 반드시 구현해야 합니다. 포함할 수 없는 경우에는 메서드를 구현하지 마십시오.

자식 ID를 자식 요소에 할당할 때 AccessibilityImplementation의 각 인스턴스 내에서 고유성을 유지하는 체계를 사용합니다. 자식 ID는 연속적이지 않아도 되고 순서를 자식 요소의 논리 순서와 일치시킬 필요도 없습니다. 자식 ID를 다시 사용하지 않도록 배열해야 합니다. 다시 말해 자식 요소가 삭제되더라도 AccessibilityImplementation 인스턴스가 유지되는 동안에는 해당 ID를 다시 사용하지 않아야 합니다. 주의할 점은 Flash Player 코드의 구현 옵션들로 인해 백만이 넘는 자식 ID를 사용할 경우 이상한 동작이 나타날 수 있다는 것입니다.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

x, y, 폭, 높이로 지정된 테두리 상자가 있는 텍스트 객체를 AccessibilityImplementation이 나타내는 구성 요소의 레이블로 간주해야 하는지 표시하기 위해 true 또는 false를 반환합니다.

x 및 y 좌표는 AccessibilityImplementation이 적용되는 구성 요소의 왼쪽 상단을 기준으로 하며 음수가 될 수 있습니다. 모든 좌표는 스테이지 픽셀 단위여야 합니다.

이 메서드를 사용하면 액세스 가능 구성 요소가 Flash Player의 자동 레이블 관계 검색에 들어맞게 되므로 객체 외부의 텍스트가 객체의 이름을 제공할 수 있습니다. 이 메서드가 제공되는 이유는 레이블을 인식하는 기준이 구성 요소마다 다를 것으로 예상되기 때문입니다. 이 메서드를 구현할 경우 플레이어 코드 내에서 버튼과 텍스트 필드에 사용되는 것과 유사한 기하학적 기준을 사용하는 데 목표를 두어야 합니다. 이러한 기준은 다음과 같습니다.

• 버튼의 경우, 버튼 안에 완전히 들어가는 모든 텍스트를 레이블로 간주합니다.
• 텍스트 필드의 경우, 위쪽 가까이에 왼쪽으로 정렬되어 나타나거나 왼쪽 가까이에 나타나는 모든 텍스트를 레이블로 간주합니다.

AccessibilityImplementation이 나타내는 구성 요소가 자동 레이블 지정 관계에 관여해서는 안 되는 경우 isLabeledBy를 구현하지 마십시오. 이는 항상 false를 반환하는 것과 같습니다. isLabeledBy를 구현하지 않아야 하는 예로는 앞서 get_accName 부분에서 설명한 것처럼 AccessibilityImplementation이 "구성 요소 내의 작성자 지정 이름"에 해당하는 경우를 들 수 있습니다.

다만, 이 메서드는 IAccessible 메서드에 기반을 둔 게 아니고 Flash에만 해당한다는 점에 유의해야 합니다.

매개 변수