int  - AS3

새 int 객체를 만드는 생성자입니다. int.toString() 및 int.valueOf()를 사용할 때는 int 생성자를 사용해야 합니다. int 객체의 속성을 사용할 때는 생성자를 사용하지 않습니다. new int 생성자는 기본적으로 자리 표시자로 사용됩니다. int 객체는 매개 변수를 프리미티브 값으로 변환하는 int() 함수와 다릅니다.

관련 API 요소

	 var n1:int = new int(3.4);
	 var n2:int = new int(-10);
	 

숫자를 지수 표기법으로 표현한 문자열을 반환합니다. 문자열의 소수점 앞에는 한 자리 숫자가 포함되고 소수점 뒤에는 fractionDigits 매개 변수에 지정된 최대 20자리의 숫자가 포함됩니다.

매개 변수

var num:Number = 315003;
trace(num.toExponential(2)); // 3.15e+5

숫자를 고정 소수점 표기법으로 표현한 문자열을 반환합니다. 고정 소수점 표기법을 사용하면 문자열에서 소수점 뒤에 fractionDigits 매개 변수에 지정된 특정 자릿수가 포함됩니다. fractionDigits 매개 변수의 유효한 범위는 0에서 20 사이이며 이 범위를 벗어난 값을 지정하면 예외가 발생합니다.

매개 변수

var num:Number = 7.31343;
trace(num.toFixed(3)); // 7.313

var num:Number = 4;
trace(num.toFixed(2)); // 4.00

숫자를 지수 표기법 또는 고정 소수점 표기법으로 표현한 문자열을 반환합니다. 문자열에는 precision 매개 변수에 지정된 자릿수가 포함됩니다.

매개 변수

var num:Number = 31.570;
trace(num.toPrecision(3)); // 31.6

var num:Number = 4000;
trace(num.toPrecision(3)); // 4.00e+3

int 객체의 문자열 표현을 반환합니다.

매개 변수

	 var myint:int = new int(9);
	 trace(myint.toString(2)); // 1001
	 trace(myint.toString(8)); // 11
	 

다음 예제의 결과는 16진수 값입니다.

	 var r:int = new int(250);
	 var g:int = new int(128);
	 var b:int = new int(114);
	 var rgb:String = "0x"+ r.toString(16)+g.toString(16)+b.toString(16);
	 trace(rgb); // 0xfa8072
	 

지정된 int 객체의 프리미티브 값을 반환합니다.

	 var numSocks:int = new int(2);
	 trace(numSocks.valueOf()); // 2
	 

표현할 수 있는 가장 큰 부호 있는 32비트 정수인 2,147,483,647입니다.

	trace("int.MIN_VALUE = "+int.MIN_VALUE);
	trace("int.MAX_VALUE = "+int.MAX_VALUE);
	

이 코드는 다음 값을 표시합니다.

	int.MIN_VALUE = -2147483648
	int.MAX_VALUE = 2147483647
	

표현할 수 있는 가장 작은 부호 있는 32비트 정수인 -2,147,483,648입니다.

     trace("int.MIN_VALUE = "+int.MIN_VALUE);
     trace("int.MAX_VALUE = "+int.MAX_VALUE);
     

이 코드는 다음 값을 표시합니다.

	int.MIN_VALUE = -2147483648
	int.MAX_VALUE = 2147483647
     

1. 생성자에서 a와 b라는 두 개의 int 변수를 선언합니다.
2. addIntegers() 메서드를 사용하여 두 int 변수를 더합니다.
3. parseInteger()의 결과를 세 번째 int 변수인 c에 할당합니다. 이 메서드는 전달된 문자열의 유효성을 검사하여 int 데이터 유형의 허용 범위에 포함된 정수 값인지 확인하고 문자열이 유효하면 정수 값에 해당하는 int를 반환합니다.
4. addIntegers()를 사용하여 int 변수 a와 c를 더합니다.

package {
    import flash.display.Sprite;

    public class IntExample extends Sprite {    
        public function IntExample() {
            var a:int = 512;
            var b:int = -128;
            
            trace(addIntegers(a, b)); // 384

            var c:int = parseInteger("32");
            
            trace(addIntegers(a, c)); // 544
        }
            
        public function addIntegers(a:int, b:int):int {
            return a + b;
        }
        
        public function parseInteger(str:String):int {
            var num:Number = parseInt(str);
            if(!isNaN(num) && num <= int.MAX_VALUE && num >= int.MIN_VALUE) {
                return int(num);
            }
            
            return 0;
        }
        
    }
}