TextInput

包	fl.controls
类	public class TextInput
继承	TextInput UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object
实现	IFocusManagerComponent
子类	DataGridCellEditor

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

TextInput 组件是单行文本组件，其中包含本机 ActionScript TextField 对象。

在应用程序中，可以启用或禁用 TextInput 组件。 TextInput 组件被禁用以后，便无法接收来自鼠标或键盘的输入。启用的 TextInput 组件像 ActionScript TextField 对象一样可以实现焦点、选择和导航。

可以使用样式对 TextInput 组件进行自定义，例如，可以在禁用该组件以后更改其外观。可应用于该组件的一些其他自定义包括使用 HTML 对其进行格式设置，或者将其设置为文本必须隐藏的密码字段。

相关 API 元素

公共属性

	属性		由以下参数定义
		accessibilityImplementation : AccessibilityImplementation InteractiveObject 实例的当前辅助功能实现 (AccessibilityImplementation)。	InteractiveObject
		accessibilityProperties : AccessibilityProperties 此显示对象的当前辅助功能选项。	DisplayObject
		alpha : Number 表示指定对象的 Alpha 透明度值。	DisplayObject
		alwaysShowSelection : Boolean 获取或设置一个布尔值，指示当文本字段不具有焦点时选定内容的显示方式。	TextInput
		blendMode : String BlendMode 类中的一个值，用于指定要使用的混合模式。	DisplayObject
		blendShader : Shader [只写] 设置用于混合前景和背景的着色器。	DisplayObject
		buttonMode : Boolean 指定此 sprite 的按钮模式。	Sprite
		cacheAsBitmap : Boolean 如果设置为 true，则 Flash 运行时将缓存显示对象的内部位图表示形式。	DisplayObject
		cacheAsBitmapMatrix : Matrix 如果为非 null，则 Matrix 对象会定义显示对象在 cacheAsBitmap 设置为 true 时的呈现方式。	DisplayObject
		condenseWhite : Boolean 获取或设置一个布尔值，该值指示是否从包含 HTML 文本的 TextInput 组件中删除额外空白。	TextInput
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		contextMenu : NativeMenu 指定与此对象相关联的上下文菜单。	InteractiveObject
		displayAsPassword : Boolean 获取或设置一个布尔值，该值指示当前创建的 TextInput 组件实例用于包含密码还是文本。	TextInput
		doubleClickEnabled : Boolean 指定此对象是否接收 doubleClick 事件。	InteractiveObject
		dropTarget : DisplayObject [只读] 指定拖动 sprite 时经过的显示对象，或放置 sprite 的显示对象。	Sprite
		editable : Boolean 获取或设置一个布尔值，指示用户能否编辑文本字段。	TextInput
		enabled : Boolean [覆盖] 获取或设置一个值，该值指示组件是否可以接受用户交互。	TextInput
		filters : Array 包含当前与显示对象关联的每个滤镜对象的索引数组。	DisplayObject
		focusEnabled : Boolean 获取或设置一个布尔值，该值指示组件是否可以在用户单击它后获得焦点。	UIComponent
		focusManager : IFocusManager 获取或设置为此组件及其同级组件控制焦点的 FocusManager。	UIComponent
		focusRect : Object 指定此对象是否显示焦点矩形。	InteractiveObject
		graphics : Graphics [只读] 指定属于此 sprite 的 Graphics 对象，在此 sprite 中可执行矢量绘图命令。	Sprite
		height : Number [覆盖] 获取或设置组件的高度，以像素为单位。	UIComponent
		hitArea : Sprite 指定一个 sprite 用作另一个 sprite 的点击区域。	Sprite
		horizontalScrollPosition : int 获取或设置水平滚动条的滑块位置。	TextInput
		htmlText : String 包含文本字段所含字符串的 HTML 表示形式。	TextInput
		imeMode : String 获取或设置输入法编辑器 (IME) 的模式。	TextInput
		length : int [只读] 获取 TextInput 组件中的字符数。	TextInput
		loaderInfo : LoaderInfo [只读] 返回一个 LoaderInfo 对象，其中包含加载此显示对象所属的文件的相关信息。	DisplayObject
		mask : DisplayObject 调用显示对象被指定的 mask 对象遮罩。	DisplayObject
		maxChars : int 获取或设置用户可以在文本字段中输入的最大字符数。	TextInput
		maxHorizontalScrollPosition : int [只读] 获取一个值，描述文本字段向右滚动可达到的最远位置。	TextInput
		metaData : Object 如果元数据是通过 PlaceObject4 标记与此 DisplayObject 的实例一起存储在 SWF 文件中的，则获取 DisplayObject 实例的元数据对象。	DisplayObject
		mouseChildren : Boolean 确定对象的子级是否支持鼠标或用户输入设备。	DisplayObjectContainer
		mouseEnabled : Boolean 指定此对象是否接收鼠标或其他用户输入、消息。	InteractiveObject
		mouseFocusEnabled : Boolean 获取或设置一个值，该值指示组件是否可以在用户单击它后获得焦点。	UIComponent
		mouseX : Number [只读] 表示此鼠标或用户输入设备位置的 x 坐标，以像素为单位。	DisplayObject
		mouseY : Number [只读] 表示此鼠标或用户输入设备位置的 y 坐标，以像素为单位。	DisplayObject
		name : String 表示 DisplayObject 的实例名称。	DisplayObject
		needsSoftKeyboard : Boolean 指定当该 InteractiveObject 实例获得焦点时，是否显示虚拟键盘（显示在屏幕上的软键盘）。	InteractiveObject
		numChildren : int [只读] 返回此对象的子项数目。	DisplayObjectContainer
		opaqueBackground : Object 指定显示对象是否由于具有某种背景颜色而不透明。	DisplayObject
		parent : DisplayObjectContainer [只读] 表示包含此显示对象的 DisplayObjectContainer 对象。	DisplayObject
		restrict : String 获取或设置文本字段从用户处接受的字符串。	TextInput
		root : DisplayObject [只读] 对于加载的 SWF 文件中的显示对象，root 属性是此 SWF 文件所表示的显示列表树结构部分中的顶级显示对象。	DisplayObject
		rotation : Number 表示 DisplayObject 实例距其原始方向的旋转程度，以度为单位。	DisplayObject
		rotationX : Number 表示 DisplayObject 实例相对于 3D 父容器距离其原始方向的 x 轴旋转（以度为单位）。	DisplayObject
		rotationY : Number 表示 DisplayObject 实例相对于 3D 父容器距离其原始方向的 y 轴旋转（以度为单位）。	DisplayObject
		rotationZ : Number 表示 DisplayObject 实例相对于 3D 父容器距离其原始方向的 z 轴旋转（以度为单位）。	DisplayObject
		scale9Grid : Rectangle 当前有效的缩放网格。	DisplayObject
		scaleX : Number [覆盖] 将组件的当前宽度与缩放系数相乘。	UIComponent
		scaleY : Number [覆盖] 将组件的当前高度与缩放系数相乘。	UIComponent
		scaleZ : Number 表示从对象的注册点开始应用的对象的深度缩放比例（百分比）。	DisplayObject
		scrollRect : Rectangle 显示对象的滚动矩形范围。	DisplayObject
		selectionBeginIndex : int [只读] 获取包含一个或多个字符的选定内容中第一个所选字符的索引值。	TextInput
		selectionEndIndex : int [只读] 获取包含一个或多个字符的选定内容中最后一个所选字符的索引位置。	TextInput
		softKeyboard : String 控制软键盘的外观。	InteractiveObject
		softKeyboardInputAreaOfInterest : Rectangle 定义当显示软键盘时应在屏幕上保留的区域（在 iOS 上不支持）。	InteractiveObject
		soundTransform : flash.media:SoundTransform 控制此 sprite 中的声音。	Sprite
		stage : Stage [只读] 显示对象的舞台。	DisplayObject
		tabChildren : Boolean 确定对象的子项是否支持 Tab 键。	DisplayObjectContainer
		tabEnabled : Boolean 指定此对象是否遵循 Tab 键顺序。	InteractiveObject
		tabIndex : int 指定 SWF 文件中的对象按 Tab 键顺序排列。	InteractiveObject
		text : String 获取或设置字符串，其中包含当前 TextInput 组件中的文本。	TextInput
		textField : flash.text:TextField 对 TextInput 组件的内部文本字段的引用。	TextInput
		textHeight : Number [只读] 文本的高度，以像素为单位。	TextInput
		textSnapshot : flash.text:TextSnapshot [只读] 返回此 DisplayObjectContainer 实例的 TextSnapshot 对象。	DisplayObjectContainer
		textWidth : Number [只读] 文本的宽度，以像素为单位。	TextInput
		transform : flash.geom:Transform 一个对象，具有与显示对象的矩阵、颜色转换和像素范围有关的属性。	DisplayObject
		useHandCursor : Boolean 布尔值，表示当指针滑过 buttonMode 属性设置为 true 的 sprite 时是否显示指针手形（手形光标）。	Sprite
		visible : Boolean [覆盖] 获取或设置一个值，该值指示当前组件实例是否可见。	UIComponent
		width : Number [覆盖] 获取或设置组件的宽度（以像素为单位）。	UIComponent
		x : Number [覆盖] 获取或设置 x 坐标，该坐标表示组件在其父容器内沿 x 轴的位置。	UIComponent
		y : Number [覆盖] 获取或设置 y 坐标，该坐标表示组件在其父容器内沿 y 轴的位置。	UIComponent
		z : Number 表示 DisplayObject 实例相对于 3D 父容器沿 z 轴的 z 坐标位置。	DisplayObject

