String  - AS3

지정된 String 객체의 문자 수를 지정하는 정수입니다.

모든 문자열 인덱스는 0부터 시작하기 때문에 임의의 문자열 x에 대한 마지막 문자의 인덱스는 x.length - 1입니다.

지정된 문자열로 초기화된 새 String 객체를 만듭니다.

참고: 문자열 리터럴이 String 객체보다 오버헤드를 적게 사용하고 일반적으로 보다 간편하므로 특별히 문자열 리터럴이 아닌 String 객체를 사용해야 하는 경우가 아니면 String 클래스 대신 문자열 리터럴을 사용하는 것이 좋습니다.

index 매개 변수에 지정된 위치의 문자를 반환합니다. index가 0에서 string.length - 1 사이의 숫자가 아니면 빈 문자열이 반환됩니다.

이 메서드는 반환 값이 16비트 정수 문자 코드가 아닌 문자라는 것을 제외하면 String.charCodeAt()과 유사합니다.

매개 변수

관련 API 요소

지정된 index에 있는 문자의 유니코드 문자 코드를 숫자로 반환합니다. index가 0에서 string.length - 1 사이의 숫자가 아니면 NaN이 반환됩니다.

이 메서드는 반환 값이 실제 문자가 아니라 16비트 정수 문자 코드라는 것을 제외하면 String.charAt()과 유사합니다.

매개 변수

관련 API 요소

String 객체 끝에 지정된 인수를 추가하고 필요한 경우 문자열로 변환한 다음 결과 문자열을 반환합니다. 소스 String 객체의 원래 값은 그대로 유지됩니다.

매개 변수

매개 변수의 유니코드 문자 코드가 나타내는 문자로 구성된 문자열을 반환합니다.

매개 변수

문자열을 검색하여 val이 처음 발견된 위치 또는 호출 문자열 내의 startIndex 다음 위치를 반환합니다. 이 인덱스는 0부터 시작하므로 문자열의 첫 번째 문자는 인덱스 1이 아니라 인덱스 0입니다. val이 발견되지 않으면 -1이 반환됩니다.

매개 변수

관련 API 요소

문자열을 오른쪽에서 왼쪽으로 검색하고 startIndex 앞에서 val이 마지막으로 나타난 인덱스를 반환합니다. 이 인덱스는 0부터 시작하므로 첫 번째 문자의 인덱스는 0이고 마지막 문자의 인덱스는 string.length - 1입니다. val이 없으면 메서드는 -1을 반환합니다.

매개 변수

관련 API 요소

둘 이상의 문자열에 대한 정렬 순서를 비교하고 비교 결과를 정수로 반환합니다. 이 메서드는 비교를 로캘별로 처리하기 위한 메서드이지만 ActionScript 3.0 구현에서는 equality(==) 또는 inequality(!=) 연산자 등의 기타 문자열 비교와 결과가 같습니다. 문자열이 동일한 경우 반환 값은 0입니다. 원래 문자열 값이 other에 지정된 문자열 값보다 앞서는 경우 반환 값은 음의 정수이고 이 값의 절대값은 두 문자열 값에서 서로 다른 문자 수를 나타냅니다. 원래 문자열 값이 other보다 뒤에 나오는 경우 반환 값은 양의 정수이고 이 값의 절대값은 두 문자열 값에서 서로 다른 문자 수를 나타냅니다.

매개 변수

문자열을 지정된 pattern과 비교합니다.

매개 변수

관련 API 요소

문자열을 지정된 pattern과 비교하고 pattern의 첫 번째 일치 항목을 repl에 지정된 내용으로 바꾼 새 문자열을 반환합니다. pattern 매개 변수는 문자열이거나 일반 표현식이 될 수 있습니다. repl 매개 변수는 문자열이거나 함수가 될 수 있습니다. 이 매개 변수가 함수이면 함수를 통해 반환되는 문자열이 일치 항목 대신 삽입됩니다. 원래 문자열은 수정되지 않습니다.

