MovieClip  - AS3

재생 헤드가 MovieClip 인스턴스의 타임라인에 있는 프레임 번호를 지정합니다. 동영상 클립에 여러 장면이 있는 경우 이 값은 현재 장면의 프레임 번호입니다.

mc1.gotoAndStop(mc1.currentFrame + 5);

MovieClip 인스턴스의 타임라인에서 현재 프레임의 레이블입니다. 현재 프레임에 레이블이 없는 경우 currentLabel은 null입니다.

MovieClip 인스턴스의 타임라인에서 재생 헤드가 있는 현재의 레이블입니다. 현재 프레임에 레이블이 없는 경우 currentLabel은 레이블을 포함하는 이전 프레임의 이름으로 설정됩니다. 현재 및 이전 프레임에 레이블이 없는 경우 currentLabel은 null을 반환합니다.

trace(mc1.currentLabel);

현재 장면에서 FrameLabel 객체의 배열을 반환합니다. MovieClip 인스턴스가 장면을 사용하지 않는 경우, 배열에는 전체 MovieClip 인스턴스의 모든 프레임 레이블이 포함됩니다.

관련 API 요소

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

MovieClip 인스턴스의 타임라인에서 재생 헤드가 있는 현재의 장면입니다.

관련 API 요소

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

동영상 클립의 사용 여부를 나타내는 부울 값입니다. enabled의 기본값은 true입니다. enabled가 false로 설정된 경우 동영상 클립의 오버, 다운 및 업 프레임은 사용하지 않도록 설정됩니다. 동영상 클립은 계속해서 mouseDown, mouseUp, keyDown, keyUp 등의 이벤트를 수신합니다.

enabled 속성은 동영상 클립의 유사 버튼 속성만 제어합니다. enabled 속성은 언제든지 변경할 수 있으며, 변경된 동영상 클립은 즉시 사용하도록 설정되거나 사용하지 않도록 설정됩니다. enabled가 false로 설정된 경우 객체는 자동 탭 순서에 포함되지 않습니다.

mc1.enabled = false;

스트리밍 SWF 파일에서 로드되는 프레임 수입니다. framesLoaded 속성을 사용하여 특정 프레임 및 이 프레임 이전의 모든 프레임 내용이 로드되었는지와 브라우저에서 로컬로 사용할 수 있는지 여부를 확인할 수 있습니다. 또한 대형 SWF 파일의 다운로드를 모니터링할 수도 있습니다. 예를 들어 SWF 파일에서 지정된 프레임의 로드 작업이 완료될 때까지 SWF 파일을 로드하고 있다는 메시지를 사용자에게 표시할 수 있습니다.

동영상 클립에 여러 장면이 있는 경우 framesLoaded 속성은 해당 동영상 클립의 모든 장면에 대해 로드된 프레임 수를 반환합니다.

관련 API 요소

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

동영상 클립이 현재 재생 중인지 여부를 나타내는 부울 값입니다.

MovieClip 인스턴스에 포함된 장면의 이름, 프레임 수, 프레임 레이블이 각각 나열되어 있는 Scene 객체의 배열입니다.

관련 API 요소

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

MovieClip 인스턴스의 총 프레임 수입니다.

동영상 클립에 여러 장면이 있는 경우 totalFrames 속성은 동영상 클립의 모든 장면에 대해 총 프레임 수를 반환합니다.

 trace(mc1.totalFrames);

SimpleButton 또는 MovieClip 등의 다른 표시 객체에서 마우스 릴리스 이벤트 또는 다른 사용자 입력 릴리스 이벤트를 수신할 수 있는지 여부를 나타냅니다. trackAsMenu 속성을 사용하면 메뉴를 만들 수 있습니다. 모든 SimpleButton 또는 MovieClip 객체에서 trackAsMenu 속성을 설정할 수 있습니다. trackAsMenu 속성의 기본값은 false입니다.

trackAsMenu 속성은 언제든지 변경할 수 있으며, 변경된 동영상 클립에는 즉시 새 비헤이비어가 적용됩니다.

 mc1.trackAsMenu = true;

새 MovieClip 인스턴스를 만듭니다. MovieClip을 만든 후에는 스테이지에 있는 표시 객체 컨테이너의 addChild() 또는 addChildAt() 메서드를 호출합니다.

지정된 프레임에서 SWF 파일 재생을 시작합니다. 이것은 해당 프레임에서 나머지 액션이 모두 실행을 마친 뒤에 발생합니다. 프레임뿐만 아니라 장면을 지정하려면 scene 매개 변수 값을 지정합니다.

매개 변수

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

동영상 클립의 특정 프레임으로 재생 헤드를 가져온 다음 정지합니다. 이것은 해당 프레임에서 나머지 액션이 모두 실행을 마친 뒤에 발생합니다. 프레임뿐만 아니라 장면을 지정하려면 scene 매개 변수를 사용합니다.

매개 변수

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

재생 헤드를 다음 프레임으로 보낸 다음 정지합니다. 이것은 해당 프레임에서 나머지 액션이 모두 실행을 마친 뒤에 발생합니다.

관련 API 요소

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

재생 헤드를 MovieClip 인스턴스의 다음 장면으로 움직입니다. 이것은 해당 프레임에서 나머지 액션이 모두 실행을 마친 뒤에 발생합니다.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

동영상 클립의 타임라인에서 재생 헤드를 이동합니다.

관련 API 요소

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

재생 헤드를 이전 프레임으로 보낸 다음 정지합니다. 이것은 해당 프레임에서 나머지 액션이 모두 실행을 마친 뒤에 발생합니다.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

재생 헤드를 MovieClip 인스턴스의 이전 장면으로 움직입니다. 이것은 해당 프레임에서 나머지 액션이 모두 실행을 마친 뒤에 발생합니다.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

동영상 클립의 재생 헤드를 정지합니다.

1. 생성자 함수가 MovieClipExample 객체(MovieClip을 확장함)의 속성 값을 표시하는 데 사용되는 텍스트 필드를 정의합니다.
2. getPropertiesString() 메서드의 반환 값은 outputText 텍스트 필드의 텍스트로 사용됩니다. getPropertiesString() 메서드는 currentFrame, currentLabel, currentScene, framesLoaded, totalFrames 및 trackAsMenu 등과 같은 동영상 클립 속성 값으로 채워지는 문자열을 반환합니다.
3. 생성자 함수의 두 코드 줄을 사용하여 outputText 텍스트 필드의 width 및 height 속성을 조정할 수 있습니다.
4. 생성자 함수의 마지막 줄이 outputText 텍스트 필드를 표시 목록에 추가합니다.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}