NetStatusEvent  - AS3

Obiekt z właściwościami opisującymi stan obiektu lub warunek błędu.

Obiekt informacyjny może mieć właściwość code zawierającą ciąg znaków reprezentujący konkretne zdarzenie lub właściwość level zawierającą ciąg znaków"status" albo "error".

Obiekt informacyjny może mieć także inną strukturę. W niektórych implementacjach właściwości code i level mogą nie działać, a niektóre serwery mogą wysyłać inne obiekty.

Połączenia P2P wysyłają komunikaty do obiektu NetConnection za pomocą parametru stream obiektu informacyjnego, który wskazuje obiekt NetStream, do którego odnosi się dany komunikat.

Na przykład serwer Flex Data Services wysyła obiekty Message, które powodują błędy zgodności typów przy próbie dostępu do właściwości code lub level.

W poniższej tabeli opisano możliwe wartości właściwości code i level (ciągi znaków).

Jeśli regularnie zgłaszane są błędy dotyczące buforu, należy zmodyfikować ustawienia buforu, korzystając z właściwości NetStream.bufferTime.

Powiązane elementy interfejsu API

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Tworzy obiekt Event zawierający informacje o zdarzeniach netStatus. Obiekty Event są przekazywane jako parametry do detektorów zdarzeń.

Powiązane elementy interfejsu API

Tworzy kopię obiektu NetStatusEvent i ustawia wartości poszczególnych właściwości zgodnie z właściwościami oryginału.

Zwraca ciąg znaków, który zawiera wszystkie właściwości obiektu NetStatusEvent. Format ciągu znaków jest następujący:

[NetStatusEvent type=wartość bubbles=wartość cancelable=wartość info=wartość]

Definiuje wartość właściwości type obiektu zdarzenia netStatus.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

W tym przykładzie metoda netStatusHandler jest rejestrowana jako detektor zdarzenia NetStatusEvent NetConnection.netStatus. Po ustaleniu stanu (powodzenie lub niepowodzenie) próby połączenia NetConnection.connect(), zdarzenie netStatus wywołuje tę metodę. Jeśli próba połączenia z obiektem NetConnection powiedzie się (innymi słowy, jeśli właściwość info obiektu NetStatusEvent wywołanego przez zdarzenie netStatus ma właściwość code o wartości wskazującej na powodzenie), kod tworzy obiekty Video i NetStream, a następnie wywołuje metody Video.attachNetStream() i NetStream.play().

Uwaga: Do uruchomienia tego przykładu potrzebny jest plik FLV o nazwie i lokalizacji zgodnej z wartością zmiennej przekazanej do właściwości videoURL; w tym przypadku jest to plik FLV o nazwie Video.flv znajdujący się w tym samym katalogu, co plik SWF.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }