NativeWindow  - AS3

이 윈도우가 활성 응용 프로그램 윈도우인지 여부를 나타냅니다.

activate() 메서드를 사용하여 윈도우를 활성화시킬 수 있습니다.

관련 API 요소

이 윈도우가 항상 다른 윈도우(다른 응용 프로그램의 윈도우 포함)의 앞에 오도록 할지 여부를 지정합니다.

시스템 심도 순서에는 두 가지 그룹의 윈도우가 있습니다. alwaysInFront 그룹의 윈도우는 항상 다른 모든 윈도우의 앞에 표시됩니다. 동일한 그룹에 있는 윈도우 사이의 심도 순서는 일반적으로 결정됩니다. 즉, 윈도우를 활성화하면 해당 그룹의 다른 윈도우 앞에 활성화한 윈도우가 표시됩니다.

alwaysInFront를 false에서 true로 변경하면 윈도우가 다른 윈도우의 맨 위에 표시됩니다. 속성을 true에서 false로 변경하면 윈도우를 "alwaysInFront" 윈도우의 뒤로 보내지만 여전히 다른 윈도우의 앞에 표시됩니다. 속성을 현재 값으로 설정하면 윈도우 심도 순서는 변경되지 않습니다. 소유자가 있는 윈도우의 alwaysInFront 속성을 설정하더라도 아무런 영향을 주지 않습니다.

alwaysInFront 속성은 되도록 true로 설정하지 않아야 합니다. 이렇게 설정된 윈도우는 다른 응용 프로그램이 활성화된 경우에도 다른 응용 프로그램 윈도우 앞에 표시되기 때문입니다.

OS 비헤이비어 참고 사항:

• 일부 Linux 윈도우 관리자에서는 alwaysInFront 속성이 전체 화면 윈도우 앞에 설정된 윈도우를 표시하지 않습니다.
• 참고: Mac^® OS X에서 alwaysInFront를 true로 설정한 경우 윈도우 스테이지의 displayState 속성이 fullScreen 또는 fullScreenInteractive이면 아무런 영향이 없습니다.

windowObj.alwaysInFront = true;

displayObject.stage.nativeWindow.alwaysInFront=true;

window.nativeWindow.alwaysInFront = true;

이 윈도우의 크기 및 위치입니다.

윈도우 크기에는 모든 시스템 크롬이 포함됩니다. 윈도우 스테이지의 크기는 윈도우 크기에 모든 시스템 크롬을 뺀 것과 같습니다. 윈도우의 폭과 높이를 변경하면 스테이지의 stageWidth 및 stageHeight도 변경됩니다. 이와 반대로도 적용되어 스테이지 크기를 변경하면 윈도우의 크기도 변경됩니다.

루트 HTML 윈도우에서 outerWidth 및 outerHeight 속성은 윈도우 height 및 width 속성에 해당합니다. innerWidth 및 innerHeight 속성은 stage.stageWidth 및 stage.stageHeight 속성에서 윈도우에 표시된 자동 스크롤 막대의 두께를 뺀 것과 같습니다.

resize 이벤트는 이 윈도우의 폭이나 높이가 변경될 때마다 전달됩니다. 이와 마찬가지로 move 이벤트는 이 윈도우의 원점(x,y)이 변경될 때마다 전달됩니다. Mac OS 및 Windows에서 bounds 속성을 직접 설정하면 moving 또는 resizing 이벤트가 전달되지 않습니다. 그러나 Linux에서 NativeWindow는 bounds 속성을 설정할 때 moving 및 resizing 이벤트를 전달합니다.

윈도우의 bounds 속성을 설정하는 것은 윈도우의 x, y, width 및 height 속성을 설정하는 것과 같습니다. 이와 마찬가지로 개별 크기를 설정하는 것은 bounds 속성을 설정하는 것과 같습니다. bounds 속성을 사용하여 동시에 모든 크기를 설정하면 전달되는 이벤트가 적어집니다.

개별 크기가 설정되는 순서는 확실하지 않습니다. 윈도우가 데스크톱 영역을 벗어나 확장될 수 없는 Linux 윈도우 관리자에서 속성 변경 사항을 모두 적용한 결과가 유효한 윈도우로 나타나더라도 개별 속성 변경 작업이 차단될 수 있습니다.

지정된 폭 또는 높이가 허용되는 폭 또는 높이의 최소값보다 작거나 최대값보다 크면 윈도우 폭 또는 높이가 유효한 크기에 가장 가까운 값으로 설정됩니다. 폭 및 높이의 최소값과 최대값을 결정하는 요소는 다음과 같습니다.

• NativeWindow 객체의 minSize 및 maxSize 속성
• 운영 체제의 최소 및 최대 제한 값, 즉 NativeWindow.systemMinSize 및 NativeWindow.systemMaxSize 값
• Adobe AIR 윈도우의 최대 폭 및 높이(각각 4095픽셀). AIR 1.5 이전 버전에서는 윈도우의 최대 폭과 높이가 각각 2880픽셀입니다.
• 표시된 시스템 크롬에 필요한 최소 폭 및 높이

윈도우 위치나 크기가 변경될 경우 픽셀 값은 가장 가까운 정수로 반올림됩니다.

관련 API 요소

windowObj.bounds = new Rectangle(200, 200, 1000, 800);

displayObject.stage.nativeWindow.bounds = new Rectangle(20, 20, 800, 600);

window.nativeWindow.bounds = new air.Rectangle(20, 20, 800, 600);

이 윈도우가 닫혔는지 여부를 나타냅니다.

닫힌 윈도우에 대해 다음 속성에 액세스하면 잘못된 작업 오류가 발생합니다.

• title
• bounds
• x, y, width, height
• displayState
• visible

이와 마찬가지로 닫힌 윈도우에 대해 다음 메서드를 호출하면 잘못된 작업 오류가 발생합니다.

• minimize()
• maximize()
• restore()
• startResize()
• startMove()

var isWindowClosed:Boolean = windowObj.closed;

var isWindowClosed:Boolean = displayObject.stage.nativeWindow.closed;

var isWindowClosed = window.nativeWindow.closed;

이 윈도우의 표시 상태입니다.

사용 가능한 값을 위한 상수는 NativeWindowDisplayState 클래스에서 정의됩니다.

