AccessibilityImplementation  - AS3

表示错误代码。表示错误为带外错误，而不是返回值错误。要表示错误，请将 errno 属性设置为“AccessibilityImplementation 常量”附录中记录的错误代码之一。这样会导致忽略返回值。在调用任何 AccessibilityImplementation 方法之前，Player 始终会清除 AccessibilityImplementation 的 errno 属性（设置为 0）。

相关 API 元素

用于创建组件辅助功能存根。如果释放的组件不具有 ActionScript 辅助功能实现，Adobe 建议您添加组件辅助功能存根。在组件内，为实现辅助功能，此存根会使 Flash Player 将组件视为简单图形，而不会公开按钮和 Textfield 等的内部结构。

要创建组件辅助功能存根，请对相关的 AccImpl 类进行子分类，从而用 true 值覆盖属性存根。

相关 API 元素

静态构造函数。请勿通过调用 AccessibilityImplementation 的构造函数直接将它实例化，而应通过扩展每个新组件的 mx.accessibility.AccImpl 类来创建新的辅助功能实现。

相关 API 元素

一个 IAccessible 方法，执行与此 AccessibilityImplementation 表示的组件关联的默认操作，或执行该组件的子元素之一的默认操作。

仅当 AccessibilityImplementation 表示一个在 MSAA 模型中具有默认操作的 UI 元素时，才能实现此方法。

如果只针对 AccessibilityImplementation 本身或其子元素实现 accDoDefaultAction()，则有时需要指明传递的特定 childID 没有默认操作。为 E_MEMBERNOTFOUND 设置 errno 属性即可指明这一点。

参数

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

MSAA 方法，返回指定 AccessibilityImplementation 中子元素边框的 DisplayObject 或 Rectangle。

从不会使用零值的 childID 调用此方法。如果 AccessibilityImplementation 始终不会包含子元素，则不应实现此方法。如果 AccessibilityImplementation 可以包含子元素，则强制实现此方法。

通常可以通过返回表示子元素本身的对象来满足对此方法的要求。只要子元素为 DisplayObject，就可以采用这种方式。在这些情况下，将只返回与实例名称对应的 DisplayObject，该实例名称与显示列表中的相关可视对象相关联。

如果子元素不满足上述技术要求，您可以自己进行边框计算，返回具有以下属性的 Rectangle：x、y、width 和 height。x 和 y 成员指定边框的左上角，width 和 height 成员指定边框的大小。所有四个成员都应以舞台像素为单位，其值相对于 AccessibilityImplementation 所表示的组件的原点。x 和 y 属性可能具有负值，因为 DisplayObject 的原点未必在其左上角。

如果 childID 所指定的子元素不可见（即该子元素的 get_accState 将返回 STATE_SYSTEM_INVISIBLE 值），则您可能会从 accLocation 得到 null。您也可以返回一个 Rectangle，表示可见子元素显示处的坐标。

参数

了解详细信息

相关 API 元素

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

IAccessible 方法，更改此 AccessibilityImplementation 所表示组件中的选定内容。

childID 参数始终是非零参数。此方法始终应用于子元素，而不是应用于整个组件；Flash Player 自身管理整个组件的选择。

selFlag 参数是包含一个或多个选择标志常量的位域，MSAA 客户端可以使用该参数表示应如何选择 childID 所引用的项，或者使该项获得焦点。该参数后面是对选择标志常量的描述，以及这些常量向辅助功能实现传达的信息。实际操作时，此方法在辅助功能实现中继承自 Flex mx.accessibility.ListBaseAccImpl 类的大多数实现会忽略 selFlag 常量，而依赖该组件的键盘选择行为来处理多项选择。

selFlag 参数不一定包含 SELFLAG_TAKEFOCUS 标志。如果该参数确实包含此标志，则应将子焦点设置为指定的 childID，并且，除非参数也包含 SELFLAG_EXTENDSELECTION，否则请将该子元素设为选择锚点。另外，尽管下述其他标志可能会修改选定内容，但是仍然不应修改子焦点和选择锚点。

selFlag 参数将始终包含以下四个标志之一，表示需要哪种选择修改：

• SELFLAG_TAKESELECTION：清除所有现有的选定内容，并将选定内容设置为指定的 childID。

