Loader  - AS3

load() 또는 loadBytes() 메서드를 사용하여 로드된 SWF 파일 또는 이미지(JPG, PNG 또는 GIF) 파일의 루트 표시 객체를 포함합니다.

관련 API 요소

로드 중인 객체에 해당하는 LoaderInfo 객체를 반환합니다. LoaderInfo 객체는 Loader 객체와 로드된 내용 객체 간에 공유되며, 로드된 파일에 대한 로드 진행률 정보 및 통계를 제공합니다.

해당 로드와 연관된 이벤트는 Loader 객체의 contentLoaderInfo 속성에서 참조하는 LoaderInfo 객체에 의해 전달됩니다. contentLoaderInfo 속성을 유효한 LoaderInfo 객체로 설정하면 이벤트 수신자를 로드보다 먼저 객체에 추가할 수 있습니다.

로드된 SWF에서 발생한 포착되지 않는 오류를 검색하려면 Loader.contentLoaderInfo.uncaughtErrorEvents가 아닌 Loader.uncaughtErrorEvents 속성을 사용합니다.

관련 API 요소

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

이 Loader 객체에 의해 로드된 SWF에서 처리되지 않은 오류가 발생하는 경우 uncaughtError 이벤트를 전달하는 객체입니다. try..catch 블록 밖에서 오류가 발생하는 경우 또는 리스너가 등록되지 않은 상태로 ErrorEvent 객체가 전달되는 경우 포착되지 않는 오류가 발생합니다.

Loader 객체의 uncaughtErrorEvents 속성은 객체가 직접 전달하는 이벤트가 아닌 객체를 통해 버블링되는 이벤트를 전달합니다. 이 속성은 대상 단계의 uncaughtErrorEvent는 전달하지 않으며 캡처 및 버블링 단계의 이벤트만 전달합니다. Loader 객체가 정의되어 있는 현재 SWF에서 포착되지 않는 오류를 검색하려면 LoaderInfo.uncaughtErrorEvents 속성을 대신 사용하십시오.

Loader 객체에 의해 로드된 내용이 AVM1(ActionScript 2) SWF 파일일 경우, AVM1 SWF 파일에서 잡히지 않은 오류는 uncaughtError 이벤트로 나타나지 않습니다.

관련 API 요소

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

SWF, JPEG, GIF 또는 PNG 파일 등을 로드하는 데 사용할 수 있는 Loader 객체를 만듭니다. load() 메서드를 호출하여 해당 에셋을 Loader 인스턴스의 자식으로 로드합니다. 그런 다음, Loader 객체를 표시 목록에 추가할 수 있습니다(예: DisplayObjectContainer 인스턴스의 addChild() 메서드 사용). 에셋은 자신이 로드되는 Stage에 나타납니다.

표시 목록의 표시 객체 컨테이너에 해당 객체를 추가하지 않는 Loader 인스턴스의 "오프리스트(offlist)" 모드를 사용할 수도 있습니다. 이 모드에서 Loader 인스턴스는 응용 프로그램의 추가 모듈을 포함하는 SWF 파일을 로드하는 데 사용될 수 있습니다.

SWF 파일 로드가 완료되는 시점을 감지하기 위해 Loader 객체의 contentLoaderInfo 속성과 관련된 LoaderInfo 객체의 이벤트를 사용할 수 있습니다. 이때 모듈 SWF 파일의 코드가 실행되어 모듈을 초기화하고 시작할 수 있습니다. offlist 모드에서 Loader 인스턴스는 구성 요소 또는 미디어 에셋을 포함하는 SWF 파일을 로드하는 데 사용될 수 있습니다. 앞에서와 마찬가지로 LoaderInfo 객체 이벤트 알림을 사용하여 구성 요소가 로드를 완료하는 시점을 감지할 수 있습니다. 이때 응용 프로그램은 SWF 파일의 라이브러리에 있는 구성 요소와 미디어 에셋을 나타내는 ActionScript 3.0 클래스를 인스턴스화함으로써 해당 구성 요소와 에셋을 사용할 수 있습니다.

Loader 객체의 상태를 확인하려면 Loader 객체의 contentLoaderInfo 속성과 연관된 LoaderInfo 객체의 다음과 같은 이벤트를 모니터링합니다.