公共方法

隐藏继承的公共方法

显示继承的公共方法

	方法		由以下参数定义
		TextInput() 创建新的 TextInput 组件实例。	TextInput
		addChild(child:DisplayObject):DisplayObject 将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject 将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void 使用 EventDispatcher 对象注册事件侦听器对象，以使侦听器能够接收事件通知。	EventDispatcher
		appendText(text:String):void 将指定字符串追加到 TextArea 所包含的最后一个字符之后。	TextInput
		areInaccessibleObjectsUnderPoint(point:Point):Boolean 表示安全限制是否会导致出现以下情况：在列表中忽略了使用指定 point 点调用 DisplayObjectContainer.getObjectsUnderPoint() 方法时返回的所有显示对象。	DisplayObjectContainer
		clearStyle(style:String):void 删除此组件实例的样式属性。	UIComponent
		contains(child:DisplayObject):Boolean 确定指定显示对象是 DisplayObjectContainer 实例的子项还是该实例本身。	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean 将事件调度到事件流中。	EventDispatcher
		drawFocus(draw:Boolean):void [覆盖] 在此组件上显示或隐藏焦点指示符。	TextInput
		drawNow():void 启动立即绘制操作，但不像 invalidateNow 那样使全部设置失效。	UIComponent
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle 返回一个矩形，该矩形定义相对于 targetCoordinateSpace 对象坐标系的显示对象区域。	DisplayObject
		getChildAt(index:int):DisplayObject 返回位于指定索引处的子显示对象实例。	DisplayObjectContainer
		getChildByName(name:String):DisplayObject 返回具有指定名称的子显示对象。	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int 返回 DisplayObject 的 child 实例的索引位置。	DisplayObjectContainer
		getFocus():InteractiveObject 检索当前具有焦点的对象。	UIComponent
		getLineMetrics(index:int):flash.text:TextLineMetrics 检索有关指定文本行的信息。	TextInput
		getObjectsUnderPoint(point:Point):Array 返回对象的数组，这些对象位于指定点下，并且是该 DisplayObjectContainer 实例的子项（或孙子项，依此类推）。	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle 返回一个矩形，该矩形根据 targetCoordinateSpace 参数定义的坐标系定义显示对象的边界，但不包括形状上的任何笔触。	DisplayObject
		getStyle(style:String):Object 检索组件的样式查找链中设置的样式属性。	UIComponent
		getStyleDefinition():Object [静态] 检索当前组件的默认样式映射。	TextInput
		globalToLocal(point:Point):Point 将 point 对象从舞台（全局）坐标转换为显示对象的（本地）坐标。	DisplayObject
		globalToLocal3D(point:Point):Vector3D 将二维点从舞台（全局）坐标转换为三维显示对象的（本地）坐标。	DisplayObject
		hasEventListener(type:String):Boolean 检查 EventDispatcher 对象是否为特定事件类型注册了任何侦听器。	EventDispatcher
		hasOwnProperty(name:String):Boolean 表示对象是否已经定义了指定的属性。	Object
		hitTestObject(obj:DisplayObject):Boolean 计算显示对象的边框，以确定它是否与 obj 显示对象的边框重叠或相交。	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean 计算显示对象，以确定它是否与 x 和 y 参数指定的点重叠或相交。	DisplayObject
		invalidate(property:String, callLater:Boolean = true):void 在未另外指定的情况下，将属性标记为无效，并在下一帧上重绘组件。	UIComponent
		isPrototypeOf(theClass:Object):Boolean 表示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		local3DToGlobal(point3d:Vector3D):Point 将三维显示对象的（本地）坐标的三维点转换为舞台（全局）坐标中的二维点。	DisplayObject
		localToGlobal(point:Point):Point 将 point 对象从显示对象的（本地）坐标转换为舞台（全局）坐标。	DisplayObject
		mergeStyles(... list):Object [静态] 将多个类的样式合并到一个对象中。	UIComponent
		move(x:Number, y:Number):void 将组件移动到其父项内的指定位置。	UIComponent
		propertyIsEnumerable(name:String):Boolean 表示指定的属性是否存在、是否可枚举。	Object
		removeChild(child:DisplayObject):DisplayObject 从 DisplayObjectContainer 实例的子列表中删除指定的 child DisplayObject 实例。	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject 从 DisplayObjectContainer 的子列表中指定的 index 位置删除子 DisplayObject。	DisplayObjectContainer
		removeChildren(beginIndex:int = 0, endIndex:int = 0x7fffffff):void 从 DisplayObjectContainer 实例的子级列表中删除所有子 DisplayObject 实例。	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void 从 EventDispatcher 对象中删除侦听器。	EventDispatcher
		requestSoftKeyboard():Boolean 显示虚拟键盘。	InteractiveObject
		setChildIndex(child:DisplayObject, index:int):void 更改现有子项在显示对象容器中的位置。	DisplayObjectContainer
		setFocus():void 设置此组件的焦点。	UIComponent
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		setSelection(beginIndex:int, endIndex:int):void 设置在具有焦点的文本区域中选定内容的范围。	TextInput
		setSize(width:Number, height:Number):void 将组件设置为指定宽度和高度。	UIComponent
		setStyle(style:String, value:Object):void 对此组件实例设置样式属性。	UIComponent
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void 允许用户拖动指定的 Sprite。	Sprite
		startTouchDrag(touchPointID:int, lockCenter:Boolean = false, bounds:Rectangle = null):void 使用户可以在启用触摸的设备上拖动指定的 Sprite。	Sprite
		stopAllMovieClips():void 对源起于此对象的所有 MovieClip 递归停止时间轴执行。	DisplayObjectContainer
		stopDrag():void 结束 startDrag() 方法。	Sprite
		stopTouchDrag(touchPointID:int):void 结束 startTouchDrag() 方法，用于启用触摸的设备。	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void 交换两个指定子对象的 Z 轴顺序（从前到后顺序）。	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void 在子级列表中两个指定的索引位置，交换子对象的 Z 轴顺序（前后顺序）。	DisplayObjectContainer
		toLocaleString():String 返回此对象的字符串表示形式，其格式设置遵守区域设置特定的约定。	Object
		toString():String 返回指定对象的字符串表示形式。	Object
		validateNow():void 验证并更新此对象的属性和布局，如果需要的话重绘对象。	UIComponent
		valueOf():Object 返回指定对象的原始值。	Object
		willTrigger(type:String):Boolean 检查是否用此 EventDispatcher 对象或其任何祖代为指定事件类型注册了事件侦听器。	EventDispatcher

