StyleManager

套件	fl.managers
類別	public class StyleManager
繼承	StyleManager Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

StyleManager 類別會提供靜態方法，而這些方法可用來取得並設定組件實體的樣式、整個組件類型的樣式，或 Flash 文件中所有使用者介面組件的樣式。樣式是一些定義為會影響組件顯示方式的值，包括邊框距離、文字格式和外觀元素。

檢視範例

公用屬性

隱藏繼承公用屬性

顯示繼承公用屬性

	屬性		定義自
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		StyleManager() 會建立新的 StyleManager 物件。	StyleManager
		clearComponentStyle(component:Object, name:String):void [靜態] 會移除指定組件的樣式。	StyleManager
		clearStyle(name:String):void [靜態] 會從文件中的所有使用者介面組件移除全域樣式。	StyleManager
		getComponentStyle(component:Object, name:String):Object [靜態] 會取得存在於特定組件的樣式。	StyleManager
		getStyle(name:String):Object [靜態] 會依名稱取得全域樣式。	StyleManager
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		registerInstance(instance:UIComponent):void [靜態] 使用樣式管理員註冊組件實體。	StyleManager
		setComponentStyle(component:Object, name:String, style:Object):void [靜態] 會在某個組件類型的所有實體上設定樣式，例如在 Button 組件的所有實體上設定，或在 ComboBox 組件的所有實體上設定。	StyleManager
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		setStyle(name:String, style:Object):void [靜態] 會針對文件中的所有使用者介面組件設定全域樣式。	StyleManager
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回指定之物件的字串形式。	Object
		valueOf():Object 會傳回指定之物件的基本值。	Object

建構函式詳細資料

()

建構函式

public function StyleManager()

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會建立新的 StyleManager 物件。

方法詳細資訊

clearComponentStyle

()

方法

public static function clearComponentStyle(component:Object, name:String):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會移除指定組件的樣式。

參數

	`component:Object` — 要從其中移除樣式的組件名稱。

	`name:String` — 要移除的樣式名稱。

clearStyle

()

方法

public static function clearStyle(name:String):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會從文件中的所有使用者介面組件移除全域樣式。

參數

name:String — 要移除之全域樣式的名稱。

getComponentStyle

()

方法

public static function getComponentStyle(component:Object, name:String):Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會取得存在於特定組件的樣式。

參數

	`component:Object` — 要在其中尋找要求之樣式的組件實體名稱。

	`name:String` — 要擷取的樣式名稱。

傳回值

Object — 指定之組件的要求樣式。如果找不到指定的樣式，此函數會傳回 null。

getStyle

()

方法

public static function getStyle(name:String):Object

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會依名稱取得全域樣式。

參數

name:String — 要擷取的樣式名稱。

傳回值

Object — 已擷取的全域樣式值。

registerInstance

()

方法

public static function registerInstance(instance:UIComponent):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

使用樣式管理員註冊組件實體。組件實體一經實體化，即可使用樣式管理員進行註冊，以便在樣式變更時獲得通知。組件實體可以註冊以接收有關組件性或全域性樣式變更的通知。

參數

instance:UIComponent — 要註冊以用於樣式管理的組件實體。

setComponentStyle

()

方法

public static function setComponentStyle(component:Object, name:String, style:Object):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會在某個組件類型的所有實體上設定樣式，例如在 Button 組件的所有實體上設定，或在 ComboBox 組件的所有實體上設定。

參數

	`component:Object` — 組件的類型，例如 Button 或 ComboBox。此參數也會接受組件實體，或者可用來識別某個組件類型之所有實體的類別。

	`name:String` — 要設定的樣式名稱。

	`style:Object` — 描述要設定之樣式的樣式物件。

setStyle

()

方法

public static function setStyle(name:String, style:Object):void

語言版本:

ActionScript 3.0

產品版本:

Flash CS3

執行階段版本:

Flash Player 9.0.28.0, AIR 1.0

會針對文件中的所有使用者介面組件設定全域樣式。

參數

	`name:String` — 命名要設定之樣式的字串值。

	`style:Object` — 要設定的樣式物件。這個屬性的值取決於使用者設定的樣式。例如，如果樣式設定為 "textFormat"，style 屬性就必須設定為 TextFormat 物件。樣式名稱和樣式屬性值不相符的情況可能會導致組件的行為表現發生錯誤。

範例如何使用本範例

StyleManagerExample.as

此範例將示範如何以動態方式建立 DataGrid 並偵聽其事件。

若要執行範例，請遵循下列步驟：

將 DataGrid、Button、Label 和 TextArea 組件加入元件庫。
將此程式碼另存為 StyleManagerExample.as，與 FLA 檔放在同一個目錄中。
將 FLA 檔中的 Document 類別設定為 StyleManagerExample。

package
{
    import fl.controls.Button;
    import fl.controls.DataGrid;
    import fl.controls.Label;
    import fl.controls.TextArea;
    import fl.core.UIComponent;
    import fl.managers.FocusManager;
    import fl.managers.StyleManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class StyleManagerExample extends Sprite 
    {
        private var btn:Button;
        private var ta1:TextArea;
        private var ta2:TextArea;
        private var ta3:TextArea;
        private var ta4:TextArea;
        private var description:Label;
        private var dg:DataGrid;
        private var formatForInstance:TextFormat;
        private var formatForGlobal:TextFormat;
        
        private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
        private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
        
        public function StyleManagerExample() {
            setupComponents();
            setupUI();
            setupStyles();
        }
        private function setupUI():void {
            var setInstanceStyleBtn:Button = new Button();
            var clearInstanceStyleBtn:Button = new Button();
            var setClassStyleBtn:Button = new Button();
            var clearClassStyleBtn:Button = new Button();
            var setGlobalStyleBtn:Button = new Button();
            var clearGlobalStyleBtn:Button = new Button();
            
            setInstanceStyleBtn.label = "Set Instance Style";
            clearInstanceStyleBtn.label = "Clear Instance Style";
            setClassStyleBtn.label = "Set Class Style";
            clearClassStyleBtn.label = "Clear Class Style";
            setGlobalStyleBtn.label = "Set Global Style";
            clearGlobalStyleBtn.label = "Clear Global Style";
            setInstanceStyleBtn.focusEnabled = false;
            clearInstanceStyleBtn.focusEnabled = false;
            setClassStyleBtn.focusEnabled = false;
            clearClassStyleBtn.focusEnabled = false;
            setGlobalStyleBtn.focusEnabled = false;
            clearGlobalStyleBtn.focusEnabled = false;
            
            setInstanceStyleBtn.move(10,310);
            clearInstanceStyleBtn.move(10,340);
            setClassStyleBtn.move(140,310);
            clearClassStyleBtn.move(140,340);
            setGlobalStyleBtn.move(270,310);
            clearGlobalStyleBtn.move(270,340);
            setInstanceStyleBtn.setSize(120,24);
            clearInstanceStyleBtn.setSize(120,24);
            setClassStyleBtn.setSize(120,24);
            clearClassStyleBtn.setSize(120,24);
            setGlobalStyleBtn.setSize(120,24);
            clearGlobalStyleBtn.setSize(120,24);
            
            setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
            clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
            setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
            clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
            setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
            clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);

            description = new Label();
            description.move(10, 370);
            description.autoSize = TextFieldAutoSize.LEFT;
            description.text = "";

            addChild(setInstanceStyleBtn);
            addChild(clearInstanceStyleBtn);
            addChild(setClassStyleBtn);
            addChild(clearClassStyleBtn);
            addChild(setGlobalStyleBtn);
            addChild(clearGlobalStyleBtn);
            addChild(description);
        }
        private function setupComponents():void {
            dg = new DataGrid();
            dg.addItem( { Name:"John Alpha",     Number:"555-123-0101" } );
            dg.addItem( { Name:"Mary Bravo",     Number:"555-372-3322" } );
            dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
            dg.addItem( { Name:"Susan Delta",     Number:"555-987-3434" } );        
            dg.move(10,10);
            dg.setSize(200,290);
            dg.columns = ["Name","Number"];
            addChild(dg);
            
            ta1 = new TextArea();
            ta1.move(220,10);
            ta1.setSize(150,140);
            ta1.text = testString;
            ta1.tabEnabled = true;
            addChild(ta1);
            
            ta2 = new TextArea();
            ta2.move(380,10);
            ta2.setSize(150,140);
            ta2.text = testString;
            ta2.tabEnabled = true;
            addChild(ta2);
            
            ta3 = new TextArea();
            ta3.move(220,160);
            ta3.setSize(150,140);
            ta3.text = testString;
            ta3.tabEnabled = true;
            addChild(ta3);
            
            ta4 = new TextArea();
            ta4.move(380,160);
            ta4.setSize(150,140);
            ta4.text = testString;
            ta4.tabEnabled = true;
            addChild(ta4);
        }
        private function setupStyles():void {
            formatForGlobal = new TextFormat();
            formatForGlobal.font = "Georgia";
            formatForGlobal.size = 10;
            formatForInstance = new TextFormat();
            formatForInstance.underline = true;            
        }
        private function setInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.setStyle("textFormat",formatForInstance);    
                description.text = "The TextArea object with focus is now underlined.";            
            }
        }
        private function clearInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.clearStyle("textFormat");
                description.text = "The TextArea object with focus is no longer underlined.";
            }
        }
        private function setClassStyle(e:MouseEvent):void {
            var c:Class = TextArea;
            var styleName:String = "textPadding";
            var value:Number = 10;
            StyleManager.setComponentStyle(c,styleName,value);    
            description.text = "Padding for all TextArea instances is now 10.";
        }
        private function clearClassStyle(e:MouseEvent):void {
            var styleName:String = "textPadding";
            var c:Class = TextArea;
            StyleManager.clearComponentStyle(c,styleName);                    
            description.text = "TextArea padding has been reset to the default.";
        }
        private function setGlobalStyle(e:MouseEvent):void {            
            var styleName:String = "textFormat";
            var value:Object = formatForGlobal;
            StyleManager.setStyle(styleName,value);
            description.text = "All components now use font Georgia size 10.";
        }
        private function clearGlobalStyle(e:MouseEvent):void {
            var styleName:String = "textFormat";
            StyleManager.clearStyle(styleName);    
            description.text = "Font style for all components has been cleared.";
        }
    }
}

法律聲明 | 線上隱私權政策

StyleManager - AS3 Flash

類別 x

StyleManager

clearComponentStyle

clearStyle

getComponentStyle

getStyle

registerInstance

setComponentStyle

setStyle