• open 이벤트 - 로드가 시작될 때 전달됩니다.
• ioError 또는 securityError 이벤트 - 파일을 로드할 수 없는 경우 또는 로드 프로세스 중 오류가 발생한 경우 전달됩니다.
• progress 이벤트 - 파일이 로드되는 동안 계속해서 발생합니다.
• complete 이벤트 - 파일 다운로드가 완료된 후, 로드된 동영상 클립의 메서드와 속성이 사용 가능한 상태가 되기 전에 전달됩니다.
• init 이벤트 - 로드된 SWF 파일을 조작할 수 있도록, 로드된 SWF 파일의 속성과 메서드가 액세스 가능한 상태가 된 후에 전달됩니다. 이 이벤트는 complete 핸들러에 앞서 전달됩니다. 스트리밍 SWF 파일의 경우 init 이벤트는 complete 이벤트보다 훨씬 더 이전에 발생할 수 있습니다. 대부분의 경우에는 init 핸들러를 사용합니다.

참고(iOS에만 해당): iOS의 AIR 응용 프로그램에서는 ActionScript가 포함된 SWF 파일을 응용 프로그램 패키지에서만 로드할 수 있습니다. 이 제한 사항에는 ActionScript용으로 내보낸 클래스 이름이 포함된 에셋 같은 모든 ActionScript가 포함됩니다. SWF 파일을 로드할 때 부모 SWF와 동일한 응용 프로그램 도메인을 사용하여 SWF를 로드해야 합니다.

AIR 3.6 이하에서는 응용 프로그램 패키지에서 로드하든, 네트워크에서 로드하든 ActionScript 바이트 코드가 포함되지 않은 SWF 파일만 로드할 수 있습니다. ActionScript가 있는 외부 SWF 파일을 사용하는 대신 SWC 라이브러리를 만들어 기본 SWF에 연결하는 방법도 있습니다.

이 제한 사항은 응용 프로그램이 iOS 시뮬레이터(ipa-test-interpreter-simulator 또는 ipa-debug-interpreter-simulator)나 인터프리터 모드(ipa-test-interpreter 또는 ipa-debug-interpreter)에서 실행되는 경우에는 적용되지 않습니다.

관련 API 요소

현재 Loader 인스턴스에 대해 진행 중인 load() 메서드 작업을 취소합니다.

관련 API 요소

SWF, JPEG, 점진적 JPEG, 비애니메이션 GIF 또는 PNG 파일을 이 Loader 객체의 자식 객체로 로드합니다. 애니메이션 GIF 파일을 로드하는 경우 첫 번째 프레임만 표시됩니다. Loader 객체는 하나의 자식만을 포함할 수 있기 때문에 후속 load() 요청을 발생시키면 이전 요청(여전히 대기 중인 경우)이 종료되고 새 로드가 시작됩니다.

참고: AIR 1.5 및 Flash Player 10에서는 로드된 이미지의 최대 크기가 8,191픽셀(폭 또는 높이)이며 총 픽셀 수는 16,777,215픽셀을 초과할 수 없습니다. 따라서 로드된 이미지의 폭이 8,191픽셀이면 높이가 2,048픽셀 이하여야 합니다. Flash Player 9 이전 버전 및 AIR 1.1 이전 버전에서는 이 제한이 높이 2,880픽셀 및 폭 2,880픽셀입니다.

Loader 객체로 로드된 SWF 파일 또는 이미지는 Loader 객체의 부모 표시 객체로부터 위치, 회전 및 크기 조절 속성을 상속합니다.

이 메서드를 사용하여 로드한 동영상 또는 이미지를 제거하거나 진행 중인 로드 작업을 취소하려면 unload() 메서드를 사용합니다.

SWF 내용이 들어 있는 HTML 페이지에서 allowNetworking 매개 변수(object 및 embed 태그)를 설정하여 SWF 파일에서 이 메서드를 사용하지 않게 할 수 있습니다.

iOS 참고 사항

iOS의 AIR 응용 프로그램에서는 ActionScript가 포함된 SWF 파일을 응용 프로그램 패키지에서만 로드할 수 있습니다. 이 제한 사항에는 ActionScript용으로 내보낸 클래스 이름이 포함된 에셋 같은 모든 ActionScript가 포함됩니다. SWF 파일을 로드할 때 다음 예제에서처럼 부모 SWF와 동일한 응용 프로그램 도메인을 사용하여 SWF를 로드해야 합니다.

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

또한 iOS에서 ActionScript ByteCode(ABC)를 포함한 SWF 파일을 로드했다가 언로드한 다음 다시 로드할 수 없습니다. 이를 수행하려는 경우 런타임 오류 3764가 발생합니다.

AIR 3.6 이하에서는 응용 프로그램 패키지에서 로드하든, 네트워크에서 로드하든 ActionScript 바이트 코드가 포함되지 않은 SWF 파일만 로드할 수 있습니다. ActionScript가 있는 외부 SWF 파일을 사용하는 대신 SWC 라이브러리를 만들어 기본 SWF에 연결하는 방법도 있습니다.