受保护的方法

隐藏继承的受保护方法

显示继承的受保护方法

	方法		由以下参数定义
		getStyleValue(name:String):Object 参照在全局级别、组件级别和实例级别上设置的所有样式，为组件返回指定的样式。	UIComponent

事件

单击此处了解有关事件的更多信息

隐藏继承的事件

显示继承的事件

	摘要	由以下参数定义
activate	[广播事件] Flash Player 或 AIR 应用程序获得操作系统焦点并变为活动状态时将调度此事件。	EventDispatcher
added	将显示对象添加到显示列表中时调度。	DisplayObject
addedToStage	在将显示对象直接添加到舞台显示列表或将包含显示对象的子树添加至舞台显示列表中时调度。	DisplayObject
change	当用户在 TextInput 组件中输入更改文本时调度。	TextInput
clear	当用户从文本上下文菜单中选择“清除”（或“删除”）时调度。	InteractiveObject
click	用户在同一 InteractiveObject 上按下并释放用户指针设备的主按钮时调度。	InteractiveObject
contextMenu	当用户手势触发 AIR 应用程序中与此交互式对象相关联的上下文菜单时调度。	InteractiveObject
copy	在用户为复制操作激活特定于平台的加速键组合或从文本上下文菜单中选择“复制”时调度。	InteractiveObject
cut	在用户为剪切操作激活特定于平台的加速键组合或从文本上下文菜单中选择“剪切”时调度。	InteractiveObject
deactivate	[广播事件] Flash Player 或 AIR 应用程序失去操作系统焦点并变为非活动状态时将调度此事件。	EventDispatcher
doubleClick	如果 InteractiveObject 的 doubleClickEnabled 标志设置为 true，当用户在该对象上快速连续按下两次并释放指针设备的主按钮时调度。	InteractiveObject
enter	当用户按下 Enter 键时调度。	TextInput
enterFrame	[播放事件] 播放头进入新帧时调度。	DisplayObject
exitFrame	[广播事件] 播放头退出当前帧时调度。	DisplayObject
focusIn	显示对象获得焦点后调度。	InteractiveObject
focusOut	显示对象失去焦点后调度。	InteractiveObject
frameConstructed	[广播事件] 在帧显示对象的构造函数运行之后但在帧脚本运行之前调度。	DisplayObject
gestureDirectionalTap	当用户使用 InteractiveObject 实例沿触摸面边缘创建接触点时调度（如在 Siri Remote for Apple TV 上沿触摸面边缘轻击）。有些设备也可能将这种接触解释为多个触摸事件的组合。	InteractiveObject
gestureLongPress	当用户在启用触摸设备上的同一 InteractiveObject 实例上按下两个接触点时（例如，在配有触摸屏的移动电话或平板电脑上的显示对象上按下和释放两个手指）调度。	InteractiveObject
gesturePan	当用户在启用触摸的设备上的 InteractiveObject 实例上移动接触点时（例如，在配有触摸屏的移动电话或平板电脑上的显示对象上从左向右移动手指）调度。	InteractiveObject
gestureRotate	当用户在接触点处使用 InteractiveObject 实例执行旋转手势时（例如，将两个手指放在屏幕上，然后在配有触摸屏的移动电话或平板电脑上的显示对象上旋转这两个手指）调度。	InteractiveObject
gestureSwipe	当用户在接触点处使用 InteractiveObject 实例执行滑动手势（例如，在配有触摸屏的移动电话或平板电脑上用三根手指触摸屏幕，然后在一个显示对象上平行移动这三根手指）时调度。	InteractiveObject
gestureTap	当用户使用 InteractiveObject 实例创建接触点，然后点击启用触屏的设备时（例如，将几个手指放在显示对象上以打开菜单，然后点击一个手指在配有触摸屏的移动电话或平板电脑上选择一个菜单项）调度。	InteractiveObject
gestureZoom	当用户在接触点处使用 InteractiveObject 实例执行缩放手势操作时（例如，将两个手指放在屏幕上，然后在配有触摸屏的移动电话或平板电脑上的显示对象上快速分开手指）调度。	InteractiveObject
hide	在组件可见性从可见改为不可见以后调度。	UIComponent
imeStartComposition	此事件被调度到任何支持使用 IME 进行内联输入的客户端应用程序	InteractiveObject
keyDown	用户按下某个键时调度。	InteractiveObject
keyFocusChange	用户尝试使用键盘导航更改焦点时调度。	InteractiveObject
keyUp	用户释放某个键时调度。	InteractiveObject
middleClick	当用户在同一 InteractiveObject 上按下并释放用户指针设备的中间按钮时调度。	InteractiveObject
middleMouseDown	当用户在 InteractiveObject 实例上按下指针设备的中间按钮时调度。	InteractiveObject
middleMouseUp	当用户在 InteractiveObject 实例上释放指针设备按钮时调度。	InteractiveObject
mouseDown	当用户在 InteractiveObject 实例上按下指针设备按钮时调度。	InteractiveObject
mouseFocusChange	用户尝试使用指针设备更改焦点时调度。	InteractiveObject
mouseMove	用户移动 InteractiveObject 上的指针设备时调度。	InteractiveObject
mouseOut	用户将指针设备从 InteractiveObject 实例上移开时调度。	InteractiveObject
mouseOver	用户将指针设备移动到 InteractiveObject 实例上时调度。	InteractiveObject
mouseUp	当用户在 InteractiveObject 实例上释放指针设备按钮时调度。	InteractiveObject
mouseWheel	当鼠标滚轮滚动到 InteractiveObject 实例上时调度。	InteractiveObject
move	在移动组件以后调度。	UIComponent
nativeDragComplete	当用户释放拖动手势时由拖动启动器 InteractiveObject 调度。	InteractiveObject
nativeDragDrop	在将拖动对象放置到目标上且已通过对 DragManager.acceptDragDrop() 的调用接受该放置操作时，由目标 InteractiveObject 调度。	InteractiveObject
nativeDragEnter	当拖动手势进入其边界时由 InteractiveObject 调度。	InteractiveObject
nativeDragExit	当拖动手势离开其边界时由 InteractiveObject 调度。	InteractiveObject
nativeDragOver	当拖动手势保持在其边界内时，由 InteractiveObject 持续调度。	InteractiveObject
nativeDragStart	在拖动操作开始时由在 DragManager.doDrag() 调用中指定为拖动启动器的 InteractiveObject 调度。	InteractiveObject
nativeDragUpdate	在拖动操作期间由在 DragManager.doDrag() 调用中指定为拖动启动器的 InteractiveObject 调度。	InteractiveObject
paste	在用户为粘贴操作激活特定于平台的加速键组合或从文本上下文菜单中选择“粘贴”时调度。	InteractiveObject
proximityBegin	当用户将活动笔针放低经过屏幕的邻近检测阈值上时调度。	InteractiveObject
proximityEnd	当用户将活动笔针抬高放在屏幕的邻近检测阈值上时调度。	InteractiveObject
proximityMove	当用户将活动笔针移动到屏幕上但仍保留在邻近检测阈值中时调度。	InteractiveObject
proximityOut	当用户直接将活动笔针从此 InteractiveObject 上移开但仍保留在屏幕的邻近检测阈值中时调度。	InteractiveObject
proximityOver	当用户直接将活动笔针移动到此 InteractiveObject 上但仍保留在屏幕的邻近检测阈值中时调度。	InteractiveObject
proximityRollOut	当用户从此 InteractiveObject 及其任一子项中移开而仍保留在屏幕的邻近检测阈值中时调度。	InteractiveObject
proximityRollOver	当用户将活动笔针从显示列表中子项的对象树中滑过此 InteractiveObject 时（而仍保留在屏幕的邻近检测阈值中）时调度。	InteractiveObject
releaseOutside	在用户首先在 InteractiveObject 实例上按下按钮，然后将指针设备移离 InteractiveObject 实例，释放指针设备上的按钮时调度。	InteractiveObject
removed	将要从显示列表中删除显示对象时调度。	DisplayObject
removedFromStage	在从显示列表中直接删除显示对象或删除包含显示对象的子树时调度。	DisplayObject
render	[广播事件] 将要更新和呈现显示列表时调度。	DisplayObject
resize	在调整组件大小以后调度。	UIComponent
rightClick	当用户在同一 InteractiveObject 上按下并释放用户指针设备的右按钮时调度。	InteractiveObject
rightMouseDown	当用户在 InteractiveObject 实例上按下指针设备按钮时调度。	InteractiveObject
rightMouseUp	当用户在 InteractiveObject 实例上释放指针设备按钮时调度。	InteractiveObject
rollOut	用户将指针设备从 InteractiveObject 实例上移开时调度。	InteractiveObject
rollOver	用户将指针设备移动到 InteractiveObject 实例上时调度。	InteractiveObject
selectAll	在用户为全选操作激活特定于平台的加速键组合或从文本上下文菜单中选择“全选”时调度。	InteractiveObject
show	在组件可见性从不可见改为可见以后调度。	UIComponent
softKeyboardActivate	在放开软键盘之后立即调度。	InteractiveObject
softKeyboardActivating	在放开软键盘之前立即调度。	InteractiveObject
softKeyboardDeactivate	在隐藏软键盘之后立即调度。	InteractiveObject
tabChildrenChange	对象的 tabChildren 标志值发生更改时调度。	InteractiveObject
tabEnabledChange	对象的 tabEnabled 标志发生更改时调度。	InteractiveObject
tabIndexChange	对象的 tabIndex 属性值发生更改时调度。	InteractiveObject
textInput	当用户输入文本时调度。	TextInput
touchBegin	当用户第一次触摸启用触摸的设备时（例如，用手指触摸配有触摸屏的移动电话或平板）调度。	InteractiveObject
touchEnd	当用户移除与启用触摸的设备的接触时（例如，将手指从配有触摸屏的移动电话或平板电脑上抬起）调度。	InteractiveObject
touchMove	当用户触碰设备时进行调度，而且会连续调度，直到接触点被删除。	InteractiveObject
touchOut	当用户将接触点从启用触摸的设备上的 InteractiveObject 实例移开时（例如，在配有触摸屏的移动电话或平板电脑上，将手指从一个显示对象拖到另一个显示对象）调度。	InteractiveObject
touchOver	当用户在启用触摸的设备的 InteractiveObject 实例上移动接触点时（例如，在配有触摸屏的移动电话或平板电脑上，将手指从显示对象外的一点拖动到显示对象上的一点）调度。	InteractiveObject
touchRollOut	当用户移动接触点，使其远离启用触摸的设备上的 InteractiveObject 实例时（例如，在配有触摸屏的移动电话或平板电脑上将一个手指从显示对象上的一点移动到显示对象外的一点）调度。	InteractiveObject
touchRollOver	当用户在启用触摸的设备的 InteractiveObject 实例上移动接触点时（例如，在配有触摸屏的移动电话或平板电脑上，将手指从显示对象外的一点拖动到显示对象上的一点）调度。	InteractiveObject
touchTap	当用户在启用触摸设备上的已启动接触的同一 InteractiveObject 实例上抬起接触点时（例如，在配有触摸屏的移动电话或平板的显示对象上的某一点处按下并释放手指）调度。	InteractiveObject