• NativeWindowDisplayState.NORMAL
• NativeWindowDisplayState.MINIMIZED
• NativeWindowDisplayState.MAXIMIZED

관련 API 요소

var state:String = windowObj.displayState;

이 윈도우의 높이(픽셀)입니다.

윈도우 크기에는 표시되는 모든 시스템 윈도우 크롬이 포함됩니다. 윈도우 안에 있는 사용 가능한 표시 영역의 높이는 Stage.stageHeight 속성에서 사용할 수 있습니다.

윈도우의 height 속성을 변경하는 것은 bounds 속성을 통해 높이를 변경하는 것과 같습니다.

지정된 높이가 허용된 높이의 최소값보다 작거나 최대값보다 크면 윈도우 높이가 유효한 크기에 가장 가까운 값으로 설정됩니다. 높이의 최소값과 최대값을 결정하는 요소는 다음과 같습니다.

• NativeWindow 객체의 minSize.x 및 maxSize.x 속성
• 운영 체제의 최소 및 최대 제한, 즉 NativeWindow.systemMinSize.x 및 NativeWindow.systemMaxSize.x 값
• Adobe AIR에서 윈도우의 최대 높이(4095픽셀)를 나타냅니다. AIR 1.5 이전에서는 2880픽셀입니다.

Linux에서 height 속성을 설정하는 것은 비동기 작업입니다.

높이 변경이 완료되는 것을 감지하려면 모든 플랫폼에서 전달되는 resize 이벤트를 수신합니다.

윈도우 높이가 변경될 경우 픽셀 값은 가장 가까운 정수로 반올림됩니다.

관련 API 요소

클라이언트 시스템에서 기본 윈도우가 지원되는지 여부를 나타냅니다.

이 윈도우를 만드는 데 사용된 최대화 가능 설정을 보고합니다.

윈도우를 만든 후에는 maximizable 설정을 변경할 수 없습니다.

참고: 일부 Linux 윈도우 관리자에서는 maximizable 속성이 false로 설정된 경우에도 사용자가 윈도우를 최대화할 수 있습니다.

관련 API 요소

이 윈도우의 최대 크기입니다.

크기 제한은 Point 객체의 좌표로 지정됩니다. 점 x 속성은 윈도우 폭에 해당하고 y 속성은 윈도우 높이에 해당합니다.

maxSize 제한은 ActionScript 코드 및 운영 체제 모두를 통해 호출된 윈도우 크기 조절 작업에 적용됩니다.

maxSize를 설정하면 현재 경계가 새로운 최대 크기보다 클 경우 윈도우 경계가 변경됩니다.

지정된 폭 또는 높이가 허용되는 폭 또는 높이의 최대값보다 크면 윈도우 폭이 유효한 크기에 가장 가까운 값으로 설정됩니다. 폭 및 높이의 최소값과 최대값을 결정하는 요소는 다음과 같습니다.

• 운영 체제의 최대 제한(NativeWindow.systemMaxSize 값)
• Adobe AIR 윈도우의 최대 폭 및 높이(각각 4095픽셀). AIR 1.5 이전 버전에서는 윈도우의 최대 폭과 높이가 각각 2880픽셀입니다.

참고: Mac OS X와 같은 일부 운영 체제에서 윈도우를 최대화하면 최대화된 윈도우가 운영 체제 화면보다 작더라도 maxSize 값까지만 윈도우를 확대할 수 있습니다. 윈도우는 최대화된 표시 상태를 계속 유지합니다.

관련 API 요소

windowObj.maxSize = new Point(1040,920);

displayObject.stage.nativeWindow.maxSize = new Point(800,600);

window.nativeWindow.maxSize = new air.Point(960,960);

윈도우의 기본 메뉴입니다.

NativeMenu 객체가 윈도우 menu 속성에 지정되면 윈도우 systemChrome 속성이 NativeWindowSystemChrome.NONE이 아닌 경우에 NativeWindow.supportsMenu가 true이면 윈도우에 기본 메뉴가 표시됩니다.

참고: NativeWindow.supportsMenu가 false이거나 윈도우 systemChrome 속성이 NativeWindowSystemChrome.NONE일 때 윈도우에 메뉴를 지정할 수 있지만 아무런 작업이 수행되지 않습니다. NativeWindow.supportsMenu 속성을 사용하여 운영 체제가 윈도우 메뉴를 지원하는지 여부를 확인하십시오. Capabilities.os 등의 다른 방법을 사용하여 지원 여부를 확인할 경우 프로그래밍 오류가 발생할 수 있습니다(일부 가능한 대상 운영 체제가 고려되지 않는 경우).

관련 API 요소

이 윈도우를 만드는 데 사용된 최소화 가능 설정을 보고합니다.

윈도우를 만든 후에는 minimizable 설정을 변경할 수 없습니다.

참고: 일부 Linux 윈도우 관리자에서는 minimizable 속성이 false로 설정된 경우에도 사용자가 윈도우를 최소화할 수 있습니다.

관련 API 요소

이 윈도우의 최소 크기입니다.

크기 제한은 Point 객체의 좌표로 지정됩니다. 점 x 속성은 윈도우 폭에 해당하고 y 속성은 윈도우 높이에 해당합니다.

minSize를 설정하면 현재 경계가 새로운 최소 크기보다 작을 경우 윈도우 경계가 변경됩니다.

minSize 제한은 ActionScript 코드 및 운영 체제 모두를 통해 호출된 윈도우 크기 조절 작업에 적용됩니다.

참고: 모든 표시된 시스템 크롬의 폭과 높이로는 윈도우를 지정된 최소 크기만큼 작게 설정하지 못할 수도 있습니다.

관련 API 요소

windowObj.minSize = new Point(200,80);

displayObject.stage.nativeWindow.minSize = new Point(120,60);

window.nativeWindow.minSize = new air.Point(80,60);

이 윈도우를 소유하는 NativeWindow 객체입니다.

윈도우가 만들어질 때 윈도우 소유권이 설정되었으며 이를 변경할 수 없습니다. 소유자가 있는 윈도우를 만들려면 소유하는 NativeWindow 객체를 소속 윈도우를 만드는 데 사용되는 NativeWindowInitOptions 객체의 owner 속성으로 설정합니다.

