AccessibilityImplementation  - AS3

指出錯誤碼。在帶外通訊而非在傳回值中指出的錯誤。若要指出錯誤，請將 errno 屬性設定為在 AccessibilityImplementation 常數附錄中所記載的錯誤碼其中之一。這會使得傳回值被忽略。在呼叫 AccessibilityImplementation 方法之前，播放程式永遠都會清除 (設定為零) AccessibilityImplementation 的 errno 屬性。

相關 API 元素

用於建立組件輔助功能虛設常式。如果未經 ActionScript 輔助功能實作即發行組件，Adobe 建議您加入組件輔助功能虛設常式。基於輔助功能的目的，此虛設常式會使 Flash Player 將組件視為單一圖形，而非公開組件中按鈕、文字欄位等的內部結構。

若要建立組件輔助功能虛設常式，請將相關的 AccImpl 類別分成子分類，並以值 true 來覆寫屬性虛設常式。

相關 API 元素

靜態建構函式。不要呼叫 AccessibilityImplementation 的建構函式，來直接實體化 AccessibilityImplementation。而是為每個新組件擴充 mx.accessibility.AccImpl 類別，以建立新的輔助功能實作。

相關 API 元素

IAccessible 方法會執行與組件關聯的預設動作，而該組件是由此 AccessibilityImplementation 或其子元素之一所代表。

只有在 AccessibilityImplementation 代表的 UI 元素在 MSAA 模型中有預設動作時，才實作此方法。

如果您只要為 AccessibilityImplementation 本身或是僅為其子元素實作 accDoDefaultAction()，在某些情況下，您將需要指出已傳遞的特定 childID 沒有預設動作。如果要這麼做，請將 errno 屬性設定為 E_MEMBERNOTFOUND。

參數

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

MSAA 方法適用於傳回 DisplayObject 或 Rectangle，以便在 AccessibilityImplementation 中指定子系元素的範圍框。

此方法從未使用值為零的 childID 來呼叫。如果 AccessibilityImplementation 不會包含子元素，則不應該實作此方法。如果 AccessibilityImplementation 可以包含子元素，這個方法則為強制性。

您通常可以透過傳回代表子元素本身的物件，來滿足此方法的需求。只要子元素為 DisplayObject，此做法便會成功。在這些情況下，只要傳回對應至與顯示清單中相關視覺物件相關聯的實體名稱之 DisplayObject。

如果子元素不適合上述技巧，您可以自行進行範圍框算術，並使用下列項目傳回 Rectangle：x、y、width 和 height 屬性。x 與 y 成員會指定範圍框的左上角，而 width 與 height 成員則會指定其大小。所有四個成員都應該使用「舞台」像素的單位，並相對於 AccessibilityImplementation 所代表的組件原點。x 與 y 屬性可能會有負值，因為 DisplayObject 的原點不需要在其左上角。

如果看不見 childID 所指定的子元素 (也就是該子系的 get_accState 會傳回包括 STATE_SYSTEM_INVISIBLE 的值)，您可以從 accLocation 傳回 null。如果子元素為可見，您也可以傳回代表子元素顯示座標的 Rectangle。

參數

詳細資訊

相關 API 元素

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

用於改變組件中之選擇的 IAccessible 方法，該組件是由此 AccessibilityImplementation 所代表。

childID 參數將永遠不為零。此方法永遠適用於子元素，而非整個組件，Flash Player 會管理整個組件本身的選取範圍。

selFlag 參數是一種位元欄位，包含一或多個選取旗標常數，允許 MSAA 用戶端指出 childID 所參考的項目應如何選取或聚焦。後面會接著選取旗標常數的說明，以及這些常數與輔助功能實作通訊的內容。實際上，在繼承自 Flex mx.accessibility.ListBaseAccImpl 類別之輔助功能實作中此方法的大部分實作，都會忽略 selFlag 常數，並依賴組件的鍵盤選取行為處理多重選取。

selFlag 參數可包含或不包含 SELFLAG_TAKEFOCUS 旗標。如果包含，您應該將子元素焦點設為指定的 childID，而且除非 SELFLAG_EXTENDSELECTION 也存在，否則請將子元素設為選取錨點。如果不包含，子元素焦點與選取錨點應該維持不變，儘管在下方所述的其他旗標可能修改此選取範圍。

selFlag 引數永遠都包含下列四個旗標之一，這會指出要使用哪種選取範圍修改：

• SELFLAG_TAKESELECTION：清除任何現有的選取範圍，並將選取範圍設定為指定的 childID。

