Camera  - AS3

Intensywność ruchu wykrywanego przez kamerę. Wartości mieszczą się w przedziale od 0 (żaden ruch nie został wykryty) do 100 (wykryto dużą intensywność ruchu) Wartość tej właściwości jest pomocna przy określaniu, czy do metodysetMotionLevel() należy przekazać ustawienie.

Jeśli kamera jest dostępna, ale nie była jeszcze używana, ponieważ nie wywołano metody Video.attachCamera(), właściwość będzie miała wartość -1.

Jeśli strumieniowo przesyłane są jedynie nieskompresowane lokalne materiały wideo, ta właściwość będzie ustawiana tylko wtedy, gdy przypisano funkcję do obsługi zdarzeń. W innym wypadku pozostanie niezdefiniowana.

Powiązane elementy interfejsu API

Maksymalna szerokość pasma bieżącego wyjściowego strumienia wideo (w bajtach). Wartość 0 oznacza, że źródło może korzystać z szerokości pasma w potrzebnym mu wymiarze w celu zachowania pożądanej jakości klatki.

Aby ustawić tę właściwość, należy skorzystać z metodysetQuality().

Powiązane elementy interfejsu API

Szybkość przechwytywania danych przez kamerę (liczba klatek na sekundę). Właściwości nie można ustawić; można jednak skorzystać z metodysetMode(), aby ustawić powiązaną właściwość — fps — która określa maksymalną liczbę klatek na sekundę, z jaką kamera będzie przechwytywać dane.

Powiązane elementy interfejsu API

Maksymalna szybkość przechwytywania danych przez kamerę (liczba klatek na sekundę). Maksymalna do osiągnięcia szybkość zależy od możliwości kamery; ta liczba klatek na sekundę może nie zostać osiągnięta.

• Aby ustawić odpowiednią wartość tej właściwości, należy skorzystać z metodysetMode().
• Aby określić szybkość aktualnie przechwytywanych przez kamerę danych, należy skorzystać z właściwości currentFPS.

Powiązane elementy interfejsu API

Bieżąca wysokość przechwytywanego obrazu (w pikselach). Aby ustawić wartość dla tej właściwości, należy skorzystać z metodysetMode().

Powiązane elementy interfejsu API

Indeks liczony od zera, który określa położenia kamery w tablicy Camera.names zawierającej listę dostępnych kamer.

Powiązane elementy interfejsu API

Właściwość isSupported ma wartość true, jeśli na bieżącej platformie jest obsługiwana klasa Camera; w przeciwnym razie ma wartość false.

Liczba klatek wideo transmitowanych w całości (tzw. klatki podstawowe), a nie w postaci klatek interpolowanych za pomocą algorytmu do kompresji wideo. Wartością domyślna jest 15, co oznacza, że każda 15. klatka jest klatką podstawową. Wartość 1 oznacza, że wszystkie klatki są klatkami podstawowymi. Dopuszczalne wartości mieszczą się w przedziale od 1 do 300.

Powiązane elementy interfejsu API

Określa, czy lokalny obraz danych przechwytywanych przez kamerę ma być kompresowany i dekompresowany (true), tak jak dzieje się to w przypadku transmisji na żywo za pomocą oprogramowania Flash Media Server, czy też ma nie być kompresowany (false). Wartością domyślną jest false.

Mimo, że skompresowany strumień jest użyteczny dla celów testowych takich, jak podglądanie ustawień jakości wideo, obarczony jest znaczącym kosztem przetwarzania Lokalny obraz jest kompresowany, edytowany do celów transmisji (podobnie jak w połączeniu z transmisją na żywo) i dekompresowany w celu lokalnego wyświetlania.

Aby ustawić tę wartość, należy skorzystać z metodyCamera.setLoopback(). Aby ustawić stopień użytej kompresji, jeśli ta właściwość ma wartość true, należy skorzystać z metody Camera.setQuality().

Powiązane elementy interfejsu API