참고: Linux의 경우 일부 윈도우 관리자는 소유자 윈도우가 전체 화면 모드일 때 소속 윈도우를 소유자 앞에 표시하지 않습니다.

관련 API 요소

이 윈도우를 만드는 데 사용된 윈도우 renderMode 설정을 보고합니다.

NativeWindow.renderMode에 의해 반환된 값은 NativeWindowRenderMode 클래스에서 정의된 상수 중 하나가 됩니다.

윈도우를 만든 후에는 renderMode 설정을 변경할 수 없습니다.

관련 API 요소

이 윈도우를 만드는 데 사용된 크기 조절 가능 설정을 보고합니다.

윈도우를 만든 후에는 resizable 설정을 변경할 수 없습니다.

관련 API 요소

이 윈도우의 Stage 객체입니다. Stage 객체는 ActionScript 3.0 기반 SWF 내용에 사용된 표시 목록 아키텍처의 루트 객체입니다.

스테이지는 윈도우 표시 목록의 루트입니다. 시각적 표시 객체를 스테이지나 이 스테이지의 표시 목록에 이미 있는 다른 객체에 시각적 표시 객체를 추가하여 이들을 윈도우에 추가합니다. 윈도우가 시스템 크롬을 사용할 경우 스테이지 크기는 윈도우 클라이언트 영역의 스테이지 크기에 해당합니다. 시스템 크롬이 사용되지 않을 경우 스테이지 크기는 윈도우의 크기와 같습니다.

관련 API 요소

import flash.display.StageAlign;

windowObj.stage.align = StageAlign.TOP_LEFT;

AIR가 현재 컴퓨터 시스템의 기본 윈도우 메뉴를 지원하는지 여부를 나타냅니다.

NativeWindow.supportsMenu가 true이면 윈도우 systemChrome 속성이 NativeWindowSystemChrome.NONE이 아닌 경우에 NativeMenu 객체가 윈도우 menu 속성에 지정될 때 윈도우에 기본 메뉴가 표시됩니다. NativeWindow.supportsMenu 속성을 사용하여 운영 체제가 기본 윈도우 메뉴를 지원하는지 확인하십시오. Capabilities.os 등의 다른 방법을 사용하여 지원 여부를 확인할 경우 프로그래밍 오류가 발생할 수 있습니다(일부 가능한 대상 운영 체제가 고려되지 않는 경우).

참고: NativeWindow.supportsMenu가 false이거나 윈도우 systemChrome 속성이 NativeWindowSystemChrome.NONE일 때 윈도우에 메뉴를 지정할 수 있지만 아무런 작업이 수행되지 않습니다.

관련 API 요소

AIR가 현재 컴퓨터 시스템의 윈도우 알림 큐 실행을 지원하는지 여부를 나타냅니다.

NativeWindow.supportsNotification이 true일 때 윈도우의 notifyUser() 메서드를 호출하면 관련 이벤트가 발생한 사용자에게 시각적 큐가 표시됩니다. 이 시각적 큐는 기본 시스템의 운영 체제 규칙을 따릅니다. 예를 들어 Windows^®에서 작업 표시줄 아이콘은 깜박거립니다.

참고: NativeWindow.supportsNotification이 false일 때 notifyUser()를 호출할 수 있지만 아무런 작업이 수행되지 않습니다.

관련 API 요소

AIR에서 투명 픽셀이 있는 기본 윈도우를 지원하는지 여부를 나타냅니다.

NativeWindow.supportsTransparency가 true이면 기본 윈도우의 픽셀에서 투명도가 유지됩니다(윈도우의 transparent 속성이 true로 설정된 경우). NativeWindow.supportsTransparency가 false이면 윈도우의 transparent 속성에 관계없이 모든 픽셀의 불투명도가 1로 설정됩니다. NativeWindow.supportsTransparency가 false이면 완전히 투명한 픽셀이 검은색으로 렌더링됩니다. NativeWindow.supportsTransparency 속성을 사용하여 운영 체제가 투명도를 지원하는지 여부를 확인하십시오. Capabilities.os 등의 다른 방법을 사용하여 지원 여부를 확인할 경우 프로그래밍 오류가 발생할 수 있습니다(일부 가능한 대상 운영 체제가 고려되지 않는 경우).

참고: 이 속성의 값은 응용 프로그램이 실행되는 도중 운영 체제에 대해 설정된 사용자 환경 설정에 따라 변경될 수 있습니다.

관련 API 요소

이 윈도우를 만드는 데 사용된 시스템 크롬 설정을 보고합니다.

NativeWindow.systemChrome에 의해 반환된 값은 NativeWindowSystemChrome 클래스에서 정의된 상수 중 하나가 됩니다.

윈도우를 만든 후에는 시스템 크롬 설정을 변경할 수 없습니다.

관련 API 요소

var sysChromeType:String = windowObj.systemChrome;

var sysChromeType:String = displayObject.stage.nativeWindow.systemChrome;

var sysChromeType = window.nativeWindow.systemChrome;

import flash.display.NativeWindow;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowInitOptions;

public function deChromeWindow(oldWindow:NativeWindow):NativeWindow{
    if(oldWindow.systemChrome != NativeWindowSystemChrome.NONE){
        var newOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
        newOptions.systemChrome = NativeWindowSystemChrome.NONE;
        newOptions.transparent = true;
        
        var newWindow:NativeWindow = new NativeWindow(newOptions);
        newWindow.stage.stageWidth = oldWindow.stage.stageWidth;
        newWindow.stage.stageHeight = oldWindow.stage.stageHeight;
        newWindow.stage.align = oldWindow.stage.align;
        newWindow.stage.scaleMode = oldWindow.stage.scaleMode;
        
        for(var i:int = 0; i < oldWindow.stage.numChildren; i++){
            newWindow.stage.addChild(oldWindow.stage.getChildAt(i));
        }
        newWindow.activate();
        oldWindow.close();
        
        return newWindow;
    }
    return oldWindow;
}

운영 체제에서 허용하는 최대 윈도우 크기입니다.

크기 제한은 Point 객체의 좌표로 지정됩니다. 점 x 속성은 윈도우 폭에 해당하고 y 속성은 윈도우 높이에 해당합니다.

운영 체제 크기 제한 외에도 AIR에서는 최대 윈도우 크기가 4095 x 4095픽셀(AIR 1.5 이전의 경우 2880 x 2880픽셀)로 제한됩니다. 또한 응용 프로그램은 NativeWindow 객체의 maxSize 속성을 사용하여 제한을 설정할 수 있습니다.

운영 체제에서 허용하는 최소 윈도우 크기입니다.

크기 제한은 Point 객체의 좌표로 지정됩니다. 점 x 속성은 윈도우 폭에 해당하고 y 속성은 윈도우 높이에 해당합니다.

윈도우 제목입니다.

이 제목은 표시될 경우 윈도우의 시스템 크롬뿐만 아니라 작업 표시줄과 같이 시스템별로 다른 위치에 표시됩니다.

windowObj.title = "Window Title";

이 윈도우를 만드는 데 사용된 투명도 설정을 보고합니다.

윈도우를 만든 후에는 transparent 속성을 변경할 수 없습니다. 투명도는 윈도우의 표시되는 모양 및 마우스 비헤이비어 모두에 영향을 미칩니다. Windows 및 Mac OS X에서 픽셀의 알파 값이 특정 임계값(약 .06에서 .01 사이의 값으로 운영 체제에 따라 다름) 이하일 때 윈도우는 마우스 이벤트를 캡처하지 않습니다. Linux에서 윈도우는 완전히 투명한 영역에서 마우스 이벤트를 캡처하므로 사용자가 데스크톱에서 다른 윈도우 및 항목에 액세스할 수 없습니다.

참고: 윈도우 투명도가 항상 지원되는 것은 아닙니다. 사용자 운영 체제가 투명도를 사용할 수 없도록 구성된 경우 윈도우가 투명도 없이 만들어집니다. 투명도가 적용되어야 하는 영역은 검은색에 합성됩니다. 윈도우 투명도가 지원되는지 확인하려면 NativeWindow.supportsTransparency 속성을 사용합니다.

관련 API 요소

이 윈도우를 만드는 데 사용된 윈도우 type 설정을 보고합니다.

NativeWindow.type에 의해 반환된 값은 NativeWindowType 클래스에서 정의된 상수 중 하나가 됩니다.

윈도우를 만든 후에는 type 설정을 변경할 수 없습니다.

관련 API 요소

이 윈도우의 표시 여부를 지정합니다.

보이지 않는 윈도우는 데스크톱에 표시되지 않지만 모든 window 속성 및 메서드는 유효합니다.

기본적으로 visible은 false로 설정됩니다. 윈도우를 표시하려면 visible을 true로 설정하거나 NativeWindow.activate()를 호출합니다.

이 윈도우의 소유자가 있으면 소유자 윈도우의 표시 상태에 따라 이 윈도우의 표시 여부가 결정됩니다. 소유자 윈도우가 표시되지 않으면 visible 속성이 true인 경우에도 소속 윈도우가 표시되지 않습니다.

참고: Mac OS X에서 최소화된 윈도우를 visible=false로 설정하면 도크에서 해당 윈도우 아이콘이 제거되지 않습니다. 사용자가 도크 아이콘을 계속 클릭하면 윈도우가 볼 수 있는 상태로 되돌아가 데스크톱에 표시됩니다.

관련 API 요소

windowObj.visible = true;

displayObj.stage.nativeWindow.visible = true;

window.nativeWindow.visible = true;

이 윈도우의 폭(픽셀)입니다.

기본 윈도우에 대해 보고되는 크기에는 표시되는 모든 시스템 윈도우 크롬이 포함됩니다. 윈도우 안에 있는 사용 가능한 표시 영역의 폭은 Stage.stageWidth 속성에서 사용할 수 있습니다.

윈도우의 width 속성을 변경하는 것은 bounds 속성을 통해 폭을 변경하는 것과 같습니다.

지정된 폭이 허용되는 폭의 최소값보다 작거나 최대값보다 크면 윈도우 폭이 유효한 크기에 가장 가까운 값으로 설정됩니다. 폭의 최소값과 최대값을 결정하는 요소는 다음과 같습니다.

• NativeWindow 객체의 minSize.y 및 maxSize.y 속성
• 운영 체제의 최소 및 최대 제한, 즉 NativeWindow.systemMinSize.y 및 NativeWindow.systemMaxSize.y 값
• Adobe AIR에서 윈도우의 최대 폭(4095픽셀)을 나타냅니다. AIR 1.5 이전에서는 2880픽셀입니다.

Linux에서 width 속성을 설정하는 것은 비동기 작업입니다.

폭 변경이 완료되는 것을 감지하려면 모든 플랫폼에서 전달되는 resize 이벤트를 수신합니다.

윈도우 폭이 변경될 경우 픽셀 값은 가장 가까운 정수로 반올림됩니다.

관련 API 요소

운영 체제 데스크톱의 원점을 기준으로 하는 이 윈도우의 왼쪽 위 모서리에 대한 가로 축 좌표입니다.

둘 이상의 모니터가 있는 시스템에서는 x가 음수일 수 있습니다. 윈도우를 이전 위치로 재배치하려는 경우 등에서 값을 저장할 때는 위치 복원 시 해당 윈도우가 사용 가능한 위치에 배치되는지 항상 확인해야 합니다. 화면 해상도 또는 모니터 배열 변경으로 인해 윈도우가 화면 밖에 배치될 수 있습니다. Screen 클래스를 사용하여 데스크톱 배열에 대한 정보를 얻을 수 있습니다.

윈도우의 x 속성을 변경하는 것은 bounds 속성을 통해 위치를 변경하는 것과 같습니다.

Linux에서 x 속성을 설정하는 것은 비동기 작업입니다.

위치 변경이 완료되는 것을 감지하려면 모든 플랫폼에서 전달되는 move 이벤트를 수신합니다.

윈도우 x 좌표가 변경될 경우 픽셀 값은 가장 가까운 정수로 반올림됩니다.

관련 API 요소

운영 체제 데스크톱의 왼쪽 위 모서리를 기준으로 하는 이 윈도우의 왼쪽 위 모서리에 대한 세로 축 좌표입니다.