다음 예제에서는 대/소문자가 구분되어 "sh"의 첫 번째 인스턴스만 바뀝니다.

    var myPattern:RegExp = /sh/;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seashore.

다음 예제에서는 일반 표현식에 g(global) 플래그가 설정되어 있으므로 대/소문자가 구분되어 "sh"의 모든 인스턴스가 바뀝니다.

    var myPattern:RegExp = /sh/g;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seaschore.

다음 예제에서는 일반 표현식에 g(global) 플래그가 설정되어 있으므로 "sh"의 모든 인스턴스가 바뀝니다. 이때 i(ignoreCase) 플래그가 설정되어 있으므로 일치 항목의 대/소문자가 구분되지 않습니다.

    var myPattern:RegExp = /sh/gi;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // sche sells seaschells by the seaschore.

매개 변수

var str:String = "flip-flop";
    var pattern:RegExp = /(\w+)-(\w+)/g;
    trace(str.replace(pattern, "$2-$1")); // flop-flip

    var str1:String = "abc12 def34";
    var pattern:RegExp = /([a-z]+)([0-9]+)/;
    var str2:String = str1.replace(pattern, replFN);
    trace (str2);   // 12abc 34def
    
    function replFN():String {
      return arguments[2] + arguments[1];
    }

    {"abc12", "abc", "12", 0, "abc12 def34"}

    {"def34", "def", "34", 6, "abc123 def34"}

관련 API 요소

지정된 pattern을 검색하고 일치하는 첫 번째 하위 문자열의 인덱스를 반환합니다. 일치하는 하위 문자열이 없으면 -1이 반환됩니다.

매개 변수

관련 API 요소

startIndex 문자부터 endIndex 문자 바로 앞까지 모든 문자가 포함된 문자열을 반환합니다. 원래의 String 객체는 수정되지 않습니다. endIndex 매개 변수를 지정하지 않으면 하위 문자열의 끝이 문자열 끝이 됩니다. startIndex에 있는 문자가 endIndex에 있는 문자와 동일하거나 오른쪽에 있으면 빈 문자열이 반환됩니다.

매개 변수

관련 API 요소

지정된 delimiter 매개 변수가 나타나는 모든 위치에서 String 객체를 하위 문자열 배열로 분할합니다.

delimiter 매개 변수가 일반 표현식이면 역추적을 통해 해당 위치에서 비어 있지 않은 하위 문자열 일치 항목을 찾을 수 있더라도 문자열의 지정된 위치에서 일치하는 첫 번째 항목만 고려됩니다. 예를 들면 다음과 같습니다.

     var str:String = "ab";
     var results:Array = str.split(/a*?/); // results == ["","b"]
     
     results = str.split(/a*/); // results == ["","b"].)

delimiter 매개 변수가 그룹 괄호를 포함한 일반 표현식인 경우 delimiter가 일치할 때마다 모든 정의되지 않은 결과를 비롯한 그룹 괄호의 결과가 출력 배열로 연결됩니다. 예를 들면 다음과 같습니다.

     var str:String = "Thi5 is a tricky-66 example.";
     var re:RegExp = /(\d+)/;
     var results:Array = str.split(re);
         // results == ["Thi","5"," is a tricky-","66"," example."]

limit 매개 변수가 지정된 경우 반환되는 배열에는 지정된 수보다 많은 요소가 포함되지 않습니다.

delimiter가 빈 문자열, 빈 일반 표현식 또는 빈 문자열과 일치하는 일반 표현식인 경우 문자열의 각 문자가 배열 요소로 출력됩니다.

delimiter 매개 변수가 정의되어 있지 않으면 문자열 전체가 반환된 배열의 첫 번째 요소에 놓입니다.

매개 변수

관련 API 요소

지정된 startIndex에서 시작하여 len에 지정된 길이의 문자로 구성된 하위 문자열을 반환합니다. 원래 문자열은 수정되지 않습니다.

매개 변수

