NativeWindow  - AS3

このウィンドウが、アクティブなアプリケーションウィンドウかどうかを示します。

activate() メソッドを使ってウィンドウをアクティブにします。

関連する API エレメント

このウィンドウを、常に他のウィンドウ（他のアプリケーションのウィンドウも含む）よりも前面に表示するかどうかを指定します。

システムでウィンドウが重なる順序において、各ウィンドウは 2 つのグループに分けられます。alwaysInFront に設定されているウィンドウのグループは、常に他のウィンドウよりも前面に表示されます。同じグループ内での重なりの順序は、通常の規則に従います。つまり、あるウィンドウをアクティブ化すると、そのウィンドウは同じグループの他のウィンドウよりも前面に表示されます。

alwaysInFront を false から true に変更すると、そのウィンドウは最前面に表示されます。このプロパティを true から false に変更すると、そのウィンドウは「alwaysInFront」ウィンドウの背面に表示されます。ただし、同じグループの他のウィンドウよりも前面に表示されたままになります。プロパティを現在の値に設定しても、ウィンドウの重なりの順序は変更されません。他のウィンドウに所有されるウィンドウの alwaysInFront プロパティを設定しても、影響はありません。

alwaysInFront プロパティが true に設定されているウィンドウは、他のアプリケーションのウィンドウがアクティブの場合でも、そのウィンドウより前面に表示されるので、このプロパティは慎重に設定する必要があります。

OS の動作に関する注意：

• 一部の Linux ウィンドウマネージャーでは、alwaysInFront が設定されているウィンドウはをフルスクリーンウィンドウの手前に表示することはできません。
• Mac^® OS X では、alwaysInFront を true に設定しても、ウィンドウステージの displayState プロパティが fullScreen または fullScreenInteractive である場合には効果はありません。

windowObj.alwaysInFront = true;

displayObject.stage.nativeWindow.alwaysInFront=true;

window.nativeWindow.alwaysInFront = true;

このウィンドウのサイズと位置です。

ウィンドウのサイズには、システムクロムが含まれます。ウィンドウのステージのサイズは、ウィンドウのサイズからシステムクロムのサイズを引いたものに等しくなります。ウィンドウの幅と高さを変更すると、ステージのstageWidth および stageHeight が変更されます。その逆も同様で、ステージのサイズを変更すると、ウィンドウのサイズが変更されます。

ルート HTML ウィンドウでは、outerWidth プロパティおよび outerHeight プロパティは、ウィンドウの height プロパティおよび width プロパティに等しくなります。innerWidth プロパティおよび innerHeight プロパティは、stage.stageWidth プロパティおよび stage.stageHeight プロパティから、ウィンドウに表示されている自動スクロールバーの幅および高さを引いた値に等しくなります。

resize イベントは、このウィンドウの幅または高さが変更されると常に送出されます。同様に、このウィンドウの起点（x,y）が変更されると、常に move イベントが送出されます。Mac OS および Windows では、bounds プロパティを直接に設定した場合 moving イベントや resizing イベントは送出されません。それに対し、Linux では、NativeWindow から moving イベントや resizing イベントが、bounds プロパティを直接に設定した場合でも送出されます。

ウィンドウの bounds プロパティを設定することは、ウィンドウの x、y、width および height プロパティを設定することと同じです。同様に、個々の寸法のいずれかを設定することは、bounds プロパティを設定することと同じです。bounds プロパティを使用してすべてのサイズを同時に設定すると、送信されるイベントの数が少なくなります。

個々のサイズが設定される順序は保証されません。デスクトップ領域より大きくウィンドウを拡大できない Linux ウィンドウマネージャーでは、すべてのプロパティ変更を適用した最終的な結果が正規のウィンドウになる場合であっても、個別のプロパティに対する変更がブロックされる場合があります。

指定された幅または高さが、許容される幅または高さの下限よりも小さい場合や上限よりも大きい場合、許容される最も近い値にウィンドウの幅または高さが設定されます。幅と高さの下限および上限は、次の要因に基づいて決定されます。

• NativeWindow オブジェクトの minSize および maxSize プロパティ。
• オペレーティングシステムの制限による上限と下限。これは、NativeWindow.systemMinSize と NativeWindow.systemMaxSize の値です。
• Adobe AIR におけるウィンドウ幅および高さの上限（4095 ピクセル）（AIR 1.5 以前では、ウィンドウの最大の幅と高さは各 2880 ピクセルです）。
• 表示されているシステムクロムに必要な幅と高さの最小値

ウィンドウの位置またはサイズが変更されると、ピクセル値は最も近い整数に四捨五入されます。

関連する API エレメント

windowObj.bounds = new Rectangle(200, 200, 1000, 800);

displayObject.stage.nativeWindow.bounds = new Rectangle(20, 20, 800, 600);

window.nativeWindow.bounds = new air.Rectangle(20, 20, 800, 600);

このウィンドウが閉じられたかどうかを示します。

閉じられたウィンドウで次のプロパティにアクセスすると、無効な操作を示すエラーがスローされます。

• title
• bounds
• x、y、width、height
• displayState
• visible

同様に、閉じられたウィンドウで次のメソッドを呼び出すと、無効な操作を示すエラーがスローされます。

• minimize()
• maximize()
• restore()
• startResize()
• startMove()

var isWindowClosed:Boolean = windowObj.closed;

var isWindowClosed:Boolean = displayObject.stage.nativeWindow.closed;

var isWindowClosed = window.nativeWindow.closed;

このウィンドウの表示状態です。

有効な値の定数は、NativeWindowDisplayState クラスで定義されています。

• NativeWindowDisplayState.NORMAL
• NativeWindowDisplayState.MINIMIZED
• NativeWindowDisplayState.MAXIMIZED