둘 이상의 모니터가 있는 시스템에서는 y가 음수일 수 있습니다. 윈도우를 이전 위치로 재배치하려는 경우 등에서 값을 저장할 때는 위치 복원 시 해당 윈도우가 사용 가능한 위치에 배치되는지 항상 확인해야 합니다. 화면 해상도 또는 모니터 배열 변경으로 인해 윈도우가 화면 밖에 배치될 수 있습니다. Screen 클래스를 사용하여 데스크톱 배열에 대한 정보를 얻을 수 있습니다.

윈도우의 y 속성을 변경하는 것은 bounds 속성을 통해 위치를 변경하는 것과 같습니다.

Linux에서 y 속성을 설정하는 것은 비동기 작업입니다.

위치 변경이 완료되는 것을 감지하려면 모든 플랫폼에서 전달되는 move 이벤트를 수신합니다.

윈도우 y 좌표가 변경될 경우 픽셀 값은 가장 가까운 정수로 반올림됩니다.

관련 API 요소

새 NativeWindow 인스턴스 및 해당 운영 체제 윈도우를 만듭니다.

윈도우를 만든 후 initOptions 매개 변수에 정의된 설정을 변경할 수 없습니다. 유효하지 않은 initOptions 설정을 사용하면 잘못된 작업 오류가 발생합니다. 설정이 유효해도 현재 시스템에서 사용할 수 없으면 예외가 발생하지 않습니다. 원할 경우 systemMaxSize와 같은 정적 NativeWindow 멤버를 사용하면 현재 운영 체제 관련 윈도우 기능이 감지될 수 있습니다.

기본 윈도우 크기는 운영 체제에 따라 결정되며, 윈도우는 보이지 않는 상태로 만들어집니다. 윈도우의 표시 상태가 변경되지 않도록 하려면, 윈도우 변경이 완료될 때까지 윈도우의 visible 속성을 true로 변경하거나 activate()를 호출하지 마십시오.

관련 API 요소

import flash.display.NativeWindowInitOptions;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowType;
import flash.display.NativeWindow;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.geom.Rectangle;

var windowOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
windowOptions.systemChrome = NativeWindowSystemChrome.STANDARD;
windowOptions.type = NativeWindowType.NORMAL;

var newWindow:NativeWindow = new NativeWindow(windowOptions);
newWindow.stage.scaleMode = StageScaleMode.NO_SCALE;
newWindow.stage.align = StageAlign.TOP_LEFT;
newWindow.bounds = new Rectangle(100, 100, 800, 800);

newWindow.activate();

이 윈도우를 활성화합니다.

윈도우를 활성화하면 다음과 같이 됩니다.

• 해당 윈도우를 볼 수 있습니다.
• 해당 윈도우를 맨 앞으로 가져옵니다.
• 해당 윈도우에 키보드 및 마우스 포커스가 옵니다.

Linux에서 activate()는 비동기 작업입니다.

NativeWindow 객체는 모든 플랫폼에서 activate 이벤트를 전달합니다.

관련 API 요소

displayObject.stage.nativeWindow.activate();

windowObj.activate();

window.nativeWindow.activate();

이 윈도우를 닫습니다.

닫기 작업이 완료되는 즉시 close 이벤트가 전달됩니다. closing 이벤트는 전달되지 않습니다. 닫기 작업을 취소할 수 있도록 해야 하는 경우 closing 이벤트를 전달하고 close() 메서드를 호출하기 전에 등록된 리스너가 기본 비헤이비어를 취소하는지 여부를 확인합니다.

윈도우가 닫힐 때 해당 윈도우가 소유한 모든 윈도우가 닫힙니다. 소속 윈도우는 closing 이벤트를 전달하지 않습니다.

현재 윈도우에 있는 표시 객체 인스턴스가 다른 위치에서 참조되지 않는 경우 가비지 수집되어 삭제됩니다(AIR에서 만들어진 초기 응용 프로그램 윈도우 제외). 초기 윈도우의 표시 객체가 가비지 수집될 수 있도록 하려면 윈도우 스테이지에서 해당 객체를 제거합니다.

닫힌 후에도 NativeWindow 객체는 여전히 유효한 참조이지만 액세스하는 대부분의 속성과 메서드에서는 잘못된 작업 오류가 발생합니다.

닫힌 윈도우는 다시 열 수 없습니다. 윈도우가 이미 닫힌 경우 수행되는 액션과 전달되는 이벤트가 없습니다.

참고: 윈도우를 닫지 않고 숨기려면 윈도우의 visible 속성을 false로 설정합니다.

관련 API 요소

windowObj.close();

displayObj.stage.nativeWindow.close();

window.close(); //overriddable in HTMLHost

window.nativeWindow.close(); //not overriddable

public function closeCommand():Boolean{
    var closeEvent:Event = new Event(Event.CLOSING,true,true);
    windowObj.dispatchEvent(closeEvent);
    if(!closeEvent.isDefaultPrevented()){
        windowObj.close();
        return true;
    } else {
      return false;
    }
}

<script src="AIRAliases.js" type="text/javascript"></script>
<script type="text/javascript">
    var dirtyData = false;
    function closeWindow(){
            var closingEvent = new air.Event(air.Event.CLOSING,true,true);
            window.nativeWindow.dispatchEvent(closingEvent);
               if(!closingEvent.isDefaultPrevented()){
                   window.nativeWindow.close();
                //or use: window.close(); 
               return true;
           } else {
               return false;
        }
    }
        
    function onClosing(event){
        if(dirtyData){
            event.preventDefault();
            //Save data...
        }
    }    

    window.nativeWindow.addEventListener(air.Event.CLOSING,onClosing);        
</script>

윈도우 스테이지의 원점을 기준으로 하는 픽셀 좌표의 포인트(표시 목록에 대한 전역 포인트)를 가상 데스크톱의 포인트로 변환합니다.

가상 데스크톱 좌표는 기본 모니터의 왼쪽 위 모서리를 기준으로 합니다.

매개 변수

관련 API 요소

이 윈도우가 소유하고 있는 NativeWindow 객체의 목록을 반환합니다.

반환된 벡터의 객체를 추가하거나 제거하는 방식으로 NativeWindows의 소유권을 변경할 수 없습니다. 윈도우가 만들어지면 윈도우 소유권을 변경할 수 없습니다.

