int

套件	最上層
類別	public final class int
繼承	int Object

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

int 類別可讓您使用代表 32 位元且具有正負號之整數的資料類型。 int 類別代表之值的範圍會從 -2,147,483,648 (-2^31) 到 2,147,483,647 (2^31-1)。

int 類別的常數屬性 MAX_VALUE 和 MIN_VALUE 都是靜態屬性，這表示您不需要物件即可使用這些屬性，因此不也需要使用建構函式。然而，這些方法並不是靜態的，這表示您需要物件才能使用它們。您可以使用 int 類別建構函式來建立 int 物件，或是宣告 int 類型的變數，並將常值指派給該變數。

int 資料類型適合用於迴圈計數器與其他不需要浮點數的情況，而且與 Java 與 C++ 中的 int 資料類型相似。int 類型變數的預設值為 0

如果您使用的數字超過 int.MAX_VALUE，請考慮使用 Number。

下列範例會呼叫 int 類別的 toString() 方法，以傳回字串 1234：

 var myint:int = 1234;
 myint.toString();

下列範例會在不使用建構函式的情況下，將 MIN_VALUE 屬性的值指定給所宣告的變數：

 var smallest:int = int.MIN_VALUE;

相關 API 元素

公用屬性

	屬性		定義自
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		int(num:Object) 建構函式；會建立新的 int 物件。	int
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		toExponential(fractionDigits:uint):String 使用指數標記法傳回數字的字串形式。	int
		toFixed(fractionDigits:uint):String 會使用定點標記法傳回數字的字串形式。	int
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toPrecision(precision:uint):String 會使用指數標記法或定點標記法，傳回數字的字串形式。	int
		toString(radix:uint):String 傳回 int 物件的字串形式。	int
		valueOf():int 會傳回指定之 int 物件的基本值。	int

公用常數

	常數		定義自
		MAX_VALUE : int = 2147483647 [靜態] 可表示之 32 位元的最大具有正負號整數，也就是 2,147,483,647。	int
		MIN_VALUE : int = -2147483648 [靜態] 可表示之 32 位元的最小具有正負號整數，也就是 -2,147,483,648。	int

建構函式詳細資料

()

建構函式

public function int(num:Object)

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

建構函式；會建立新的 int 物件。使用 int.toString() 和 int.valueOf() 時，您必須使用 int 建構函式。使用 int 物件的屬性時，則不需要使用建構函式。new int 建構函式主要做為預留位置之用。int 物件不同於將參數轉換成基本值的 int() 函數。

參數

num:Object — 所建立之 int 物件的數值，或是要轉換成數字的值。如果沒有提供 value，則預設值為 0。

相關 API 元素

int.toString()
int.valueOf()

範例
如何使用本範例
下列程式碼會建構新的 int 物件：

	 var n1:int = new int(3.4);
	 var n2:int = new int(-10);

方法詳細資訊

toExponential

()

方法

AS3 function toExponential(fractionDigits:uint):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

使用指數標記法傳回數字的字串形式。所謂指數標記法，就是字串會依照 fractionDigits 參數的指定方式，只在小數點前包含一位數，而在小數點後最多可包含 20 位數。

參數

fractionDigits:uint — 介於 0 到 20 之間的整數 (含上下限)，代表所需的小數位數。

傳回值

String

擲回值

RangeError — 如果 fractionDigits 引數在 0 到 20 的範圍外，則會擲回例外。

範例 ( 如何使用本範例 )

下列範例會示範 toExponential(2) 如何在指數標記法中傳回字串。


var num:Number = 315003;
trace(num.toExponential(2)); // 3.15e+5

toFixed

()

方法

AS3 function toFixed(fractionDigits:uint):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會使用定點標記法傳回數字的字串形式。所謂定點標記法，就是字串會依照 fractionDigits 參數中的指定方式，在小數點後包含特定數目的位數。 fractionDigits 參數有效的範圍是從 0 到 20。指定這個範圍以外的值會擲回例外。

參數

fractionDigits:uint — 介於 0 到 20 之間的整數 (含上下限)，代表所需的小數位數。

傳回值

String

擲回值

RangeError — 如果 fractionDigits 引數在 0 到 20 的範圍外，則會擲回例外。

範例 ( 如何使用本範例 )

下列範例會示範 toFixed(3) 如何傳回四捨五入為三位小數的字串。


var num:Number = 7.31343;
trace(num.toFixed(3)); // 7.313

下列範例會示範 toFixed(2) 如何傳回會加入結尾零的字串。


var num:Number = 4;
trace(num.toFixed(2)); // 4.00

toPrecision

()

方法

AS3 function toPrecision(precision:uint):String

語言版本:

ActionScript 3.0

執行階段版本:

Flash Player 9, AIR 1.0, Flash Lite 4

會使用指數標記法或定點標記法，傳回數字的字串形式。此字串將會包含 precision 參數中指定的位數。

參數

precision:uint — 介於 1 與 21 之間的整數 (含上下限)，代表產生的字串中所需的位數。

傳回值

String

擲回值

RangeError — 如果 precision 引數在 1 到 21 的範圍外，則會擲回例外。

範例 ( 如何使用本範例 )

下列範例會示範 toPrecision(3) 如何傳回只有三位數的字串。此字串會使用定點標記法，因為在此並不需要指數標記法。


var num:Number = 31.570;
trace(num.toPrecision(3)); // 31.6

下列範例會示範 toPrecision(3) 如何傳回只有三位數的字串。此字串是使用指數標記法，因為產生的數字未包含定點標記法所需的足夠位數。


var num:Number = 4000;
trace(num.toPrecision(3)); // 4.00e+3

toString

()

方法

AS3 function toString(radix:uint):String

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

會傳回 int 物件的字串形式。

參數

radix:uint — 會指定用於數字到字串轉換的底數 (從 2 到 36)。如果您並未指定 radix 參數，預設值會是 10。

傳回值

String — 字串。

範例
如何使用本範例
下列範例將使用 2 和 8 做為 radix 參數的值，並傳回包含數字 9 之對應表示法的字串。

	 var myint:int = new int(9);
	 trace(myint.toString(2)); // 1001
	 trace(myint.toString(8)); // 11

下列範例會產生十六進位的值。

	 var r:int = new int(250);
	 var g:int = new int(128);
	 var b:int = new int(114);
	 var rgb:String = "0x"+ r.toString(16)+g.toString(16)+b.toString(16);
	 trace(rgb); // 0xfa8072

valueOf

()

方法

AS3 function valueOf():int

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

會傳回指定之 int 物件的基本值。

傳回值

int — int 值。

範例
如何使用本範例
下列範例會產生 numSocks 物件的基本值。

	 var numSocks:int = new int(2);
	 trace(numSocks.valueOf()); // 2

常數詳細資訊

MAX_VALUE

常數

public static const MAX_VALUE:int = 2147483647

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

可表示之 32 位元的最大具有正負號整數，也就是 2,147,483,647。

範例
如何使用本範例
下列 ActionScript 會顯示可表示的最大和最小 int 物件到「輸出」面板：

	trace("int.MIN_VALUE = "+int.MIN_VALUE);
	trace("int.MAX_VALUE = "+int.MAX_VALUE);

這段程式碼會顯示下列的值：

	int.MIN_VALUE = -2147483648
	int.MAX_VALUE = 2147483647

MIN_VALUE

常數

public static const MIN_VALUE:int = -2147483648

語言版本:

ActionScript 3.0

執行階段版本:

AIR 1.0, Flash Player 9, Flash Lite 4

可表示之 32 位元的最小具有正負號整數，也就是 -2,147,483,648。

範例
如何使用本範例
下列 ActionScript 會顯示可表示的最大和最小 int 物件到「輸出」面板：

     trace("int.MIN_VALUE = "+int.MIN_VALUE);
     trace("int.MAX_VALUE = "+int.MAX_VALUE);

這段程式碼會顯示下列的值：

	int.MIN_VALUE = -2147483648
	int.MAX_VALUE = 2147483647

範例如何使用本範例

IntExample.as

下列範例會使用 IntExample 類別來示範如何處理及檢查 int 資料類型的有效性：

在建構函式中宣告兩個 int 變數：a 和 b。
這兩個 int 變數是使用 addIntegers() 方法所加入。
會將 parseInteger() 的結果指定給第三個 int 變數 c，此結果會檢查傳遞給它之字串的有效性，以確定它對於 int 資料類型而言是可接受之範圍中的整數值，而且當它有效時，會傳回等於字串之整數值的 int。
int 變數 a 和 c 是使用 addIntegers() 一起加入。

package {
    import flash.display.Sprite;

    public class IntExample extends Sprite {    
        public function IntExample() {
            var a:int = 512;
            var b:int = -128;
            
            trace(addIntegers(a, b)); // 384

            var c:int = parseInteger("32");
            
            trace(addIntegers(a, c)); // 544
        }
            
        public function addIntegers(a:int, b:int):int {
            return a + b;
        }
        
        public function parseInteger(str:String):int {
            var num:Number = parseInt(str);
            if(!isNaN(num) && num <= int.MAX_VALUE && num >= int.MIN_VALUE) {
                return int(num);
            }
            
            return 0;
        }
        
    }
}

法律聲明 | 線上隱私權政策

int - AS3

類別 x

int

toExponential

toFixed

toPrecision

toString

valueOf

MAX_VALUE

MIN_VALUE