関連する API エレメント

var state:String = windowObj.displayState;

このウィンドウの高さ（ピクセル単位）です。

ウィンドウのサイズには、表示されているシステムウィンドウのクロムが含まれます。ウィンドウ内側の使用可能な表示領域の高さは、Stage.stageHeight プロパティから取得できます。

ウィンドウの height プロパティを変更すると、bounds プロパティから高さを変更した場合と同じ動作をします。

指定された高さが、許容される高さの下限よりも小さい場合や上限よりも大きい場合、許容される最も近い値にウィンドウの高さが設定されます。高さの下限および上限は、次の要因に基づいて決定されます。

• NativeWindow オブジェクトの minSize.x および maxSize.x プロパティ
• オペレーティングシステムの制限による上限と下限。これは、NativeWindow.systemMinSize.x と NativeWindow.systemMaxSize.x の値です。
• Adobe AIR でのウィンドウの最大の高さは 4095 ピクセルです（AIR 1.5 以前では 2880 ピクセルです）。

Linux の場合、height プロパティを設定する操作は非同期的に実行されます。

高さ変更の完了を検出するには、resize イベントを監視します。これは、どのプラットフォームでも送出されるイベントです。

ウィンドウの高さが変更されると、ピクセル値は最も近い整数に四捨五入されます。

関連する API エレメント

クライアントシステムでネイティブウィンドウがサポートされているかどうかを示します。

このウィンドウの作成に使用される最大化可能設定を報告します。

ウィンドウが作成された後で、maximizable 設定を変更することはできません。

注意：一部の Linux ウィンドウマネージャーでは、maximizable プロパティが false に設定されている場合でも、ユーザーがウィンドウを最大化できます。

関連する API エレメント

このウィンドウの最大サイズです。

サイズ制限は、Point オブジェクトの座標として指定されます。ポイントの x プロパティはウィンドウの幅に相当し、y プロパティはウィンドウの高さに相当します。

maxSize の制限は、ActionScript コードとオペレーティングシステムの両方で呼び出されるウィンドウサイズの変更操作に対して強制的に設定されます。

現在の境界が新しい最大サイズよりも大きい場合、maxSize を設定すると、ウィンドウの境界が変化します。

指定された幅または高さが、許容される幅または高さの上限よりも大きい場合、許容される最も近い値にウィンドウの幅または高さが設定されます。幅と高さの下限および上限は、次の要因に基づいて決定されます。

• オペレーティング システムによる上限。これは、NativeWindow.systemMaxSize の値です。
• Adobe AIR におけるウィンドウ幅および高さの上限（各 4095 ピクセル）（AIR 1.5 以前では、ウィンドウの最大の幅と高さは各 2880 ピクセルです）。

注意：Mac OS X などの一部のオペレーティングシステムでは、ウィンドウを maxSize 値まで拡大しても、最大化したウィンドウはオペレーティングシステムの画面より小さくなります。このような場合でも、ウィンドウは最大化された表示状態となります。

関連する API エレメント

windowObj.maxSize = new Point(1040,920);

displayObject.stage.nativeWindow.maxSize = new Point(800,600);

window.nativeWindow.maxSize = new air.Point(960,960);

このウィンドウのネイティブメニューです。

NativeMenu オブジェクトがウィンドウの menu プロパティに割り当てられている場合、NativeWindow.supportsMenu が true に設定されていれば、ウィンドウにネイティブメニューが表示されます。ただし、ウィンドウの systemChrome プロパティが NativeWindowSystemChrome.NONE の場合は表示されません。

注意：NativeWindow.supportsMenu が false の場合、またはウィンドウの systemChrome プロパティが NativeWindowSystemChrome.NONE の場合も、メニューを割り当てることはできますが、効果はありません。使用しているオペレーティングシステムでウィンドウメニューがサポートされているか確認するには、必ず NativeWindow.supportsMenu プロパティを使用してください。その他の方法（Capabilities.os など）でサポートの有無を判断すると、プログラミングエラーの原因になる可能性があります（ターゲットとなり得るオペレーティングシステムの種類についての配慮が完全でない場合）。

関連する API エレメント

このウィンドウの作成に使用される最小化可能設定を報告します。

ウィンドウが作成された後で、minimizable 設定を変更することはできません。

注意：一部の Linux ウィンドウマネージャーでは、minimizable プロパティが false に設定されている場合でも、ユーザーがウィンドウを最小化できます。

関連する API エレメント

このウィンドウの最小サイズです。

サイズ制限は、Point オブジェクトの座標として指定されます。ポイントの x プロパティはウィンドウの幅に相当し、y プロパティはウィンドウの高さに相当します。

現在の境界が新しい最小サイズよりも小さい場合、minSize を設定すると、ウィンドウの境界が変化します。

minSize の制限は、ActionScript コードとオペレーティングシステムの両方で呼び出されるウィンドウサイズの変更操作に対して強制的に設定されます。

注意：表示されているシステムクロムの幅および高さによって、ウィンドウのサイズを指定された最小サイズにできない場合があります。

関連する API エレメント

windowObj.minSize = new Point(200,80);

displayObject.stage.nativeWindow.minSize = new Point(120,60);

window.nativeWindow.minSize = new air.Point(80,60);

このウィンドウを所有する NativeWindow オブジェクトです。

ウィンドウの所有関係は作成時に確立され、変更することはできません。所有者を持つウィンドウを作成するには、ウィンドウの作成時に使用した NativeWindowInitOptions オブジェクトの owner プロパティに所有者の NativeWindow オブジェクトを設定します。

