UILoader

套件	fl.containers
類別	public class UILoader
繼承	UILoader UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

UILoader 類別可讓您設定要載入的內容，然後在執行階段監視載入作業。此類別也會處理載入內容的大小調整作業。若從不同的網域 (安全執行程序) 載入內容，安全性意義可能代表內容屬性無法存取。如需詳細資訊，請參閱 ProLoader 類別。

使用 ActionScript 設定 UILoader 類別的屬性，將會覆寫在「屬性」檢測器或「組件檢測器」中設定的同名稱參數。

此組件會包裝 fl.display.ProLoader。ProLoader 類別會處理所有實際的載入作業，而 UILoader 只會為 ProLoader 物件提供視覺化顯示。

注意：如果是從不同的網域或系統安全執行程序載入內容，則基於安全考量，可能無法讓您存取此內容的屬性。如需有關網域安全性如何影響載入程序的詳細資訊，請參閱 ProLoader 類別。

相關 API 元素

公用屬性

	屬性		定義自
		accessibilityImplementation : AccessibilityImplementation 對此 InteractiveObject 實體目前的輔助功能實作 (AccessibilityImplementation)。	InteractiveObject
		accessibilityProperties : AccessibilityProperties 此顯示物件的目前輔助功能選項。	DisplayObject
		alpha : Number 指出所指定物件的 Alpha 透明度值。	DisplayObject
		autoLoad : Boolean 會取得或設定值，指出 UILoader 實體是否會自動載入指定的內容。	UILoader
		blendMode : String 來自 BlendMode 類別的值，會指定要使用何種混合模式。	DisplayObject
		blendShader : Shader [唯寫] 設定用來混合前景和背景的著色器。	DisplayObject
		buttonMode : Boolean 可指定此 sprite 的按鈕模式。	Sprite
		bytesLoaded : uint [唯讀] 會取得已載入之內容的位元組數。	UILoader
		bytesTotal : uint [唯讀] 會取得要載入的內容位元組總數。	UILoader
		cacheAsBitmap : Boolean 如果設定為 true，Flash 執行階段會快取顯示物件的內部點陣圖表示法。	DisplayObject
		cacheAsBitmapMatrix : Matrix 如果為非 null，當 cacheAsBitmap 設定為 true 時，這個 Matrix 物件會定義顯示物件的顯示方法。	DisplayObject
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		content : DisplayObject [唯讀] 會包含使用 load() 方法或設定 source 屬性所載入之 SWF 檔或影像檔 (JPEG、PNG 或 GIF 格式的檔案) 的根顯示物件。	UILoader
		contextMenu : NativeMenu 指定與此物件有關聯的快顯選單。	InteractiveObject
		doubleClickEnabled : Boolean 會指定物件是否會收到 doubleClick 事件。	InteractiveObject
		dropTarget : DisplayObject [唯讀] 指定要將 sprite 拖曳至或丟棄至哪個顯示物件上。	Sprite
		enabled : Boolean 會取得或設定值，指出組件是否可以接受使用者互動。	UIComponent
		filters : Array 索引的陣列，其中包含目前和顯示物件相關的每個濾鏡物件。	DisplayObject
		focusEnabled : Boolean 會取得或設定 Boolean 值，指出組件是否可以在使用者按一下之後成為焦點。	UIComponent
		focusManager : IFocusManager 會取得或設定控制此組件及其同輩之焦點的 FocusManager。	UIComponent
		focusRect : Object 會指定這個物件是否會顯示焦點矩形。	InteractiveObject
		graphics : Graphics [唯讀] 指定屬於此 sprite 物件的 Graphics 物件，其中可能會產生向量繪圖命令。	Sprite
		height : Number [覆寫] 會取得或設定組件的高度，以像素為單位。	UIComponent
		hitArea : Sprite 指定用來當作 sprite 作用區域的另一個 sprite。	Sprite
		loaderInfo : LoaderInfo [唯讀] 會傳回 LoaderInfo 物件，其中包含關於載入此顯示物件所屬之檔案的資訊。	DisplayObject
		maintainAspectRatio : Boolean 會取得或設定值，指出要維持原始影像使用的比例，還是將影像大小調整成 UILoader 組件的目前寬度和高度。	UILoader
		mask : DisplayObject 呼叫之顯示物件會以指定的 mask 物件遮蓋。	DisplayObject
		metaData : Object 如果中繼資料是透過 PlaceObject4 標籤與 SWF 檔案中的這個 DisplayObject 實體一同儲存，則會取得 DisplayObject 實體的中繼資料物件。	DisplayObject
		mouseChildren : Boolean 判斷物件的子系是否支援啟用滑鼠或使用者輸入裝置。	DisplayObjectContainer
		mouseEnabled : Boolean 指定此物件是否接收滑鼠或其他使用者輸入及訊息。	InteractiveObject
		mouseFocusEnabled : Boolean 會取得或設定值，指出組件是否可以在使用者按一下之後成為焦點。	UIComponent
		mouseX : Number [唯讀] 指出滑鼠或使用者輸入裝置位置的 x 座標，以像素為單位。	DisplayObject
		mouseY : Number [唯讀] 指出滑鼠或使用者輸入裝置位置的 y 座標，以像素為單位。	DisplayObject
		name : String 指出 DisplayObject 的實體名稱。	DisplayObject
		needsSoftKeyboard : Boolean 指定虛擬鍵盤 (螢幕上的軟體鍵盤) 是否應在此 InteractiveObject 實體接收到焦點時顯示。	InteractiveObject
		numChildren : int [唯讀] 傳回此物件的子系數量。	DisplayObjectContainer
		opaqueBackground : Object 會指定顯示物件是否不透明，並具有特定背景顏色。	DisplayObject
		parent : DisplayObjectContainer [唯讀] 指出包含此顯示物件的 DisplayObjectContainer 物件。	DisplayObject
		percentLoaded : Number [唯讀] 會取得介於 0 和 100 之間的數字，表示已載入內容的百分比。	UILoader
		root : DisplayObject [唯讀] 對載入之 SWF 檔案的顯示物件而言，root 屬性就是該 SWF 檔案所呈現之顯示清單樹狀結構部分的最上層顯示物件。	DisplayObject
		rotation : Number 指出 DisplayObject 實體的旋轉度數 (從該物件原本方向算起)。	DisplayObject
		rotationX : Number 表示 DisplayObject 實體相對於 3D 父輩容器從原始方向旋轉的 x 軸旋轉 (以度數為單位)。	DisplayObject
		rotationY : Number 表示 DisplayObject 實體相對於 3D 父輩容器從原始方向旋轉的 y 軸旋轉 (以度數為單位)。	DisplayObject
		rotationZ : Number 表示 DisplayObject 實體相對於 3D 父輩容器從原始方向旋轉的 z 軸旋轉 (以度數為單位)。	DisplayObject
		scale9Grid : Rectangle 目前產生效用的縮放格線。	DisplayObject
		scaleContent : Boolean 會取得或設定值，指出是否要自動將影像縮放為 UILoader 實體的大小。	UILoader
		scaleX : Number [覆寫] 會將目前組件的寬度乘以縮放比例係數。	UIComponent
		scaleY : Number [覆寫] 會將目前組件的高度乘以縮放比例係數。	UIComponent
		scaleZ : Number 指出從物件註冊點套用的物件深度縮放 (百分比)。	DisplayObject
		scrollRect : Rectangle 顯示物件的捲動矩形範圍。	DisplayObject
		softKeyboard : String 控制軟體鍵盤的外觀。	InteractiveObject
		softKeyboardInputAreaOfInterest : Rectangle 定義顯示軟體鍵盤時，應保留於螢幕上的區域 (iOS 未提供)。	InteractiveObject
		soundTransform : flash.media:SoundTransform 控制此 Sprite 的聲音。	Sprite
		source : Object 會取得或設定絕對或相對 URL，它會識別要載入之 SWF 或影像檔的位置、元件庫中影片片段的類別名稱、顯示物件的參考，或是識別與組件位於相同層級的影片片段實體名稱。	UILoader
		stage : Stage [唯讀] 顯示物件的「舞台」。	DisplayObject
		tabChildren : Boolean 判斷物件的子系是否支援啟用定位鍵。	DisplayObjectContainer
		tabEnabled : Boolean 會指定這個物件是否在停駐點順序中。	InteractiveObject
		tabIndex : int 會指定 SWF 檔中的物件停駐點順序。	InteractiveObject
		textSnapshot : flash.text:TextSnapshot [唯讀] 傳回此 DisplayObjectContainer 實體的 TextSnapshot 物件。	DisplayObjectContainer
		transform : flash.geom:Transform 這是一個物件，具有和顯示物件的矩陣、顏色轉換和像素邊界有關的屬性。	DisplayObject
		useHandCursor : Boolean 指示當指標滑入 Sprite，且其 buttonMode 屬性設為 true 時，是否要出現指示手掌 (手掌游標) 的 Boolean 值。	Sprite
		visible : Boolean [覆寫] 會取得或設定值，指出目前組件實體是否為可見。	UIComponent
		width : Number [覆寫] 會取得或設定組件的寬度，以像素為單位。	UIComponent
		x : Number [覆寫] 會取得或設定 x 座標，代表組件在其父輩容器內的 x 軸位置。	UIComponent
		y : Number [覆寫] 會取得或設定 y 座標，代表組件在其父輩容器內的 y 軸位置。	UIComponent
		z : Number 表示 DisplayObject 實體相對於 3D 父輩容器的 z 座標位置 (沿著 z 軸)。	DisplayObject

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		UILoader() 建立新的 UILoader 組件實體。	UILoader
		addChild(child:DisplayObject):DisplayObject 將 DisplayObject 子實體加入至此 DisplayObjectContainer 實體。	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject 將 DisplayObject 子實體加入至此 DisplayObjectContainer 實體。	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void 會在 EventDispatcher 物件註冊事件偵聽程式，以便讓偵聽程式收到事件的通知。	EventDispatcher
		areInaccessibleObjectsUnderPoint(point:Point):Boolean 指出安全性限制是否會造成傳回的清單 (可用指定的 point 點呼叫 DisplayObjectContainer.getObjectsUnderPoint() 方法來取得) 省略任何顯示物件。	DisplayObjectContainer
		clearStyle(style:String):void 從此組件實體刪除某種樣式屬性。	UIComponent
		close():void 取消 ProLoader 實體目前正在進行的 load() 方法作業。	UILoader
		contains(child:DisplayObject):Boolean 判斷指定的顯示物件是否為 DisplayObjectContainer 實體的子系，或為實體本身。	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean 會將事件傳送到事件流程。	EventDispatcher
		drawFocus(focused:Boolean):void 會顯示或隱藏此組件上的焦點指示器。	UIComponent
		drawNow():void 會起始立即繪製作業，而不需像 invalidateNow 一樣使所有項目無效化。	UIComponent
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle 傳回可定義顯示物件區域 (相對於 targetCoordinateSpace 物件的座標系統) 的矩形。	DisplayObject
		getChildAt(index:int):DisplayObject 傳回存在於指定索引位置的子顯示物件實體。	DisplayObjectContainer
		getChildByName(name:String):DisplayObject 傳回具有指定名稱的子顯示物件。	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int 傳回 child DisplayObject 實體的索引位置。	DisplayObjectContainer
		getFocus():InteractiveObject 會擷取目前成為焦點的物件。	UIComponent
		getObjectsUnderPoint(point:Point):Array 傳回位於指定點底下，且屬於此 DisplayObjectContainer 實體之子系 (或孫系，以下類推) 的物件陣列。	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle 根據 targetCoordinateSpace 參數所定義的座標系統，並排除形狀上的任何筆畫，傳回可定義顯示物件邊界的矩形。	DisplayObject
		getStyle(style:String):Object 會擷取在組件樣式查閱鏈中設定的樣式屬性。	UIComponent
		getStyleDefinition():Object [靜態] 會擷取目前組件的預設樣式對應。	UILoader
		globalToLocal(point:Point):Point 將 point 物件從「舞台」(全域) 座標轉換成顯示物件的 (區域) 座標。	DisplayObject
		globalToLocal3D(point:Point):Vector3D 將二維點從「舞台」(全域) 座標轉換為三維顯示物件的 (區域) 座標。	DisplayObject
		hasEventListener(type:String):Boolean 會檢查 EventDispatcher 物件是否有對特定的事件類型註冊偵聽程式。	EventDispatcher
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		hitTestObject(obj:DisplayObject):Boolean 評估顯示物件的範圍框，看它是否與 obj 顯示物件的範圍框重疊或相交。	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean 評估顯示物件，看它是否與 x 和 y 參數所指定的點重疊或相交。	DisplayObject
		invalidate(property:String, callLater:Boolean = true):void 會將屬性標示為無效，除非另有指定，否則會在下一個影格上重繪組件。	UIComponent
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		load(request:URLRequest = null, context:LoaderContext = null):void 會載入指定的內容；如果未指定內容，則會從 source 屬性所識別的位置載入內容。	UILoader
		loadBytes(bytes:ByteArray, context:LoaderContext = null):void 會載入儲存在 ByteArray 物件中的二進位資料。	UILoader
		local3DToGlobal(point3d:Vector3D):Point 將三維顯示物件的 (區域) 座標的三維點轉換為「舞台」(全域) 座標中的二維點。	DisplayObject
		localToGlobal(point:Point):Point 將 point 物件從顯示物件的 (區域) 座標轉換成「舞台」(全域) 座標。	DisplayObject
		mergeStyles(... list):Object [靜態] 會將多種類別中的樣式合併為一個物件。	UIComponent
		move(x:Number, y:Number):void 將組件移至其父輩內指定的位置。	UIComponent
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		removeChild(child:DisplayObject):DisplayObject 將指定的 child DisplayObject 實體從 DisplayObjectContainer 實體的子清單中移除。	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject 從 DisplayObjectContainer 子清單中的指定索引位置移除子 DisplayObject。	DisplayObjectContainer
		removeChildren(beginIndex:int = 0, endIndex:int = 0x7fffffff):void 將所有 child DisplayObject 實體從 DisplayObjectContainer 實體的子清單中移除。	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void 會從 EventDispatcher 物件移除偵聽程式。	EventDispatcher
		requestSoftKeyboard():Boolean 升起顯示虛擬鍵盤。	InteractiveObject
		setChildIndex(child:DisplayObject, index:int):void 變更顯示物件容器中現有子系的位置。	DisplayObjectContainer
		setFocus():void 將焦點設定到此組件。	UIComponent
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		setSize(w:Number, h:Number):void [覆寫] 將組件調整為要求的大小。	UILoader
		setStyle(style:String, value:Object):void 針對此組件實體設定樣式屬性。	UIComponent
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void 讓使用者拖曳指定的 sprite。	Sprite
		startTouchDrag(touchPointID:int, lockCenter:Boolean = false, bounds:Rectangle = null):void 讓使用者將指定的 Sprite 拖曳至觸控裝置上。	Sprite
		stopAllMovieClips():void 遞迴停止執行所有 MovieClips 的時間軸根源於此物件。	DisplayObjectContainer
		stopDrag():void 結束 startDrag() 方法。	Sprite
		stopTouchDrag(touchPointID:int):void 結束觸控裝置使用的 startTouchDrag() 方法。	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void 替換兩個指定子物件的 z 順序 (深度階層，由前至後順序)。	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void 在子清單的兩個指定索引位置，替換子物件的 z 順序 (深度階層，由前至後順序)。	DisplayObjectContainer
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回指定之物件的字串形式。	Object
		unload():void 會移除這個 UILoader 物件的子系，此物件是使用 load() 方法或 source 屬性載入。	UILoader
		validateNow():void 會確認此物件之屬性和版面的有效性並加以更新，並在必要時重繪此物件。	UIComponent
		valueOf():Object 會傳回指定之物件的基本值。	Object
		willTrigger(type:String):Boolean 檢查此 EventDispatcher 物件是否已註冊事件偵聽程式，或者此物件的任何祖系已為特定事件類型註冊事件偵聽程式。	EventDispatcher

保護方法

隱藏繼承保護方法

顯示繼承保護方法

	方法		定義自
		getStyleValue(name:String):Object 考量全域層級、組件層級和實體層級上設定的所有樣式之後，傳回組件的指定樣式。	UIComponent

事件

按一下以瞭解事件的詳細資訊

隱藏繼承事件

顯示繼承事件

	摘要	定義自
activate	[廣播事件] 當 Flash Player 或 AIR 應用程式取得作業系統焦點並成為作用中時傳送。	EventDispatcher
added	當顯示物件加入顯示清單中時傳送。	DisplayObject
addedToStage	會在顯示物件加入舞台上的顯示清單時，以直接或是透過加入包含該顯示物件之子樹狀結構的方式傳送。	DisplayObject
clear	當使用者從文字快顯選單中選取「清除」(或「刪除」) 時傳送。	InteractiveObject
click	會當使用者在相同的 InteractiveObject 上方按下並放開使用者的指向裝置主按鈕時傳送。	InteractiveObject
complete	在內容載入完成時傳送。	UILoader
contextMenu	當使用者手勢在 AIR 應用程式中觸發與此互動式物件相關聯的快顯選單時傳送。	InteractiveObject
copy	當使用者針對複製作業啟動平台特有的快速鍵組合或從文字快顯選單中選取「複製」時傳送。	InteractiveObject
cut	當使用者針對剪下作業啟動平台特有的快速鍵組合或從文字快顯選單中選取「剪下」時傳送。	InteractiveObject
deactivate	[廣播事件] 當 Flash Player 或 AIR 應用程式失去作業系統焦點並成為非作用中時傳送。	EventDispatcher
doubleClick	在 InteractiveObject 物件的 doubleClickEnabled 旗標設為 true 的情況下，當使用者在相同的物件上方連續兩次快速按下並放開指標裝置主要按鈕時傳送。	InteractiveObject
enterFrame	[廣播事件] 當播放磁頭進入新影格時傳送。	DisplayObject
exitFrame	[廣播事件] 當播放磁頭結束目前影格時傳送。	DisplayObject
focusIn	當顯示物件取得焦點之後傳送。	InteractiveObject
focusOut	當顯示物件失去焦點時傳送。	InteractiveObject
frameConstructed	[廣播事件] 在影格顯示物件的建構函式執行之後，且影格指令碼執行之前傳送。	DisplayObject
gestureDirectionalTap	當使用者沿著觸控面與 InteractiveObject 實體建立接觸點 (例如沿著 Apple TV 的 Siri Remote 觸控面點選)，某些裝置可能也會將此接觸解譯為數個觸控事件的組合。	InteractiveObject
gestureLongPress	當使用在觸控裝置上的同一個 InteractiveObject 實體上按下兩個接觸點後送出 (例如在行動電話或平板電腦觸控螢幕的顯示物件上方，以兩支手指按下後鬆開)。	InteractiveObject
gesturePan	當使用者在觸控裝置上，將接觸點移動到 InteractiveObject 實體上方後傳送 (例如，在行動電話或平板電腦觸控螢幕的顯示物件上，由左向右移動手指)。	InteractiveObject
gestureRotate	當使用者在 InteractiveObject 實體的接觸點上做出旋轉手勢後傳送 (例如兩指觸摸行動電話或平板電腦的觸控螢幕，然後手指在顯示物件上旋轉)。	InteractiveObject
gestureSwipe	當使用者在與 InteractiveObject 實體的某個接觸點上做出揮動手勢後傳送 (例如，三指併在一起觸碰行動電話或平板電腦的觸控螢幕，然後在顯示物件上快速平行移動手指)。	InteractiveObject
gestureTap	當使用者與 InteractiveObject 實體建立接觸點，然後在觸控裝置上點一下後送出 (例如，將多根手指放到行動電話或平板電腦觸控螢幕的顯示物件上以開啟選單，然後其中一根手點一下，選取選單項目)。	InteractiveObject
gestureZoom	當使用者在 InteractiveObject 實體的某個接觸點上做出放大縮小手勢後傳送 (例如兩指併在一起觸摸行動電話或平板電腦的觸控螢幕，然後手指在顯示物件上快速張開)。	InteractiveObject
hide	在組件的可見性從可見變更為隱藏之後傳送。	UIComponent
imeStartComposition	這個事件會送出至任何支援 IME 內嵌輸入的用戶端應用程式。	InteractiveObject
init	當您可以存取載入的 SWF 檔案的屬性和方法時傳送。	UILoader
ioError	在發生輸入或輸出錯誤之後傳送。	UILoader
keyDown	會當使用者按下按鍵時傳送。	InteractiveObject
keyFocusChange	當使用者嘗試使用鍵盤瀏覽變更焦點時傳送。	InteractiveObject
keyUp	會當使用者放開按鍵時傳送。	InteractiveObject
middleClick	當使用者在相同的 InteractiveObject 上方按下並放開使用者的指向裝置中間按鈕時傳送。	InteractiveObject
middleMouseDown	當使用者將指向裝置的中間按鈕移至 InteractiveObject 實體上方按下時傳送。	InteractiveObject
middleMouseUp	當使用者將指向裝置按鈕移至 InteractiveObject 實體上方放開時傳送。	InteractiveObject
mouseDown	當使用者將指向裝置按鈕移至 InteractiveObject 實體上方按下時傳送。	InteractiveObject
mouseFocusChange	會當使用者嘗試使用指向裝置變更焦點時傳送。	InteractiveObject
mouseMove	會當指向裝置停在 InteractiveObject 上方的情況下使用者將其移動時傳送。	InteractiveObject
mouseOut	會當使用者將指向裝置移開 InteractiveObject 實體時傳送。	InteractiveObject
mouseOver	會當使用者將指向裝置移至 InteractiveObject 實體上方時傳送。	InteractiveObject
mouseUp	當使用者將指向裝置按鈕移至 InteractiveObject 實體上方放開時傳送。	InteractiveObject
mouseWheel	當滑鼠滾輪在 InteractiveObject 實體上方轉動時傳送。	InteractiveObject
move	在移動組件之後傳送。	UIComponent
nativeDragComplete	當使用者釋放手勢時，由拖曳初始程式 InteractiveObject 傳送。	InteractiveObject
nativeDragDrop	已在目標 InteractiveObject 上放下拖曳的物件，而且已呼叫 DragManager.acceptDragDrop() 接受該放開的資料時，由此目標 InteractiveObject 傳送。	InteractiveObject
nativeDragEnter	當手勢進入 InteractiveObject 的邊界時，由此 InteractiveObject 傳送。	InteractiveObject
nativeDragExit	當手勢離開 InteractiveObject 的邊界時，由此 InteractiveObject 傳送。	InteractiveObject
nativeDragOver	當拖曳手勢還留在 InteractiveObject 的邊界內，由此 InteractiveObject 持續傳送。	InteractiveObject
nativeDragStart	在呼叫 DragManager.doDrag() 進行拖曳作業初期，由指定做為拖曳初始程式的 InteractiveObject 傳送。	InteractiveObject
nativeDragUpdate	在呼叫 DragManager.doDrag() 進行拖曳作業期間，由指定做為拖曳初始程式的 InteractiveObject 傳送。	InteractiveObject
open	在網路作業開始之後傳送。	UILoader
paste	當使用者針對貼上作業啟動平台特有的快速鍵組合或從文字快顯選單中選取「貼上」時傳送。	InteractiveObject
progress	當內容正在載入時傳送。	UILoader
proximityBegin	在使用者將作用中觸控筆往下移至超過螢幕鄰近偵測邊框時傳送。	InteractiveObject
proximityEnd	在使用者將作用中觸控筆提到螢幕鄰近偵測邊框時傳送。	InteractiveObject
proximityMove	在使用者將作用中觸控筆移到螢幕上方，而其餘仍在鄰近偵測邊框內時傳送。	InteractiveObject
proximityOut	在使用者將作用中觸控筆移出這個 InteractiveObject 之外，而其餘仍在螢幕的鄰近偵測邊框內時傳送。	InteractiveObject
proximityOver	在使用者直接將作用中觸控筆移到這個 InteractiveObject 上方，而其餘仍在螢幕的鄰近偵測邊框內時傳送。	InteractiveObject
proximityRollOut	在使用者將作用中觸控筆移出這個 InteractiveObject 及其任一子系之外，而其餘仍在螢幕的鄰近偵測邊框內時傳送。	InteractiveObject
proximityRollOver	在使用者透過這個 InteractiveObject，從顯示清單中後代的物件樹狀結構之外移動作用中觸控筆時傳送 (而其餘仍在螢幕的鄰近偵測邊框內)。	InteractiveObject
releaseOutside	當使用者第一次按下 InteractiveObject 實體上方的按鈕，然後將指向裝置滑出 InteractiveObject 實體之後即放開指向裝置上的按鈕時傳送。	InteractiveObject
removed	會當顯示物件將要從顯示清單移除時傳送。	DisplayObject
removedFromStage	會在顯示物件即將從顯示清單移除時，以直接或是透過移除包含該顯示物件之子樹狀結構的方式傳送。	DisplayObject
render	[廣播事件] 當顯示清單將要更新和顯示時傳送。	DisplayObject
resize	在調整組件大小之後傳送。	UILoader
rightClick	當使用者在相同的 InteractiveObject 上方按下並放開使用者的指向裝置右邊按鈕時傳送。	InteractiveObject
rightMouseDown	當使用者將指向裝置按鈕移至 InteractiveObject 實體上方按下時傳送。	InteractiveObject
rightMouseUp	當使用者將指向裝置按鈕移至 InteractiveObject 實體上方放開時傳送。	InteractiveObject
rollOut	會當使用者將指向裝置移開 InteractiveObject 實體時傳送。	InteractiveObject
rollOver	會當使用者將指向裝置移至 InteractiveObject 實體上方時傳送。	InteractiveObject
securityError	在載入內容期間發生了安全性錯誤時傳送。	UILoader
selectAll	當使用者針對全選作業啟動平台特有的快速鍵組合或從文字快顯選單中選取「全選」時傳送。	InteractiveObject
show	在組件的可見性從隱藏變更為可見之後傳送。	UIComponent
softKeyboardActivate	升起顯示軟體鍵盤之後立即傳送。	InteractiveObject
softKeyboardActivating	升起顯示軟體鍵盤前立即傳送。	InteractiveObject
softKeyboardDeactivate	降下隱藏軟體鍵盤之後立即傳送。	InteractiveObject
tabChildrenChange	在物件的 tabChildren 旗標值變更時傳送。	InteractiveObject
tabEnabledChange	在物件的 tabEnabled 旗標變更時傳送。	InteractiveObject
tabIndexChange	在物件的 tabIndex 屬性值變更時傳送。	InteractiveObject
textInput	當使用者輸入一或多文字的字元時送出。	InteractiveObject
touchBegin	當使用者在第一次接觸觸控裝置後傳送 (例如手指觸摸行動電話或平板電腦的觸控螢幕)。	InteractiveObject
touchEnd	當使用者在觸控裝置上移除接觸點後傳送 (例如在行動電話或平板電腦觸控螢幕上移開手指)。	InteractiveObject
touchMove	當使用者觸控裝置時傳送，並且連續不斷地傳送，直到接觸點移除為止。	InteractiveObject
touchOut	當使用者在觸控裝置中，將接觸點移出 InteractiveObject 實體後送出 (例如在行動電話或平板電腦的觸控螢幕上，將手指從顯示物件移至另一個顯示物件)。	InteractiveObject
touchOver	當使用者在觸控裝置中將接觸點移至 InteractiveObject 實體上方後送出 (例如在行動電話或平板電腦的觸控螢幕上，將手指從顯示物件外面的某一點，往顯示物件上方拖曳)。	InteractiveObject
touchRollOut	當使用者在觸控裝置上，將接觸點從 InteractiveObject 實體移出後送出 (例如，在行動電話或平板電腦的觸控螢幕上，將手指從顯示物件上方拖曳到顯示物件以外)。	InteractiveObject
touchRollOver	當使用者在觸控裝置中將接觸點移至 InteractiveObject 實體上方後送出 (例如在行動電話或平板電腦的觸控螢幕上，將手指從顯示物件外面的某一點，往顯示物件上方拖曳)。	InteractiveObject
touchTap	當使用者在觸控裝置的同一個 InteractiveObject 實體上，在原先開始接觸點放開後送出 (例如在行動電話或平板電腦觸控螢幕上的顯示物件上方，以手指按下某個點後又鬆開)。	InteractiveObject

樣式

樣式可分為一般樣式及與特定主題關聯的樣式兩種。如果是一般樣式，可以與任何主題搭配使用。如果是與特定主題關聯的樣式，只有在您的應用程式使用特定主題時才能使用該樣式。

一般樣式

按一下以瞭解樣式的詳細資訊

隱藏繼承樣式

顯示繼承樣式

	說明	定義自
disabledTextFormat	類型: flash.text.TextFormat 語言版本: ActionScript 3.0 產品版本: Flash CS3 執行階段版本: Flash9.0.28.0, AIR 1.0 當按鈕停用時用來繪製組件標籤的 TextFormat 物件.	UIComponent
focusRectPadding	類型: Number 格式: Length 語言版本: ActionScript 3.0 產品版本: Flash CS3 執行階段版本: Flash9.0.28.0, AIR 1.0 分開組件外邊框與焦點指示器的外邊緣的邊框 (以像素計).	UIComponent
focusRectSkin	類型: Class 語言版本: ActionScript 3.0 產品版本: Flash CS3 執行階段版本: Flash9.0.28.0, AIR 1.0 用來顯示焦點指示器的外觀元素.	UIComponent
textFormat	類型: flash.text.TextFormat 語言版本: ActionScript 3.0 產品版本: Flash CS3 執行階段版本: Flash9.0.28.0, AIR 1.0 用來繪製組件標籤的 TextFormat 物件.	UIComponent

公用常數

隱藏繼承公用常數

顯示繼承公用常數

	常數		定義自
		version : String = "3.0.3.1" 組件的版本號碼。	UIComponent

屬性詳細資訊

autoLoad

屬性

autoLoad:Boolean

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得或設定值，指出 UILoader 實體是否會自動載入指定的內容。值為 true 表示 UILoader 會自動載入內容；值為 false 則表示要等到呼叫 load() 方法之後，才會載入內容。

預設值為 true。

實作
public function get autoLoad():Boolean
public function set autoLoad(value:Boolean):void

相關 API 元素

load()
source

範例 ( 如何使用本範例 )

下列範例會顯示將 autoLoad 屬性設定為 false 如何防止在呼叫 load() 方法前載入內容：


import fl.containers.UILoader;
import fl.controls.Button;

var myUILoader:UILoader = new UILoader();
myUILoader.autoLoad = false;
myUILoader.scaleContent = false;
myUILoader.source = "http://www.helpexamples.com/flash/images/image1.jpg";
myUILoader.move(10, 40);
addChild(myUILoader);

var myButton:Button = new Button();
myButton.label = "Load image";
myButton.move(10, 10);
myButton.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(myButton);

function clickHandler(event:MouseEvent):void {
    myUILoader.load();
}

bytesLoaded