样式

样式为常见样式，或与特定主题关联。如果为常见样式，则可以用于任何主题。如果样式与特定主题关联，则只有应用程序使用该主题时才能使用该样式。

常见样式

单击此处了解有关样式的更多信息

隐藏继承的样式

显示继承的样式

	说明	由以下参数定义
disabledSkin	类型: Class 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 将 TextInput 组件的 `enabled` 属性设置为 `false` 时用作该组件背景的类的名称。默认值为 `TextInput_disabledSkin`。	TextInput
disabledTextFormat	类型: flash.text.TextFormat 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 用于在禁用了按钮的情况下呈现组件标签的 TextFormat 对象.	UIComponent
embedFonts	类型: Boolean 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 指示是否使用嵌入字体轮廓呈现文本字段。如果该值为 `true`，则 Flash Player 使用嵌入字体轮廓呈现文本字段。如果该值为 `false`，则 Flash Player 使用设备字体呈现文本字段。如果将文本字段的 `embedFonts` 属性设置为 `true`，则必须使用应用于该文本字段的 TextFormat 对象的 `font` 属性来指定该文本的字体。如果指定的字体没有嵌入 SWF 文件中，则不会显示该文本。默认值为 `false`。	TextInput
focusRectPadding	类型: Number 格式: Length 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 用于分隔组件的外边框和焦点指示符的外边框的填充（以像素为单位）.	UIComponent
focusRectSkin	类型: Class 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 用于显示焦点指示符的外观.	UIComponent
textFormat	类型: flash.text.TextFormat 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 用于呈现组件标签的 TextFormat 对象.	UIComponent
textPadding	类型: Number 格式: Length 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 用于分隔组件边框和文本的填充（以像素为单位）。默认值为 `0`。	TextInput
upSkin	类型: Class 语言版本: ActionScript 3.0 产品版本: Flash CS3 运行时版本: Flash9.0.28.0, AIR 1.0 用作 TextInput 组件背景的类的名称。默认值为 `TextInput_upSkin`。	TextInput