注意：一部の Linux ウィンドウマネージャーでは、所有者ウィンドウがフルスクリーンモードの場合、所有されるウィンドウはその前面には表示されません。

関連する API エレメント

このウィンドウの作成に使用されるウィンドウの renderMode 設定を報告します。

NativeWindow.renderMode から返される値は、NativeWindowRenderMode クラスで定義されている定数のいずれかになります。

ウィンドウが作成された後で、renderMode 設定を変更することはできません。

関連する API エレメント

このウィンドウの作成に使用されるサイズ変更可能設定を報告します。

ウィンドウが作成された後で、resizable 設定を変更することはできません。

関連する API エレメント

このウィンドウの Stage オブジェクトです。Stage オブジェクトは、ActionScript 3.0 ベースの SWF コンテンツで使用されている表示リストアーキテクチャのルートオブジェクトです。

ステージは、ウィンドウの表示リストのルートです。ビジュアル表示オブジェクトをウィンドウに追加するには、そのオブジェクトをステージまたは既にこのステージの表示リストに存在する別のオブジェクトに追加します。ステージのサイズは、ウィンドウがシステムクロムを使用する場合のウィンドウクライアント領域のサイズです。システムクロムが使用されていない場合、ステージのサイズはウィンドウのサイズと等しくなります。

関連する API エレメント

import flash.display.StageAlign;

windowObj.stage.align = StageAlign.TOP_LEFT;

AIR が現在のコンピューターシステムのネイティブのウィンドウメニューをサポートするかどうかを示します。

NativeWindow.supportsMenu が true の場合、NativeMenu オブジェクトがウィンドウの menu プロパティに割り当てられると、そのウィンドウにネイティブメニューが表示されます。ただし、ウィンドウの systemChrome プロパティが NativeWindowSystemChrome.NONE の場合は表示されません。使用しているオペレーティングシステムでネイティブウィンドウメニューがサポートされているか確認するには、必ず NativeWindow.supportsMenu プロパティを使用してください。その他の方法（Capabilities.os など）でサポートの有無を判断すると、プログラミングエラーの原因になる可能性があります（ターゲットとなり得るオペレーティングシステムの種類についての配慮が完全でない場合）。

注意：NativeWindow.supportsMenu が false の場合、またはウィンドウの systemChrome プロパティが NativeWindowSystemChrome.NONE の場合にメニューを割り当てることも可能ですが、何も実行されません。

関連する API エレメント

AIR が現在のコンピューターシステムのウィンドウ通知キュー送信をサポートするかどうかを示します。

NativeWindow.supportsNotification が true の場合、ウィンドウの notifyUser() メソッドを呼び出すと、該当するイベントが発生したユーザーに対して視覚的なキューを表示します。この視覚的なキューは、ネイティブシステムのオペレーティングシステムの規則に従います。例えば、Windows^® では、タスクバーアイコンが点滅します。

注意：notifyUser() の呼び出しは、NativeWindow.supportsNotification が false の場合でも可能です。ただし、何も実行されません。

関連する API エレメント

AIR が透明なピクセルを含むネイティブのウィンドウをサポートするかどうかを示します。

NativeWindow.supportsTransparency が true である場合、ウィンドウの transparent プロパティが true に設定されていれば、ネイティブのウィンドウのピクセル透過性が適用されます。ウィンドウの transparent プロパティの値にかかわらず、NativeWindow.supportsTransparency が false であれば、すべてのピクセルの不透明度が 1 に設定されます。NativeWindow.supportsTransparency が false の場合、完全に透明なピクセルは黒としてレンダリングされます。使用しているオペレーティングシステムで透明度がサポートされているか確認するには、必ず NativeWindow.supportsTransparency プロパティを使用してください。その他の方法（Capabilities.os など）でサポートの有無を判断すると、プログラミングエラーの原因になる可能性があります（ターゲットとなり得るオペレーティングシステムの種類についての配慮が完全でない場合）。

注意：このプロパティの値は、オペレーティングシステムで設定されるユーザー環境設定に基づいて、アプリケーションの実行中に変化する可能性があります。

関連する API エレメント

このウィンドウの作成に使用されるシステムクロム設定を報告します。

NativeWindow.systemChrome から返される値は、NativeWindowSystemChrome クラスで定義されている定数のいずれかになります。

ウィンドウが作成された後で、システムクロムの設定を変更することはできません。

関連する API エレメント

var sysChromeType:String = windowObj.systemChrome;

var sysChromeType:String = displayObject.stage.nativeWindow.systemChrome;

var sysChromeType = window.nativeWindow.systemChrome;

import flash.display.NativeWindow;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowInitOptions;

public function deChromeWindow(oldWindow:NativeWindow):NativeWindow{
    if(oldWindow.systemChrome != NativeWindowSystemChrome.NONE){
        var newOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
        newOptions.systemChrome = NativeWindowSystemChrome.NONE;
        newOptions.transparent = true;
        
        var newWindow:NativeWindow = new NativeWindow(newOptions);
        newWindow.stage.stageWidth = oldWindow.stage.stageWidth;
        newWindow.stage.stageHeight = oldWindow.stage.stageHeight;
        newWindow.stage.align = oldWindow.stage.align;
        newWindow.stage.scaleMode = oldWindow.stage.scaleMode;
        
        for(var i:int = 0; i < oldWindow.stage.numChildren; i++){
            newWindow.stage.addChild(oldWindow.stage.getChildAt(i));
        }
        newWindow.activate();
        oldWindow.close();
        
        return newWindow;
    }
    return oldWindow;
}

オペレーティングシステムで許可されている最大のウィンドウサイズです。

サイズ制限は、Point オブジェクトの座標として指定されます。ポイントの x プロパティはウィンドウの幅に相当し、y プロパティはウィンドウの高さに相当します。

