Video  - AS3

Określa typ filtra zastosowanego do dekodowanych danych wideo podczas przetwarzania końcowego. Wartością domyślną jest 0, co oznacza, że kompresor wideo będzie odpowiednio do potrzeb stosował filtr usuwający bloki.

Kompresja obrazu wideo może spowodować powstanie niepożądanych artefaktów. Korzystając z właściwości deblocking, można ustawić filtry usuwające bloki i i zniekształcenia typu ringing z obrazu wideo skompresowanego za pomocą kodeka On2.

Przez bloki rozumie się niedoskonałości widoczne na granicach bloków tworzących klatkę wideo. Zniekształcenia typu ringing to zniekształcone krawędzie wokół elementów na obrazie wideo.

Dostępne są dwa filtry usuwania bloków: filtr w kodeku Sorenson oraz filtr w kodeku On2 VP6. Ponadto filtr zniekształceń typu ringing jest dostępny w przypadku korzystania z kodeka On2 VP6. Aby ustawić filtr, należy skorzystać z jednej z następujących wartości:

• 0 — pozwala kompresorowi wideo na stosowanie filtru usuwającego bloki odpowiednio do potrzeb.
• 1 — nie zezwala na użycie filtru usuwającego bloki.
• 2 — umożliwia zastosowanie filtru Sorenson do usuwania bloków.
• 3 — umożliwia zastosowanie filtru On2 do usuwania bloków, bez filtru zniekształceń typu ringing (tylko dla wideo w formacie On2).
• 4 — umożliwia zastosowanie filtru On2 usuwania bloków i usuwania zniekształceń typu ringing (tylko dla wideo w formacie On2).
• 5 — umożliwia zastosowanie filtru On2 usuwania bloków i bardziej wydajnego filtru On2 zniekształceń typu ringing (tylko dla wideo formatu On2).

Jeśli dla wideo skompresowanego za pomocą kodeka Sorenson wybrana została wartość większa od 2, dekoder Sorenson ponownie ustawi ją na wartość domyślną 2.

Użycie filtru usuwania bloków ma wpływ na ogólną wydajność odtwarzania i zwykle nie jest konieczne jego stosowanie dla wideo o dużej szybkości transmisji/wysokiej rozdzielczości. Jeśli system użytkownika nie ma wystarczająco dużej mocy obliczeniowej, użytkownik może natrafić napotkać trudności w odtwarzaniu wideo zarejestrowanego z włączonym filtrem usuwającym bloki.

Określa, czy podczas skalowania obraz wideo powinien zostać wygładzony (poddany interpolacji). Aby funkcja wygładzania rozpoczęła działanie, należy przełączyć środowisko wykonawcze na tryb wysokiej jakości (domyślny). Wartością domyślną jest false (brak wygładzania).

Aby móc odtwarzać wideo za pomocą programu Flash Player w wersji 9.0.115.0 lub nowszej, należy ustawić tę właściwość na wartość true w celu skorzystania z optymalizacji obrazu techniką mipmappingu.

Liczba całkowita określająca wysokość strumienia wideo (w pikselach). Dla strumieni w trybie na żywo, ta wartość jest taka sama jak we właściwości Camera.height obiektu Camera, który przechwytuje strumień wideo. W przypadku nagranych plików wideo ta wartość oznacza wysokość wideo. W przypadku zmiany tej wartości dla nagranych materiałów wideo wywoływane jest zdarzenie NetStream.Video.DimensionChange.

Z tej właściwości można skorzystać, na przykład aby upewnić się, że użytkownik widzi obraz wideo w tej samej rozdzielczości, w której zostało ono zapisane, bez względu na rzeczywistą rozdzielczość obiektu Video na stole montażowym.

Powiązane elementy interfejsu API