公共常量

隐藏继承的公共常量

显示继承的公共常量

	常量		由以下参数定义
		version : String = "3.0.3.1" 组件的版本号。	UIComponent

属性详细信息

alwaysShowSelection

属性

alwaysShowSelection:Boolean

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置一个布尔值，指示当文本字段不具有焦点时选定内容的显示方式。

如果该值设置为 true 且文本字段不具有焦点，Flash Player 将以灰色突出显示文本字段中的选定内容。如果该值设置为 false 且文本字段不具有焦点，则 Flash Player 不会突出显示文本字段中的选定内容。

默认值为 false。

实现
public function get alwaysShowSelection():Boolean
public function set alwaysShowSelection(value:Boolean):void

示例 ( 如何使用本示例 )

下例创建一个 TextInput 组件，并使用 setSelection() 方法选择一些文本：


import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.text = "The quick brown fox jumped over the lazy dog.";
myTextInput.alwaysShowSelection = true;
myTextInput.setSelection(16, 19);
myTextInput.move(10, 10);
addChild(myTextInput);

condenseWhite

属性

condenseWhite:Boolean

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置一个布尔值，该值指示是否从包含 HTML 文本的 TextInput 组件中删除额外空白。空格和换行符都属于组件中的额外空白。 true 值指示删除多余的空白；false 值指示不删除多余的空白。

此属性只影响使用 htmlText 属性设置的文本，而不影响使用 text 属性设置的文本。如果使用 text 属性设置文本，则忽略 condenseWhite 属性。

如果将 condenseWhite 属性设置为 true，则必须使用标准 HTML 命令（如 <br> 和 <p>）将换行符放在文本字段中。

默认值为 false。

实现
public function get condenseWhite():Boolean
public function set condenseWhite(value:Boolean):void

相关 API 元素

TextField.condenseWhite

displayAsPassword

属性

displayAsPassword:Boolean

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置一个布尔值，该值指示当前创建的 TextInput 组件实例用于包含密码还是文本。 true 值指示组件实例为密码文本字段；false 值指示组件实例为正常文本字段。

将此属性设置为 true 时，对于用户在文本字段中输入的每个字符，TextInput 组件实例将显示星号。此外，“剪切”和“复制”命令及其键盘快捷键将被禁用。这些措施可防止有人从无人看管的计算机上获取密码。

默认值为 false。

实现
public function get displayAsPassword():Boolean
public function set displayAsPassword(value:Boolean):void

相关 API 元素

TextField.displayAsPassword

示例 ( 如何使用本示例 )

下例创建两个 TextInput 组件实例，其中一个实例的 displayAsPassword 属性设置为 true，另一个实例的该属性设置为 false：


import fl.controls.Label;
import fl.controls.TextInput;

var usernameLabel:Label = new Label();
usernameLabel.text = "User name:";
usernameLabel.move(10, 10);
addChild(usernameLabel);

var usernameTextInput:TextInput = new TextInput();
usernameTextInput.move(90, 10);
addChild(usernameTextInput);

var passwordLabel:Label = new Label();
passwordLabel.text = "Password:";
passwordLabel.move(10, 40);
addChild(passwordLabel);

var passwordTextInput:TextInput = new TextInput();
passwordTextInput.displayAsPassword = true;
passwordTextInput.move(90, 40);
addChild(passwordTextInput);

editable

属性

