Transform  - AS3

ColorTransform 物件，含有調整整個顯示物件中顏色的值。

相關 API 元素

ColorTransform 物件，代表套用至顯示物件及其所有父物件之根層級中的混合顏色轉換。 如果在不同的層級套用不同的顏色轉換，所有這些轉換都會連接至這個屬性的其中一個 ColorTransform 物件。

相關 API 元素

Matrix 物件，代表顯示物件及其所有父物件之根層級中的混合變形矩陣。 如果在不同的層級套用不同的變形矩陣，這些所有矩陣都會連接至這個屬性的其中一個矩陣。此外，若為在瀏覽器中執行的可調整大小 SWF 內容，這個屬性會列入由於視窗調整大小而造成舞台座標與視窗座標之間產生差異的因素。因此，這個屬性會將區域座標轉換成視窗座標，而其座標空間可能與「舞台」的座標空間不同。

Matrix 物件，含有變更顯示物件之縮放、旋轉和轉移的值。

如果 matrix 屬性設定為某個值 (非 null)，matrix3D 屬性就是 null。而且，如果 matrix3D 屬性設定為某個值 (非 null)，matrix 屬性就是 null。

相關 API 元素

讓使用者存取三維顯示物件的 Matrix3D 物件。Matrix3D 物件代表變形矩陣，會決定顯示物件的位置和方向。Matrix3D 物件也會執行透視投影。

如果 matrix 屬性設定為某個值 (非 null)，matrix3D 屬性就是 null。而且，如果 matrix3D 屬性設定為某個值 (非 null)，matrix 屬性就是 null。

相關 API 元素

讓使用者存取三維顯示物件的 PerspectiveProjection 物件。PerspectiveProjection 物件可以用來修改舞台的透視變形，或將透視變形指定給顯示物件的所有三維子系。

根據舞台檢視和比例 (尺寸)，會將預設的 PerspectiveProjection 物件指定給根物件。

相關 API 元素

Rectangle 物件，定義舞台上顯示物件的矩形邊界。

傳回 Matrix3D 物件，這個物件可以相對於目前顯示物件的空間來轉換指定之顯示物件的空間。您可以使用 getRelativeMatrix3D() 方法，相對於另一個三維顯示物件來移動一個三維顯示物件。

參數

相關 API 元素

1. TransformExample() 建構函式會建立新的 Sprite 物件 target。
2. TransformExample() 建構函式會呼叫 draw() 方法，在 Sprite 中繪製漸層正方形。
3. TransformExample()建構函式會為 Sprite 加入按滑鼠事件偵聽程式，這個偵聽程式是由 clickHandler() 方法處理。
4. clickHandler() 方法會建立新的 Matrix 物件 skewMatrix，並將它設定為套用傾斜效果。另一個矩陣 tempMatrix 會指定給 Sprite 目前的變形矩陣，然後使用 concat() 方法將它與 skewMatrix 合併。這個矩陣是指定給正方形 Sprite 的 transform.matrix 屬性。每當使用者按一下正方形時，就會呼叫 clickHandler()，讓正方形傾斜來修改其形狀。
5. 此外，clickHandler() 方法也會建立新的 ColorTransform 物件。 新 ColorTransform 的 redOffset 屬性會設定為 redOffset 的目前值，並增加 25。同樣地，blueOffset 屬性會減少 25。每按一下，Sprite 的顏色就會改變。

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}