• SELFLAG_EXTENDSELECTION：計算在選取錨點與指定的 childID 之間 (包含此兩者) 的子元素範圍。如果 SELFLAG_ADDSELECTION 存在，請將這些子元素全部都新增至選取範圍。如果 SELFLAG_REMOVESELECTION 存在，請將這些子元素全部都從選取範圍移除。如果 SELFLAG_ADDSELECTION 或 SELFLAG_REMOVESELECTION 都不存在，所有這些子元素都應該具有選取範圍錨點的選取範圍狀態：如果選取範圍錨點為已選取狀態，請將這些子元素新增至選取範圍；否則請從選取範圍移除它們。

• SELFLAG_ADDSELECTION (沒有 SELFLAG_EXTENDSELECTION)：將指定的 childID 新增至選取範圍。

• SELFLAG_REMOVESELECTION (沒有 SELFLAG_EXTENDSELECTION)：從選取範圍移除指定的 childID。

請注意對於非可多重選取的組件而言，唯一有效的 selFlag 參數值是 SELFLAG_TAKEFOCUS 與 SELFLAG_TAKESELECTION。理論上，您也可以為允許使用者強制 null 選取範圍的非可多重選取之組件，選擇支援 SELFLAG_REMOVESELECTION，但是實際上大部分非可多重選取的組件並不是以此方式運作，MSAA 用戶端無法嘗試此類型的作業。

如果發生無效的旗標，請將 errno 設為 E_INVALIDARG。

最後，請注意在呼叫 accSelect 時，Flash Player 可確保它具有「主機焦點」(其容器應用程式的視窗焦點)，而且您的組件在 Flash Player 中具有焦點。

參數

詳細資訊

相關 API 元素

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

傳回組件預設動作的 MSAA 方法，該組件是由此 AccessibilityImplementation 或其子元素之一所代表。

只有在 AccessibilityImplementation 代表的 UI 元素在 MSAA 模型中有預設動作時，才實作此方法；請務必確定傳回 MSAA 模型指定的相同字串。例如，Button 組件的預設動作字串是 "Press"。

如果您只要為 AccessibilityImplementation 本身或是僅為其子元素實作 get_accDefaultAction，在某些情況下，您將需要指出已傳遞的特定 childID 沒有預設動作。只要傳回 null 就可以做到。

參數

詳細資訊

相關 API 元素

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

傳回子元素 (如果有的話) 無正負號整數 ID 的 MSAA 方法，該子元素在組件中具有子元素焦點。如果沒有具有子系焦點的子系，此方法會傳回零。

詳細資訊

相關 API 元素

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

傳回組件名稱的 MSAA 方法，該組件是由此 AccessibilityImplementation 或其子元素之一所代表。

在 AccessibilityImplementation 本身的案例中 (childID == 0)，如果未實作此方法或是未傳回值，Flash Player 會使用 AccessibilityProperties.name 屬性值 (如果此屬性值存在)。

對於有子元素的 AccessibilityImplementations，必須實作此方法，而且在 childID 不為零時必須傳回字串值。

視使用者介面元素的類型而定，在 MSAA 中的名稱表示兩件不同事情之一：作者指定的名稱，或是元素的實際文字內容。通常，AccessibilityImplementation 本身會歸類至前者的類別。其 name 屬性是作者指定的名稱。子元素永遠都歸類為第二個類別。其名稱會指出其文字內容。

AccessibilityImplementation 的 name 屬性具有作者指定之名稱的意義，組件從作者取得名稱的方式有兩種。第一種方式需要在組件本身中有名稱；例如，核取方塊組件包括作為其名稱的文字標籤。第二種方式 (第一種方式的後援) 需要在 UI 中指定名稱，並以 AccessibilityProperties.name 做結尾。此後援選項可讓使用者指定名稱，就像為任何其他 Sprite 或 MovieClip 指定名稱一樣。

這使得 AccessibilityImplementation 本身有三種可能性 (childID == zero)：

• 作者在組件中指定名稱。應該實作 get_accName 方法，並且在 childID 為零時應該傳回 AccessibilityImplementation 之名稱的字串值。如果 childID 為零，但是 AccessibilityImplementation 沒有名稱，get_accName 應該傳回空的字串，以防止播放程式回復成 AccessibilityProperties.name 屬性。

• 作者從 UI 指定名稱。 如果 AccessibilityImplementation 可以具有子元素，get_accName 方法應該予以實作，但不應該在 childID 為零時傳回值。如果 AccessibilityImplementation 永遠都不會有子元素，則不應該實作 get_accName。