オペレーティングシステムのサイズ制限のほかに、AIR には 4095 x 4095 ピクセルの最大ウィンドウサイズ制限（AIR 1.5 以前では、2880 x 2880 ピクセル）があります。また、アプリケーションが NativeWindow オブジェクトの maxSize プロパティを使用して制限を設定することもできます。

オペレーティングシステムで許可されている最小のウィンドウサイズです。

サイズ制限は、Point オブジェクトの座標として指定されます。ポイントの x プロパティはウィンドウの幅に相当し、y プロパティはウィンドウの高さに相当します。

ウィンドウのタイトルです。

タイトルを表示する場合は、ウィンドウのシステムクロムに加え、その他のシステムに依存した場所（タスクバーなど）に表示されます。

windowObj.title = "Window Title";

このウィンドウの作成に使用される透明度設定を報告します。

ウィンドウが作成された後で、transparent プロパティを変更することはできません。透明度は、ウィンドウの視覚的な外観とマウス動作に影響します。Windows および Mac OS X の場合、ピクセルのアルファ値が特定のしきい値を下回っている場合、ウィンドウでマウスイベントはキャプチャされません。この値は、オペレーティングシステムによってはおよそ .06 ～ .01 の間で変わります。Linux の場合、このウィンドウでは完全に透明な領域の上のマウスイベントがキャプチャされます。したがって、ユーザーはデスクトップ上のその他のウィンドウおよびアイテムにアクセスすることができません。

注意：ウィンドウの透明度は必ずしもサポートされているとは限りません。ユーザーのオペレーティングシステムの設定で透明度が使用できない場合、ウィンドウは透明度なしで作成されます。透明にしている領域は、黒と合成されます。NativeWindow.supportsTransparency プロパティを使用して、ウィンドウの透明度をサポートするかどうかを指定します。

関連する API エレメント

このウィンドウの作成に使用されるウィンドウの type の設定を報告します。

NativeWindow.type から返される値は、NativeWindowType クラスで定義されている定数のいずれかになります。

ウィンドウが作成された後で、type 設定を変更することはできません。

関連する API エレメント

このウィンドウが可視かどうかを指定します。

不可視のウィンドウはデスクトップに表示されませんが、ウィンドウのプロパティとメソッドはすべて有効です。

デフォルトでは、visible は false に設定されています。ウィンドウを表示するには、visible を true に設定するか、NativeWindow.activate() を呼び出します。

このウィンドウに所有者がある場合、このウィンドウが表示されるかどうかは、所有側ウィンドウの可視状態によって決まります。所有側ウィンドウが非表示であれば、所有されている各ウィンドウの visible プロパティが true かどうかに関係なく、それらのウィンドウはすべて非表示になります。

注意：Mac OS X では、最小化されたウィンドウで visible=false に設定しても、ウィンドウアイコンはドックから削除されません。その後、ユーザーがドックアイコンをクリックするとウィンドウは可視状態に戻り、デスクトップに表示されます。

関連する API エレメント

windowObj.visible = true;

displayObj.stage.nativeWindow.visible = true;

window.nativeWindow.visible = true;

このウィンドウの幅（ピクセル単位）です。

ネイティブウィンドウの通知されるサイズには、表示されているシステムウィンドウのクロムが含まれます。ウィンドウ内側の使用可能な表示領域の幅は、Stage.stageWidth プロパティから取得できます。

ウィンドウの width プロパティを変更すると、bounds プロパティから幅を変更した場合と同じ動作をします。

指定された幅が、許容される幅の下限よりも小さい場合や上限よりも大きい場合、許容される最も近い値にウィンドウの幅が設定されます。幅の下限および上限は、次の要因に基づいて決定されます。

• NativeWindow オブジェクトの minSize.y および maxSize.y プロパティ
• オペレーティングシステムの制限による上限と下限。これは、NativeWindow.systemMinSize.y と NativeWindow.systemMaxSize.y の値です。
• Adobe AIR での最大ウィンドウ幅は 4095 ピクセルです（AIR 1.5 以前では 2880 ピクセルです）。

Linux の場合、width プロパティを設定する操作は非同期的に実行されます。

幅変更の完了を検出するには、resize イベントを監視します。これは、どのプラットフォームでも送出されるイベントです。

ウィンドウの幅が変更されると、ピクセル値は最も近い整数に四捨五入されます。

関連する API エレメント

オペレーティングシステムのデスクトップの起点を基準とした、このウィンドウの左上隅の水平軸座標です。

複数のモニターがあるシステムでは、x が負の値になることがあります。ウィンドウを以前の場所に再位置付けするために値を保存した場合、位置を復元したときにウィンドウが使用可能な場所に配置されていることを常に検証する必要があります。画面の解像度やモニターの配置を変更すると、ウィンドウが画面外に配置されることがあります。Screen クラスを使用して、デスクトップジオメトリに関する情報を取得してください。

ウィンドウの x プロパティを変更すると、bounds プロパティから位置を変更した場合と同じ動作をします。

Linux の場合、x プロパティを設定する操作は非同期的に実行されます。

位置変更の完了を検出するには、move イベントを監視します。これは、どのプラットフォームでも送出されるイベントです。

ウィンドウ の x 座標が変更されると、ピクセル値は最も近い整数に四捨五入されます。

関連する API エレメント

オペレーティングシステムのデスクトップの左上隅を基準とした、このウィンドウの左上隅の垂直軸座標です。

複数のモニターがあるシステムでは、y が負の値になることがあります。ウィンドウを以前の場所に再位置付けするために値を保存した場合、位置を復元したときにウィンドウが使用可能な場所に配置されていることを常に検証する必要があります。画面の解像度やモニターの配置を変更すると、ウィンドウが画面外に配置されることがあります。Screen クラスを使用して、デスクトップジオメトリに関する情報を取得してください。