Intensywność ruchu niezbędna do wywołania zdarzenia activity. Dopuszczalne wartości mieszczą się w przedziale od 0 do 100. Wartością domyślną jest 50.

Wideo można wyświetlić bez względu na wartość właściwości motionLevel. Aby znaleźć więcej informacji na ten temat, należy zapoznać się z metodą setMotionLevel()

Powiązane elementy interfejsu API

Liczba milisekund, które muszą upłynąć od momentu wyłączenia kamery po wykryciu ruchu do momentu wywołania zdarzenia activity. Wartość domyślna to 2000 milisekund (2 sekundy).

Aby ustawić tę wartość, należy skorzystać z metody setMotionLevel().

Powiązane elementy interfejsu API

Wartość typu Boolean, która określa, czy użytkownik zablokował dostęp do kamery (true), czy też zezwolił na ten dostęp (false) w oknie dialogowym Prywatność programu Flash Player. Jeśli wartość ulegnie zmianie, wywołane zostanie zdarzenie status.

Powiązane elementy interfejsu API

Nazwa bieżącej kamery (zgodnie z danymi przekazanymi przez urządzenie).

Powiązane elementy interfejsu API

Tablica ciągów znaków zawierająca nazwy wszystkich dostępnych kamer. Uzyskanie dostępu do tej tablicy nie powoduje wyświetlenia okna dialogowego Prywatność programu Flash Player. Zawiera ona indeksy liczone od zera dla każdej kamery oraz liczbę kamer w systemie (przy użyciu właściwości names.length).

Wywołanie właściwości names wymaga rozległego sprawdzania urządzeń. W większości przypadków istnieje możliwość skorzystania z domyślnej kamery.

Powiązane elementy interfejsu API

Sprawdź, czy system otrzymał pozwolenie na dostęp do korzystania z kamery.

Powiązane elementy interfejsu API

Określa panel urządzenia, na którym znajduje się kamera.

Za pomocą właściwości position można ustalić, czy kamera znajduje się na przednim czy na tylnym panelu urządzenia przenośnego. Poniższa funkcja sprawdza wszystkie dostępne kamery do momentu znalezienia kamery o żądanym położeniu. Jeśli żadna z kamer nie ma żądanego położenia, zwracana jest kamera domyślna.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

W przypadku urządzeń przenośnych położenie kamery ma zazwyczaj wartość CameraPosition.FRONT lub CameraPosition.BACK. Jeśli nie można określić położenia kamery, zgłaszana jest wartość CameraPosition.UNKNOWN. W przypadku platform (komputerów) stacjonarnych położenie ma zawsze wartość CameraPosition.UNKNOWN.

Stałe dla wartości prawidłowych tej właściwości są zdefiniowane w klasie CameraPosition.

Powiązane elementy interfejsu API

Wymagany poziom jakości obrazu, zgodnie z intensywnością kompresji stosowanej do poszczególnych klatek wideo. Dopuszczalne wartości jakości mieszczą się w przedziale od 1 (najniższa jakość, najwyższy stopień kompresji) do 100 (najwyższa jakość, brak kompresji). Wartością domyślną jest 0, co oznacza, że jakość obrazu można zmieniać w zależności od potrzeb w celu uniknięcia przekroczenia szerokości pasma.

Aby ustawić tę właściwość, należy skorzystać z metodysetQuality().

Powiązane elementy interfejsu API

Bieżąca szerokość przechwytywanego obrazu (w pikselach). Aby ustawić pożądaną wartość dla tej właściwości, należy skorzystać z metodysetMode().

Powiązane elementy interfejsu API

Wypełnia tablicę bajtów na podstawie prostokątnego obszaru pikseli.

Zapisuje w tablicy bajtów liczbę całkowitą bez znaku (32-bitową wartość nieprzemnożoną pikseli) dla każdego piksela. Rozmiar tablicy jest zmieniany tak, aby zawierała liczbę bajtów wystarczającą do przechowywania danych wszystkich pikseli.

Parametry

Powiązane elementy interfejsu API

Wypełnia wektor na podstawie prostokątnego obszaru pikseli.

