Transform  - AS3

표시 객체의 색상을 전체적으로 조정하는 값이 포함된 ColorTransform 객체입니다.

관련 API 요소

표시 객체와 해당하는 모든 부모 객체(루트 레벨까지)에 적용된 색상 변환의 결합을 나타내는 ColorTransform 객체입니다. 다른 레벨에서 다른 색상 변환이 적용된 경우, 이러한 색상 변환은 모두 이 속성에 대한 하나의 ColorTransform 객체로 연결됩니다.

관련 API 요소

표시 객체와 해당하는 모든 부모 객체(루트 레벨까지)의 결합된 변형 행렬을 나타내는 Matrix 객체입니다. 다른 레벨에서 다른 변형 행렬이 적용된 경우, 이러한 변형 행렬은 모두 이 속성에 대한 하나의 행렬로 연결됩니다. 또한 브라우저에서 실행 중인 크기 조절 가능한 SWF 내용의 경우 이 속성에는 윈도우 크기 조절로 인한 스테이지 좌표와 윈도우 좌표의 차이가 적용됩니다. 따라서 이 속성은 로컬 좌표를 스테이지의 좌표 공간과 다를 수 있는 윈도우 좌표로 변환합니다.

표시 객체의 크기 조절, 회전 및 평행 이동에 영향을 주는 값이 들어 있는 Matrix 객체입니다.

matrix 속성을 null이 아닌 값으로 설정하면 matrix3D 속성이 null이 됩니다. 그리고 matrix3D 속성을 null이 아닌 값으로 설정하면 matrix 속성이 null이 됩니다.

관련 API 요소

3차원 표시 객체의 Matrix3D 객체에 액세스합니다. Matrix3D 객체는 표시 객체의 위치와 방향을 결정하는 변형 행렬을 나타냅니다. Matrix3D 객체는 원근 투영을 수행할 수도 있습니다.

matrix 속성을 null이 아닌 값으로 설정하면 matrix3D 속성이 null이 됩니다. 그리고 matrix3D 속성을 null이 아닌 값으로 설정하면 matrix 속성이 null이 됩니다.

관련 API 요소

3차원 표시 객체의 PerspectiveProjection 객체에 액세스합니다. PerspectiveProjection 객체를 사용하여 스테이지의 원근 변형을 수정하거나 표시 객체의 모든 3차원 자식에 원근 변형을 할당할 수 있습니다.

스테이지의 시야 및 종횡비(크기)에 따라 루트 객체에 기본 PerspectiveProjection 객체가 할당됩니다.

관련 API 요소

스테이지에서 표시 객체의 경계 사각형을 정의하는 Rectangle 객체입니다.

현재 표시 객체의 공간을 기준으로 지정된 표시 객체의 공간을 변형할 수 있는 Matrix3D 객체를 반환합니다. getRelativeMatrix3D() 메서드를 사용하면 다른 3차원 표시 객체를 기준으로 3차원 표시 객체를 이동할 수 있습니다.

매개 변수

관련 API 요소

1. TransformExample() 생성자가 새 Sprite 객체 target을 만듭니다.
2. TransformExample() 생성자가 Sprite에 그래디언트 사각형을 그리는 draw() 메서드를 호출합니다.
3. TransformExample() 생성자가 해당 Sprite에 대한 click 이벤트 리스너를 추가합니다. 이 리스너는 clickHandler() 메서드에 의해 처리됩니다.
4. clickHandler() 메서드가 기울임 효과를 적용하도록 설정된 새 Matrix 객체인 skewMatrix를 만듭니다. 다른 행렬인 tempMatrix를 스프라이트의 현재 변형 행렬에 할당한 다음 skewMatrix와 결합합니다. 이때 concat() 메서드를 사용합니다. 이 행렬을 사각형 스프라이트의 transform.matrix 속성에 할당합니다. 사용자가 사각형을 클릭할 때마다 clickHandler()가 호출되어 사각형의 모양을 기울여 변경합니다.
5. 또한 clickHandler() 메서드는 새 ColorTransform 객체를 만듭니다. 새 ColorTransform의 redOffset 속성은 redOffset의 현재 값으로 설정된 후 25가 더해집니다. 마찬가지로 blueOffset 속성은 25만큼 감소합니다. 따라서 클릭할 때마다 스프라이트의 색상이 변합니다.

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}