ウィンドウの y プロパティを変更すると、bounds プロパティから位置を変更した場合と同じ動作をします。

Linux の場合、y プロパティを設定する操作は非同期的に実行されます。

位置変更の完了を検出するには、move イベントを監視します。これは、どのプラットフォームでも送出されるイベントです。

ウィンドウ の y 座標が変更されると、ピクセル値は最も近い整数に四捨五入されます。

関連する API エレメント

NativeWindow インスタンスと、対応するオペレーティングシステムウィンドウを新たに作成します。

ウィンドウの作成後は、initOptions パラメーターで定義されている設定を変更することはできません。initOptions 設定が無効な場合、無効な操作を示すエラーがスローされます。現在のシステムで使用できなくても、設定が有効な場合は、例外はスローされません。現在のオペレーティングシステムに固有の機能は、必要に応じて、静的な NativeWindow メンバー（systemMaxSize など）を使用することで検出できます。

デフォルトのウィンドウサイズはオペレーティングシステムによって決まり、ウィンドウは不可視状態で作成されます。ウィンドウを可視状態のまま変更しないようにするために、ウィンドウの変更が終わるまで、ウィンドウの visible プロパティを true にしたり、activate() を呼び出したりしないでください。

関連する API エレメント

import flash.display.NativeWindowInitOptions;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowType;
import flash.display.NativeWindow;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.geom.Rectangle;

var windowOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
windowOptions.systemChrome = NativeWindowSystemChrome.STANDARD;
windowOptions.type = NativeWindowType.NORMAL;

var newWindow:NativeWindow = new NativeWindow(windowOptions);
newWindow.stage.scaleMode = StageScaleMode.NO_SCALE;
newWindow.stage.align = StageAlign.TOP_LEFT;
newWindow.bounds = new Rectangle(100, 100, 800, 800);

newWindow.activate();

このウィンドウをアクティブ化します。

ウィンドウをアクティブ化すると、次のようになります。

• ウィンドウが可視になります。
• ウィンドウが前面に移動します。
• キーボードおよびマウスのフォーカスが、そのウィンドウに移動します。

Linux の場合、activate() は非同期的に実行される操作です。

NativeWindow オブジェクトは、どのプラットフォームでも activate イベントを送出します。

関連する API エレメント

displayObject.stage.nativeWindow.activate();

windowObj.activate();

window.nativeWindow.activate();

このウィンドウを閉じます。

閉じる操作が完了すると、close イベントが直ちに送出されます。closing イベントは送出されません。閉じる操作のキャンセルを許可する場合は、closing イベントを送出し、登録されているリスナーがデフォルトの動作をキャンセルするかどうかを、close() メソッドを呼び出す前にチェックします。

ウィンドウを閉じると、そのウィンドウが所有しているウィンドウもすべて閉じられます。所有されているウィンドウが closing イベントを送出することはありません。

現在ウィンドウにある表示オブジェクトのインスタンスが他の場所で参照されていない場合は、AIR によって作成された最初のアプリケーションウィンドウを除き、ガベージコレクションされて破棄されます。最初のウィンドウにある表示オブジェクトがガベージコレクションされるようにするには、ウィンドウステージからそれらを削除します。

閉じられた後でも NativeWindow オブジェクトは有効な参照として残りますが、プロパティやメソッドにアクセスすると、多くの場合は無効な操作を示すエラーがスローされます。

閉じたウィンドウを再び開くことはできません。ウィンドウが既に閉じられている場合、アクションは実行されず、イベントも送出されません。

注意：ウィンドウを閉じずに非表示にするには、ウィンドウの visible プロパティを false に設定します。

関連する API エレメント

windowObj.close();

displayObj.stage.nativeWindow.close();

window.close(); //overriddable in HTMLHost

window.nativeWindow.close(); //not overriddable

public function closeCommand():Boolean{
    var closeEvent:Event = new Event(Event.CLOSING,true,true);
    windowObj.dispatchEvent(closeEvent);
    if(!closeEvent.isDefaultPrevented()){
        windowObj.close();
        return true;
    } else {
      return false;
    }
}

<script src="AIRAliases.js" type="text/javascript"></script>
<script type="text/javascript">
    var dirtyData = false;
    function closeWindow(){
            var closingEvent = new air.Event(air.Event.CLOSING,true,true);
            window.nativeWindow.dispatchEvent(closingEvent);
               if(!closingEvent.isDefaultPrevented()){
                   window.nativeWindow.close();
                //or use: window.close(); 
               return true;
           } else {
               return false;
        }
    }
        
    function onClosing(event){
        if(dirtyData){
            event.preventDefault();
            //Save data...
        }
    }    

    window.nativeWindow.addEventListener(air.Event.CLOSING,onClosing);        
</script>

ウィンドウステージの起点を基準としたピクセル単位の座標のポイント（表示リストから見たグローバルポイント）を、仮想デスクトップのポイントに変換します。

仮想デスクトップの座標は、主モニターの左上隅を基準としています。

パラメーター

関連する API エレメント

このウィンドウが所有する NativeWindow オブジェクトのリストを返します。

返されたベクトルにオブジェクトを追加したり、オブジェクトを削除することで NativeWindow オブジェクトの所有関係を変更することはできません。ウィンドウの作成後に、その所有関係を変更することはできません。

関連する API エレメント

このウィンドウを最大化します。