Liczba całkowita określająca szerokość strumienia wideo (w pikselach). Dla strumieni w trybie na żywo, ta wartość jest taka sama jak we właściwości Camera.width obiektu Camera, który przechwytuje strumień wideo. W przypadku nagranych plików wideo ta wartość oznacza szerokość wideo. W przypadku zmiany tej wartości dla nagranych materiałów wideo wywoływane jest zdarzenie NetStream.Video.DimensionChange.

Z tej właściwości można skorzystać na przykład po to, aby upewnić się, że użytkownik widzi obraz wideo w tej samej rozdzielczości, w której zostało ono zapisane, bez względu na rzeczywistą rozdzielczość obiektu Video na stole montażowym.

Powiązane elementy interfejsu API

Tworzy nową instancję klasy Video. Jeśli żadne wartości nie zostaną przekazane do parametrów width oraz height, użyte będą wartości domyślne. Istnieje możliwość ustawienia właściwości szerokości i wysokości obiektu Video również po jego utworzeniu za pomocą Video.width i Video.height. W momencie tworzenia obiektu Video wartości zerowe dla parametrów szerokości i wysokości są niedozwolone; przekazanie do nich wartości zero spowoduje ustawienie wartości domyślnych.

Po utworzeniu obiektu Video, należy wywołać metodę DisplayObjectContainer.addChild() lub DisplayObjectContainer.addChildAt(), aby dodać obiekt Video do nadrzędnego obiektu DisplayObjectContainer.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Określa strumień wideo z kamery, który ma być wyświetlany w obszarze wyznaczonym przez obiekt Video w oknie aplikacji.

Za pomocą tej metody można dołączać wideo „na żywo” przechwycone przez użytkownika, do obiektu Video. Istnieje możliwość odtwarzania obrazu wideo lokalnie na tym samym komputerze lub urządzeniu, na którym było przechwytywane lub przesłania go do serwera z oprogramowaniem Flash Media Server i skorzystania z niego w celu strumieniowej transmisji do pozostałych użytkowników.

Uwaga: W aplikacji AIR w systemie iOS nie można wyświetlać wideo z kamery, gdy aplikacja korzysta z trybu renderingu GPU.

Parametry

Powiązane elementy interfejsu API

Określa strumień danych wideo, który ma być wyświetlany w obszarze wyznaczonym przez obiekt Video w oknie aplikacji. Strumień wideo jest plikiem wideo odtwarzanym za pomocą metody NetStream.play(), obiektem Camera lub wartością null. Plik wideo może być przechowywany w lokalnym systemie plików lub na serwerze Flash Media Server. Jeśli argument netStream ma wartość null, wideo nie jest już odtwarzane w obiekcie Video.

Nie należy korzystać z tej metody, jeśli plik wideo zawiera jedynie dźwięk; sekcja dźwięku pliku wideo jest automatycznie odtwarzana po wywołaniu metody NetStream.play(). Aby kontrolować strumień audio skojarzony z plikiem wideo, należy skorzystać z właściwości soundTransform obiektu NetStream, który odtwarza plik wideo.

Parametry

Powiązane elementy interfejsu API

Usuwa obraz aktualnie wyświetlany w obiekcie Video (a nie strumień wideo). Ta metoda jest używana w ramach obsługi bieżącego obrazu. Przykład: można usunąć ostatni obraz lub wyświetlić informacje dotyczące stanu oczekiwania bez ukrywania obiektu Video.

Powiązane elementy interfejsu API

W przykładzie kod tworzący obiekty Video oraz NetStream i wywołujący metody Video.attachNetStream() oraz NetStream.play() jest umieszczany w funkcji modułu obsługi. Moduł obsługi wywoływany jest jedynie w momencie próby połączenia z obiektem NetConnection zakończonej pomyślnie, czyli wtedy, gdy zdarzenie netStatus zwróci obiekt info z właściwością code wskazującą na powodzenie operacji. Zaleca się zaczekanie·do momentu pomyślnego nawiązania połączenia, zanim wywołana zostanie metoda NetStream.play().

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }