NetConnection  - AS3

Wskazuje obiekt, w ramach którego są uaktywniane metody wywołań zwrotnych. Domyślnym ustawieniem jest ta instancja NetConnection. Jeśli właściwość client zostanie ustawiona na inny obiekt, metody wywołania zwrotnego będą wywoływane w tym innym obiekcie.

Wskazuje, czy aplikacja jest połączona z serwerem za pomocą trwałego połączenia RTMP (wartość true), czy nie (wartość false). Jeśli połączenie zostało zrealizowane za pomocą protokołu HTTP, ta właściwość ma wartość false, chyba że połączenie nastąpiło do usług Flash Remoting na serwerze aplikacji; dla tego przypadku właściwość ma wartość true.

Typ serwera proxy użytego do pomyślnego nawiązania połączenia z serwerem Flash Media Server. Możliwe wartości to: "none", "HTTP", "HTTPS" i "CONNECT".

Wartość "none" oznacza, że połączenie nie jest tunelowane lub jest natywnym połączeniem SSL.

Wartość "HTTP" oznacza, że połączenie jest tunelowane przez protokół HTTP.

Wartość "HTTPS" oznacza, że połączenie jest tunelowane przez protokół HTTPS.

Wartość "CONNECT" oznacza, że połączenie jest tunelowane przy użyciu metody CONNECT za pośrednictwem serwera proxy.

Domyślne kodowanie obiektów NetConnection. Gdy obiekt jest zapisywany do lub odczytywany z danych binarnych, właściwość defaultObjectEncoding wskazuje, która wersja formatu AMF (Action Message Format) zostanie użyta do serializacji danych: format ActionScript 3.0 (ObjectEncoding.AMF3), czy format ActionScript 1.0 i ActionScript 2.0 (ObjectEncoding.AMF0).

Wartością domyślną jest ObjectEncoding.AMF3. Zmiana właściwości NetConnection.defaultObjectEncoding nie wpływa na istniejące instancje NetConnection; wpływa jedynie na instancje, które zostały utworzone w późniejszym czasie.

Aby oddzielnie ustawiać kodowanie obiektów (a nie ustawiać kodowanie obiektów dla całej aplikacji), należy zamiast tej właściwości ustawić właściwość objectEncoding obiektu NetConnection.

Szczegółowe informacje na ten temat zawiera opis właściwości objectEncoding.

Powiązane elementy interfejsu API

Identyfikator instancji serwera Flash Media Server, do którego podłączona jest ta instancja programu Flash Player lub aplikacji Adobe AIR. Właściwość jest znacząca jedynie dla połączeń RTMFP. Wartość tej właściwości jest dostępna jedynie po ustanowieniu połączenia RTMFP.

Powiązane elementy interfejsu API

Wartość wybrana jako znacząca przez serwer Flash Media Server, unikalna dla tego połączenia. Wartość jest widoczna na serwerze jako wartość właściwości client.nearNonce. Ta wartość jest zdefiniowana tylko dla połączeń RTMFP, RTMPE i RTMPTE.

Czas oczekiwania na odpowiedź HTTP wyrażony w milisekundach. Wartością domyślną jest zero.

• Wartość httpIdleTimeout jest obiektem Number.
• W przypadku używania połączenia HTTP wartość dodatnia oznacza liczbę milisekund, przez którą nieaktywne połączenie ma pozostać otwarte.
• Wartość zerowa oznacza, że należy użyć domyślnej wartości limitu czasu bezczynności sieci dla danej platformy.
• Wartość ujemna spowoduje wygenerowanie wyjątku RangeError.
• W przypadku przekroczenia wartości httpIdleTimeout jest wywoływane zdarzenie netStatus.
• Ta właściwość wpływa tylko na obiekty NetConnection utworzone za pomocą połączeń HTTP. Ta właściwość nie ma wpływu na obiekty NetConnection utworzone za pomocą kanałów RTMP, RTMFP lub innych kanałów HTTP.

    //Set the timeout to 5 seconds
    connection = new NetConnection();
    connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
    connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
    connection.httpIdleTimeout = 5000;
    

Całkowita liczba wejściowych i wyjściowych połączeń równorzędnych, na które zezwala ta instancja programu Flash Player lub aplikacji Adobe AIR. Wartością domyślną jest 8.

Wartość nie rozróżnia połączeń wydawcy i subskrybenta. Jeśli wartość zostanie zmniejszona, gdy połączenia równorzędne są połączeniami bieżącymi, nowa wartość będzie miała wpływ jedynie na połączenia wejściowe. Istniejące połączenia nie zostaną usunięte.

Identyfikator instancji programu Flash Player lub aplikacji Adobe AIR dla instancji NetConnection. Właściwość jest znacząca jedynie dla połączeń RTMFP.

Każda instancja NetConnection posiada niepowtarzalną właściwość nearID. Żadna instancja programu Flash Player, aplikacji Adobe AIR lub NetConnection nie ma takiego samego identyfikatora.

Pozostałe instancje programu Flash Player lub aplikacji Adobe AIR używają tego identyfikatora jako wartości we właściwości peerID dla nowych połączeń NetStream do tego klienta. W konsekwencji ten identyfikator jest wartością właściwości farID w we wszystkich równorzędnych obiektach NetStream, które są połączone z tą instancją.

Powiązane elementy interfejsu API

Wartość wybrana jako znacząca przez instancję programu Flash Player lub aplikacji Adobe AIR, unikalna dla tego połączenia. Wartość jest widoczna na serwerze jako wartość właściwości client.farNonce. Ta wartość jest zdefiniowana tylko dla połączeń RTMFP, RTMPE i RTMPTE.

Kodowanie obiektu dla tej instancji NetConnection.

Gdy obiekt jest zapisywany do lub odczytywany z danych binarnych, właściwość defaultObjectEncoding wskazuje, która wersja formatu AMF (Action Message Format) zostanie użyta do serializacji danych: format ActionScript 3.0 (ObjectEncoding.AMF3) czy format ActionScript 1.0 i ActionScript 2.0 (ObjectEncoding.AMF0). Aby ustawić wersję formatu AMF dla instancji NetConnection, należy ustawić właściwość objectEncoding.

Zrozumienie tej właściwości jest ważne, jeśli aplikacja wymaga porozumiewania się z serwerami obsługującymi wersje poprzedzające Flash Player 9. Możliwe są następujące trzy scenariusze:

• Połączenie z serwerem obsługującym format AMF3 (na przykład Flex Data Services 2 lub Flash Media Server 3). Wartością domyślną właściwości defaultObjectEncoding jest ObjectEncoding.AMF3. Wszystkie instancje NetConnection utworzone w tym pliku stosują serializację AMF3, a zatem nie ma potrzeby ustawiania właściwości objectEncoding.
• Połączenie z serwerem, który nie obsługuje formatu AMF3 (na przykład Flash Media Server 2). W tym scenariuszu należy ustawić stałą właściwość NetConnection.defaultObjectEncoding na wartość ObjectEncoding.AMF0. Wszystkie instancje NetConnection utworzone w pliku SWF używają serializacji w formacie AMF0. Nie ma konieczności ustawiania właściwości objectEncoding.
• Połączenie z wieloma serwerami, które używają różnych wersji kodowania. Zamiast właściwości defaultObjectEncoding należy ustawić kodowanie obiektu za pomocą właściwości objectEncoding osobno dla każdego połączenia. Aby połączyć się z serwerami, które używają kodowania w formacie AMF0, na przykład Flash Media Server 2, należy ustawić właściwość na wartość ObjectEncoding.AMF0; ustawiając wartość właściwości na ObjectEncoding.AMF3, możliwe będzie połączenie z serwerami, które używają kodowania w formacie, na przykład Flex Data Services 2.

Po połączeniu z instancją NetConnection, jej właściwość objectEncoding będzie tylko do odczytu.

Jeśli do połączenia z serwerem użyte zostanie błędne kodowanie, obiekt NetConnection wywoła zdarzenie netStatus. Właściwość NetStatusEvent.info zawiera obiekt informacji z właściwością code o wartości NetConnection.Connect.Failed oraz opis wyjaśniający, że kodowanie obiektu jest niepoprawne.

Powiązane elementy interfejsu API

Protokół użyty do ustanowienia połączenia. Ta właściwość znajduje zastosowanie, gdy używany jest serwer Flash Media Server. Możliwe są następujące wartości:

• "rtmp": protokół RTMP (Real-Time Messaging Protocol)
• "rtmpe": szyfrowany protokół RTMP
• "rtmpt": protokół HTTP tunelujący protokół RTMP
• "rtmpte": protokół HTTP tunelujący szyfrowany protokół RTMP
• "rtmps": RTMP na bazie protokołu HTTPS
• "rtmfp": protokół RTMFP (Real-Time Media Flow Protocol)

Określa metody awaryjne, które są wykorzystywane w przypadku niepowodzenia nawiązania wstępnego połączenia z serwerem Flash Media Server. Przed wywołaniem metody NetConnection.connect() należy ustawić właściwość proxyType.

Dopuszczalne wartości to "none", "HTTP", "CONNECTOnly", "CONNECT" i "best". Wartość domyślna to "none".

Aby użyć natywnego połączenia SSL, należy ustawić właściwość na wartość "best". Jeśli odtwarzacz nie może nawiązać bezpośredniego połączenia z serwerem (przez domyślny port 443 lub inny wskazany port), a obecny jest serwer proxy, odtwarzacz podejmuje próbę połączenia przy użyciu metody CONNECT. Jeśli ta próba nie powiedzie się, odtwarzacz tuneluje połączenie przez protokół HTTPS.

W przypadku ustawienia tej właściwości na "CONNECTOnly" odtwarzacz próbuje najpierw użyć metody CONNECT. Nie ma opcji zastępczej w sytuacji, gdy nie jest to możliwe.

Jeśli właściwość ma wartość "HTTP" i bezpośrednie połączenie nie zostało zrealizowane pomyślnie, użyte zostanie tunelowanie HTTP. Jeśli właściwość ma wartość "CONNECT" i bezpośrednie połączenie nie zostało zrealizowane pomyślnie, użyte zostanie tunelowanie metodą CONNECT. Jeśli i ta próba nie powiedzie się, nie będzie podejmowana próba tunelowania połączenia przez protokół HTTP.

Ta właściwość ma zastosowanie tylko w przypadku użycia protokołu RTMP, RTMPS lub RTMPT. Metody CONNECT i CONNECTOnly są stosowane tylko u użytkowników łączących się z siecią przez serwer proxy.

Obiekt przechowujący wszystkie równorzędne subskrybujące obiekty NetStream, które nie są skojarzone z publikującymi obiektami NetStream. Subskrybujące obiekty NetStream, które nie są skojarzone z publikującymi obiektami NetStream znajdują się w tablicyNetStream.peerStreams.

Powiązane elementy interfejsu API

Identyfikator przekazany do metody NetConnection.connect(). Jeśli metoda NetConnection.connect() nie została wywołana lub nie przekazano żadnego identyfikatora URI, właściwość ma wartość undefined.

Wskazuje, że bezpieczne połączenie nawiązano przy użyciu macierzystych zabezpieczeń TLS (Transport Layer Security), a nie protokołu HTTPS. Ta właściwość jest poprawna tylko wtedy, gdy obiekt NetConnection jest połączony.

Tworzy obiekt NetConnection. Aby utworzyć połączenie, należy wywołać metodę connect().

Jeśli aplikacja wymaga komunikowania się z serwerami obsługującymi wersje poprzedzające Flash Player 9, należy ustawić właściwość objectEncoding obiektu NetConnection.

Poniższy kod służy do tworzenia obiektu NetConnection:

     var nc:NetConnection = new NetConnection();
     

Powiązane elementy interfejsu API

Dodaje nagłówek kontekstowy do struktury pakietu formatu Action Message Format (AMF). Nagłówek jest wysyłany z każdym kolejnym pakietem formatu AMF. Jeśli metoda NetConnection.addHeader() wywołana zostanie z tą samą nazwą, istniejący nagłówek zostanie zastąpiony nowym, który pozostanie w pamięci na czas życia obiektu NetConnection. Aby usunąć obiekt niezdefiniowany, można usunąć nagłówek, wywołując metodę NetConnection.addHeader() z nazwą nagłówka.

Parametry

Wywołuje polecenie lub metodę na serwerze Flash Media Server lub na serwerze aplikacji, na którym uruchomiony jest program Flash Remoting. Przed wywołaniem metody NetConnection.call() należy wywołać metodę NetConnection.connect(), aby połączyć się z serwerem. Aby przekazać serwerową funkcję do tej metody, należy ją utworzyć.

Nie można połączyć się z portem, który zazwyczaj jest zastrzeżony. Pełną listę zablokowanych portów zawiera sekcja „Ograniczanie sieciowych interfejsów API” w publikacji ActionScript 3.0 — podręcznik dla programistów.

Parametry

Powiązane elementy interfejsu API

Zamyka połączenie, które otwarto lokalnie lub do serwera i wywołuje zdarzenie netStatus z właściwością code o wartości NetConnection.Connect.Closed.

Metoda rozłącza wszystkie obiekty NetStream uruchomione w połączeniu. Wszystkie kolejkowane dane, które nie zostały wysłane, zostaną odrzucone. (Aby zakończyć strumienie lokalne lub strumienie serwera, nie zamykając jednocześnie połączenia, należy użyć metody NetStream.close()). Jeśli połączenie zostanie zamknięte i potrzebne będzie utworzenie nowego, należy utworzyć nowy obiekt NetConnection i ponownie wywołać metodę connect().

Metoda close() również rozłącza wszystkie zdalne obiekty udostępnione uruchomione w tym połączeniu. Nie ma jednak potrzeby ponownego tworzenia obiektu udostępnionego w celu ponownego połączenia. W zamian można wywołać metodę SharedObject.connect(), aby ponownie ustanowić połączenie z obiektem udostępnionym. Także wszystkie dane obiektu udostępnionego, które były kolejkowane, gdy wywołana została metoda NetConnection.close(), zostaną wysłane po ponownym ustanowieniu połączenia z obiektem udostępnionym.

Najlepszą praktyką programistyczną jest wywołanie metody close(), gdy klient nie potrzebuje już połączenia z serwerem. (Dotyczy serwera Flash Media Server). Wywołanie metody close() jest najszybszym sposobem na wyczyszczenie nieużywanych połączeń. Serwer można skonfigurować tak, aby automatycznie zamykał bezczynne połączenia. Aby uzyskać więcej informacji, należy zapoznać się z podręcznikiem Flash Media Server Configuration and Administration Guide.

Powiązane elementy interfejsu API

Tworzy dwukierunkowe połączenie do aplikacji na serwerze Flash Media Server lub do programu Flash Remoting albo tworzy dwukierunkowy punkt końcowy sieci do komunikacji grupowej w sieci P2P za pomocą protkołu RTMFP. Aby zgłosić jego status lub warunek błędu, należy wywołać metodę NetConnection.connect(), która wywoła zdarzenie netStatus.

Wywołanie metody NetConnection.connect() umożliwia wykonanie następujących czynności:

• Aby odtworzyć pliki wideo lub MP3 z lokalnego systemu plików lub z serwera WWW, należy przekazać parametr "null".
• Aby nawiązać połączenie z serwerem aplikacji, na którym jest uruchomiony program Flash Remoting, należy przekazać adres URL z protokołem "http". Klasa NetServices służy do wywoływania funkcji i zwracania wyników z serwera aplikacji za pomocą obiektu NetConnection. Aby uzyskać więcej informacji, należy zapoznać się z dokumentacją programu Flash Remoting.
• Aby nawiązać połączenie z aplikacją Flash Media Server, należy przekazać adres URL z protokołem "rtmp/e/s".
• Aby utworzyć dwukierunkowy punkt końcowy sieci dla komunikacji klient-serwer, P2P i multiemisji IP za pośrednictwem protokołu RTMFP, należy przekazać adres URL z protokołem "rtmfp".
• Aby utworzyć bezserwerowy, dwukierunkowy punkt końcowy sieci dla multiemisji RTMFP IP, należy przekazać ciąg znaków "rtmfp:".

Weźmy pod uwagę następujący model zabezpieczeń:

• Domyślnie program Flash Player lub środowisko AIR odmawia dostępu między obszarami izolowanymi. Serwis sieci Web może zezwolić na dostęp do zasobu, za pomocą pliku reguł URL.
• Aplikacja użytkownika może odmówić dostępu do zasobów serwera. W aplikacji Flash Media Server do odmawiania dostępu służy kod ActionScript po stronie serwera. Więcej informacji zawiera Dokumentacja serwera Flash Media Server.
• Nie można wywołać metody NetConnection.connect(), jeśli wywołujący plik znajduje się w lokalnym obszarze izolowanym z dostępem do systemu plików.
• Nie można połączyć się z portem, który zazwyczaj jest zastrzeżony. Pełną listę zablokowanych portów zawiera sekcja „Ograniczanie sieciowych interfejsów API” w publikacji ActionScript 3.0 — podręcznik dla programistów.
• Aby zablokować plik SWF przed wywołaniem tej metody, należy ustawić parametr allowNetworking oraz znaczniki object i embed na stronie HTML zawierającej treść SWF.

Jednak w aplikacji Adobe AIR zawartość obszaru izolowanego application (zawartość instalowana razem z aplikacją AIR) nie jest ograniczana przez te reguły zabezpieczeń.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w witrynie Adobe Flash Player Developer Center: Bezpieczeństwo.

Parametry

Powiązane elementy interfejsu API

Wywoływana w przypadku asynchronicznego zgłoszenia wyjątku — pochodzącego z macierzystego kodu asynchronicznego.

To zdarzenie ma następujące właściwości:

Wywoływana, gdy wystąpi błąd wejścia lub wyjścia uniemożliwiający operację sieciową.

To zdarzenie ma następujące właściwości:

Wywoływana, gdy obiekt NetConnection zgłasza swój stan lub warunek błędu. Zdarzenie netStatus zawiera właściwość info, która jest obiektem informacji zawierającym informacje charakterystyczne dla zdarzenia np. czy próba połączenia zakończona została pomyślnie, czy niepowodzeniem.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, jeśli wywołanie metody NetConnection.call() skutkuje próbą połączenia z serwerem na zewnątrz obszaru izolowanego.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

W tym przykładzie kod tworzący obiekty Video oraz NetStream i wywołujący metody Video.attachNetStream() i NetStream.play() jest umieszczany w funkcji modułu obsługi. Moduł obsługi wywoływany jest jedynie w momencie próby połączenia z obiektem NetConnection zakończonej pomyślnie, czyli wtedy, gdy zdarzenie netStatus zwróci obiekt info z właściwością code wskazującą na powodzenie operacji. Zalecane jest odczekanie do momentu pomyślnego nawiązania połączenia, zanim wywołana zostanie metoda NetStream.play().

package {
    import flash.display.Sprite;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.Event;

    public class NetConnectionExample extends Sprite {
        private var videoURL:String = "http://www.helpexamples.com/flash/video/cuepoints.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video = new Video();        

        public function NetConnectionExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Stream not found: " + videoURL);
                    break;
            }
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function connectStream():void {
            addChild(video);
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.client = new CustomClient();
            video.attachNetStream(stream);
            stream.play(videoURL);
        }
    }
}

class CustomClient {
    public function onMetaData(info:Object):void {
        trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
    }
    public function onCuePoint(info:Object):void {
        trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
    }
}