Zapisuje w wektorze liczbę całkowitą bez znaku (32-bitową wartość nieprzemnożoną pikseli) dla każdego piksela. Rozmiar wektora jest zmieniany tak, aby zawierał liczbę pozycji wystarczającą do przechowywania danych wszystkich pikseli.

Parametry

Powiązane elementy interfejsu API

Kopiuje ostatnią klatkę do bitmapy.

Ta metoda kopiuje zawartość ostatniej klatki do obiektu BitmapData.

Parametry

Powiązane elementy interfejsu API

Zwraca odwołanie do obiektu Camera odpowiedzialnego za przechwytywanie wideo. Aby rozpocząć przechwytywanie wideo, należy dołączyć obiekt Camera do obiektu Video (szczegóły można znaleźć w opisie metody Video.attachCamera() ). Aby rozpocząć transmisję wideo na serwer z oprogramowaniem Flash Media Server, należy wywołać metodę NetStream.attachCamera() w celu dołączenia obiektu Camera do obiektu NetStream.

Wielokrotne wywołania metody getCamera() odwołują się do tego samego sterownika kamery. Zatem, jeśli fragment kodu wygląda podobnie do tego firstCam:Camera = getCamera() i secondCam:Camera = getCamera(), wtedy obie kamery firstCam i secondCam odwołują się do tej samej domyślnej kamery użytkownika.

Na urządzeniach przenośnych wyposażonych w kamerę skierowaną do przodu i do tyłu można przechwytywać wideo tylko z jednej kamery naraz.

Na ogół nie należy przekazywać wartości do parametru name; prościej użyć metody getCamera(), aby zwrócić odwołanie do domyślnej kamery. Za pomocą panelu ustawień kamery (omówiony w dalszej części tej sekcji) użytkownik może określić domyślną kamerę, z której będzie korzystać.

Nie można użyć języka ActionScript, aby skonfigurować ustawienia zezwalania lub odmawiania dostępu do kamery, ale istnieje możliwość wyświetlenia okna dialogowego ustawień kamery w ustawieniach programu Adobe Flash Player, w którym użytkownik może ustalić uprawnienia do kamery. Jeśli plik SWF usiłuje za pomocą metody attachCamera() dołączyć do obiektu Video lub NetStream kamerę zwróconą przez metodę getCamera(), program Flash Player wyświetli okno dialogowe, które umożliwi użytkownikowi wybranie, czy zezwolić, czy odmówić dostępu do kamery. (Należy upewnić się, że rozmiar okna aplikacji ma wymiary przynajmniej 215 x 138 pikseli; jest to minimalny rozmiar wymagany przez program Flash Player w celu poprawnego wyświetlania okna dialogowego). Jeśli użytkownik odpowiada w oknie dialogowym ustawień kamery, program Flash Player zwraca informacje w zdarzeniu status, które wskazuje odpowiedź użytkownika: Camera.Muted oznacza, że użytkownik odmówił dostępu do kamery; Camera.Unmuted oznacza, że użytkownik zezwolił na dostęp do kamery. Aby określić, czy użytkownik odmówił, czy zezwolił na dostęp do kamery, nie obsługując zdarzenia status, należy skorzystać z właściwości muted.

W programie Flash Player użytkownik może określić stałe ustawienia prywatności dla konkretnej domeny, klikając prawym klawiszem myszy (system Windows oraz Linux) lub klikając klawisz Control (komputery Macintosh) podczas odtwarzania pliku SWF, wybierając Ustawienia, otwierając okno dialogowe Prywatność i wybierając opcję Zapamiętaj. Jeśli użytkownik wybrał opcję Zapamiętaj, program Flash Player nie będzie więcej pytał użytkownika, czy zezwolić, czy odmówić plikom SWF z tej domeny dostępu do kamery.