屬性

bytesLoaded:uint [唯讀]

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得已載入之內容的位元組數。當此屬性等於 bytesTotal 的值時，就表示已經載入所有的位元組。

預設值為 0。

實作
public function get bytesLoaded():uint

相關 API 元素

bytesTotal
percentLoaded

範例 ( 如何使用本範例 )

下列範例會建立顯示載入之影像的 UILoader 組件實體，和顯示影像目前下載狀態的 ProgressBar 與 Label 組件實體：


import fl.containers.UILoader;
import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var url:String = "http://www.helpexamples.com/flash/images/image3.jpg";

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 10);
addChild(myLabel);

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.MANUAL;
myProgressBar.move(10, 30);
addChild(myProgressBar);

var myUILoader:UILoader = new UILoader();
myUILoader.load(new URLRequest(url));
myUILoader.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myUILoader.addEventListener(Event.COMPLETE, completeHandler);
myUILoader.move(10, 35);
addChild(myUILoader);

function progressHandler(event:ProgressEvent):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    var kbLoaded:String = Number(uiLdr.bytesLoaded / 1024).toFixed(1);
    var kbTotal:String = Number(uiLdr.bytesTotal / 1024).toFixed(1);
    myLabel.text = kbLoaded + " of " + kbTotal + " KB" + " (" + Math.round(uiLdr.percentLoaded) + "%)";
    myProgressBar.setProgress(event.bytesLoaded, event.bytesTotal);
}

function completeHandler(event:Event):void {
    myLabel.visible = false;
    myProgressBar.visible = false;
    myUILoader.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myUILoader.removeEventListener(Event.COMPLETE, completeHandler);
}

bytesTotal

屬性

bytesTotal:uint [唯讀]

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得要載入的內容位元組總數。

預設值為 0。

實作
public function get bytesTotal():uint

相關 API 元素

bytesLoaded
percentLoaded

範例 ( 如何使用本範例 )

下列範例會建立顯示載入之影像的 UILoader 組件實體，和顯示影像目前下載狀態的 ProgressBar 與 Label 組件實體：


import fl.containers.UILoader;
import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var url:String = "http://www.helpexamples.com/flash/images/image3.jpg";

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 10);
addChild(myLabel);

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.MANUAL;
myProgressBar.move(10, 30);
addChild(myProgressBar);

var myUILoader:UILoader = new UILoader();
myUILoader.load(new URLRequest(url));
myUILoader.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myUILoader.addEventListener(Event.COMPLETE, completeHandler);
myUILoader.move(10, 35);
addChild(myUILoader);

function progressHandler(event:ProgressEvent):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    var kbLoaded:String = Number(uiLdr.bytesLoaded / 1024).toFixed(1);
    var kbTotal:String = Number(uiLdr.bytesTotal / 1024).toFixed(1);
    myLabel.text = kbLoaded + " of " + kbTotal + " KB" + " (" + Math.round(uiLdr.percentLoaded) + "%)";
    myProgressBar.setProgress(event.bytesLoaded, event.bytesTotal);
}

function completeHandler(event:Event):void {
    myLabel.visible = false;
    myProgressBar.visible = false;
    myUILoader.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myUILoader.removeEventListener(Event.COMPLETE, completeHandler);
}

content

屬性

content:DisplayObject [唯讀]

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會包含使用 load() 方法或設定 source 屬性所載入之 SWF 檔或影像檔 (JPEG、PNG 或 GIF 格式的檔案) 的根顯示物件。載入開始之前，這個值會是 undefined。為 complete 事件之事件處理常式函數中的內容設定屬性。

預設值為 null。

實作
public function get content():DisplayObject

相關 API 元素

complete
load()
source

範例 ( 如何使用本範例 )

下列範例會建立修改 UILoader 物件內容之透明度的滑動軸：


import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.SliderEvent;

var s:Slider = new Slider();
s.minimum = 10;
s.maximum = 100;
s.liveDragging = true;
s.value = s.maximum;
s.move(10,10);
s.addEventListener(SliderEvent.THUMB_DRAG, updateUILoaderContentAlpha);
addChild(s);

var loader:UILoader = new UILoader();
loader.move(10,40);
loader.setSize(400, 300);
loader.source = "http://www.helpexamples.com/flash/images/image2.jpg";
addChild(loader);

function updateUILoaderContentAlpha(e:SliderEvent):void {
    loader.content.alpha = s.value/100;
}

maintainAspectRatio

屬性

maintainAspectRatio:Boolean

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得或設定值，指出要維持原始影像使用的比例，還是將影像大小調整成 UILoader 組件的目前寬度和高度。值為 true 表示要維持原始比例；值為 false 則表示載入的內容應調整成 UILoader 的目前尺寸。

若要使用這個屬性，您必須將 scaleContent 屬性設定為 false，否則會忽略此屬性。

預設值為 true。

實作
public function get maintainAspectRatio():Boolean
public function set maintainAspectRatio(value:Boolean):void

相關 API 元素

scaleContent

範例 ( 如何使用本範例 )

下列範例會使用核取方塊來切換 maintainAspectRatio 屬性的值：


import fl.containers.UILoader;
import fl.controls.CheckBox;

var myUILoader:UILoader = new UILoader();
myUILoader.setSize(200, 200);
myUILoader.scaleContent = true;
myUILoader.maintainAspectRatio = true;
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 10);
addChild(myUILoader);

var myCheckBox:CheckBox = new CheckBox();
myCheckBox.label = "maintainAspectRatio";
myCheckBox.selected = myUILoader.maintainAspectRatio;
myCheckBox.width = 150;
myCheckBox.move(220, 10);
myCheckBox.addEventListener(Event.CHANGE, changeHandler);
addChild(myCheckBox);

function changeHandler(event:Event):void {
    myUILoader.maintainAspectRatio = event.target.selected;
}

percentLoaded

屬性

percentLoaded:Number [唯讀]

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得介於 0 和 100 之間的數字，表示已載入內容的百分比。如果是從元件庫載入的資源，而非外部載入的內容，則 percentLoaded 屬性會設定為 0。

預設值為 0。

實作
public function get percentLoaded():Number

相關 API 元素

bytesLoaded
bytesTotal

範例 ( 如何使用本範例 )

下列範例會建立顯示載入之影像的 UILoader 組件實體，和顯示影像目前下載狀態的 ProgressBar 與 Label 組件實體：


import fl.containers.UILoader;
import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var url:String = "http://www.helpexamples.com/flash/images/image3.jpg";

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 10);
addChild(myLabel);

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.MANUAL;
myProgressBar.move(10, 30);
addChild(myProgressBar);

var myUILoader:UILoader = new UILoader();
myUILoader.load(new URLRequest(url));
myUILoader.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myUILoader.addEventListener(Event.COMPLETE, completeHandler);
myUILoader.move(10, 35);
addChild(myUILoader);

function progressHandler(event:ProgressEvent):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    var kbLoaded:String = Number(uiLdr.bytesLoaded / 1024).toFixed(1);
    var kbTotal:String = Number(uiLdr.bytesTotal / 1024).toFixed(1);
    myLabel.text = kbLoaded + " of " + kbTotal + " KB" + " (" + Math.round(uiLdr.percentLoaded) + "%)";
    myProgressBar.setProgress(event.bytesLoaded, event.bytesTotal);
}

function completeHandler(event:Event):void {
    myLabel.visible = false;
    myProgressBar.visible = false;
    myUILoader.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myUILoader.removeEventListener(Event.COMPLETE, completeHandler);
}

scaleContent

屬性

scaleContent:Boolean

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得或設定值，指出是否要自動將影像縮放為 UILoader 實體的大小。值為 true 表示影像會自動縮放為 UILoader 實體的大小；值為 false 則表示載入的內容會自動縮放為預設大小。

預設值為 true。

實作
public function get scaleContent():Boolean
public function set scaleContent(value:Boolean):void

相關 API 元素

maintainAspectRatio

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 物件，它會載入並符合影像的尺寸：


import fl.containers.UILoader;

var loader:UILoader = new UILoader();
loader.scaleContent = false;
loader.source = "http://www.helpexamples.com/flash/images/image2.jpg";
addChild(loader);

source

屬性

source:Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得或設定絕對或相對 URL，它會識別要載入之 SWF 或影像檔的位置、元件庫中影片片段的類別名稱、顯示物件的參考，或是識別與組件位於相同層級的影片片段實體名稱。

有效的影像檔格式包括 GIF、PNG 和 JPEG。若要使用 URLRequest 物件來載入資源，請使用 load() 方法。

預設值為 null。

實作
public function get source():Object
public function set source(value:Object):void

相關 API 元素

autoLoad
load()

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 物件，它會載入並符合影像的尺寸：

import fl.containers.UILoader;

var loader:UILoader = new UILoader();
loader.scaleContent = false;
loader.source = "http://www.helpexamples.com/flash/images/image2.jpg";
addChild(loader);

建構函式詳細資料

()

建構函式

public function UILoader()

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

建立新的 UILoader 組件實體。

方法詳細資訊

close

()

方法

public function close():void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

取消 ProLoader 實體目前正在進行的 load() 方法作業。load() 方法也可以透過 source 參數加以呼叫。

擲回值

Error — URLStream 物件沒有開啟的串流。

相關 API 元素

load()
source

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 組件實體，以及建立可讓您取消 UILoader 實體影像下載的 Button 組件實體：


import fl.containers.UILoader;
import fl.controls.Button;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image1.jpg";
myUILoader.move(10, 30);
addChild(myUILoader);

var cancelButton:Button = new Button();
cancelButton.label = "Cancel download";
cancelButton.move(10, 10);
cancelButton.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(cancelButton);

function clickHandler(event:MouseEvent):void {
    var uil:UILoader = myUILoader;
    try {
        uil.close();
        trace("Download cancelled:", uil.source);
    } catch (error:Error) {
        trace("Unable to cancel download.", error.message);
    }
}

getStyleDefinition

()

方法

public static function getStyleDefinition():Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會擷取目前組件的預設樣式對應。視組件使用的樣式而定，樣式對應會包含適用於組件的類型。例如，disabledTextFormat 樣式會包含 null 值或 TextFormat 物件。您可以使用這些樣式，並針對目前的組件呼叫 setStyle()。下列程式碼會覆寫指定組件上預設的 disabledTextFormat 樣式：

componentInstance.setStyle("disabledTextFormat", new TextFormat());

傳回值

Object — 預設的樣式物件。

範例 ( 如何使用本範例 )

下列範例會為幾個組件類別建立樣式瀏覽器：

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

load

()

方法

public function load(request:URLRequest = null, context:LoaderContext = null):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會載入指定的內容；如果未指定內容，則會從 source 屬性所識別的位置載入內容。根據預設，LoaderContext 物件會使用目前的網域做為應用程式網域。若要指定不同的應用程式網域、檢查原則檔，或變更安全性網域，請初始化新的 LoaderContext 物件，並將它傳遞至此方法。

根據預設，context 屬性會使用目前的網域。若要指定不同的 ApplicationDomain、檢查原則檔，或變更 SecurityDomain，請傳遞新的 LoaderContext 物件。

參數

	`request:URLRequest` (default = `null`) — 用於識別載入內容之來源位置的 URLRequest 物件。如果未指定這個值，則會使用 `source` 屬性目前的值當做內容位置。

	`context:LoaderContext` (default = `null`) — LoaderContext 物件，可設定載入作業的內容。

範例 ( 如何使用本範例 )

下列範例會建立新的 UILoader 實體，並使用 load() 方法搭配 source 屬性載入影像：


import fl.containers.UILoader;

var myUILoader:UILoader = new UILoader();
myUILoader.autoLoad = false;
myUILoader.scaleContent = false;
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.load();
myUILoader.move(10, 10);
addChild(myUILoader);

下列範例會建立新的 UILoader 實體，並使用 load() 方法搭配 URLRequest 實體載入影像：


import fl.containers.UILoader;

var url:String = "http://www.helpexamples.com/flash/images/image3.jpg";
var req:URLRequest = new URLRequest(url);

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.move(10, 10);
myUILoader.load(req);
addChild(myUILoader);

loadBytes

()

方法

public function loadBytes(bytes:ByteArray, context:LoaderContext = null):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會載入儲存在 ByteArray 物件中的二進位資料。

參數

	`bytes:ByteArray` — ByteArray 物件包含的檔案是使用 ProLoader 類別支援的下列其中一種格式：SWF、GIF、JPEG 或 PNG。

	`context:LoaderContext` (default = `null`) — 只會套用 LoaderContext 物件的 `applicationDomain` 屬性，而不會套用 LoaderContext 物件的 `checkPolicyFile` 和 `securityDomain` 屬性。

擲回值

	`ArgumentError` — ByteArray 物件的 `length` 屬性為 0。

	`IllegalOperationError` — `context` 參數的 `checkPolicyFile` 或 `securityDomain` 屬性為非 null。

	`SecurityError` — 所提供之 `context` 屬性的 `applicationDomain` 屬性來自不受允許的網域。

範例 ( 如何使用本範例 )

下列範例會將 GIF 的原始位元組載入至 UILoader 物件中：

import fl.containers.UILoader;

