CellRenderer  - AS3 Flash

Bir bileşenle ilişkili verileri temsil eden Object nesnesini alır veya ayarlar. Bu değer ayarlandığında, bileşen verileri saklanır ve içeren bileşen geçersiz kılınır. Ardından, geçersiz kılınan bileşen otomatik olarak yeniden çizilir.

Veri özelliği, hücrenin temsil ettiği DataProvider öğesinde öğeyi içeren bir nesneyi temsil eder. Veri özelliği genellikle, bileşen türüne bağlı olan standart özellikleri içerir. List veya ComboBox bileşenindeki CellRenderer öğesinde veriler label, icon ve data özelliklerine sahiptir; TileList: bir label ve source özelliği; bir DataGrid hücresi her sütun için değerler içerir. Veri özelliği ayrıca, belirli bir hücre için kullanıcı tarafından belirlenmiş verileri de içerebilir. Kullanıcı, bir bileşenin hücrenin oluşturulması sırasındaki verilere yönelik farklı özellikleri kullanması için bir CellRenderer öğesini genişletebilir.

Ayrıca, labelField, labelFunction, iconField, iconFunction, sourceField ve sourceFunction öğeleri sırasıyla bir etiket, simge ve kaynak çizmek için hangi özelliklerin kullanıldığını belirtir.

Hücreye uygulanan index ve selected değerleri gibi liste özelliklerini alır veya ayarlar. Hücre geçersiz kılındıktan sonra bu liste özellikleri otomatik olarak güncellenir.

Geçerli hücrenin seçili olup olmadığını gösteren bir Boolean değeri alır veya ayarlar. true değeri geçerli hücrenin seçili olduğunu; false değeriyse geçerli hücrenin seçili olmadığını gösterir.

Varsayılan değer şudur false.

Yeni bir CellRenderer örneği oluşturur.

Geçerli bileşen için varsayılan stil eşlemesini alır. Stil eşlemesi, bileşenin kullandığı stile bağlı olarak bileşen için uygun olan türü içerir. Örneğin disabledTextFormat stili, null değeri veya TextFormat nesnesi içerir. Geçerli bileşende bu stilleri kullanılabilir ve setStyle() öğesini çağırabilirsiniz. Şu kod, belirtilen bileşendeki varsayılan disabledTextFormat stilini geçersiz kılar:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

İlgili API Öğeleri

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Verilerin oluşturulması gereken boyutları belirtir. Bu boyutlar, veriye ve veriyi içeren hücreye etki eder; hücre oluşturucu bu öğeleri verinin hücreye sıdığından ve bitişik hücrelere taşmadığından emin olmak için kullanır.

Parametreler

Örneği çalıştırmak için şu adımları izleyin:

1. TileList bileşenini kütüphaneye ekleyin.
2. "BlueBackground" adlı yeni bir sembol oluşturun ve sembol özelliklerinde “ActionScript için Dışa Aktar“ yazan kutuyu işaretleyin. Sınıf adını "BlueBackground" olarak bırakın.
3. "OrangeBackground" adlı yeni bir sembol oluşturun ve sembol özelliklerinde “ActionScript için Dışa Aktar“ yazan kutuyu işaretleyin. Sınıf adını "OrangeBackground" olarak bırakın.
4. "GreenBackground" adlı yeni bir sembol oluşturun ve sembol özelliklerinde “ActionScript için Dışa Aktar" yazan kutuyu işaretleyin. Sınıf adını "GreenBackground" olarak bırakın.
5. Her sembolde, 10 piksel genişliğinde, 10 piksel yüksekliğinde ve sembolün adıyla aynı renkte bir dikdörtgen oluşturun. x ve y koordinatlarını 0'dayken dikdörtgeni bırakın.
6. Bu kodu FLA dosyanızla aynı dizine CellRendererExample.as olarak kaydedin.
7. FLA dosyasındaki Document sınıfını CellRendererExample olarak ayarlayın.

package
{ 
    import fl.controls.TileList;
    import fl.core.UIComponent;
    import fl.data.DataProvider;
    import fl.events.ListEvent;
    import flash.display.Sprite;
    import flash.events.Event;
    
    public class CellRendererExample extends Sprite
    {
        public function CellRendererExample() {
            var dp:DataProvider = new DataProvider();
            var totalEntries:uint = 42;
            var i:uint;
            for(i=0; i<totalEntries; i++) {
                dp.addItem( { label:"Item "+i } );            
            }
            
            var myTileList = new TileList();
            myTileList.dataProvider = dp;
            myTileList.allowMultipleSelection = true;
            myTileList.columnWidth = 125;
            myTileList.rowHeight = 25;
            myTileList.columnCount = 3;
            myTileList.rowCount = 6;
            myTileList.move(10,10);
            myTileList.setStyle('cellRenderer', MyRenderer);    
            myTileList.addEventListener(ListEvent.ITEM_CLICK, onClick);
            addChild(myTileList);
        }
        private function onClick(e:ListEvent):void {
            var cr:MyRenderer = e.target.itemToCellRenderer(e.item) as MyRenderer;
            trace(cr.customProperty);    
        }
    }
}

import fl.controls.listClasses.CellRenderer;

class MyRenderer extends CellRenderer
{
    public var customProperty:String = "foo";
    
    public function MyRenderer() {
        var originalStyles:Object = CellRenderer.getStyleDefinition();
        setStyle("upSkin",BlueBackground);
        setStyle("downSkin",GreenBackground);
        setStyle("overSkin",OrangeBackground);
        setStyle("selectedUpSkin",originalStyles.selectedUpSkin);
        setStyle("selectedDownSkin",originalStyles.selectedDownSkin);
        setStyle("selectedOverSkin",originalStyles.selectedOverSkin);
    }
}