startIndex에서 endIndex - 1 사이의 모든 문자로 구성된 문자열을 반환합니다. endIndex를 지정하지 않으면 String.length가 사용됩니다. startIndex의 값이 endIndex의 값과 같으면 빈 문자열이 반환됩니다. startIndex의 값이 endIndex의 값보다 크면 매개 변수가 자동으로 교체된 후 함수가 실행됩니다. 원래 문자열은 수정되지 않습니다.

매개 변수

이 문자열의 모든 대문자를 소문자로 변환한 복사본을 반환합니다. 원래 문자열은 수정되지 않습니다. 이 메서드는 변환을 로캘별로 처리하기 위한 것이지만 ActionScript 3.0 구현에서는 toLowerCase() 메서드와 결과가 같습니다.

관련 API 요소

이 문자열의 모든 소문자를 대문자로 변환한 복사본을 반환합니다. 원래 문자열은 수정되지 않습니다. 이 메서드는 변환을 로캘별로 처리하기 위한 것이지만 ActionScript 3.0 구현에서는 toUpperCase() 메서드와 결과가 같습니다.

관련 API 요소

이 문자열의 모든 대문자를 소문자로 변환한 복사본을 반환합니다. 원래 문자열은 수정되지 않습니다.

이 메서드는 A에서 Z뿐만 아니라 해당 유니코드 소문자가 있는 모든 문자를 변환합니다.

     var str:String = " JOSÉ BARÇA";
     trace(str.toLowerCase()); // josé barça

이러한 대/소문자 매핑은 유니코드 문자 데이터베이스 사양에 정의되어 있습니다.

관련 API 요소

이 문자열의 모든 소문자를 대문자로 변환한 복사본을 반환합니다. 원래 문자열은 수정되지 않습니다.

이 메서드는 a에서 z뿐만 아니라 해당 유니코드 대문자가 있는 모든 문자를 변환합니다.

     var str:String = "José Barça";
     trace(str.toUpperCase()); // JOSÉ BARÇA

이러한 대/소문자 매핑은 유니코드 문자 데이터베이스 사양에 정의되어 있습니다.

관련 API 요소

String 인스턴스의 프리미티브 값을 반환합니다. 이 메서드는 String 객체를 프리미티브 문자열 값으로 변환하기 위한 것입니다. Flash 런타임에서는 필요한 경우 valueOf()를 자동으로 호출하므로 이 메서드를 명시적으로 호출할 필요가 거의 없습니다.

1. StringExample의 생성자에서 로컬 String 인스턴스를 여러 개 선언합니다. 각 인스턴스는 다양한 문자열 및 새 StringHelper 객체를 사용하여 초기화됩니다.
2. StringHelper 클래스에는 다음 메서드가 있습니다.
   • replace(): String의 split() 및 join() 메서드를 호출하여 메서드에 전달된 문자열의 하위 문자열을 새 문자열로 바꿉니다.
   • trim(): 전달된 문자열을 사용하여 trimBack() 및 trimFront() 메서드를 모두 호출하고 업데이트된 문자열을 반환합니다.
   • trimFront(): char 매개 변수와 일치하는 모든 문자를 재귀적으로 제거합니다. 문자열의 맨 앞에서 끝으로 진행하면서 문자열의 첫 번째 문자가 char와 일치하지 않을 때까지 작업을 계속한 다음 업데이트된 문자열을 반환합니다.
   • trimBack(): char 매개 변수와 일치하는 모든 문자를 재귀적으로 제거합니다. 문자열의 맨 끝에서 앞으로 진행하면서 문자열의 마지막 문자가 char와 일치하지 않을 때까지 작업을 계속한 다음 업데이트된 문자열을 반환합니다.
   • stringToCharacter(): 전달된 문자열의 첫 번째 문자를 반환합니다.
3. 그런 다음 선언된 문자열 변수를 사용하여 세 개의 문자열을 생성합니다. 두 번째 문자열을 생성하는 데는 replace() 메서드를 호출하고 세 번째 문자열을 생성하는 데는 trim()을 호출합니다.

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}