var imageBytes:Array = [ 71, 73, 70, 56, 57, 97, 50, 0, 30, 0, 230, 0, 0, 0, 0, 0, 173, 169, 206, 82, 73, 153, 74, 74, 74, 115, 109, 155, 248, 247, 251, 102, 102, 102, 26, 24, 35, 181, 181, 181, 70, 61, 145, 222, 222, 222, 153, 153, 153, 204, 204, 204, 58, 58, 58, 132, 132, 132, 231, 231, 231, 8, 7, 14, 90, 90, 90, 89, 81, 163, 153, 153, 153, 191, 188, 217, 165, 165, 165, 190, 190, 190, 237, 237, 233, 51, 51, 51, 214, 214, 214, 90, 82, 156, 156, 152, 190, 123, 123, 123, 140, 140, 140, 140, 135, 187, 103, 96, 165, 78, 70, 150, 173, 173, 173, 127, 121, 179, 82, 82, 82, 206, 204, 226, 195, 195, 193, 102, 102, 102, 247, 247, 247, 41, 41, 41, 66, 66, 66, 183, 179, 212, 146, 141, 190, 21, 21, 20, 227, 226, 238, 119, 111, 181, 198, 195, 221, 99, 91, 162, 255, 255, 255, 218, 216, 233, 114, 114, 114, 16, 15, 27, 114, 107, 171, 210, 208, 228, 8, 8, 8, 179, 175, 209, 240, 239, 246, 153, 153, 153, 234, 233, 243, 95, 88, 160, 90, 74, 156, 33, 33, 33, 16, 16, 16, 163, 159, 200, 142, 137, 188, 197, 189, 222, 134, 129, 183, 151, 147, 193, 202, 199, 223, 222, 221, 235, 122, 115, 176, 215, 213, 231, 74, 66, 147, 82, 75, 146, 197, 197, 197, 106, 99, 166, 231, 230, 240, 175, 171, 207, 239, 239, 239, 209, 207, 227, 25, 25, 22, 119, 112, 182, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 33, 249, 4, 0, 7, 0, 255, 0, 44, 0, 0, 0, 0, 50, 0, 30, 0, 0, 7, 255, 128, 49, 130, 131, 132, 132, 8, 24, 0, 16, 6, 15, 133, 141, 5, 54, 69, 77, 141, 147, 148, 147, 51, 63, 0, 153, 0, 40, 8, 148, 5, 1, 53, 48, 48, 31, 30, 50, 149, 167, 133, 5, 41, 154, 172, 0, 33, 141, 59, 76, 9, 2, 26, 181, 32, 32, 42, 168, 168, 170, 173, 172, 63, 23, 132, 59, 31, 32, 181, 197, 181, 73, 185, 186, 147, 5, 3, 189, 173, 29, 131, 194, 196, 198, 198, 184, 202, 141, 205, 206, 172, 35, 130, 77, 195, 212, 224, 73, 56, 215, 131, 217, 218, 154, 41, 49, 222, 211, 224, 212, 226, 228, 230, 231, 153, 6, 5, 223, 237, 237, 239, 186, 241, 242, 0, 11, 46, 236, 247, 194, 5, 64, 181, 79, 222, 129, 15, 180, 2, 6, 76, 226, 164, 82, 193, 115, 52, 148, 72, 80, 72, 145, 225, 164, 135, 218, 34, 242, 160, 200, 145, 225, 133, 12, 229, 248, 177, 210, 200, 177, 36, 136, 13, 140, 98, 112, 16, 169, 9, 130, 146, 141, 37, 75, 38, 121, 17, 195, 2, 38, 150, 81, 8, 76, 228, 40, 160, 39, 79, 38, 77, 26, 176, 4, 192, 130, 129, 148, 132, 10, 147, 0, 65, 162, 1, 169, 194, 32, 67, 127, 100, 40, 224, 244, 94, 18, 34, 130, 108, 248, 228, 200, 242, 7, 131, 24, 70, 170, 134, 91, 65, 8, 202, 86, 133, 17, 248, 121, 21, 148, 131, 135, 216, 98, 73, 255, 130, 52, 42, 114, 182, 157, 8, 5, 62, 206, 173, 29, 228, 33, 137, 85, 15, 148, 232, 190, 213, 0, 195, 84, 5, 109, 123, 7, 181, 104, 26, 110, 200, 169, 23, 32, 196, 38, 24, 40, 168, 195, 141, 86, 40, 190, 54, 34, 161, 33, 73, 207, 158, 73, 0, 163, 122, 33, 192, 115, 79, 16, 87, 11, 101, 152, 209, 0, 195, 128, 5, 39, 42, 237, 32, 194, 132, 7, 143, 35, 20, 174, 181, 88, 241, 193, 182, 8, 154, 228, 42, 229, 200, 17, 188, 184, 241, 224, 29, 150, 148, 0, 25, 35, 67, 133, 24, 39, 20, 44, 89, 18, 3, 1, 243, 37, 8, 136, 215, 68, 112, 34, 250, 146, 39, 5, 16, 88, 16, 36, 125, 73, 120, 230, 25, 16, 164, 44, 81, 194, 0, 2, 235, 5, 44, 116, 232, 244, 0, 67, 135, 8, 41, 58, 52, 200, 80, 194, 129, 131, 1, 49, 204, 48, 195, 2, 6, 224, 197, 65, 6, 35, 44, 192, 193, 12, 57, 160, 112, 95, 126, 13, 40, 16, 130, 1, 21, 140, 144, 129, 3, 51, 84, 128, 194, 18, 28, 148, 32, 31, 7, 6, 196, 160, 64, 4, 49, 44, 65, 162, 3, 11, 88, 128, 98, 10, 10, 164, 35, 72, 6, 0, 46, 48, 131, 32, 3, 88, 64, 98, 123, 42, 85, 136, 226, 12, 29, 112, 163, 146, 5, 28, 88, 16, 66, 7, 11, 0, 56, 98, 77, 33, 162, 56, 194, 88, 18, 10, 52, 240, 64, 4, 22, 40, 208, 1, 3, 36, 50, 48, 130, 116, 17, 28, 9, 100, 12, 14, 132, 224, 64, 7, 82, 142, 168, 94, 10, 37, 112, 16, 66, 10, 25, 48, 144, 194, 5, 90, 38, 89, 193, 2, 40, 140, 128, 65, 5, 12, 248, 224, 3, 7, 79, 10, 226, 128, 157, 37, 156, 192, 141, 5, 51, 114, 80, 193, 19, 24, 196, 121, 66, 157, 173, 49, 208, 161, 3, 40, 68, 208, 0, 7, 129, 0, 0, 59 ];

var totalBytes:uint = imageBytes.length;
var newBytes:ByteArray = new ByteArray()
var i:uint;
for(i=0; i<totalBytes; i++) {
    newBytes.writeByte(imageBytes[i]);
}

var loader:UILoader = new UILoader();
loader.loadBytes(newBytes);
addChild(loader);

setSize

()

方法

override public function setSize(w:Number, h:Number):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

將組件調整為要求的大小。如果 scaleContent 屬性設定為 true，則不會調整 UILoader 的大小。

參數

	`w:Number` — 組件的寬度，以像素為單位。

	`h:Number` — 組件的高度，以像素為單位。

相關 API 元素

scaleContent

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 組件實體，並使用 setSize() 方法在「舞台」上重新調整其大小：


import fl.containers.UILoader;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image2.jpg";
myUILoader.addEventListener(Event.COMPLETE, completeHandler);
addChild(myUILoader);

function completeHandler(event:Event):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    var image:DisplayObject = uiLdr.content as DisplayObject;
    trace("UILoader:", uiLdr.width, uiLdr.height); // 100 100
    trace("UILoader.content:", image.width, image.height); // 400 267
    uiLdr.setSize(image.width, image.height);
    uiLdr.move((stage.stageWidth - image.width) / 2, (stage.stageHeight - image.height) / 2);
}

unload

()

方法

public function unload():void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會移除這個 UILoader 物件的子系，此物件是使用 load() 方法或 source 屬性載入。

相關 API 元素

load()
source

範例 ( 如何使用本範例 )

下列範例會將影像載入至 UILoader 組件，並在傳送 UILoader 組件的 click 事件時取消載入所載入的影像：


import fl.containers.UILoader;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image1.jpg";
myUILoader.move(10, 10);
myUILoader.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(myUILoader);

function clickHandler(event:MouseEvent):void {
    var uil:UILoader = event.currentTarget as UILoader;
    uil.unload();
    removeChild(uil);
}