관련 API 요소

이 윈도우를 최대화합니다.

maximize() 메서드를 호출하면 displayStateChange 이벤트 및 적용 가능한 move와 resize 이벤트가 전달됩니다. 사용자가 최대화 명령을 시작하면 시스템 크롬은 취소할 수 있는 displayStateChanging 이벤트를 전달하지만 원할 경우 사용자의 최대화 논리로 이 비헤이비어를 구현해야 합니다.

maximize() 메서드는 비동기적으로 실행됩니다. 상태 변경이 완료되는 것을 감지하려면 displayStateChange 이벤트를 수신합니다. 윈도우가 이미 최대화된 경우 수행되는 액션과 전달되는 이벤트가 없습니다.

OS 비헤이비어 참고 사항:

• 윈도우 최대화로 크기 조절까지 금지되지는 않는 Mac OS X와 같은 운영 체제에서는 maximize()를 호출하면 윈도우를 확대하여 화면을 채울 수 있고 이후 윈도우의 크기 조정도 가능합니다. 확대된 윈도우의 크기를 조정하면 표시 상태도 복원됩니다.
• Mac OS X와 같은 일부 운영 체제 및 일부 Linux 윈도우 관리자에서는 윈도우를 최대화해도 윈도우가 maxSize 속성에 지정된 폭 및 높이 이상으로 확장되지 않습니다. 다른 운영 체제에서는 스크린이 maxSize보다 큰 경우에도 윈도우가 스크린 전체를 채웁니다.
• 일부 Linux 윈도우 관리자에서는 유틸리티 윈도우를 최대화할 수 없습니다.

관련 API 요소

public function maximizeWindow(nativeWin:NativeWindow):Boolean{
  if(nativeWin.displayState != NativeWindowDisplayState.MAXIMIZED){
    var beforeState:String = nativeWin.displayState;
    var afterState:String = NativeWindowDisplayState.MAXIMIZED;
    var displayStateEvent:NativeWindowDisplayStateEvent = 
        new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
    nativeWin.dispatchEvent(displayStateEvent);
    if(!displayStateEvent.isDefaultPrevented()){
        nativeWin.maximize();
        return true;
    } else {
      return false;
    }
  }
  return false;
}