maximize() を呼び出すと、displayStateChange イベントが送出されます。また、該当する場合は、move イベントおよび resize イベントも送出されます。ユーザーが maximize コマンドを発行すると、システムクロムがキャンセル可能な displayStateChanging イベントを送出しますが、必要に応じて、この動作を最大化ロジックに実装する必要があります。

maximize() メソッドは非同期に実行されます。状態変更の完了を検出するには、displayStateChange イベントを監視します。ウィンドウが既に最大化されている場合、アクションは実行されず、イベントも送出されません。

OS の動作に関する注意：

• Mac OS X などのオペレーティングシステムでは、ウィンドウを最大化してもサイズ変更は禁止されません。そのため、maximize() を呼び出すとウィンドウが画面いっぱいに拡大されますが、その後でウィンドウのサイズを変更することができます。拡大されたウィンドウのサイズを変更すると、表示状態も元に戻ります。
• Mac OS X などの一部のオペレーティングシステムおよび Linux の一部のウィンドウマネージャーでは、ウィンドウを最大化しても、maxSize プロパティで指定されている幅と高さより大きくは拡大しません。それ以外では、画面が maxSize よりも大きい場合でもウィンドウは画面いっぱいに拡大されます。
• Linux の一部のウィンドウマネージャーでは、ユーティリティウィンドウを最大化できません。

関連する API エレメント

public function maximizeWindow(nativeWin:NativeWindow):Boolean{
  if(nativeWin.displayState != NativeWindowDisplayState.MAXIMIZED){
    var beforeState:String = nativeWin.displayState;
    var afterState:String = NativeWindowDisplayState.MAXIMIZED;
    var displayStateEvent:NativeWindowDisplayStateEvent = 
        new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
    nativeWin.dispatchEvent(displayStateEvent);
    if(!displayStateEvent.isDefaultPrevented()){
        nativeWin.maximize();
        return true;
    } else {
      return false;
    }
  }
  return false;
}