• SELFLAG_EXTENDSELECTION：计算选择锚点和所指定 childID 之间（含）的子元素范围。如果存在 SELFLAG_ADDSELECTION，则将所有这些子元素添加到选定内容中。如果存在 SELFLAG_REMOVESELECTION，则从选定内容中删除所有这些子元素。如果 SELFLAG_ADDSELECTION 和 SELFLAG_REMOVESELECTION 不存在，则所有这些子元素都应采用选择锚点的选择状态：如果选择了选择锚点，则将这些子元素添加到选定内容中；否则，将从选定内容中删除这些子元素。

• SELFLAG_ADDSELECTION（没有 SELFLAG_EXTENDSELECTION）：将指定的 childID 添加到选定内容中。

• SELFLAG_REMOVESELECTION（没有 SELFLAG_EXTENDSELECTION）：从选定内容中删除指定的 childID。

请注意，对于非多项选择组件，唯一有效的 selFlag 参数值为 SELFLAG_TAKEFOCUS 和 SELFLAG_TAKESELECTION。对于允许用户强制执行 null 选择的非多项选择组件，从理论上也可以选择支持 SELFLAG_REMOVESELECTION，但实际上大多数非多项选择组件不采用此种方式，MSAA 客户端也可能不会尝试进行此类操作。

如果遇到看似无效的标志，请为 E_INVALIDARG 设置 errno。

最后请注意，调用 accSelect 时，Flash Player 可确保它具有宿主焦点（即容器应用程序的窗口焦点），并确保组件在 Flash Player 中具有焦点。

参数

了解详细信息

相关 API 元素

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

MSAA 方法，返回此 AccessibilityImplementation 所表示组件的默认操作，或该组件的子元素之一的默认操作。

仅当 AccessibilityImplementation 表示在 MSAA 模型中具有默认操作的 UI 元素时，才实现此方法；请确保返回 MSAA 模型指定的确切字符串。例如，Button 组件的默认操作字符串是“Press”。

如果只针对 AccessibilityImplementation 本身或其子元素实现 get_accDefaultAction，则有时需要指明传递的特定 childID 没有默认操作。只需返回 null 即可执行此操作。

参数

了解详细信息

相关 API 元素

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

MSAA 方法，返回在组件内具有子焦点的子元素（如果有）的无符号整数 ID。如果不存在具有子焦点的子元素，则该方法返回零。

了解详细信息

相关 API 元素

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

MSAA 方法，返回此 AccessibilityImplementation 所表示组件的名称或组件子元素之一的名称。

对于 AccessibilityImplementation 本身 (childID == 0)，如果不实现此方法，或者不返回值，则 Flash Player 将使用 AccessibilityProperties.name 属性值（如果存在）。

对于可以包含子元素的 AccessibilityImplementation，必须实现此方法，并且在 childID 不为零时必须返回一个字符串值。

根据用户界面元素的类型，MSAA 中的名称表示以下两种不同类型的内容之一：作者分配的名称或元素的实际文本内容。通常，AccessibilityImplementation 本身属于前一类，它的 name 属性就是作者分配的名称。子元素始终属于第二类，子元素名称表示其文本内容。

如果 AccessibilityImplementation 的 name 属性表示作者分配的名称，则组件从作者处获得名称的方式有两种。第一种方式采用组件本身内含的名称，例如，复选框组件可能将其包含的文本标签用作该组件的名称。第二种方式是第一种方式的后备方式，它采用 UI 中指定的名称，并以 AccessibilityProperties.name 结尾。通过此后备选项，用户指定名称的方式完全与任何其他 Sprite 或 MovieClip 名称的指定方式相同。

因此，对于 AccessibilityImplementation 本身 (childID == 0)，有三种可能：

• 组件内由作者分配的名称。如果 childID 为零，应实现 get_accName 方法，并应返回包含 AccessibilityImplementation 名称的字符串值。如果 childID 为零，但 AccessibilityImplementation 没有名称，则 get_accName 方法应返回一个空字符串，以避免 Player 转而使用 AccessibilityProperties.name 属性。

• UI 中作者分配的名称。如果 AccessibilityImplementation 可以包含子元素，则当 childID 为零时，应实现 get_accName 方法，但该方法不应返回任何值。如果 AccessibilityImplementation 不能包含子元素，则不应实现 get_accName 方法。