function maximizeWindow(nativeWin){
    if(nativeWin.displayState != air.NativeWindowDisplayState.MAXIMIZED){
        var beforeState = nativeWin.displayState;
        var afterState = air.NativeWindowDisplayState.MAXIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.maximize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

이 윈도우를 최소화합니다.

minimize()를 호출하면 displayStateChange 이벤트 및 적용 가능한 move와 resize 이벤트가 전달됩니다. 사용자가 최소화 명령을 시작하면 시스템 크롬은 취소할 수 있는 displayStateChanging 이벤트를 전달하지만 minimize()를 직접 호출하면 그렇지 않습니다. 원할 경우 사용자의 최소화 논리로 이 비헤이비어를 구현할 수도 있습니다.

minimize() 메서드는 비동기적으로 실행됩니다. 상태 변경이 완료되는 것을 감지하려면 모든 플랫폼에서 전달되는 displayStateChange 이벤트를 수신합니다. 윈도우가 이미 최소화된 경우 수행되는 액션과 전달되는 이벤트가 없습니다.

윈도우가 최소화되면 이 윈도우가 소유한 윈도우도 숨겨집니다. 소속 윈도우는 displayStateChanging 또는 displayStateChange 이벤트를 전달하지 않습니다.

참고:

• Windows에서 보이지 않는 윈도우(visible == false)를 최소화하면 윈도우가 보이게 됩니다.
• 일부 Linux 윈도우 관리자에서는 유틸리티 윈도우를 최소화할 수 없습니다.

관련 API 요소

public function minimizeWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.MINIMIZED){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

 
function minimizeWindow(){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.MINIMIZED){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

관련 이벤트가 발생한 운영 체제를 통해 시각적 큐를 트리거합니다.

NativeWindow.supportsNotification이 true인 경우 시각적 큐는 기본 시스템의 운영 체제 규칙을 따릅니다. 예를 들어 Windows에서 작업 표시줄 아이콘은 깜박거립니다.

type 매개 변수는 큐의 강도를 결정합니다. 허용된 값을 위한 상수는 NotificationType 클래스에서 정의되며 다음과 같습니다.

• NotificationType.INFORMATIONAL
• NotificationType.CRITICAL

정보 알림을 위해 제공된 큐는 잠깐 동안 발생하지만, 중요한 알림을 위해 제공된 큐는 사용자가 이 윈도우를 활성화할 때까지 계속됩니다. 일부 Linux 윈도우 관리자에서는 두 가지 수준의 알림이 지원되지 않습니다. 이러한 윈도우 관리자의 경우 지정하는 옵션에 관계없이 notifyUser()의 결과가 같습니다.

참고: NativeWindow.supportsNotification이 false일 때 notifyUser()를 호출할 수 있지만 아무런 작업이 수행되지 않습니다.

매개 변수

이 윈도우를 지정된 윈도우의 바로 뒤로 보냅니다.

윈도우 또는 응용 프로그램에 대한 포커스를 활성화하거나 사용하지 않습니다. 최소화되거나 숨겨진(visible = false) 윈도우는 재배열할 수 없습니다.

소속된 윈도우는 소유자 뒤로 이동할 수 없습니다. 이 윈도우의 소유자가 있는 경우 소유자 및 다른 소속 윈도우도 대상 뒤에 정렬됩니다. 대상 윈도우의 소유자가 있는 경우 이 윈도우는 대상의 소유자 뒤에 정렬됩니다.

일부 Linux 윈도우 관리자에서는 유틸리티 윈도우를 일반 윈도우 뒤에 정렬할 수 없습니다.

매개 변수

windowBehind.orderInBackOf(windowFront);

displayObjBehind.stage.nativeWindow.orderInBackOf(displayObjectFront.stage.nativeWindow);

jsWindowObjBehind.nativeWindow.orderInBackOf(jsWindowObjFront.nativeWindow);

이 윈도우를 지정된 윈도우의 바로 앞으로 가져옵니다.

윈도우 또는 응용 프로그램에 대한 포커스를 활성화하거나 사용하지 않습니다. 최소화되거나 숨겨진(visible = false) 윈도우는 재배열할 수 없습니다.

윈도우를 해당 윈도우가 소유한 윈도우 앞으로 이동할 수 없습니다. 이 윈도우의 소유자가 있는 경우 소유자 및 다른 소속 윈도우도 대상 앞에 정렬됩니다. 대상 윈도우의 소유자가 있는 경우 이 윈도우도 대상과 소유자가 같은 다른 윈도우 앞에 정렬됩니다.

일부 Linux 윈도우 관리자에서는 일반 윈도우를 유틸리티 윈도우 앞에 정렬할 수 없습니다.

매개 변수

windowFront.orderInFrontOf(windowBehind);

displayObjFront.stage.nativeWindow.orderInFrontOf(displayObjectBehind.stage.nativeWindow);

jsWindowObjFront.nativeWindow.orderInFrontOf(jsWindowObjBehind.nativeWindow);

이 윈도우를 표시된 다른 윈도우의 뒤로 보냅니다.

이 윈도우 또는 응용 프로그램에 대한 포커스를 활성화하거나 사용하지 않습니다. 최소화되거나 숨겨진(visible = false) 윈도우는 재배열할 수 없습니다.

alwaysInFront가 true인 경우 이 메서드를 호출하면 이 윈도우를 alwaysInFront가 false로 설정된 윈도우 뒤로 보내지 못합니다.

소속된 윈도우는 소유자 뒤로 이동할 수 없습니다. 이 윈도우의 소유자가 있는 경우 소유자 및 다른 소속 윈도우도 윈도우 표시 목록 아래쪽으로 정렬됩니다. 이 윈도우는 동일한 윈도우가 소유한 다른 모든 윈도우 뒤로 이동합니다. 이 윈도우가 다른 윈도우를 소유한 경우 소속 윈도우도 뒤로 이동하여 서로에 대해 현재 순서를 유지합니다.

일부 Linux 윈도우 관리자에서는 유틸리티 윈도우를 일반 윈도우 뒤에 정렬할 수 없습니다.

windowObj.orderToBack();

displayObj.stage.nativeWindow.orderToBack();

window.nativeWindow.orderToBack();

이 윈도우를 표시된 다른 윈도우의 앞으로 가져옵니다.

이 윈도우 또는 응용 프로그램에 대한 포커스를 활성화하거나 사용하지 않습니다. 최소화되거나 숨겨진(visible = false) 윈도우는 재배열할 수 없습니다.

alwaysInFront가 false인 경우 이 메서드를 호출하면 이 윈도우를 alwaysInFront가 true로 설정된 윈도우 앞으로 보내지 못합니다.

윈도우를 해당 윈도우가 소유한 윈도우 앞으로 이동할 수 없습니다. 이 윈도우가 다른 윈도우를 소유한 경우 소속 윈도우도 서로에 대해 현재 순서를 유지하면서 앞으로 이동할 수 있습니다. 이 윈도우의 소유자가 있는 경우 소유자 및 다른 소속 윈도우도 윈도우 표시 목록 위쪽으로 정렬됩니다. 이 윈도우를 소유자가 동일한 다른 윈도우 앞으로 이동합니다.

일부 Linux 윈도우 관리자에서는 일반 윈도우를 유틸리티 윈도우 앞에 정렬할 수 없습니다.

windowObj.orderToFront();

displayObj.stage.nativeWindow.orderToFront();

window.nativeWindow.orderToFront();

최소화 또는 최대화된 상태에서 이 윈도우를 복원합니다.

restore()를 호출하면 displayStateChange 이벤트 및 해당하는 경우 move와 resize 이벤트가 전달됩니다. 사용자가 복원 명령을 시작하면 시스템 크롬은 취소할 수 있는 displayStateChanging 이벤트를 전달하지만 원할 경우 사용자의 복원 논리로 이 비헤이비어를 구현해야 합니다.

윈도우가 이미 NativeWindowDisplayState.NORMAL 상태인 경우 수행되는 액션과 전달되는 이벤트가 없습니다.

상태 변경이 완료되는 것을 감지하려면 모든 플랫폼에서 전달되는 displayStateChange 이벤트를 수신합니다.

관련 API 요소

public function restoreWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.NORMAL){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.NORMAL;
        var displayStateChangingEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateChangingEvent);
        if(!displayStateChangingEvent.isDefaultPrevented()){
            nativeWin.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

function restoreWindow(nativeWin){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.NORMAL){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.NORMAL;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

이 윈도우의 시스템 제어 이동을 시작합니다.

mouseDown 이벤트에서 이 메서드를 호출하면 mouseUp이 발생할 때까지 계속되는 마우스 기반 이동 시퀀스가 시작됩니다.

다른 코드에서 이 메서드를 호출하면 운영 체제의 기본 시퀀스에 따라 키보드 또는 마우스 기반 이동 시퀀스가 시작됩니다.

이동 시퀀스 중 윈도우의 원점이 이동될 때 일련의 이벤트가 전달됩니다. 이동이 추가될 때마다 우선 moving 이벤트가 전달되고, moving 이벤트가 취소되지 않으면 윈도우 위치가 업데이트되고 move 이벤트가 전달됩니다. moving 이벤트가 취소되면 바로 이동 시퀀스가 종료됩니다.

var initOpts:NativeWindowInitOptions = new NativeWindowInitOptions();
var win:NativeWindow = new NativeWindow(initOpts);
win.activate();
win.stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);

function mouseDownHandler(event:MouseEvent):void
{
    win.startMove();
}

이 윈도우의 시스템 제어 크기 조절 작업을 시작합니다.

mouseDown 이벤트 핸들러에서 이 메서드를 호출하면 mouseUp 이벤트가 발생할 때까지 계속되는 마우스 기반 이동 시퀀스가 시작됩니다.

다른 코드에서 이 메서드를 호출하면 운영 체제의 기본 시퀀스에 따라 키보드 또는 마우스 기반 크기 조절 시퀀스가 시작됩니다.

크기 조절 시퀀스 중 윈도우의 크기가 변경될 때 일련의 이벤트가 전달됩니다. 변경이 추가될 때마다 우선 resizing 이벤트가 전달되고, resizing 이벤트가 취소되지 않으면 윈도우 크기가 업데이트되고 resize 이벤트가 전달됩니다. resizing 이벤트가 취소되면 바로 해당 시퀀스가 종료됩니다.

매개 변수

관련 API 요소

stage.addEventListener(MouseEvent.MOUSE_DOWN, onResizeCommand);

function onResizeCommand(event:MouseEvent):void
{
    var win:NativeWindow = event.target.nativeWindow;
    var resizeFrom:String = "";
    if (event.stageY < win.height * .33)
    {
        resizeFrom = NativeWindowResize.TOP;
    }
    else if (event.stageY > win.height * .66)
    {
        resizeFrom = NativeWindowResize.BOTTOM;
    }
    if (event.stageX < win.width * .33)
    {
        resizeFrom += NativeWindowResize.LEFT;
    }
    else if (event.stageX > win.width * .66)
    {
        resizeFrom += NativeWindowResize.RIGHT;
    }
    win.startResize(resizeFrom);    
}

윈도우가 활성화된 후 이 NativeWindow 객체에 의해 전달됩니다.

참고: 이 이벤트에는 "캡처 단계" 또는 "버블링 단계"가 없으므로 대상이 표시 목록에 있는지 여부에 관계없이 잠재적인 모든 대상에 이벤트 리스너를 직접 추가해야 합니다.

AIR for TV 장치는 이 이벤트를 자동으로 전달하지 않습니다. 하지만 수동으로 전달할 수는 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

윈도우가 닫힌 후 이 NativeWindow 객체에 의해 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

윈도우가 닫히기 직전 이 NativeWindow 객체에 의해 전달됩니다. 이 이벤트를 취소하면 윈도우가 닫히지 않게 할 수 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

윈도우가 비활성화된 후 이 NativeWindow 객체에 의해 전달됩니다.

참고: 이 이벤트에는 "캡처 단계" 또는 "버블링 단계"가 없으므로 대상이 표시 목록에 있는지 여부에 관계없이 잠재적인 모든 대상에 이벤트 리스너를 직접 추가해야 합니다.

AIR for TV 장치는 이 이벤트를 자동으로 전달하지 않습니다. 하지만 수동으로 전달할 수는 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

윈도우의 displayState 속성이 변경된 후 이 NativeWindow 객체에 의해 전달됩니다.

displayStateChange 이벤트 핸들러에서 윈도우의 크기를 조절하거나 표시 상태를 변경하지 마십시오.

이 이벤트에는 다음과 같은 속성이 있습니다.

윈도우에서 표시 상태가 변경되기 직전 이 NativeWindow 객체에 의해 전달됩니다. 이 이벤트를 취소하면 변경되지 않게 할 수 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

function displayStateChanging_handler(displayStateEvent:NativeWindowDisplayStateEvent):void
{
  //shouldStopStateChange is an application-defined Boolean indicating 
  //that display state changes should be canceled
  if (displayStateEvent.type == NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING 
                                  &&    shouldStopStateChange)
  {
    displayStateEvent.preventDefault();
  }
}

데스크톱에서 윈도우가 이동된 후 이 NativeWindow 객체에 의해 전달됩니다.

move 이벤트는 윈도우의 원점(x 또는 y 속성)이 변경될 때마다 전달됩니다. 이는 시스템 제어 윈도우 이동, 최소화, 최대화 또는 복원 작업으로 인해 발생하거나 x, y 또는 bounds 속성 설정을 통한 윈도우 위치 변경 작업으로 인해 발생할 수 있습니다.

참고: NativeWindow 객체의 moving 및 move 이벤트에 대한 핸들러 함수에서 운영 체제 대화 상자를 동시에 열 수 있는 액션을 수행하지 마십시오. 예를 들어 두 핸들러 함수 모두에서 오류가 발생하면 이런 현상이 발생할 수 있습니다. 이런 경우 두 번째 열린 대화 상자에서 마우스 클릭이 등록되지 않으며 해당 대화 상자를 키보드를 사용하여 닫아야 합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

데스크톱에서 윈도우가 이동되기 직전 NativeWindow 객체에 의해 전달됩니다. 이 이벤트를 취소하면 이동을 방지하거나 수정할 수 있습니다.

참고: NativeWindow 객체의 moving 및 move 이벤트에 대한 핸들러 함수에서 운영 체제 대화 상자를 동시에 열 수 있는 액션을 수행하지 마십시오. 예를 들어 두 핸들러 함수 모두에서 오류가 발생하면 이런 현상이 발생할 수 있습니다. 이런 경우 두 번째 열린 대화 상자에서 마우스 클릭이 등록되지 않으며 해당 대화 상자를 키보드를 사용하여 닫아야 합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고: Linux에서는 이 이벤트에 대해 preventDefault() 메서드가 지원되지 않습니다.

윈도우의 크기가 조절된 후 이 NativeWindow 객체에 의해 전달됩니다. resize 이벤트는 윈도우의 크기(width 또는 height 속성)가 변경될 때마다 전달됩니다. 이는 시스템 제어 윈도우 크기 조절, 최소화, 최대화 또는 복원 작업으로 인해 발생하거나 width, height 또는 bounds 속성 설정을 통한 윈도우 크기 변경 작업으로 인해 발생할 수 있습니다. NativeWindow resize 이벤트는 시스템 제어 크기 조절이 반복되는 동안 전달됩니다. 반면 Stage 객체 resize 이벤트는 Stage가 드로잉에 사용할 준비가 될 때 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

데스크톱에서 윈도우의 크기가 조절되기 직전 이 NativeWindow 객체에 의해 전달됩니다. 이 이벤트는 취소하면 크기 조절을 방지하거나 수정할 수 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고: Linux에서는 이 이벤트에 대해 preventDefault() 메서드가 지원되지 않습니다.

function boundsChanging_handler(boundsEvent:NativeWindowBoundsEvent):void
{
  //shouldStopResize is an application-defined Boolean indicating 
  //that resize operations should be canceled
  if (boundsEvent.type == NativeWindowBoundsEvent.RESIZING && shouldStopResize)
  {
    boundsEvent.preventDefault();
  }
}