function maximizeWindow(nativeWin){
    if(nativeWin.displayState != air.NativeWindowDisplayState.MAXIMIZED){
        var beforeState = nativeWin.displayState;
        var afterState = air.NativeWindowDisplayState.MAXIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.maximize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

このウィンドウを最小化します。

minimize() を呼び出すと、displayStateChange イベントが送出されます。また、該当する場合は、move イベントおよび resize イベントも送出されます。ユーザーが minimize コマンドを発行すると、システムクロムがキャンセル可能な displayStateChanging イベントを送出するのに対し、minimize() を直接呼び出してもこのイベントは発行されません。必要に応じて、この動作を最小化ロジックに実装できます。

minimize() メソッドは非同期に実行されます。状態変更の完了を検出するには、displayStateChange イベントを監視します。これは、どのプラットフォームでも送出されるイベントです。ウィンドウが既に最小化されている場合、アクションは実行されず、イベントも送出されません。

このウィンドウが最小化されると、所有されているすべてのウィンドウは非表示になります。所有されているウィンドウが displayStateChanging または displayStateChange イベントを送出することはありません。

注意：

• Windows では、不可視のウィンドウを最小化すると（visible == false）、ウィンドウを表示できます。
• 一部の Linux ウィンドウマネージャーでは、ユーティリティウィンドウを最小化できません。

関連する API エレメント

public function minimizeWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.MINIMIZED){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

 
function minimizeWindow(){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.MINIMIZED){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

該当するイベントが発生したオペレーティングシステムを通して、視覚的なキューをトリガーします。

NativeWindow.supportsNotification が true の場合、視覚的なキューは、ネイティブシステムのオペレーティングシステムの規則に従います。例えば、Windows では、タスクバーアイコンが点滅します。

キューの強度は、type パラメーターによって決定されます。有効な値の定数は NotificationType クラスで定義されていて、次のようになる場合があります。

• NotificationType.INFORMATIONAL
• NotificationType.CRITICAL

情報の通知を目的としたキューは、継続時間が短く設定されています。重要な通知のキューは、ユーザーがこのウィンドウをアクティブ化するまで継続します。一部の Linux ウィンドウマネージャーは、2 レベルの通知をサポートしていません。このようなウィンドウマネージャーでは、どのオプションを指定しても、notifyUser() は同じ動作をします。

注意：notifyUser() の呼び出しは、NativeWindow.supportsNotification が false の場合でも可能です。ただし、何も実行されません。

パラメーター

このウィンドウを、指定されたウィンドウの背面に直接移動します。

ウィンドウまたはアプリケーションをアクティブ化したり、フォーカスを取得したりしません。最小化または非表示（visible が false）にされているウィンドウの順序は変更できません。

所有されているウィンドウを所有する側のウィンドウの背後に移動することはできません。このウィンドウに所有者がある場合、所有する側のウィンドウおよびそのウィンドウが所有するほかのウィンドウもターゲットの背後に順に配置されます。ターゲットウィンドウに所有者がある場合、このウィンドウはターゲットではなくその所有者の背後に配置されます。

一部の Linux ウィンドウマネージャーでは、ユーティリティウィンドウを標準ウィンドウよりも後に順序付けすることはできません。

パラメーター

windowBehind.orderInBackOf(windowFront);

displayObjBehind.stage.nativeWindow.orderInBackOf(displayObjectFront.stage.nativeWindow);

jsWindowObjBehind.nativeWindow.orderInBackOf(jsWindowObjFront.nativeWindow);

このウィンドウを、指定されたウィンドウの前面に直接移動します。

ウィンドウまたはアプリケーションをアクティブ化したり、フォーカスを取得したりしません。最小化または非表示（visible が false）にされているウィンドウの順序は変更できません。

ウィンドウを所有するウィンドウの前面に移動することはできません。このウィンドウに所有者がある場合、所有する側のウィンドウおよびそのウィンドウが所有するほかのウィンドウもターゲットの前面に順に配置されます。ターゲットウィンドウに所有者がある場合、このウィンドウはターゲットと同じ所有者に所有されるほかのすべてのウィンドウの前面に配置されます。

一部の Linux ウィンドウマネージャーでは、標準ウィンドウをユーティリティウィンドウよりも前に順序付けすることはできません。

パラメーター

windowFront.orderInFrontOf(windowBehind);

displayObjFront.stage.nativeWindow.orderInFrontOf(displayObjectBehind.stage.nativeWindow);

jsWindowObjFront.nativeWindow.orderInFrontOf(jsWindowObjBehind.nativeWindow);

このウィンドウを他のすべての可視ウィンドウの背面に移動します。

このウィンドウまたはアプリケーションをアクティブ化したり、フォーカスを取得したりしません。最小化または非表示（visible が false）にされているウィンドウの順序は変更できません。

alwaysInFront が true の場合、このメソッドを呼び出しても、alwaysInFront が false に設定されているウィンドウの背面には移動しません。

所有されているウィンドウを所有する側のウィンドウの背後に移動することはできません。このウィンドウに所有者がある場合、所有する側のウィンドウおよびそのウィンドウが所有するほかのウィンドウもウィンドウ表示リストの末尾に順に配置されます。このウィンドウは同じウィンドウに所有されるほかのすべてのウィンドウの背後に移動します。このウィンドウがほかのウィンドウを所有している場合、それらのウィンドウも背後に移動され、現在のウィンドウ相互の位置関係が保持されます。

一部の Linux ウィンドウマネージャーでは、ユーティリティウィンドウを標準ウィンドウよりも後に順序付けすることはできません。

windowObj.orderToBack();

displayObj.stage.nativeWindow.orderToBack();

window.nativeWindow.orderToBack();

このウィンドウを他の可視ウィンドウの前面に移動します。

このウィンドウまたはアプリケーションをアクティブ化したり、フォーカスを取得したりしません。最小化または非表示（visible が false）にされているウィンドウの順序は変更できません。

alwaysInFront が false の場合、このメソッドを呼び出しても、alwaysInFront が true に設定されているウィンドウの前面には移動しません。

ウィンドウを所有するウィンドウの前面に移動することはできません。このウィンドウがほかのウィンドウを所有している場合、それらのウィンドウも前面に移動され、現在のウィンドウ相互の位置関係が保持されます。このウィンドウに所有者がある場合、所有する側のウィンドウおよびそのウィンドウが所有するほかのウィンドウもウィンドウ表示リストの先頭に順に配置されます。このウィンドウは同じ所有者に所有される他のウィンドウの前面に移動します。

一部の Linux ウィンドウマネージャーでは、標準ウィンドウをユーティリティウィンドウよりも前に順序付けすることはできません。

windowObj.orderToFront();

displayObj.stage.nativeWindow.orderToFront();

window.nativeWindow.orderToFront();

最小化または最大化された状態から、このウィンドウを元の状態に戻します。

restore() を呼び出すと、displayStateChange イベントが送出されます。また、該当する場合は、move イベントおよび resize イベントも送出されます。ユーザーが restore コマンドを発行すると、システムクロムがキャンセル可能な displayStateChanging イベントを送出しますが、必要に応じて、この動作を元に戻すロジックに実装する必要があります。

ウィンドウが既に NativeWindowDisplayState.NORMAL の状態の場合、アクションは実行されず、イベントも送出されません。

状態変更の完了を検出するには、displayStateChange イベントを監視します。これは、どのプラットフォームでも送出されるイベントです。

関連する API エレメント

public function restoreWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.NORMAL){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.NORMAL;
        var displayStateChangingEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateChangingEvent);
        if(!displayStateChangingEvent.isDefaultPrevented()){
            nativeWin.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

function restoreWindow(nativeWin){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.NORMAL){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.NORMAL;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

このウィンドウのシステム制御による移動を開始します。

mouseDown イベントから呼び出された場合、このメソッドはマウス操作による移動シーケンスを開始し、mouseUp イベントが発生するまで続行します。

その他のコードから呼び出された場合、このメソッドは、オペレーティングシステムのデフォルトのシーケンスに従い、キーボードまたはマウス操作による移動シーケンスを開始します。

移動シーケンスの間、ウィンドウの起点が移動すると、一連のイベントが送出されます。各増分移動について、最初に moving イベントが送出され、moving イベントがキャンセルされなかった場合は、ウィンドウの位置が更新されて move イベントが送出されます。moving イベントがキャンセルされた場合、移動シーケンスは直ちに終了します。

var initOpts:NativeWindowInitOptions = new NativeWindowInitOptions();
var win:NativeWindow = new NativeWindow(initOpts);
win.activate();
win.stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);

function mouseDownHandler(event:MouseEvent):void
{
    win.startMove();
}

このウィンドウのシステム制御によるサイズ変更操作を開始します。

mouseDown イベントハンドラーから呼び出された場合、このメソッドはマウス操作によるサイズ変更シーケンスを開始し、mouseUp イベントが発生するまで続行します。

その他のコードから呼び出された場合、このメソッドは、オペレーティングシステムのデフォルトのシーケンスに従い、キーボードまたはマウス操作によるサイズ変更シーケンスを開始します。

サイズ変更シーケンスの間、ウィンドウのサイズが変化すると、一連のイベントが送出されます。各増分変化について、最初に resizing イベントが送出され、resizing イベントがキャンセルされなかった場合は、ウィンドウのサイズが更新されて resize イベントが送出されます。resizing イベントがキャンセルされた場合、サイズ変更シーケンスは直ちに終了します。

パラメーター

関連する API エレメント

stage.addEventListener(MouseEvent.MOUSE_DOWN, onResizeCommand);

function onResizeCommand(event:MouseEvent):void
{
    var win:NativeWindow = event.target.nativeWindow;
    var resizeFrom:String = "";
    if (event.stageY < win.height * .33)
    {
        resizeFrom = NativeWindowResize.TOP;
    }
    else if (event.stageY > win.height * .66)
    {
        resizeFrom = NativeWindowResize.BOTTOM;
    }
    if (event.stageX < win.width * .33)
    {
        resizeFrom += NativeWindowResize.LEFT;
    }
    else if (event.stageX > win.width * .66)
    {
        resizeFrom += NativeWindowResize.RIGHT;
    }
    win.startResize(resizeFrom);    
}

ウィンドウがアクティブになると、この NativeWindow オブジェクトから送出されます。

注意：このイベントには「キャプチャ段階」と「バブリング段階」はありません。したがって、ターゲットが表示リストにあるかないかに関わらず、潜在的なターゲットにはイベントリスナーを直接追加する必要があります。

AIR for TV デバイスでは、このイベントが自動的に送出されることはありません。手動での送出は可能です。

このイベントには、次のプロパティがあります。

ウィンドウが閉じられると、この NativeWindow オブジェクトから送出されます。

このイベントには、次のプロパティがあります。

ウィンドウが閉じられる直前に、この NativeWindow オブジェクトから送出されます。このイベントは、ウィンドウが閉じられないようにキャンセルできます。

このイベントには、次のプロパティがあります。

ウィンドウが非アクティブになると、この NativeWindow オブジェクトから送出されます。

注意：このイベントには「キャプチャ段階」と「バブリング段階」はありません。したがって、ターゲットが表示リストにあるかないかに関わらず、潜在的なターゲットにはイベントリスナーを直接追加する必要があります。

AIR for TV デバイスでは、このイベントが自動的に送出されることはありません。手動での送出は可能です。

このイベントには、次のプロパティがあります。

ウィンドウの displayState プロパティが変化すると、この NativeWindow オブジェクトによって送出されます。

ウィンドウのサイズを変えたり、displayStateChange イベントハンドラーでのウィンドウの表示状態を変更しないでください。

このイベントには、次のプロパティがあります。

ウィンドウがその表示状態を変更する直前に、この NativeWindow オブジェクトから送出されます。このイベントは、変更されないようにキャンセルすることができます。

このイベントには、次のプロパティがあります。

function displayStateChanging_handler(displayStateEvent:NativeWindowDisplayStateEvent):void
{
  //shouldStopStateChange is an application-defined Boolean indicating 
  //that display state changes should be canceled
  if (displayStateEvent.type == NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING 
                                  &&    shouldStopStateChange)
  {
    displayStateEvent.preventDefault();
  }
}

デスクトップ上でウィンドウが移動されると、この NativeWindow オブジェクトから送出されます。

ウィンドウの原点が変更されると、常に move イベントが送出されます。ウィンドウの原点（x プロパティまたは y プロパティ）の移動は、システムによって制御されたウィンドウの移動の場合、最小化、最大化またはウィンドウのサイズを元に戻した場合、または x、y または bounds の各プロパティを設定して移動した場合に行われます。

注意： NativeWindow オブジェクトの moving イベントと move イベントの両方に対するハンドラー関数でオペレーティングシステムのダイアログボックスを同時に開くようなアクションは避けてください。これは、例えば、両方のハンドラー関数がエラーをスローする場合などに発生します。そのようなアクションが発生した場合、2 番目に開かれるダイアログボックスにはマウスのクリックが登録されないので、キーボードを使って閉じることが必要になります。

このイベントには、次のプロパティがあります。

デスクトップ上でウィンドウが移動される直前に、NativeWindow オブジェクトから送出されます。このイベントは、移動を中止または変更するためにキャンセルできます。

注意： NativeWindow オブジェクトの moving イベントと move イベントの両方に対するハンドラー関数でオペレーティングシステムのダイアログボックスを同時に開くようなアクションは避けてください。これは、例えば、両方のハンドラー関数がエラーをスローする場合などに発生します。そのようなアクションが発生した場合、2 番目に開かれるダイアログボックスにはマウスのクリックが登録されないので、キーボードを使って閉じることが必要になります。

このイベントには、次のプロパティがあります。

注意：Linux では、このイベントでは preventDefault() メソッドはサポートされません。

ウィンドウのサイズが変更されると、この NativeWindow オブジェクトから送出されます。ウィンドウのサイズが変更されると、常に resize イベントが送出されます。ウィンドウのサイズ（width プロパティまたは height プロパティ）変更は、システムによって制御されたウィンドウサイズの変更の場合、最小化、最大化またはウィンドウのサイズを元に戻した場合、width、height または bounds の各プロパティを設定して変更した場合に行われます。NativeWindow の resize イベントは、システム制御のサイズ変更ループの場合に送出されます。一方、Stage オブジェクトの resize イベントは、ステージの描画の準備が整っている場合に送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

デスクトップ上でウィンドウのサイズが変更される直前に、この NativeWindow オブジェクトから送出されます。このイベントは、サイズ変更を中止または変更するためにキャンセルすることができます。

このイベントには、次のプロパティがあります。

注意：Linux では、このイベントでは preventDefault() メソッドはサポートされません。

function boundsChanging_handler(boundsEvent:NativeWindowBoundsEvent):void
{
  //shouldStopResize is an application-defined Boolean indicating 
  //that resize operations should be canceled
  if (boundsEvent.type == NativeWindowBoundsEvent.RESIZING && shouldStopResize)
  {
    boundsEvent.preventDefault();
  }
}