事件詳細資訊

complete

事件

事件物件類型: flash.events.Event
屬性 Event.type = flash.events.Event.COMPLETE

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

在內容載入完成時傳送。無論載入作業是透過自動載入程序，或是藉由明確呼叫 load() 方法觸發，都會傳送此事件。

Event.COMPLETE 常數會定義 complete 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`target`	已完成載入的網路物件。

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 實體，並在指定的影像完成載入時，將影像置於「舞台」中央：


import fl.containers.UILoader;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.source = "http://www.helpexamples.com/flash/images/image2.jpg";
myUILoader.addEventListener(Event.COMPLETE, completeHandler);
addChild(myUILoader);

function completeHandler(event:Event):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - uiLdr.content.width) / 2;
    var newY:uint = (stage.stageHeight - uiLdr.content.height) / 2;
    uiLdr.move(newX, newY);
}

相關 API 元素

progress

init

事件

事件物件類型: flash.events.Event
屬性 Event.type = flash.events.Event.INIT

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

當您可以存取載入的 SWF 檔案的屬性和方法時傳送。下列條件必須成立，才會傳送此事件：

所有與載入物件相關聯的屬性和方法，以及那些與組件相關聯的屬性和方法，都必須可供存取。
所有子物件的建構函式都必須已完成。

Event.INIT 常數會定義 init 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`target`	與所載入之 SWF 檔相關聯的 LoaderInfo 物件。

ioError

事件

事件物件類型: flash.events.IOErrorEvent
屬性 IOErrorEvent.type = flash.events.IOErrorEvent.IO_ERROR

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

在發生輸入或輸出錯誤之後傳送。

定義 ioError 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`errorID`	與特定錯誤相關聯的參考號碼 (僅限 AIR)。
`target`	遭遇輸入/輸出錯誤的網路物件。
`text`	要顯示為錯誤訊息的文字。

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 組件實體，和嘗試載入不存在的檔案，而這會導致傳送 ioError 事件：


import fl.containers.UILoader;

var url:String = "http://www.helpexamples.com/flash/images/image404.jpg"

var myUILoader:UILoader = new UILoader();
myUILoader.load(new URLRequest(url));
myUILoader.move(10, 10);
myUILoader.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
addChild(myUILoader);

function ioErrorHandler(event:IOErrorEvent):void {
    trace("<<", event.text, ">>");
    myUILoader.removeEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
    removeChild(myUILoader);
}

open

事件

事件物件類型: flash.events.Event
屬性 Event.type = flash.events.Event.OPEN

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

在網路作業開始之後傳送。

Event.OPEN 常數會定義 open 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`target`	已開啟連線的網路物件。

progress

事件

事件物件類型: flash.events.ProgressEvent
屬性 ProgressEvent.type = flash.events.ProgressEvent.PROGRESS

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

當內容正在載入時傳送。無論載入作業是透過自動載入程序，或是藉由明確呼叫 load() 方法觸發，都會傳送此事件。

定義 progress 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`bytesLoaded`	在偵聽程式處理事件時，載入的項目或位元組數目。
`bytesTotal`	如果載入程序成功時，最終將載入的項目或位元組總數。
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`target`	回報進度的物件。

範例 ( 如何使用本範例 )

下列範例會建立顯示載入之影像的 UILoader 組件實體，和顯示影像目前下載狀態的 ProgressBar 與 Label 組件實體：


import fl.containers.UILoader;
import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var url:String = "http://www.helpexamples.com/flash/images/image3.jpg";

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 10);
addChild(myLabel);

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.MANUAL;
myProgressBar.move(10, 30);
addChild(myProgressBar);

var myUILoader:UILoader = new UILoader();
myUILoader.load(new URLRequest(url));
myUILoader.addEventListener(ProgressEvent.PROGRESS, progressHandler);
myUILoader.addEventListener(Event.COMPLETE, completeHandler);
myUILoader.move(10, 35);
addChild(myUILoader);

function progressHandler(event:ProgressEvent):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    var kbLoaded:String = Number(uiLdr.bytesLoaded / 1024).toFixed(1);
    var kbTotal:String = Number(uiLdr.bytesTotal / 1024).toFixed(1);
    myLabel.text = kbLoaded + " of " + kbTotal + " KB" + " (" + Math.round(uiLdr.percentLoaded) + "%)";
    myProgressBar.setProgress(event.bytesLoaded, event.bytesTotal);
}

function completeHandler(event:Event):void {
    myLabel.visible = false;
    myProgressBar.visible = false;
    myUILoader.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myUILoader.removeEventListener(Event.COMPLETE, completeHandler);
}

相關 API 元素

complete

resize

事件

事件物件類型: fl.events.ComponentEvent
屬性 ComponentEvent.type = fl.events.ComponentEvent.RESIZE

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

在調整組件大小之後傳送。

定義 resize 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`target`	已經傳送該事件的物件。此目標不一定是偵聽該事件的物件。您可以使用 `currentTarget` 屬性，存取目前正在偵聽該事件的物件。

範例 ( 如何使用本範例 )

下列範例會建立 UILoader 組件實體、偵聽 resize 事件，並在其完成載入後將影像置於「舞台」中央：


import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var uiLdr:UILoader = event.currentTarget as UILoader;
    trace(uiLdr.width, uiLdr.height); // 400 267
    uiLdr.move((stage.stageWidth - uiLdr.width) / 2, (stage.stageHeight - uiLdr.height) / 2);
}

securityError

事件

事件物件類型: flash.events.SecurityErrorEvent
屬性 SecurityErrorEvent.type = flash.events.SecurityErrorEvent.SECURITY_ERROR

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

在載入內容期間發生了安全性錯誤時傳送。

SecurityErrorEvent.SECURITY_ERROR 常數會定義 securityError 事件物件的 type 屬性值。

這個事件具有下列屬性：

屬性	值
`bubbles`	`false`
`cancelable`	`false`；沒有要取消的預設行為指令。
`currentTarget`	正主動使用事件偵聽程式處理 Event 物件的物件。
`target`	回報安全性錯誤的網路物件。
`text`	要顯示為錯誤訊息的文字。

範例如何使用本範例

UILoaderExample.as

此範例將示範與 UILoader 類別進行簡單的互動。

將 UILoader 的實體放置在舞台上，並將該實體命名為「uiLoader」。
將 Label 的實體放置在 UILoader 實體的上方，並將它命名為「uiLoaderLabel」。
將這個程式碼儲存成 UILoaderExample.as，並與您的 FLA 存放在相同的目錄中。
將 FLA 中的 DocumentClass 設定為 UILoaderExample。

package
{
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.ProgressEvent;

    public class UILoaderExample extends Sprite
    {
        private var sampleImagePath:String = "test.jpg";
        
        public function UILoaderExample() {
            var request:URLRequest = new URLRequest(sampleImagePath);
            uiLoader.scaleContent = false;
            uiLoader.addEventListener(Event.COMPLETE,loadComplete);
            uiLoader.addEventListener(ProgressEvent.PROGRESS,loadProgress);            
            uiLoader.load(request);
        }
        private function loadProgress(e:ProgressEvent):void {
            uiLoaderLabel.text = String(e.target.percentLoaded);
        }
        private function loadComplete(e:Event):void {
            uiLoaderLabel.text = "Load Complete";    
        }
    }
}

法律聲明 | 線上隱私權政策

UILoader - AS3 Flash

類別 x

autoLoad

bytesLoaded

bytesTotal

content

maintainAspectRatio

percentLoaded

scaleContent

source

UILoader

close

getStyleDefinition

load

loadBytes

setSize

unload

complete

init

ioError

open

progress

resize

securityError