• 表示内容的名称。如果 childID 为零，应实现 get_accName 方法并由它返回适当的字符串值。如果 childID 为零，但 AccessibilityImplementation 没有内容，则 get_accName 方法应返回一个空字符串，以避免 Player 转而使用 AccessibilityProperties.name 属性。

请注意，对于子元素（如果 AccessibilityImplementation 可以包含子元素），总是适合第三种情况。如果 childID 不为零，应实现 get_accName 方法并由它返回适当的字符串值。

参数

了解详细信息

相关 API 元素

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

MSAA 方法，返回此 AccessibilityImplementation 所表示组件的名称或组件子元素之一的系统角色。为 MSAA 中的所有组件预定义系统角色。

参数

了解详细信息

相关 API 元素

MSAA 方法，返回包含全部所选子元素的 ID 的数组。返回的数组可以包含零个、一个或多个 ID，这些 ID 全部是无符号整数。

了解详细信息

相关 API 元素

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

IAccessible 方法，返回此 AccessibilityImplementation 所表示组件的当前运行时状态，或该组件的子元素之一的当前运行时状态。

此方法必须为 MSAA 中的组件返回零个、一个或多个预定义对象状态常量的组合。当要应用多个状态时，应使用 |（按位的 OR 运算符）将状态常量合并为一个位域。

要表示当前未应用任何状态常量，此方法应返回零。

无需跟踪或报告 STATE_SYSTEM_FOCUSABLE 或 STATE_SYSTEM_FOCUSED 状态，Flash Player 会自动处理这两种状态。

参数

了解详细信息

相关 API 元素

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

MSAA 方法，返回此 AccessibilityImplementation 所表示组件的运行时值，或该组件的子元素之一的运行时值。

仅当 AccessibilityImplementation 表示一个在 MSAA 模型中具有值的 UI 元素时，才能实现此方法。请注意，某些具有外观“值”的 UI 元素实际上会通过不同方式公开此值，例如通过 get_accName（如文本）、get_accState（如复选框）或 get_accSelection（如列表框）。

如果只针对 AccessibilityImplementation 本身或其子元素实现 get_accValue，则有时需要指明传递的特定 childID 没有值的概念。只需返回 null 即可执行此操作。

参数

了解详细信息

相关 API 元素

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

返回一个数组，其中包含 AccessibilityImplementation 中所有子元素的无符号整数 ID。

数组长度可以为零。数组中 ID 的显示顺序应与它们代表的子元素的逻辑顺序相同。如果 AccessibilityImplementation 可以包含子元素，则必须实现此方法；否则，请勿实现此方法。

为子元素分配子元素 ID 时，可以使用在 AccessibilityImplementation 的每个实例内保持唯一性的任何方案。子元素 ID 不一定连续，并且其顺序不必与子元素的逻辑顺序一致。您应妥善安排，避免重用子元素 ID；如果已删除某个子元素，则其 ID 在该 AccessibilityImplementation 实例的生命周期内始终不应再次使用。请注意，由于可以使用 Flash Player 代码进行多种形式的实现，因此使用的子元素 ID 数目超过一百万个时会导致意外行为发生。

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

返回 true 或 false，以表示边框由 x、y、width 和 height 指定的文本对象是否应该视为 AccessibilityImplementation 表示的组件的标签。

x 和 y 坐标是相对于应用 AccessibilityImplementation 的组件的左上角，可能为负值。所有坐标都以舞台像素为单位。

此方法允许可访问组件符合 Flash Player 对自动标签关系的搜索，从而允许对象外的文本提供对象的名称。之所以提供此方法，是因为预计用于识别标签的标准会因组件而异。如果实现了此方法，应该致力于使用与 Player 代码内部用于按钮和文本字段的标准类似的几何标准。这些标准如下所示：

• 对于按钮，将任何完全位于按钮内部的文本视为标签。
• 对于文本字段，将任何在上方附近和左对齐或左侧附近显示的文本都视为标签。

如果 AccessibilityImplementation 表示的组件始终不应参与自动标签关系，则不要实现 isLabeledBy。这等效于始终返回 false。不应实现 isLabeledBy 的一种情况是，当 AccessibilityImplementation 属于上述 get_accName 中介绍的“组件内由作者分配的名称”这种情况时。

请注意，此方法不基于任何 IAccessible 方法；它特定于 Flash。

参数