editable:Boolean

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置一个布尔值，指示用户能否编辑文本字段。 true 值指示用户可以编辑文本字段；false 值指示用户不能编辑文本字段。

默认值为 true。

实现
public function get editable():Boolean
public function set editable(value:Boolean):void

enabled

属性

enabled:Boolean[覆盖]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置一个值，该值指示组件是否可以接受用户交互。 true 值指示组件可以接受用户交互；false 值指示组件无法接受用户交互。

如果将 enabled 属性设置为 false，则容器的颜色将变暗，并且禁止用户输入（Label 和 ProgressBar 组件除外）。

实现
override public function get enabled():Boolean
override public function set enabled(value:Boolean):void

horizontalScrollPosition

属性

horizontalScrollPosition:int

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置水平滚动条的滑块位置。

默认值为 0。

实现
public function get horizontalScrollPosition():int
public function set horizontalScrollPosition(value:int):void

相关 API 元素

maxHorizontalScrollPosition

示例 ( 如何使用本示例 )

下例创建一个 TextInput 组件实例，并显示其 horizontalScrollPosition 和 maxHorizontalScrollPosition 属性的当前值：


import fl.controls.Label;
import fl.controls.Slider;
import fl.controls.TextInput;
import fl.events.SliderEvent;

var myTextInput:TextInput = new TextInput();
myTextInput.text = "The quick brown fox jumped over the lazy dog.";
myTextInput.width = 120;
myTextInput.move(10, 10);
myTextInput.addEventListener(Event.CHANGE, textInputChangeHandler);
myTextInput.textField.addEventListener(Event.SCROLL, scrollHandler);
addChild(myTextInput);

var mySlider:Slider = new Slider();
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.minimum = 0;
mySlider.maximum = myTextInput.maxHorizontalScrollPosition;
mySlider.value = myTextInput.horizontalScrollPosition;
mySlider.liveDragging = true;
mySlider.addEventListener(SliderEvent.CHANGE, sliderChangeHandler);
mySlider.width = 120;
mySlider.move(10, 40);
addChild(mySlider);

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 50);
addChild(myLabel);

getScrollPosition();

function getScrollPosition():void {
    myTextInput.drawNow();
    var scrollPos:uint = myTextInput.horizontalScrollPosition;
    var maxScrollPos:uint = myTextInput.maxHorizontalScrollPosition;
    myLabel.text = "scrollPosition: " + scrollPos + " of " + maxScrollPos;
    mySlider.value = scrollPos;
    mySlider.maximum = maxScrollPos;
}

function scrollHandler(event:Event):void {
    getScrollPosition();
}

function sliderChangeHandler(event:SliderEvent):void {
    myTextInput.horizontalScrollPosition = event.value;
    getScrollPosition();
}

function textInputChangeHandler(event:Event):void {
    getScrollPosition();
}

htmlText

属性

htmlText:String

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

包含文本字段所含字符串的 HTML 表示形式。

默认值为 ""。

实现
public function get htmlText():String
public function set htmlText(value:String):void

相关 API 元素

text
flash.text.TextField.htmlText

示例 ( 如何使用本示例 )

下例创建一个不可编辑的 TextInput 组件，并设置 htmlText 属性以将 HTML 格式应用于文本字段的文本：


import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.editable = false;
myTextInput.enabled = false;
myTextInput.htmlText = "(<i>auto assigned</i>)";
myTextInput.move(10, 10);
addChild(myTextInput);

imeMode

属性

imeMode:String

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置输入法编辑器 (IME) 的模式。 IME 使用户能够使用 QWERTY 键盘从中文、日文和韩文字符集输入字符。

Flash 在组件获得焦点时将 IME 设置为指定模式，并在组件失去焦点后还原为初始值。

flash.system.IMEConversionMode 类定义此属性的有效值的常量。将此属性设置为 null 阻止对组件使用 IME。

实现
public function get imeMode():String
public function set imeMode(value:String):void

length

属性

length:int [只读]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取 TextInput 组件中的字符数。

默认值为 0。

实现
public function get length():int

相关 API 元素

maxChars

示例 ( 如何使用本示例 )

下例创建一个 TextInput 组件，并设置其 maxChars 和 restrict 属性以限制可输入的字符数：


import fl.controls.Label;
import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.restrict = "0-9A-F";
myTextInput.maxChars = 6;
myTextInput.move(10, 10);
myTextInput.addEventListener(Event.CHANGE, changeHandler);
addChild(myTextInput);

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = myTextInput.length + " of " + myTextInput.maxChars;
myLabel.move(10, 30);
addChild(myLabel);

function changeHandler(event:Event):void {
    myLabel.text = myTextInput.length + " of " + myTextInput.maxChars;
}

maxChars

属性

maxChars:int

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置用户可以在文本字段中输入的最大字符数。

默认值为 0。

实现
public function get maxChars():int
public function set maxChars(value:int):void

相关 API 元素

length

示例 ( 如何使用本示例 )

下例创建一个 TextInput 组件，并设置其 maxChars 和 restrict 属性以限制可输入的字符数：


import fl.controls.Label;
import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.restrict = "0-9A-F";
myTextInput.maxChars = 6;
myTextInput.move(10, 10);
myTextInput.addEventListener(Event.CHANGE, changeHandler);
addChild(myTextInput);

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = myTextInput.length + " of " + myTextInput.maxChars;
myLabel.move(10, 30);
addChild(myLabel);

function changeHandler(event:Event):void {
    myLabel.text = myTextInput.length + " of " + myTextInput.maxChars;
}

maxHorizontalScrollPosition

属性

maxHorizontalScrollPosition:int [只读]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取一个值，描述文本字段向右滚动可达到的最远位置。

默认值为 0。

实现
public function get maxHorizontalScrollPosition():int

相关 API 元素

horizontalScrollPosition

restrict

属性

restrict:String

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置文本字段从用户处接受的字符串。请注意，未包含在本字符串中的以编程方式输入的字符也为文本字段所接受。

字符串中字符的读取顺序为从左到右。可以使用连字符 (-) 指定一个字符范围。

如果此属性的值为 null，则文本字段会接受所有字符。如果此属性设置为空字符串 ("")，则文本字段不接受任何字符。

如果字符串以尖号 (^) 开头，则先接受所有字符，然后从接受字符集中排除字符串中 ^ 之后的字符。如果字符串不以尖号 (^) 开头，则最初不接受任何字符，然后将字符串中的字符包括在接受字符集中。

默认值为 null。

实现
public function get restrict():String
public function set restrict(value:String):void

相关 API 元素

TextField.restrict

