ContextMenuItem  - AS3

パッケージ	flash.ui
クラス	public final class ContextMenuItem
継承	ContextMenuItem NativeMenuItem EventDispatcher Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9

ContextMenuItem クラスは、コンテキストメニューのアイテムを表します。各 ContextMenuItem オブジェクトには、コンテキストメニューに表示されるキャプション（テキスト）を指定できます。コンテキストメニューに新しいアイテムを追加するには、ContextMenu オブジェクトの customItems 配列にアイテムを追加します。

ContextMenuItem クラスのプロパティを使用して、特定のメニューアイテムを有効または無効にして、アイテムを表示または非表示にすることができます。

menuItemSelect イベントのイベントハンドラーを記述して、ユーザーがメニューアイテムを選択したときにメニューアイテムに機能を追加します。

カスタムメニューアイテムは、コンテキストメニューの一番上、つまり、どのビルトインアイテムよりも上に表示されます。カスタムメニューアイテムとビルトインアイテムとの間にはセパレーターが表示されます。 AIR には、ビルトインアイテムは存在しません。また、AIR アプリケーションサンドボックスのコンテンツに、次の制約は適用されません。

制約：

• コンテキストメニューに追加できるカスタムアイテムは 15 アイテム以内です。
• 各キャプションには、少なくとも 1 つの表示可能な文字が含まれている必要があります。
• 制御文字、改行、その他の空白文字は無視されます。
• キャプションの長さは 100 文字以内である必要があります。
• ビルトインメニューアイテムまたは他のカスタムメニューアイテムと同じキャプションは、一致するアイテムが表示されているかどうかにかかわらず無視されます。メニューキャプションは、ビルトインキャプションまたは既存のカスタムキャプションと比較されます。その際、大文字と小文字は区別されず、カンマとピリオド、空白文字は無視されます。
• 以下のキャプションは許可されませんが、他の単語と組み合わせてカスタムキャプションを作成することはできます。例えば、「ペースト」は許可されませんが、「ペーストはおいしい」は許可されます。

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• 以下の単語は、単独でも他の単語と組み合わせてもカスタムキャプションには使用できません。

   Adobe
   Macromedia
   Flash Player
   Settings
   

注意：英語以外のシステムで実行される場合、キャプションストリングは英語の一覧およびローカライズされた一覧の両方と比較されます。

例を表示

関連する API エレメント

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}