Uwaga: metoda·attachCamera() nie wywoła okna dialogowego w celu przyznania lub odmowy dostępu do kamery, jeśli użytkownik odmówił dostępu wybierając opcję Pamiętaj w oknie dialogowym ustawień programu Flash Player. W tym przypadku można poprosić użytkownika o zmianę ustawienia zezwolenia lub odmowy, wyświetlając panel ustawień prywatności programu Flash Player za pomocą metody Security.showSettings(SecurityPanel.PRIVACY).

Jeśli metoda getCamera() zwróci wartość null, oznacza to, że z kamery korzysta inna aplikacja lub nie ma żadnych kamer zainstalowanych w systemie. Aby określić, czy w systemie są zainstalowane kamery, należy skorzystać z właściwości names.length. Aby wyświetlić panel ustawień kamery Flash Player, który umożliwia użytkownikowi wybranie kamery, do której będzie się odwoływać metoda getCamera(), należy skorzystać z metody Security.showSettings(SecurityPanel.CAMERA).

Skanowanie sprzętu w celu wyszukania kamer jest czasochłonne. Jeśli środowisko wykonawcze znajdzie przynajmniej jedną kamerę, sprzęt nie będzie ponownie skanowany w celu określenia czasu życia instancji odtwarzacza. Jednak jeśli program nie znajdzie żadnej kamery, będzie przeprowadzał skanowanie przy każdym wywołaniu metody getCamera. Jest to pomocne, jeśli kamera podłączona, ale wyłączona; jeśli plik SWF udostępnia przycisk Spróbuj ponownie, który wywołuje getCamera, program Flash Player znajdzie kamerę bez konieczności ponownego uruchamiania pliku SWF.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Wysyła żądanie pozwolenia aplikacji na dostęp do kamery.

Określa, które klatki wideo mają być transmitowane w całości (tzw. klatki podstawowe), a nie w postaci klatek interpolowanych za pomocą algorytmu do kompresji wideo. Tę metodę można stosować tylko, jeśli wideo transmitowane jest za pomocą oprogramowania Flash Media Server.

Algorytm do kompresji wideo Flash kompresuje obraz wideo, transmitując jedynie te fragmenty, które uległy zmianom w porównaniu z ostatnią klatką wideo; te fragmenty są rozpatrywane jako klatki interpolowane. Klatki wideo mogą być interpolowane zgodnie z zawartością poprzedniej klatki. Jednak klatka podstawowa jest klatką wideo, która jest kompletna; nie jest interpolowana na podstawie wcześniejszych klatek.

Podejmując decyzję o wyborze wartości dla parametru keyFrameInterval, należy brać pod uwagę zarówno przepustowość, jak i możliwość odtwarzania wideo przez użytkowników. Na przykład wyższa wartość właściwości keyFrameInterval (przesyłanie klatek kluczowych z mniejszą częstotliwością) zmniejsza zajęte pasmo (wymaganą przepustowość). Może to jednak zwiększyć ilość czasu potrzebnego do ustawienia głowicy odtwarzania w konkretnym punkcie obrazu wideo; dla wcześniejszych klatek wideo mogła istnieć konieczność ich interpolacji, zanim odtwarzanie wideo zostanie wznowione.

Odpowiednio, kiedy wartość określana właściwości keyFrameInterval jest mniejsza (przesyłanie klatek podstawowych z wyższą częstotliwością), wtedy użycie dostępności pasma wzrasta, ponieważ pełne klatki wideo są częściej transmitowane, ale może to zmniejszyć ilość czasu potrzebnego na wyszukanie konkretnej klatki wideo w nagranym pliku.

Parametry

Powiązane elementy interfejsu API

Określa, czy strumień danych wideo z kamery ma być kompresowany. Tę metodę można stosować tylko, jeśli wideo transmitowane jest za pomocą serwera z oprogramowaniem Flash Media Server; ustawienie parametru compress na wartość true umożliwi lepsze zaprezentowanie sposobu, w jaki wideo zostanie wyświetlone użytkownikom, kiedy będą oglądać go w czasie rzeczywistym.

