ContextMenu  - AS3

ContextMenuBuiltInItems クラスのインスタンスには、forwardAndBack、loop、play、print、quality、rewind、save および zoom の各プロパティがあります。これらのプロパティを false に設定すると、対応するメニューアイテムが、指定した ContextMenu オブジェクトから削除されます。これらのプロパティは列挙することができ、デフォルトでは true に設定されています。

注意：AIR では、コンテキストメニューにビルトインアイテムはありません。

関連する API エレメント

ContextMenuClipboardItems クラスのインスタンスには、cut、copy、paste、delete、selectAll の各プロパティがあります。これらのプロパティのいずれかを false に設定すると、クリップボードメニューの対応するアイテムが無効になります。

関連する API エレメント

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

クリップボードメニューを使用するかどうかを指定します。この値が true の場合、clipboardItems プロパティはクリップボードメニューで、どのアイテムが有効または無効になっているかを決定します。

link プロパティが null 以外の場合、この clipBoardMenu プロパティは無視されます。

ContextMenuItem オブジェクトの配列です。配列内の各オブジェクトは、定義したカスタムコンテキストメニューアイテムを表します。このプロパティを使用して、これらのカスタムメニューアイテムを追加、削除、変更することができます。

新しいメニューアイテムを追加するには、ContextMenuItem オブジェクトを作成し、このオブジェクトを customItems 配列に追加します。このとき、Array.push() などを使用します。メニューアイテムの作成について詳しくは、ContextMenuItem クラスを参照してください。

関連する API エレメント

現在のプラットフォームで ContextMenu クラスがサポートされている場合、isSupported プロパティは true に設定されます。サポートされていない場合は、false に設定されます。

このメニューのカスタムアイテムの配列です。

このプロパティの使用は、customItems プロパティを使用するのと同じです。配列は、表示順にソートされています。

リンクの URLRequest です。このプロパティが null の場合、通常のコンテキストメニューが表示されます。このプロパティが null でない場合、リンクのコンテキストメニューが表示され、指定された url で動作します。

link が指定されている場合、clipboardMenu プロパティは無視されます。

デフォルト値は null です。

このメニュー内のアイテムの数です。

ContextMenu オブジェクトを作成します。

関連する API エレメント

メニューの下部に、メニューアイテムを追加します。

コンテキストメニューを作成する場合は、NativeMenuItem または ContextMenuItem オブジェクトのいずれかを追加できます。ただし、メニュー内のすべてのアイテムが同じプロパティを持つようにするため、コンテキストメニューでは 1 つの型のオブジェクトのみを使用することをお勧めします。

パラメーター

指定された ContextMenu オブジェクトのコピーを作成します。このコピーは、元のメニューオブジェクトのすべてのプロパティを継承しています。

このメニューが、指定されたメニューアイテムを含むかどうかを報告します。

パラメーター

このメニューを、指定された位置にポップアップ表示します。

注意：Flash Player では、このメソッドはサポートされていません。

パラメーター

指定されたインデックス位置にあるメニューアイテムを取得します。

パラメーター

指定されたアイテムの位置を取得します。

パラメーター

「設定」を除き、指定された ContextMenu オブジェクト内のすべてのビルトインメニューアイテムを非表示にします。デバッガー版の Flash Player が実行されている場合、デバッグのメニューアイテムは表示されますが、リモートデバッグが有効化されていない SWF ファイルについては、デバッグのメニューアイテムはグレー表示されます。

このメソッドは、標準コンテキストメニューに表示されるメニューアイテムだけを非表示にします。編集メニューおよびエラーメニューに表示されるメニューアイテムには影響しません。

このメソッドは、 my_cm .builtInItems に含まれるブール型プロパティをすべて false に設定するという形で機能します。 my_cm .builtInItems 内の対応するアイテムを true に設定すれば、個々のビルトインアイテムを選択的に表示させることができます。

注意：AIR では、コンテキストメニューにビルトインアイテムはありません。このメソッドを呼び出しても無効です。

関連する API エレメント

メニューからすべてのアイテムを削除します。

指定されたインデックス位置にあるメニューアイテムを削除して返します。

パラメーター

ユーザーが最初にコンテキストメニューを生成したときに、コンテキストメニューの内容が表示される前に送出されます。これにより、コンテキストメニューを表示する前に、プログラムによってコンテキストメニューアイテムのセットを変更できます。ユーザーは、ポインティングデバイスを右クリックすることにより、コンテキストメニューを生成します。

このイベントには、次のプロパティがあります。

1. myContextMenu プロパティが宣言されて、新しい ContextMenu オブジェクトに割り当てられます。次に Sprite 型の redRectangle プロパティが宣言されます。
2. removeDefaultItems() メソッドが呼び出されます。このメソッドによって、すべてのビルトインコンテキストメニューアイテムが削除されます。ただし、「プリント」を除きます。
3. addCustomMenuItems() メソッドが呼び出され、Red to Black メニュー選択というメニューアイテムが defaultItems 配列に配置されます。このとき、配列の push() メソッドが使用されます。menuItemSelect イベントリスナーが ContextMenuItem オブジェクトに追加されます。関連付けられるメソッドは menuItemSelectHandler() という名前です。このメソッドは、trace() を使用してステートメントを出力します。ステートメントが出力されるのは、コンテキストメニューにアクセスし、Red to Black を選択した場合です。また、赤色の四角形は削除されて黒色の四角形に置換されます。
4. タイプが menuSelect のイベントリスナーが、関連する menuSelectHandler メソッドと共に追加されます。このメソッドは、コンテキストメニューアイテムが開かれるたびに trace() を使用して 3 つのステートメントを出力します。
5. 次に、addChildren() は、赤色の四角形を描画し、それを表示リストに追加します。この四角形は、すぐに表示リストに表示されます。
6. 最後に、myContextMenu が redRectangle スプライトのコンテキストメニューに割り当てられ、マウスポインターが四角形上に置かれたときのみカスタムコンテキストメニューが表示されるようになります。

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}