Transform  - AS3

一个 ColorTransform 对象，其中包含整体调整显示对象颜色的值。

相关 API 元素

一个 ColorTransform 对象，表示应用于此显示对象及其所有父级对象的组合颜色转换，回到根级别。如果在不同级别上应用了不同的颜色转换，则将其中所有转换连接成此属性的一个 ColorTransform 对象。

相关 API 元素

一个 Matrix 对象，表示此显示对象及其所有父级对象的组合转换矩阵，回到根级别。如果在不同级别上应用了不同的转换矩阵，则将其中所有矩阵连接成此属性的一个矩阵。此外，对于浏览器中运行的可调整大小的 SWF 内容，此属性将因调整窗口大小而造成的舞台坐标与窗口坐标之差视为重要因素。因此，该属性将局部坐标转换为窗口坐标，后者可能与舞台的坐标空间不同。

一个 Matrix 对象，其中包含更改显示对象的缩放、旋转和平移的值。

如果将 matrix 属性设置为某个值（非 null），则 matrix3D 属性为 null。如果将 matrix3D 属性设置为某个值（非 null），则 matrix 属性为 null。

相关 API 元素

提供对三维显示对象的 Matrix3D 对象的访问。Matrix3D 对象表示一个转换矩阵，它确定显示对象的位置和方向。Matrix3D 对象还可以执行透视投影。

如果将 matrix 属性设置为某个值（非 null），则 matrix3D 属性为 null。如果将 matrix3D 属性设置为某个值（非 null），则 matrix 属性为 null。

相关 API 元素

提供对三维显示对象的 PerspectiveProjection 对象的访问。可以使用 PerspectiveProjection 对象修改舞台的透视转换，也可以将透视转换分配给显示对象的所有三维子级。

基于视野和舞台的高宽比（尺寸），将默认的 PerspectiveProjection 对象分配给 root 对象。

相关 API 元素

一个 Rectangle 对象，它定义舞台上的显示对象的边界矩形。

返回一个 Matrix3D 对象，该对象可以相对于当前显示对象的空间转换指定显示对象的空间。可以使用 getRelativeMatrix3D() 方法，将一个三维显示对象相对于另一个三维显示对象移动。

参数

相关 API 元素

1. TransformExample() 构造函数创建一个新的 sprite 对象 target。
2. TransformExample() 构造函数调用 draw() 方法，该方法在 sprite 中绘制一个渐变正方形。
3. TransformExample() 构造函数为 sprite 添加 click 事件侦听器，该侦听器由 clickHandler() 方法处理。
4. clickHandler() 方法创建一个新的 Matrix 对象 skewMatrix，该对象被设置为应用倾斜效果。将另一个矩阵 tempMatrix 分配给 Sprite 的当前转换矩阵，然后使用 concat() 方法将它与 skewMatrix 合并。将此矩阵分配给正方形 Sprite 的 transform.matrix 属性。每次用户单击正方形时，对 clickHandler() 的调用都将通过倾斜正方形来修改其形状。
5. 此外，clickHandler() 方法创建一个新的 ColorTransform 对象。新 ColorTransform 的 redOffset 属性设置为 redOffset 的当前值并且每次增加 25。同样，blueOffset 属性每次减少 25。每次单击时，Sprite 的颜色都会改变。

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}