Mimo, że skompresowany strumień jest użyteczny dla celów testowych takich, jak podglądanie ustawień jakości wideo, obarczony jest znaczącym kosztem przetwarzania, ponieważ lokalny obraz danych nie jest zwyczajnie kompresowany; jest kompresowany, edytowany do celów transmisji (podobnie jak w połączeniu z transmisją na żywo) i dekompresowany do lokalnego przeglądania.

Aby skonfigurować stopień kompresji użytej w czasie ustawiania parametru compress na wartość true, należy skorzystać z metody Camera.setQuality().

Parametry

Powiązane elementy interfejsu API

Ustawia macierzysty tryb przechwytywania kamery, który jest najlepiej dostosowany do określonych wymagań. Jeśli kamera nie ma trybu natywnego, który odpowiadałby wszystkim przekazanym parametrom, środowisko wykonawcze wybiera tryb przechwytywania, który jest najbardziej zgodny z żądanym trybem. Takie przekształcenie może wpłynąć na obcinanie obrazu i pomijanie klatek.

Domyślnie środowisko wykonawcze zmniejsza liczbę klatek w razie potrzeby, aby zachować rozdzielczość obrazu. Aby zminimalizować liczbę pominiętych klatek, nawet jeśli oznaczałoby to zmniejszenie rozdzielczość obrazu, należy przekazać do parametru favorArea wartość false.

Wybierając tryb natywny, środowisko wykonawcze usiłuje zachować żądany współczynnik kształtu obrazu zawsze, kiedy to możliwe. Jeśli na przykład zostanie wywołane polecenie mojaKamera.setMode(400, 400, 30), a największą dostępną rozdzielczością obrazu kamery jest 320 x 288, środowisko wykonawcze ustawi wartość 288 zarówno dla wysokości, jak i szerokości. Ustawiając te właściwości na taką samą wartość, środowisko wykonawcze zachowa żądany współczynnik kształtu obrazu równy 1:1.

Aby określić wartości przypisane do tych właściwości, po wybraniu przez środowisko wykonawcze trybu, który najbardziej odpowiada żądanym wartościom, należy użyć właściwości width, height oraz fps.

Korzystając z oprogramowania Flash Media Server, można także przechwytywać pojedyncze klatki lub tworzyć zdjęcia poklatkowe. Aby uzyskać·więcej informacji na ten temat, należy zapoznać się z metodą NetStream.attachCamera().

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Określa intensywność ruchu niezbędną do wywołania zdarzeniaactivity. Opcjonalnie ustawia czas bezczynności (w milisekundach), jaki musi upłynąć, zanim środowisko wykonawcze uwzględni zatrzymanie ruchu i wywoła zdarzenie.

Uwaga: wideo może być wyświetlane bez względu na wartość parametru motionLevel. Parametr określa jedynie kiedy i jakich okolicznościach wywoływane jest zdarzenie — nie zaś, czy obraz wideo jest w tej chwili przechwytywany lub wyświetlany.

Aby uniemożliwić wykrywanie ruchu przez kamerę, należy przekazać wartość 100 w parametrze motionLevel; zdarzenie activity nigdy nie zostanie wywołane. (Prawdopodobnie wartość ta będzie używana jedynie w celach testowych — na przykład aby tymczasowo wyłączyć moduły obsługi, które są zazwyczaj uruchamiane w momencie wywoływania zdarzenia).

Aby określić intensywność ruchu, który w danym momencie wykrywa kamera, należy skorzystać z właściwości activityLevel. Wartości czułości na ruch bezpośrednio odpowiadają wartościom aktywności. Całkowity brak ruchu oznacza wartość aktywności równą 0. Ciągły ruch to aktywność o wartości 100. Wartość aktywności jest mniejsza od wartości czułości na ruch, kiedy kamera się nie porusza; jeśli kamera jest w ruchu wartości aktywności często przewyższa wartość czułości na ruch.

Metoda ma podobne przeznaczenie, jak metoda Microphone.setSilenceLevel(); obie metody są używane do określania, kiedy należy wywołać zdarzenie activity. Jednak obie metody mają znacząco różny wpływ na publikowanie strumieni:

• Metoda Microphone.setSilenceLevel() została zaprojektowana w celu optymalizacji szerokości pasma. Jeśli strumień audio zostanie uznany za cichy, żadne dane audio nie będą przesyłane. W zamian przesłany zostanie komunikat informujący o rozpoczęciu się ciszy.
• Metoda Camera.setMotionLevel() została zaprojektowana w celu wykrywania ruchu i nie ma żadnego wpływu na użycie szerokości pasma. Nawet jeśli w strumieniu wideo nie jest wykrywany ruch, wideo jest nadal przesyłane.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Pozwala ustawić maksymalną szerokość pasma na sekundę lub wymaganą jakość wyjściowego obrazu wideo. Tę metodę można stosować tylko, jeśli wideo transmitowane jest za pomocą serwera z oprogramowaniem Flash Media Server.

Za pomocą tej metody można określić, który element wyjściowego obrazu wideo jest ważniejszy dla aplikacji — wykorzystanie przepustowości czy jakość obrazu.

• Aby wskazać, że wykorzystanie przepustowości jest ważniejsze, należy przekazać wartość dla parametru bandwidth i wartość 0 dla parametru quality. Środowisko wykonawcze transmituje wideo o najwyższej jakości dostępnej dla określonej przepustowości. W razie potrzeby środowisko wykonawcze obniża jakość obrazu, aby uniknąć przekroczenia określonej przepustowości. Na ogół wzrost intensywności ruchu obniża jakość obrazu.
• Aby wskazać, że jakość jest ważniejsza, należy przekazać do parametru bandwidth wartość 0 i wartość liczbową do parametru quality. Środowisko wykonawcze korzysta z przepustowości wymaganej do zachowania określonej jakości obrazu. W razie potrzeby środowisko wykonawcze obniża liczbę klatek na sekundę, aby zachować jakość obrazu. Na ogół wzrost intensywności ruchu powoduje zwiększenie szerokości pasma.
• Aby wskazać, że szerokość pasma i jakość są równie ważne, należy przekazać wartość liczbową do obu parametrów. Środowisko wykonawcze transmituje wideo o ustalonej jakości, która nie powoduje przekroczenia określonej przepustowości. W razie potrzeby środowisko wykonawcze obniża liczbę klatek na sekundę, aby zachować jakość obrazu, nie przekraczając określonej przepustowości.

Parametry

Powiązane elementy interfejsu API

Dysponowana, gdy aparat rozpoczyna lub kończy sesję. Wywołanie metody Camera.setMotionLevel() pozwala określić intensywność ruchu wymaganą do wywołania zdarzenia activity z właściwością activating o wartości true lub czas bezczynności jaki musi upłynąć, zanim wywołane zostanie zdarzenie activity dla, której właściwość activating będzie miała wartość false.

To zdarzenie ma następujące właściwości:

Rozsyłane, gdy aplikacja zażąda pozwolenia na użycie kamery urządzenia. Sprawdź wartość właściwości status, aby zobaczyć, czy pozwolenie zostało udzielone czy nie.

Powiązane elementy interfejsu API

Wywoływane, gdy aparat zgłasza swój stan. Przed uzyskaniem dostępu do kamery środowisko wykonawcze wyświetla okno dialogowe, dzięki któremu użytkownik może uzyskać dostęp do zawartości kamery lub zrezygnować z używania kamery. Jeśli właściwość code ma wartość "Camera.muted", oznacza to, że użytkownik odmówił udzielenia dostępu do kamery dla pliku SWF. Jeśli właściwość code ma wartość "Camera.Unmuted", oznacza to, że użytkownik zezwolił plikowi SWF na dostęp do kamery.

Uwaga: To zdarzenie nie jest wywoływane na platformie AIR. Jest ono używane tylko w programie Flash Player.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane bezpośrednio po przetworzeniu nowej klatki kamery przez kod podstawowy, gdy dane są dostępne do skopiowania.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Uwaga: Aby ten przykład zadziałał prawidłowo, należy podłączyć kamerę do komputera.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}