• 代表內容的名稱。應該實作 get_accName 方法，並且在 childID 為零時應該傳回適當的字串值。如果 childID 為零，但是 AccessibilityImplementation 沒有內容，get_accName 應該傳回空的字串，以防止播放程式回復到 AccessibilityProperties.name 屬性。

請注意對於子元素而言 (如果 AccessibilityImplementation 可以擁有它們)，永遠適用第三種情況。應該實作 get_accName 方法，並且在 childID 為非零時應該傳回適當的字串值。

參數

詳細資訊

相關 API 元素

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

傳回組件系統角色的 MSAA 方法，該組件是由此 AccessibilityImplementation 或其子元素之一所代表。針對 MSAA 中所有組件預先定義的系統角色。

參數

詳細資訊

相關 API 元素

傳回陣列的 MSAA 方法，該陣列包含所有選取子元素的 ID。傳回的陣列可能包含零個、一個或多個 ID，全部都是無正負號的整數。

詳細資訊

相關 API 元素

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

傳回組件目前執行階段狀態的 IAccessible 方法，該組件是由此 AccessibilityImplementation 或其子元素之一所代表。

此方法必須為 MSAA 中的組件傳回零個、一個或多個預先定義的物件狀態常數。當套用多個狀態時，應該使用 | (位元 OR 運算子) 來將狀態常數結合成位元欄位。

若要指出目前未套用任何狀態常數，此方法應該傳回零。

您不應該追蹤或回報 STATE_SYSTEM_FOCUSABLE 或 STATE_SYSTEM_FOCUSED 狀態。Flash Player 會自動處理這些狀態。

參數

詳細資訊

相關 API 元素

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

傳回組件執行階段值的 MSAA 方法，該組件是由此 AccessibilityImplementation 或其子元素之一所代表。

只有在 AccessibilityImplementation 代表的 UI 元素在 MSAA 模型中擁有值時，才實作此方法。請注意有些具有明顯「值」的 UI 元素，實際上會透過不同方式來公開此值，例如 get_accName (例如，文字)、get_accState (例如，核取方塊) 或 get_accSelection (例如，清單方塊)。

如果您只要為 AccessibilityImplementation 本身或是僅為其子元素實作 get_accValue，在某些情況下，您將需要指出已傳遞的特定 childID 沒有值的概念。只要傳回 null 就可以做到。

參數

詳細資訊

相關 API 元素

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

傳回陣列，其中包含 AccessibilityImplementation 所有子元素的無正負號整數 ID。

陣列的長度有可能是零。陣列中的 ID 應該以和其所代表的子元素之相同邏輯順序顯示。如果 AccessibilityImplementation 可以包含子元素，這個方法則為強制性，否則，請勿實作它。

在指定子 ID 給子元素時，請使用會保留 AccessibilityImplementation 每個實體中唯一性的配置。子 ID 不必是連續的，而且其順序不必符合子元素的邏輯順序。您應該加以排列，才「不會」重複使用子 ID；如果刪除子元素，在該 AccessibilityImplementation 實體的存留期間不應該再使用其 ID。請注意，因為 Flash Player 程式碼中實作選擇的關係，如果您使用超過一百萬的子 ID，可能會產生不想要的行為。

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

傳回 true 或 false，以指出具有由 x、y、width 與 height 所指定之範圍框的文字物件，是否應該被視為此 AccessibilityImplementation 所代表之組件的標籤。

x 與 y 座標是相對於 AccessibilityImplementation 套用之組件的左上角，也可能是負數。所有座標都是以「舞台」像素為單位。

此方法允許將可存取的組件整合至 Flash Player 的搜尋，以尋找自動標籤關係，這允許物件外部的文字提供物件的名稱。之所以提供此方法，是因為辨識標籤的準則，會隨不同組件而異。如果您實作此方法，您應該以使用幾何準則為目標，這個準則類似於在播放程式的程式碼內部，為按鈕與文字欄位所使用的準則。這些準則如下所示：

• 對於按鈕，任何完整位於按鈕內部的文字都會視為標籤。
• 對於文字欄位，任何顯示在上方附近與靠左對齊的文字，或是左邊附近的文字，都會視為標籤。

如果 AccessibilityImplementation 代表的組件不應該參與自動標籤關係，請勿實作 isLabeledBy。這會等於永遠傳回 false。不應該實作 isLabeledBy 的一種情況，請參考當 AccessibilityImplementation 歸類為「組件中作者指定的名稱」案例時 (如上方 get_accName 之下所述)。

請注意，這個方法未根據任何 IAccessible 方法；它是 Flash 特有的方法。

參數