selectionBeginIndex

属性

selectionBeginIndex:int [只读]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取包含一个或多个字符的选定内容中第一个所选字符的索引值。

所选字符的索引位置为从零开始并由文本区域中显示的第一个字符开始计算。如果未选择任何内容，则该值将设置为尖号的位置。

默认值为 0。

实现
public function get selectionBeginIndex():int

相关 API 元素

selectionEndIndex
setSelection()

示例 ( 如何使用本示例 )

下例创建一个 Label 组件，该组件显示 TextInput 组件的 selectionBeginIndex 和 selectionEndIndex 属性。此外，此示例还创建两个 Slider 组件实例，以使用 setSelection() 方法以编程方式设置所选内容的开始索引和结束索引：


import fl.controls.Label;
import fl.controls.Slider;
import fl.controls.TextInput;
import fl.events.SliderEvent;

var myTextInput:TextInput = new TextInput();
myTextInput.alwaysShowSelection = true;
myTextInput.text = "The quick brown fox jumped over the lazy dog.";
myTextInput.width = 120;
myTextInput.move(10, 10);
myTextInput.addEventListener(Event.CHANGE, changeHandler);
myTextInput.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
myTextInput.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
addChild(myTextInput);

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 30);
addChild(myLabel);

var beginSlider:Slider = new Slider();
beginSlider.maximum = myTextInput.length;
beginSlider.snapInterval = 1;
beginSlider.liveDragging = true;
beginSlider.width = 120;
beginSlider.move(10, 65);
beginSlider.addEventListener(SliderEvent.CHANGE, beginChangeHandler);
addChild(beginSlider);

var endSlider:Slider = new Slider();
endSlider.maximum = myTextInput.length;
endSlider.snapInterval = 1;
endSlider.liveDragging = true;
endSlider.width = 120;
endSlider.move(10, 85);
endSlider.addEventListener(SliderEvent.CHANGE, endChangeHandler);
addChild(endSlider);

var t:Timer = new Timer(50);
t.addEventListener(TimerEvent.TIMER, timerHandler);

function changeHandler(event:Event):void {
    beginSlider.maximum = myTextInput.length;
    endSlider.maximum = myTextInput.length;
    updateUI();
}

function focusInHandler(event:FocusEvent):void {
    t.start();
}

function focusOutHandler(event:FocusEvent):void {
    t.stop();
}

function beginChangeHandler(event:SliderEvent):void {
    myTextInput.setSelection(event.value, myTextInput.selectionEndIndex);
    updateUI();
}

function endChangeHandler(event:SliderEvent):void {
    myTextInput.setSelection(myTextInput.selectionBeginIndex, event.value);
    updateUI();
}

function timerHandler(event:TimerEvent):void {
    updateUI();
}

function updateUI():void {
    myLabel.text = "selectionBeginIndex:" + myTextInput.selectionBeginIndex + "\n";
    myLabel.text += "selectionEndIndex:" + myTextInput.selectionEndIndex;
    beginSlider.value = myTextInput.selectionBeginIndex;
    endSlider.value = myTextInput.selectionEndIndex;
}

selectionEndIndex

属性

selectionEndIndex:int [只读]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取包含一个或多个字符的选定内容中最后一个所选字符的索引位置。

所选字符的索引位置为从零开始并由文本区域中显示的第一个字符开始计算。如果未选择任何内容，则该值将设置为尖号的位置。

默认值为 0。

实现
public function get selectionEndIndex():int

相关 API 元素

selectionBeginIndex
setSelection()

text

属性

text:String

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

获取或设置字符串，其中包含当前 TextInput 组件中的文本。此属性包含无格式文本，不包含 HTML 标签。若要检索格式为 HTML 的文本，请使用 htmlText 属性。

默认值为 ""。

实现
public function get text():String
public function set text(value:String):void

相关 API 元素

htmlText

textField

属性

public var textField:flash.text:TextField

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

对 TextInput 组件的内部文本字段的引用。

示例 ( 如何使用本示例 )

下例创建一个 TextInput 组件实例，使用 textField 属性访问基础本机 ActionScript TextField 对象，并调用其 replaceText() 方法：


import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.text = "The quick brown fox jumped over the lazy dog.";
myTextInput.textField.replaceText(41, 44, "fox");
myTextInput.textField.replaceText(16, 19, "dog");
addChild(myTextInput);

textHeight

属性

textHeight:Number [只读]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

文本的高度，以像素为单位。

默认值为 0。

实现
public function get textHeight():Number

相关 API 元素

textWidth

属性

textWidth:Number [只读]

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

文本的宽度，以像素为单位。

默认值为 0。

实现
public function get textWidth():Number

相关 API 元素

textHeight

示例 ( 如何使用本示例 )

下例创建一个 TextInput 组件实例，每当文本字段的内容发生更改时就输出 textWidth 和 textHeight 属性：


import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.move(10, 10);
myTextInput.addEventListener(Event.CHANGE, changeHandler);
addChild(myTextInput);

function changeHandler(event:Event):void {
    trace("textWidth:" + myTextInput.textWidth + ", textHeight:" + myTextInput.textHeight);
}

构造函数详细信息

()

构造函数

public function TextInput()

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

创建新的 TextInput 组件实例。

方法详细信息

appendText

()

方法

public function appendText(text:String):void

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

将指定字符串追加到 TextArea 所包含的最后一个字符之后。与通过对 text 属性使用加法赋值来连接两个字符串（例如 myTextArea.text += moreText）相比，此方法的效率更高。此方法在 TextArea 组件包含大量内容时特别有用。

参数

text:String — 要追加到现有文本末尾的字符串。

drawFocus

()

方法

override public function drawFocus(draw:Boolean):void

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

在此组件上显示或隐藏焦点指示符。

UIComponent 类通过创建并放置 focusSkin 样式指定的类的实例来实现该方法。

参数

draw:Boolean — 指示是显示还是隐藏焦点指示符。如果该值为 true，则显示焦点指示符；如果该值为 false，则隐藏焦点指示符。

getLineMetrics

()

方法

public function getLineMetrics(index:int):flash.text:TextLineMetrics

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

检索有关指定文本行的信息。

参数

index:int — 要检索的信息所在行的行号。

flash.text:TextLineMetrics

示例 ( 如何使用本示例 )

下例在文本输入相对于基线的上缘上绘制一个红色矩形，在文本输入相对于基线的下缘上绘制一个蓝色矩形。

var format:TextFormat = new TextFormat();
format.size = 72;
format.font = "Georgia";

import fl.controls.TextInput;