이 제한 사항은 응용 프로그램이 iOS 시뮬레이터(ipa-test-interpreter-simulator 또는 ipa-debug-interpreter-simulator)나 인터프리터 모드(ipa-test-interpreter 또는 ipa-debug-interpreter)에서 실행되는 경우에는 적용되지 않습니다.

Loader 보안

이 메서드를 사용할 때는 Loader 클래스 설명에 나와 있는 Flash Player 보안 모델을 고려해야 합니다.

Flash Player 10 이상에서는 multipart Content-Type(예: "multipart/form-data")을 사용하고 POST 본문 내 "content-disposition" 헤더에 "filename" 매개 변수를 지정하여 업로드를 처리하는 경우 POST 작업이 업로드에 적용되는 보안 규칙의 영향을 받을 수 있습니다.

• POST 작업은 마우스 클릭이나 키 누르기 같은 사용자 동작에 대한 응답으로 수행됩니다.
• POST 작업이 크로스 도메인인 경우, 즉 POST 대상이 POST 요청을 보내는 SWF 파일과 같은 서버에 없는 경우 대상 서버는 크로스 도메인 액세스를 허용하는 URL 정책 파일을 제공해야 합니다.

또한 multipart Content-Type의 경우 구문이 RFC2046 표준에 따라 유효해야 합니다. 구문이 유효하지 않은 경우 POST 작업은 업로드에 적용되는 보안 규칙의 영향을 받을 수 있습니다.

보안에 대한 자세한 내용은 Flash Player 개발자 센터 항목: 보안을 참조하십시오.

매개 변수

관련 API 요소

ByteArray 객체에 저장된 이진 데이터에서 로드합니다.

loadBytes() 메서드는 비동기적입니다. 로드된 객체의 속성에 액세스하기 전에 "init" 이벤트가 발생할 때까지 기다려야 합니다.

이 메서드를 사용할 때는 Loader 클래스 설명에 나와 있는 Flash Player 보안 모델을 고려해야 합니다.

참고(iOS에만 해당): iOS의 AIR 응용 프로그램에서는 ActionScript가 포함된 SWF 파일을 응용 프로그램 패키지에서만 로드할 수 있습니다. 이 제한 사항에는 ActionScript용으로 내보낸 클래스 이름이 포함된 에셋 같은 모든 ActionScript가 포함됩니다. SWF 파일을 로드할 때 부모 SWF와 동일한 응용 프로그램 도메인을 사용하여 SWF를 로드해야 합니다.

AIR 3.6 이하에서 이 메서드 호출은 iOS에 아무런 효과가 없습니다.

매개 변수

관련 API 요소

IFilePromise 인스턴스를 로드합니다.

loadFilePromise 메서드는 IFilePromise 객체를 사용하고 이진 데이터를 로드합니다. 데이터가 점진적 문자열(예: 비디오)인 경우 "init" 또는 progress 이벤트를 기다린 후에 로드된 객체의 속성에 액세스합니다. 그렇지 않으면 complete 이벤트를 기다려서 데이터가 완전히 로드되었는지를 확인합니다.

이 메서드를 사용할 때는 Loader 클래스 설명에 나와 있는 Flash Player 보안 모델을 고려해야 합니다.

매개 변수

관련 API 요소

load() 메서드를 사용하여 로드된 이 Loader 객체의 자식을 제거합니다. 관련된 LoaderInfo 객체의 property는 null로 재설정됩니다. 해당 자식은 다른 객체에서 참조할 수 있기 때문에 반드시 삭제되지는 않지만, 더 이상 Loader 객체의 자식이 아닙니다.

unload() 메서드를 호출하면 Loader 객체의 contentLoaderInfo 속성이 null로 설정됩니다. SWF와 함께 로드된 모든 시각적 에셋이 언로드되고 메모리에서 제거됩니다. 로드된 SWF의 ActionScript 클래스 정의는 메모리에 그대로 유지되고 로드된 SWF와 같은 응용 프로그램 도메인의 코드는 해당 클래스의 인스턴스에 액세스하여 새 인스턴스를 만들 수 있습니다.

참고(iOS에만 해당): AIR 3.6 이하에서 이 메서드는 iOS에 아무런 효과가 없습니다.

자식 SWF 파일을 언로드하기 전에 해당 자식 SWF 파일의 객체(예: LocalConnection, NetConnection, NetStream 및 Sound)에 있는 모든 스트림을 확실하게 닫는 것이 좋습니다. 그렇지 않으면 자식 SWF 파일이 언로드된 경우에도 자식 SWF 파일의 오디오가 계속해서 재생될 수 있습니다. 자식 SWF 파일의 스트림을 닫으려면 이벤트 리스너를 unload 이벤트에 대해 수신하는 자식에 추가합니다. 부모가 Loader.unload()를 호출하면 unload 이벤트가 자식에 전달됩니다. 다음 코드는 이렇게 하는 방법을 보여 줍니다.

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

관련 API 요소

자식 SWF 파일 내용을 언로드하고 로드된 SWF 파일의 명령 실행을 중지합니다. 이 메서드는 자식 SWF 파일의 EventDispatcher, NetConnection, Timer, Sound 또는 Video 객체에 대한 참조를 제거하여 Loader.load() 또는 Loader.loadBytes()를 사용하여 로드되고 있는 SWF 파일을 언로드합니다. 따라서 자식 SWF 파일 및 자식 SWF 파일의 표시 목록에서 다음 동작이 발생합니다.

• 사운드가 중지됩니다.
• Stage 이벤트 리스너가 제거됩니다.
• enterFrame, frameConstructed, exitFrame, activate 및 deactivate의 이벤트 리스너가 제거됩니다.
• 타이머가 중지됩니다.
• Camera 및 Microphone 인스턴스가 분리됩니다.
• 동영상 클립이 중지됩니다.

unloadAndStop() 메서드를 호출하면 Loader 객체의 contentLoaderInfo 속성이 null로 설정됩니다. SWF와 함께 로드된 모든 시각적 에셋이 언로드되고 메모리에서 제거됩니다. 로드된 SWF의 ActionScript 클래스 정의는 메모리에 그대로 유지되고 로드된 SWF와 같은 응용 프로그램 도메인의 코드는 해당 클래스의 인스턴스에 액세스하여 새 인스턴스를 만들 수 있습니다.

참고(iOS에만 해당): AIR 3.6 이하에서 이 메서드는 iOS에 아무런 효과가 없습니다.

매개 변수

관련 API 요소

1. 이미지 파일의 이름과 위치를 나타내는 url 속성이 만들어집니다.
2. LoaderExample 생성자에서 loader라는 새 Loader 객체를 만든 후 단계 3에 설명된 configureListeners() 메서드에 전달합니다.
3. 생성자가 파일 이름 및 위치를 나타내도록 전달된 url이 있는 새 URLRequest 객체 request를 만듭니다.
4. request 객체가 loader 객체의 load() 메서드로 전달되며, 이 메서드는 이미지를 표시 목록으로 로드합니다.
5. clickHandler 이벤트 리스너가 로더에서 click 이벤트에 대해 등록됩니다. 마우스를 클릭하면 로드된 이미지가 언로드됩니다.
6. configureListeners() 메서드가 다음 메서드를 사용하여 일곱 개의 이벤트 리스너를 추가합니다.
   • completeHandler() 메서드는 이미지 로드가 완료되면 실행됩니다.
   • httpStatusHandler() 메서드는 이미지가 로컬에 로드되지 않은 경우 네트워크 요청이 사용 가능하게 되고 Flash Player에서 해당 요청을 감지할 수 있을 때만 실행됩니다.
   • initHandler() 메서드는 completeHandler() 메서드 이전 및 progressHandler() 메서드 이후에 실행됩니다. 일반적으로 SWF 파일을 로드할 경우에는 init 이벤트가 더 유용합니다.
   • ioErrorHandler() 메서드는 이미지 파일을 사용할 수 없거나 액세스할 수 없는 경우 실행됩니다.
   • openHandler() 메서드는 이미지 파일을 처음 열 때 실행됩니다.
   • progressHandler() 메서드는 이미지 파일을 로드하기 시작할 때 실행되며 이미지 로드가 완료되면 다시 한 번 실행됩니다.
   • unLoadHandler() 메서드는 사용자가 이미지를 클릭할 때 unload() 메서드를 사용하여 이미지가 언로드되면 실행됩니다.

검토를 진행할 때는 다음과 같은 요구 사항을 염두에 두어야 합니다.

• 이 예제에서는 컴파일된 SWF 파일과 같은 디렉토리에 Image.gif 파일이 있어야 합니다. 기본 SWF 파일의 크기에 알맞은 영역이 있는 이미지를 사용합니다.
• 이 예제에서는 LoaderInfo 객체에 사용 가능한 모든 이벤트를 활용하지만, 대부분의 경우 하위 세트만 필요합니다. 특히, 이미지 파일만을 로드할 경우 complete 이벤트(또는 ioError 이벤트)만 있으면 로컬 이미지를 로드하는 데는 충분합니다.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}