var ti:TextInput = new TextInput();
addChild(ti);
ti.setSize(393,82);
ti.move(10,10);
ti.setStyle("textFormat",format);
ti.text = "Hello World";
ti.drawNow();

var metrics:TextLineMetrics = ti.getLineMetrics(0);

var ascenderColoring:Shape = new Shape();
var descenderColoring:Shape = new Shape();
ti.addChild(ascenderColoring);
ti.addChild(descenderColoring);

ascenderColoring.graphics.clear();
ascenderColoring.graphics.beginFill(0xFF0000,0.2);
ascenderColoring.graphics.drawRect(0, 0, metrics.width, metrics.ascent);
descenderColoring.graphics.clear();
descenderColoring.graphics.beginFill(0x0000FF,0.2);
descenderColoring.graphics.drawRect(0, metrics.ascent + 2, metrics.width, metrics.descent);

getStyleDefinition

()

方法

public static function getStyleDefinition():Object

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

检索当前组件的默认样式映射。样式映射包含适合组件的类型，具体取决于组件使用的样式。例如，disabledTextFormat 样式包含 null 值或 TextFormat 对象。可以使用这些样式并对当前组件调用 setStyle()。下面的代码覆盖指定组件上默认的 disabledTextFormat 样式：

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Object — 默认样式对象。

示例 ( 如何使用本示例 )

下例为多个组件类创建一个样式浏览器：

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

setSelection

()

方法

public function setSelection(beginIndex:int, endIndex:int):void

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

设置在具有焦点的文本区域中选定内容的范围。选定内容的范围从由 start 参数指定的索引处开始，到由 end 参数指定的索引处结束。如果指定选定内容范围的参数值相同，则此方法会设置文本插入点，设置方式与 caretIndex 属性相同。

选定的文本被视为从零开始的一串字符，其中第一个选定字符位于索引 0 处，第二个字符位于索引 1 处，依此类推。

如果文本字段不具有焦点，则此方法无效。

参数

	`beginIndex:int` — 选定内容中第一个字符的索引位置。

	`endIndex:int` — 选定内容中最后一个字符的索引位置。

相关 API 元素

selectionBeginIndex
selectionEndIndex

示例 ( 如何使用本示例 )

下例在 TextInput 实例中输入文本，并将所选内容设置为第二个字：

import fl.controls.TextInput;

var ti:TextInput = new TextInput();
addChild(ti);
ti.text = "Hello World";
ti.setFocus();
ti.setSelection(6, 11);

下例创建一个 TextInput 组件，并使用 setSelection() 方法选择一些文本：


import fl.controls.TextInput;

var myTextInput:TextInput = new TextInput();
myTextInput.text = "The quick brown fox jumped over the lazy dog.";
myTextInput.alwaysShowSelection = true;
myTextInput.setSelection(16, 19);
myTextInput.move(10, 10);
addChild(myTextInput);

事件详细信息

change

事件

事件对象类型: flash.events.Event
属性 Event.type = flash.events.Event.CHANGE

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

当用户在 TextInput 组件中输入更改文本时调度。

注意：如果使用 ActionScript 更改文本，则不会发生此事件。

Event.CHANGE 常量定义 change 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已修改其值的对象。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

enter

事件

事件对象类型: fl.events.ComponentEvent
属性 ComponentEvent.type = fl.events.ComponentEvent.ENTER

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

当用户按下 Enter 键时调度。

定义 enter 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

textInput

事件

事件对象类型: flash.events.TextEvent
属性 TextEvent.type = flash.events.TextEvent.TEXT_INPUT

语言版本:

ActionScript 3.0

产品版本:

Flash CS3

运行时版本:

Flash Player 9.0.28.0, AIR 1.0

当用户输入文本时调度。

定义 textInput 事件对象的 type 属性值。

注意：对于 Delete 或 Backspace 键不会调度此事件。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`true`；调用 `preventDefault()` 方法以取消默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	在其中输入字符的文本字段。target 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`text`	用户输入的字符或字符序列。

示例如何使用本示例

TextInputExample.as

此示例演示如何使用 TextInput 类构建一个基本的登录系统。

将 TextInput、Label 和 Button 组件添加到库中
将该代码作为 TextInputExample.as 另存到 FLA 文件所在的同一目录中。
将 FLA 中的 DocumentClass 设置为 TextInputExample。

package 
{
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import fl.controls.TextInput;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class TextInputExample extends Sprite
    {
        private var ti1:TextInput;
        private var ti2:TextInput;
        private var label1:Label;
        private var label2:Label;
        private var submitBtn:Button;
        
        public function TextInputExample() {
            setupLabels();
            setupInputFields();    
            setupButton();
        }
        private function setupInputFields():void {
            ti1 = new TextInput();
            ti2 = new TextInput();
            ti1.move(50,10);
            ti2.move(50,40);
            ti2.displayAsPassword = true;
            ti1.addEventListener(Event.CHANGE, textEntered);
            ti2.addEventListener(Event.CHANGE, textEntered);
            addChild(ti1);
            addChild(ti2);
        }
        private function setupLabels():void {
            label1 = new Label();
            label2 = new Label();
            label1.move(10,10);
            label2.move(10,40);
            label1.text = "User:";
            label2.text = "Pass:"
            addChild(label1);
            addChild(label2);
        }
        private function setupButton():void {
            submitBtn = new Button();
            submitBtn.move(150,70);
            submitBtn.label = "Go";
            submitBtn.enabled = false;
            submitBtn.setSize(50,20);
            submitBtn.addEventListener(MouseEvent.CLICK, submitLogin);
            addChild(submitBtn);
        }
        private function textEntered(e:Event):void {
            if(ti1.text != "" && ti2.text != "") {
                submitBtn.enabled = true;
            }
            else {
                submitBtn.enabled = false;    
            }
        }
        private function submitLogin(e:MouseEvent):void {
            var submitLabel:Label = new Label();
            submitLabel.move(10,70);
            submitLabel.autoSize = "left";
            submitLabel.text = "Login has been submitted."
            addChild(submitLabel);
            submitBtn.removeEventListener(MouseEvent.CLICK, submitLogin);
        }
    }
}

法律声明 | 在线隐私策略

TextInput - AS3 Flash

类 x

alwaysShowSelection

condenseWhite

displayAsPassword

editable

enabled

horizontalScrollPosition

htmlText

imeMode

length

maxChars

maxHorizontalScrollPosition

restrict

selectionBeginIndex

selectionEndIndex

text

textField

textHeight

textWidth

TextInput

appendText

drawFocus

getLineMetrics

getStyleDefinition

setSelection

change

enter

textInput